SUM 函數

SUM 函數是數學與三角函數之一,會將所有值相加。您可以新增個別的值、儲存格參照或範圍,或混合新增這三種。

例如:

  • =SUM(A2:A10)

  • =SUM(A2:A10, C2:C10)

您的瀏覽器不支援視訊。請安裝 Microsoft Silverlight、Adobe Flash Player 或 Internet Explorer 9。

此影片是名為在 Excel 2013 中將數字相加之訓練課程的一部分。

SUM(number1,[number2],...)

引數名稱

描述

number1    (必填)

您要新增的第一個數字。這個數字可以是 4,一個 儲存格參照,像是 B6,或一個儲存格 範圍,像是 B2:B8。

number2-255    (選填)

這是您要新增的第二個數字。您可以用這種方式來指定最多 255 個數字。

若要快速取得儲存格範圍的「加總」,您只要選取範圍並查看 Excel 視窗的右下角即可。

選取儲存格範圍之後查看狀態列的螢幕擷取畫面
狀態列


這是狀態列,它會顯示有關您選取的任何項目的資訊 (無論您選取的是單一儲存格或多個儲存格)。如果您在狀態列上按一下滑鼠右鍵,將會在快顯功能對話方塊中顯示所有您可選取的選項。請注意,如果您有選取屬性,這裡就會顯示所選範圍之相對應的值。深入了解狀態列。

在工作表中新增加總公式最簡單的方法就是使用自動加總精靈。直接在您要加總的範圍的上方或下方選取空白儲存格,然後在功能區的 [常用] 或 [公式] 索引標籤中,按一下 [自動加總] > [加總]。自動加總精靈會自動感應要加總的範圍,並為您建立公式。如果您在要加總的範圍的左側或右側選取一個儲存格,此精靈也能以水平的方式運作。請注意,此精靈在非連續的範圍無法運作,但我們將在下節說明。

您可以使用自動加總精靈自動建立加總公式。請在您要加總的範圍上方/下方或左方/右方選取一個範圍,然後移至功能區的 [公式] 索引標籤選取 [自動加總] > [加總]。
使用自動加總精靈快速加總連續範圍


[自動加總] 對話方塊也可讓您選取其他常用函數如下:

垂直自動加總

儲存格 B6 顯示自動加總的加總公式︰=SUM(B2:B5)

自動加總精靈已自動偵測到儲存格 B2:B5 是要加總的範圍。您只需要按 Enter 鍵確認即可。如果您需要新增/排除更多儲存格,您可以按住 Shift 鍵 > 所需的方向鍵,直到選取範圍符合您的需要為止,並在完成後按 Enter 鍵。

Intellisense 函數指南:在函數底下的 SUM(number1,[number2], …) 浮動標籤為其 Intellisense 指南。如果您按一下 SUM 或函數名稱,它會變成藍色超連結,帶您前往該函數的 [說明] 主題。如果您按一下個別的函數元素,則會醒目提示它們在公式中的代表片段。在此情況下,由於此公式中只有一種數字參照,因此只會醒目提示 B2:B5。任何函數都會顯示 Intellisense 標籤。

水平自動加總

儲存格 D2 顯示自動加總的加總公式︰=SUM(B2:C2)

對非連續範圍使用 SUM。儲存格 C8 的公式是 =SUM(C2:C3,C5:C6)。您也可以使用已命名的範圍,這麼一來公式就會像這樣:=SUM(第 1 週,第 2 週)。

自動加總精靈一般只適用於連續範圍,因此如果加總範圍中存有空白列或欄,Excel 會在第一個空白處就停止運作。在這種情況下,您需要依據選取範圍執行加總,也就是在其中逐一新增個別的範圍。在此範例中,若在儲存格 B4 中已有資料,由於 Excel 會辨識連續範圍,因此 Excel 會產生 =SUM(C2:C6)

