COUNTIF 函數

COUNTIF 是統計函數之一,用來計算符合準則的儲存格數目,例如計算特定縣市出現在客戶清單的次數。

以其最簡單的形式而言,COUNTIF 表示:

  • =COUNTIF(要查看的位置?要尋找的項目?)

例如:

  • =COUNTIF(A2:A5,"倫敦")

  • =COUNTIF(A2:A5,A4)

您的瀏覽器不支援視訊。請安裝 Microsoft Silverlight、Adobe Flash Player 或 Internet Explorer 9。

COUNTIF(range, criteria)

引數名稱

描述

range    (必要)

您要計算的儲存格群組。Range 可以包含數字、陣列、具名範圍或含有數字的參照。空白或文字值會遭到忽略。

了解如何選取工作表中的範圍

criteria    (必要)

決定要將哪些儲存格列入計算的數字、運算式、儲存格參照或文字字串。

例如,您可以使用數字 (如 32)、比較式 (如 ">32")、儲存格 (如 B4) 或字詞 (如 "apples")。

COUNTIF 只使用單一準則。如果您想要使用多個準則,請使用 COUNTIFS

範例

若要在 Excel 中使用這些範例,請複製下表中的資料,將其貼到新工作表的儲存格 A1 中。

資料

資料

apples

32

oranges

54

peaches

75

apples

86

公式

描述

=COUNTIF(A2:A5,"apples")

計算儲存格 A2 到 A5 中有 apples 的儲存格個數。結果為 2。

=COUNTIF(A2:A5,A4)

計算儲存格 A2 到 A5 中有 peaches (A4 中的值) 的儲存格個數。結果為 1。

=COUNTIF(A2:A5,A2)+COUNTIF(A2:A5,A3)

計算儲存格 A2 到 A5 中的 apples (A2 中的值) 與 oranges (A3 中的值) 數量。結果為 3。此公式使用 COUNTIF 兩次以指定多個準則,一個運算式一個準則。此外,您也可以使用 COUNTIFS 函數。

=COUNTIF(B2:B5,">55")

計算儲存格 B2 到 B5 中值大於 55 的儲存格個數。結果為 2。

=COUNTIF(B2:B5,"<>"&B4)

計算儲存格 B2 到 B5 中值不等於 75 的儲存格個數。& 字元合併比較運算子 "<>" (不等於) 和 B4 中的值,解譯為 =COUNTIF(B2:B5,"<>75")。結果為 3。

=COUNTIF(B2:B5,">=32")-COUNTIF(B2:B5,">85")

計算儲存格 B2 到 B5 中值大於 (>) 或等於 (=) 32,且小於 (<) 或等於 (=) 85 的儲存格個數。結果為 3。

=COUNTIF(A2:A5,"*")

計算儲存格 A2 到 A5 中包含任何文字的儲存格個數。萬用字元 * 用來比對任何字元。結果為 4。

=COUNTIF(A2:A5,"?????es")

計算儲存格 A2 到 A5 中有剛好 7 個字元且以 "es" 字母結尾的儲存格個數。問號 (?) 做為萬用字元使用時,可用來比對個別字元。結果為 2。

常見問題

問題

錯在哪裡

針對長字串傳回錯誤值。

當您使用 COUNTIF 函數比對長度大於 255 個字元的字串時,該函數會傳回不正確的結果。

如要比對長於 255 個字元的字串,請使用 CONCATENATE 函數或串連運算子 &。例如,=COUNTIF(A2:A5,"long string"&"another long string")。

當您預期有值時,卻沒有值傳回。

請確定有使用引號括住 criteria 引數。

參照另一個工作表時,COUNTIF 公式收到 #VALUE! 錯誤。

當公式內的函數參照已關閉之活頁簿中的儲存格或範圍並計算儲存格時,就會發生此錯誤。 若要讓此功能正常運作,另一個活頁簿必須也是開啟狀態。

最佳做法

請執行此動作

理由

請注意,COUNTIF 會忽略文字字串中的大寫和小寫。

Criteria 不區分大小寫。換句話說,字串 "apples" 與字串 "APPLES" 會符合相同的儲存格。

使用萬用字元。

您可以在 criteria 中使用萬用字元 (問號 (?) 和星號 (*))。問號可比對任何單一字元。星號可比對任何一串字元。如果您要尋找實際的問號或星號,請在該字元前輸入波狀符號 (~)。

例如,=COUNTIF(A2:A5,"apple?") 會計算所有包含 "apple" 但僅最後一個字母不同的例項。

請確定您的資料沒有包含錯誤的字元。

計算文字值時,請確定資料不包含前置空格、結尾空格、不成對的直引號及彎引號,以及非列印字元。否則,COUNTIF 可能會傳回非預期的值。

嘗試使用 CLEAN 函數TRIM 函數

為方便起見,使用具名的範圍

COUNTIF 支援在公式中使用具名範圍 (例如 =COUNTIF(fruit,">=32")-COUNTIF(fruit,">85")。具名的範圍可以位在目前工作表、相同活頁簿的另一個工作表或不同的活頁簿的另一個工作表。若要從另一個活頁簿參照,也必須開啟第二個活頁簿。

附註: COUNTIF 函數無法根據儲存格背景或字型色彩計算儲存格數目。不過,Excel 支援使用者定義函數 (UDF) 使用 Microsoft Visual Basic for Applications (VBA) 根據背景或字型色彩進行計算儲存格數目的作業。下列範例說明如何使用 VBA 計算設為特定色彩的儲存格數目

需要更多協助嗎?

您可以隨時詢問 Excel 技術社群中的專家、在 Answers 社群取得支援,或是在 Excel User Voice 上建議新功能或增強功能。

請參閱

若要計算非空白的儲存格數目,請使用 COUNTA 函數

若要使用多個準則來計算儲存格數目,請使用 COUNTIFS 函數

觀看有關如何使用 COUNTIFS 函數的影片

SUMIF 函數只會將符合單一準則的值相加

SUMIFS 函數只會將符合多個準則的值相加

IFS 函數 (Office 365、Excel 2016 及更新版本)

使用 TRIM 函數移除儲存格中的前置和尾端空格

使用 CLEAN 函數移除儲存格中的非列印字元

Excel 公式概觀

如何避免公式出錯

偵測公式中的錯誤

統計函數

Excel 函數 (按字母排序)

Excel 函數 (依類別)

使用 SUMIF、COUNTIF 和相關函數進行快速資料分析 (免費預覽)

擴展您的技能
探索訓練
優先取得新功能
加入 Office 測試人員

這項資訊有幫助嗎?

感謝您的意見反應!

感謝您的意見反應! 我們將協助您與其中一位 Office 支援專員連絡以深入了解您的意見。

×