您可以使用 Ctrl+按一下滑鼠左鍵,快速選取多個非連續範圍。首先,請輸入 “=SUM(“,然後選取不同的範圍,Excel 就會自動為您在各個範圍之間新增逗號分隔符號。完成後,請按 Enter 鍵。

祕訣:您可以使用 ALT+ = 將 SUM 函數快速新增至儲存格中。接著,您只需要選取一個或多個範圍即可。

附註:您可能會注意到 Excel 已依據色彩醒目提示不同的函數範圍,而它們在公式本身之中相符,因此 C2:C3 是某種色彩,而 C5:C6 是另一種色彩。除非參照範圍位於不同的工作表或不同的活頁簿中,否則 Excel 對所有函數的做法都是如此。若是具有輔助技術的進階協助工具,您可以使用具名的範圍 (例如 “第 1 週”、“第 2 週” 等),然後在您的公式中參照它們:

=SUM(第 1 週,第 2 週)

您可以使用 Excel 輕鬆地執行單純的數學運算,也可以搭配 Excel 函數 (例如 SUM) 使用。下表列出了一些可用的運算子及相關函數。您可以使用鍵盤上的數字列或 10 鍵鍵盤 (如果有的話) 來輸入這些運算子。舉例來說,Shift+8 會輸入乘法用的星號 (*)。

運算子

運算

範例

+

加法

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

減法

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

乘法

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1,1) - PRODUCT 函數

/

除法

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1,1) - QUOTIENT 函數

^

乘冪

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1,1) - POWER 函數

如需詳細資訊,請參閱用 Excel 當計算機

其他範例

  1. 假設您要將「百分比折扣」套用到已加總的儲存格範圍。

    SUM 與運算子搭配使用。儲存格 B16 中的公式是 =SUM(A2:A14)*-25%。這個公式可以改成正確的結構,方法是將 -25% 改成儲存格參照,例如 =SUM(A2:A14)*E2
    • =SUM(A2:A14)*-25%

    會算出已加總範圍的 25%,不過它會用硬式編碼將 25% 寫入公式中,日後若要變更時可能會難以尋找。將 25% 改成放在一個儲存格中並參照該儲存格,會比較理想。這樣就會位於開放且容易變更之處,例如:

    • =SUM(A2:A14)*E2

    若要將乘法改為除法,您只要用 “/” 取代 “*” 即可:=SUM(A2:A14)/E2

  2. 在加總中執行加法或減法

    i. 您可以使用 + 或 - 在加總中輕鬆執行「加法」或「減法」,例如:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

本節將探討使用 SUM 函數的一些最佳做法。其中大多也可以應用於使用其他函數。

=1+2 或 =A+B 方法 – 雖然您可以輸入 =1+2+3 或 =A1+B1+C2,並取得完全正確的結果,但這些方法會因為一些原因而容易出錯:

  1. 錯字 – 請想像當您嘗試輸入類似以下的多個和/或更大的值時:

    • =14598.93+65437.90+78496.23

    然後嘗試驗證您的輸入都正確。請將這些值放在個別的儲存格並使用加總公式,這樣會容易得多。此外,當這些值在儲存格中時,您可以將它們格式化,以便在公式中能夠更容易讀取。

    使用 SUM 函數,而不要將數值硬性寫入公式中。儲存格 D5 中的公式是 =SUM(D2:D4)
  2. 參照文字 (而不是數字) 導致的 #VALUE! 錯誤

    如果您使用類似以下的公式:

    • =A1+B1+C1=A1+A2+A3

    不佳的公式結構範例。儲存格 D2 中的公式是 =A2+B2+C2

    如果參照的儲存格中有任何會傳回 #VALUE! 錯誤的非數字 (文字) 值,您的公式則會中斷。加總會略過文字值並只提供數值的加總。

    正確的公式結構。儲存格 D2 中的公式不是 =A2+B2+C2,而是 =SUM(A2:C2)
  3. 刪除列或欄的 #REF! 錯誤

    刪除欄所造成的 #REF! 錯誤。公式已變更為 =A2+#REF!+B2

    如果您刪除列或欄,公式不會更新排除刪除列的值,而是會傳回 #REF! 錯誤,不過使用 SUM 函數會自動更新。

    SUM 函數會根據插入或刪除的列與欄自動調整
  4. 插入列或欄時,公式不會更新參照

    =A+B+C 公式在新增列時不會更新

    如果您插入列或欄,公式將不會更新包含新增列的值,不過使用 SUM 函數就會自動更新 (只要不是在公式參照的範圍之外)。尤為重要的是如果您預期公式會更新但並未更新,這樣會使結果不完整,而且您可能不會發現。

    範例說明插入欄時 SUM 公式自動從 =SUM(A2:C2) 延伸至 =SUM(A2:D2)
  5. 以個別儲存格參照與範圍執行加總

    使用類似以下的公式:

    • =SUM(A1,A2,A3,B1,B2,B3)

    在參照的範圍之中插入或刪除列時,也會因為相同的原因而容易出錯。使用個別範圍會比較理想,例如:

    • =SUM(A1:A3,B1:B3)

    在新增或刪除列時,它會更新。

  1. 您當然可以搭配其他函數使用加總。下列是建立每月平均值的計算之範例:

    搭配其他函數使用 SUM。儲存格 M2 中的公式是 =SUM(A2:L2)/COUNTA(A2:L2)。備註:為了便於理解,May ( 5 月) 欄到 November (11 月) 欄已設為隱藏。
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. 這會取出 A2:L2 的 SUM (加總),除以 A2:L2 中非空白儲存格的計數 (五月至十二月是空白的)。

  1. 您有時會需要加總多個工作表上的特定儲存格。您可能會想採取的做法是,按一下所要的各個工作表及儲存格,然後用 “+” 將儲存格的值相加。不過,那樣的做法冗長且容易出錯。

    • =Sheet1!A1+Sheet2!A1+Sheet3!A1

    您可以使用 3D 或 3-Dimensional (三維) 加總,更輕鬆地完成操作:

    3D 加總:儲存格 D2 中的公式是 =SUM(Sheet1:Sheet3!A2)
    • =SUM(Sheet1:Sheet3!A1)

    這會加總所有工作表 (工作表 1 至工作表 3) 中的儲存格 A1。

    當您針對各個月份有一個單一工作表時 (一月至十二月),而您需要在一個摘要工作表上將它們加總,這種情況下此功能會相當實用。

    橫跨多個已命名工作表的 3D SUM。D2 中的公式是 =SUM(1 月:12 月!A2)
    • =SUM(1 月:12 月!A2)

    這會加總從 1 月至 12 月各個工作表的儲存格 A2。

    附註: 如果您的工作表在名稱中含有空格 (例如 “1 月銷售”),在公式中參照工作表名稱時,就需要使用單引號。請注意,要在第一個工作表名稱的「前面」,以及最後一個工作表名稱的「後面」加上單引號。

    • =SUM(‘1 月銷售:12 月銷售’!A2)

    3D 方法也可搭配其他函數使用,例如 AVERAGE、MIN、MAX 等︰

    • =AVERAGE(Sheet1:Sheet3!A1)

    • =MIN(Sheet1:Sheet3!A1)

    • =MAX(Sheet1:Sheet3!A1)

問題

錯在哪裡

我的 SUM 函數會顯示 #####,而不是結果。

檢查您的欄寬。##### 通常表示欄太窄,無法顯示公式結果。

我的 SUM 函數會以文字顯示公式本身,而不是結果。

檢查儲存格的格式未設定為文字。選取有問題的儲存格或範圍,然後使用 Ctrl+1 叫出 [儲存格格式] 對話方塊,然後按一下 [數值] 索引標籤,然後選取您想要的格式。如果儲存格的格式設定為文字,而且在您變更格式之後也不會改變,您可能需要使用 F2 > Enter 來強迫變更格式。

我的 SUM 函數不會更新。

確定已將 [計算] 設為 [自動]。在 [公式] 索引標籤移至 [計算選項]。您也可以使用 F9 強迫計算工作表。

確定已將 [計算] 設為 [自動]。從 [公式] 索引標籤移至 [計算選項]。

沒有相加某些值。

函數只會相加函數參照或範圍中的數值。空白儲存格、邏輯值 (例如 TRUE) 或文字都會被忽略。

出現 #NAME? 錯誤,而非預期的結果。

這通常表示公式拼錯,像是拼為 =sume(A1:A10),而不是 = SUM(A1:A10)。

我的 SUM 函數在應該顯示小數點時顯示了整數

請檢查您的儲存格格式,確定會顯示小數點。選取有問題的儲存格或範圍,然後使用 Ctrl+1 開啟 [儲存格格式] 對話方塊,然後按一下 [數值] 索引標籤,並選取您想要的格式,確保小數位數在您想要的位置上。

  1. 我只想要相加/相減/相乘/除以數字 請在 Excel 中的基本數學用 Excel 當計算機上觀看這系列影片。

  2. 我要如何顯示更多/較少的小數位數? 您可以變更您的數值格式。選取有問題的儲存格或範圍,然後使用 Ctrl+1 開啟 [儲存格格式] 對話方塊,然後按一下 [數值] 索引標籤,並選取您想要的格式,確保小數位數在您想要的位置上。

  3. 我要如何加上或減去時間? 您可以用幾種不同的方法加上及減去時間。舉例來說,若要得到 8:00 AM - 12:00 PM 之間的差以計算工資,您可以使用:=("12:00 PM"-"8:00 AM")*24,將結束時間減去開始時間。請注意,Excel 會將時間計算為一天的分數,因此您必須乘以 24,才能得到總時數。在第一個範例中,我們使用 =((B2-A2)+(D2-C2))*24,取得從一天開始到結束,不包括午休在內的總時數 (共 8.50 小時)。

    如果您只是想加上時間,且想要以小時和分鐘顯示,那麼您就只要加總,而不需要乘以 24。我們在第二個範例使用 =SUM(A6:C6),因為我們只需要分派工作的總小時和分鐘數 (5:36 或 5 小時 36 分鐘)。

    計算時間

    如需詳細資訊,請參閱:加上或減去時間

  4. 我要如何取得日期之間的差? 和時間一樣,您可以加上及減去日期。以下是計算兩個日期之間的天數時相當常見的範例。=B2-A2,就是這麼簡單。處理日期與時間的關鍵都是,從結束日期/時間開始,然後減去開始日期/時間。

    計算兩個日期之間差了多少天

    如需更多處理日期的方式,請參閱︰計算兩個日期之間的天數

  5. 我要如何加總可見儲存格?有時候,您會手動隱藏列或使用 [自動篩選] 顯示特定資料,您可能會想只加總可見的儲存格。您可以使用 SUBTOTAL 函數。如果您在 Excel 表格中使用合計列,您從 [合計] 下拉式清單中選取的任何函數會自動輸入成小計。請參閱更多關於如何合計 Excel 表格中的資料

需要更多協助嗎?

您可以隨時詢問 Excel 技術社群中的專家、在 Answers 社群取得支援,或是在 Excel User Voice 上建議新功能或增強功能。

另請參閱

觀看有關如何使用 SUM 函數的影片

SUMIF 函數只會將符合一項條件的值相加

SUMIFS 函數只會將符合多個準則的值相加

COUNTIF 函數只會計算符合單一準則的值

COUNTIFS 函數只會計算符合多個準則的值

Excel 中的公式概觀

如何避免公式出錯

尋找並校正公式中的錯誤

Windows 版 Excel 中的鍵盤快速鍵

Mac 版 Excel 中的鍵盤快速鍵

數學與三角函數

Excel 函數 (按字母排序)

Excel 函數 (依類別)

擴展您的技能
探索訓練
優先取得新功能
加入 Office 測試人員

這項資訊有幫助嗎?

感謝您的意見反應!

感謝您的意見反應! 我們將協助您與其中一位 Office 支援專員連絡以深入了解您的意見。

×