使用函數將文字分割至不同的資料行

使用函數將文字分割至不同的資料行

重要:  本文係由機器翻譯而成,請參閱免責聲明。本文的英文版本請見這裡,以供參考。

您可以使用 LEFT、MID、RIGHT、SEARCH 及 LEN 等文字函數來操作資料中的文字字串。例如,您可以將名字、中間名及姓氏從單一儲存格分配到三個不同的欄中。

使用文字函數分配名稱元件的關鍵,在於每個字元在文字字串內的位置。文字字串內的空格位置相當重要,因為它們代表字串中名稱元件的開頭或結尾。

例如,儲存格只包含名字和姓氏時,姓氏的開頭會在第一個空格實例的後面。您清單中的某些名稱可能會含有中間名,在此情況下,姓氏的開頭會在第二個空格實例的後面。

本文說明如何使用這些便利的函數從多種名稱格式中擷取多個元件。您也可以使用資料剖析精靈將文字分割至不同的欄

範例名稱

描述

名字

中間名

姓氏

後稱謂

1

Jeff Smith

無中間名

Jeff

Smith

2

Eric S. Kurjan

中間名縮寫

Eric

S.

Kurjan

3

Janaina B. G. Bueno

兩個中間名縮寫

Janaina

B. G.

Bueno

4

Kahn, Wendy Beth

姓氏置前,姓氏後有逗號

Wendy

Beth

Kahn

5

Mary Kay D. Andersen

由兩個部分組成的名字

Mary Kay

D.

Andersen

6

Paula Barreto de Mattos

由三個部分組成的姓氏

Paula

Barreto de Mattos

7

James van Eaton

由兩個部分組成的姓氏

James

van Eaton

8

Bacon Jr., Dan K.

姓氏和後稱謂放在前面,逗號在其後

Dan

K.

Bacon

Jr.

9

Gary Altman III

含有後稱謂

Gary

Altman

III

10

Mr. Ryan Ihrig

含有前稱謂

Ryan

Ihrig

11

Julie Taft-Rider

以連字號連接的姓氏

Julie

Taft-Rider

附註: 在下列範例圖形中,全名中醒目提示的部分就是 SEARCH 公式所尋找的字元。

範例 1:分隔 Jeff 與 Smith

此範例分隔兩個元件:名字與姓氏。這兩個名稱是由一個空格分隔。

在表格中複製儲存格,並貼入 Excel 工作表的 A1 儲存格中。左側的公式會一併顯示公式本身以供您參考,而右側的公式則會由 Excel 自動轉換為正確的結果。

提示   :將資料貼到工作表之前,請先將 A 欄和 B 欄的欄寬設為 250。

範例名稱

描述

Jeff Smith

無中間名

公式

結果 (名字)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

公式

結果 (姓氏)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 名字

    名字的開頭是字串的第一個字元 (J),結尾是第五個字元 (空格)。公式會傳回 A2 儲存格中,從左算起的五個字元。

    用於擷取名字的公式

    使用 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋空格的數值位置,從左邊開始算起。

  2. 姓氏

    姓氏的開頭是空格,離右邊有五個字元,結尾是最後一個字元 (h)。公式擷取的是 A2 裡從右邊開始算起的五個字元。

    用於擷取姓氏的公式

    使用 SEARCH 與 LEN 函數尋找 num_chars 的值:

    在 A2 中搜尋空格的數值位置,從左邊開始算起。(5)

  3. 計算文字字串的總長度,然後減去在步驟 1 中算出的第一個空格左側的字元數。

頁面頂端

範例 2:Eric S. Kurjan:擷取名字、姓氏與中間名

此範例使用的是姓名、中間名縮寫和姓氏。各個名稱元件以一個空格隔開。

在表格中複製儲存格,並貼入 Excel 工作表的 A1 儲存格中。左側的公式會一併顯示公式本身以供您參考,而右側的公式則會由 Excel 自動轉換為正確的結果。

提示   :將資料貼到工作表之前,請先將 A 欄和 B 欄的欄寬設為 250。

範例名稱

描述

Eric S. Kurjan

中間名縮寫

公式

結果 (名字)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

公式

結果 (中間名縮寫)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

公式

即時結果 (姓氏)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. 名字

    名字的開頭是從左邊數來的第一個字元 (E),結尾是第五個字元 (即第一個空格)。公式擷取的是 A2 裡從左邊開始算起的前五個字元。

    用於分隔名字、姓氏與中間名縮寫的公式

    使用 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋空格的數值位置,從左邊開始算起。(5)

  2. 中間名

    中間名的開頭是第六個字元位置 (S),結尾是第八個位置 (即第二個空格)。此公式使用巢狀 SEARCH 函數,尋找第二個空格實例。

    公式擷取的是從第六個位置開始算起的三個字元。

    用於分隔名字、中間名及姓氏的公式細節

    使用 SEARCH 函數尋找 start_num 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(5)

  3. 加 1 可得出第一個空格後的字元 (S) 位置。此數值位置是中間名的起始位置。(5 + 1 = 6)

    使用巢狀 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(5)

  4. 加 1 可得出第一個空格後的字元 (S) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格實例。(5 + 1 = 6)

  5. 在 A2 中搜尋第二個空格實例,從步驟 4 得出之第六個位置 (S) 開始算起。此字元數是中間名的結尾位置。(8)

  6. 在 A2 中搜尋空格的數值位置,從左邊第一個字元開始算起。(5)

  7. 用步驟 5 得出之第二個空格之字元數,減去步驟 6 得出之第一個空格的字元數。結果得出 MID 從文字字串所擷取的字元數,從步驟 2 得出之第六個位置開始算起。(8 – 5 = 3)

  8. 姓氏

    姓氏的開頭是從右邊數來的第六個字元 (K),結尾是右邊數來的第一個字元 (n)。此公式使用巢狀 SEARCH 函數,尋找第二個及第三個空格實例 (即是從左邊數來的第五個和第八個位置)。

    公式擷取的是 A2 裡從右邊開始算起的六個字元。

    用於分隔名字、中間名及姓氏之公式中的第二個 Search 函數

  9. 使用 LEN 及巢狀 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋空格的數值位置,從左邊第一個字元開始算起。(5)

  10. 加 1 可得出第一個空格後的字元 (S) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格實例。(5 + 1 = 6)

  11. 在 A2 中搜尋第二個空格實例,從步驟 2 得出之第六個位置 (S) 開始算起。此字元數是中間名的結尾位置。(8)

  12. 計算 A2 中文字字串的總長度,然後減去在步驟 3 中由左算至第二個空格實例的字元數。結果得出從全名右部分所擷取的字元數。(14 – 8 = 6)

頁面頂端

範例 3:Janaina B. G. Bueno

以下為您示範如何擷取兩個中間名縮寫。名稱元件會由第一個和第三個空格實例隔開。

在表格中複製儲存格,並貼入 Excel 工作表的 A1 儲存格中。左側的公式會一併顯示公式本身以供您參考,而右側的公式則會由 Excel 自動轉換為正確的結果。

提示   :將資料貼到工作表之前,請先將 A 欄和 B 欄的欄寬設為 250。

範例名稱

描述

Janaina B. G. Bueno

兩個中間名縮寫

公式

結果 (名字)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

公式

結果 (中間名縮寫)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

公式

即時結果 (姓氏)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. 名字

    名字的開頭是從左邊數來的第一個字元 (J),結尾是第八個字元 (即第一個空格)。公式擷取的是 A2 裡從左邊開始算起的前八個字元。

    用於分隔名字、姓氏及兩個中間名縮寫的公式

    使用 Search 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(8)

  2. 中間名

    中間名的開頭是第九個位置 (B),結尾是第十四個位置 (即第三個空格)。此公式使用巢狀 SEARCH 函數,尋找分別位於第八個、第十一個及第十四個位置的第一個、第二個及第三個空格實例。

    公式擷取的是從第九個位置開始算起的五個字元。

    用於分隔名字、姓氏及兩個中間名縮寫的公式

    使用 SEARCH 函數尋找 start_num 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(8)

  3. 加 1 可得出第一個空格後的字元 (B) 位置。此數值位置是中間名的起始位置。(8 + 1 = 9)

    使用巢狀 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(8)

  4. 加 1 可得出第一個空格後的字元 (B) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格實例。(8 + 1 = 9)

  5. 在 A2 中搜尋第二個空格,從步驟 4 得出的第九個位置 (B) 開始算起。(11)

  6. 加 1 可得出第一個空格後的字元 (G) 位置。這個字元數是一起始位置,您從這裡開始搜尋第三個空格。(11 + 1 = 12)

  7. 在 A2 中搜尋第三個空格,從步驟 6 得出之第十二個位置開始算起。(14)

  8. 在 A2 中搜尋第一個空格的數值位置。(8)

  9. 用步驟 7 得出之第三個空格之字元數,減去步驟 6 得出之第一個空格的字元數。結果得出 MID 從文字字串擷取的字元數,從步驟 2 得出之第九個位置開始算起。

  10. 姓氏

    姓氏的開頭是從右邊數來的第五個字元 (B),結尾是右邊數來的第一個字元 (o)。此公式使用巢狀 SEARCH 函數,尋找第一個、第二個和第三個空格實例。

    公式會擷取 A2 裡從全名的右邊開始算起的五個字元。

    用於分隔名字、姓氏及兩個中間名縮寫的公式

    使用巢狀 SEARCH 及 LEN 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(8)

  11. 加 1 可得出第一個空格後的字元 (B) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格實例。(8 + 1 = 9)

  12. 在 A2 中搜尋第二個空格,從步驟 2 得出之第九個位置 (B) 開始算起。(11)

  13. 加 1 可得出第一個空格後的字元 (G) 位置。這個字元數是一起始位置,您從這裡開始搜尋第三個空格實例。(11 + 1 = 12)

  14. 在 A2 中搜尋第三個空格,從步驟 6 得出之第十二個位置開始算起。(14)

  15. 計算 A2 裡文字字串的總長度,然後減去步驟 5 得出之從左邊算到第三個空格的字元數。結果得出從全名右邊所擷取的字元數。(19 - 14 = 5)

頁面頂端

範例 4:Kahn, Wendy Beth

在此範例中,姓氏在名字之前,而中間名出現在最後。逗號代表姓氏的結尾,每個名稱元件之間以空格分隔。

在表格中複製儲存格,並貼入 Excel 工作表的 A1 儲存格中。左側的公式會一併顯示公式本身以供您參考,而右側的公式則會由 Excel 自動轉換為正確的結果。

提示   :將資料貼到工作表之前,請先將 A 欄和 B 欄的欄寬設為 250。

範例名稱

描述

Kahn, Wendy Beth

姓氏置前,姓氏後有逗號

公式

結果 (名字)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

公式

結果 (中間名)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

公式

即時結果 (姓氏)

'=LEFT(A2, SEARCH(" ",A2,1)-2)

=LEFT(A2, SEARCH(" ",A2,1)-2)

  1. 名字

    名字的開頭是從左邊數來的第七個字元 (W),結尾是第十二個字元 (即第二個空格)。由於名字出現在全名的中間,因此您必須使用 MID 函數來擷取名字。

    公式擷取的是從第七個位置開始算起的六個字元。

    用於分隔姓氏後接名字和中間名的公式

    使用 SEARCH 函數尋找 start_num 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(6)

  2. 加 1 可得出第一個空格後的字元 (W) 位置。此數值位置是名字的起始位置。(6 + 1 = 7)

    使用巢狀 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(6)

  3. 加 1 可得出第一個空格後的字元 (W) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格。(6 + 1 = 7)

    在 A2 中搜尋第二個空格,從步驟 4 得出之第七個位置 (W) 開始算起。(12)

  4. 在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(6)

  5. 用步驟 5 得出之第二個空格之字元數,減去步驟 6 得出之第一個空格的字元數。結果得出 MID 從文字字串擷取的字元數,從步驟 2 得出之第七個位置開始算起。(12 - 6 = 6)

  6. 中間名

    中間名的開頭是從右邊數來的第四個字元 (B),結尾是右邊數來的第一個字元 (h)。此公式使用巢狀 SEARCH 函數,從左邊開始尋找分別位於第六個及第十二個位置的第一個及第二個空格實例。

    公式擷取的是從右邊開始算起的四個字元。

    用於分隔姓氏後接名字和中間名的公式

    使用巢狀 SEARCH 及 LEN 函數尋找 start_num 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(6)

  7. 加 1 可得出第一個空格後的字元 (W) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格。(6 + 1 = 7)

  8. 在 A2 中搜尋第二個空格實例,從步驟 2 得出之第七個位置 (W) 開始算起。(12)

  9. 計算 A2 裡文字字串的總長度,然後減去步驟 3 得出之從左邊算到第二個空格的字元數。結果得出從全名右邊所擷取的字元數。(16 - 12 = 4)

  10. 姓氏

    姓氏的開頭是從左邊數來的第一個字元 (K),結尾是第四個字元 (n)。公式擷取的是從左邊開始算起的四個字元。

    用於分隔姓氏後接名字和中間名的公式

    使用 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(6)

  11. 減 2 以取得姓氏結尾字元 (n) 的數值位置。結果得出 LEFT 要抽選的字元數。(6 - 2 =4)

頁面頂端

範例 5:Mary Kay D. Andersen

此範例使用的名字 Mary Kay 是由兩個部分組成。各個名稱元件以第二個和第三個空格隔開。

在表格中複製儲存格,並貼入 Excel 工作表的 A1 儲存格中。左側的公式會一併顯示公式本身以供您參考,而右側的公式則會由 Excel 自動轉換為正確的結果。

提示   :將資料貼到工作表之前,請先將 A 欄和 B 欄的欄寬設為 250。

範例名稱

描述

Mary Kay D. Andersen

由兩個部分組成的名字

公式

結果 (名字)

LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

公式

結果 (中間名縮寫)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

公式

即時結果 (姓氏)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. 名字

    名字的開頭是從左邊數來的第一個字元,結尾是第九個字元 (即第二個空格)。此公式使用巢狀 SEARCH 函數,尋找左邊數來的第二個空格實例。

    公式擷取的是從左邊開始算起的九個字元。

    用於分隔名字、中間名縮寫及姓氏的公式

    使用巢狀 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(5)

  2. 加 1 可得出第一個空格後的字元 (K) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格實例。(5 + 1 = 6)

  3. 在 A2 中搜尋第二個空格實例,從步驟 2 得出之第六個位置 (S) 開始算起。結果得出 LEFT 從文字字串所擷取的字元數。(9)

  4. 中間名

    中間名的開頭是第十個位置 (D),結尾是第十二個位置 (即第三個空格)。此公式使用巢狀 SEARCH 函數,尋找第一個、第二個和第三個空格實例。

    公式擷取的是從第十個位置開始算起的中間兩個字元。

    用於分隔名字、中間名縮寫及姓氏的公式

    使用巢狀 SEARCH 函數尋找 start_num 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊第一個字元開始算起。(5)

  5. 加 1 可得出第一個空格後的字元 (K) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格。(5 + 1 = 6)

  6. 在 A2 中搜尋第二個空格實例的位置,從步驟 2 得出之第六個位置 (K) 開始算起。結果得出 LEFT 從左邊所擷取的字元數。(9)

  7. 加 1 可得出第二個空格後的字元 (D) 位置。結果得出中間名的起始位置。(9 + 1 = 10)

    使用巢狀 SEARCH 函數尋找 num_chars 的值:

    搜尋第二個空格後之字元 (D) 的數值位置。結果得出一字元數,可從該字元數位置開始搜尋第三個空格。(10)

  8. 在 A2 中搜尋第三個空格的數值位置,從左邊開始算起。結果得出中間名的結尾位置。(12)

  9. 搜尋第二個空格後之字元 (D) 的數值位置。結果得出中間名的起始位置。(10)

  10. 用步驟 6 得出之第三個空格之字元數,減去步驟 7 得出之 "D" 的字元數。結果得出 MID 從文字字串擷取的字元數,從步驟 4 得出之第十個位置開始算起。(12 - 10 = 2)

  11. 姓氏

    姓氏的開頭是從右數來的第八個字元。此公式使用巢狀 SEARCH 函數,尋找分別在第五個、第九個及第十二個位置的第一個、第二個及第三個空格。

    公式擷取的是從右邊算起的八個字元。

    用於分隔名字、中間名縮寫及姓氏的公式

    使用巢狀 SEARCH 及 LEN 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(5)

  12. 加 1 可得出第一個空格後的字元 (K) 位置。結果得出一字元數,可從該字元數位置開始搜尋空格。(5 + 1 = 6)

  13. 在 A2 中搜尋第二個空格,從步驟 2 得出之第六個位置 (K) 開始算起。(9)

  14. 加 1 可得出第二個空格後的字元 (D) 位置。結果得出中間名的起始位置。(9 + 1 = 10)

  15. 在 A2 中搜尋第三個空格的數值位置,從左邊開始算起。結果得出中間名的結尾位置。(12)

  16. 計算 A2 裡文字字串的總長度,然後減去步驟 5 得出之從左邊算到第三個空格的字元數。結果得出從全名右邊所擷取的字元數。(20 - 12 = 8)

頁面頂端

範例 6:Paula Barreto de Mattos

此範例使用由三個部分組成的姓氏:Barreto de Mattos。第一個空格代表名字的結尾與姓氏的開頭。

在表格中複製儲存格,並貼入 Excel 工作表的 A1 儲存格中。左側的公式會一併顯示公式本身以供您參考,而右側的公式則會由 Excel 自動轉換為正確的結果。

提示   :將資料貼到工作表之前,請先將 A 欄和 B 欄的欄寬設為 250。

範例名稱

描述

Paula Barreto de Mattos

由三個部分組成的姓氏

公式

結果 (名字)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

公式

結果 (姓氏)

RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 名字

    名字的開頭是從左邊數來的第一個字元 (P),結尾是第六個字元 (即第一個空格)。公式擷取的是從左邊算起的六個字元。

    用於分隔名字及由三部分組成之姓氏的公式

    使用 Search 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(6)

  2. 姓氏

    姓氏的開頭是從右邊數來的第十七個字元 (B),結尾是右邊數來的第一個字元 (s)。公式擷取的是從右邊開始算起的十七個字元。

    用於分隔名字及由三部分組成之姓氏的公式

    使用 LEN 及 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(6)

  3. 計算 A2 裡文字字串的總長度,然後減去步驟 1 得出之從左邊算到第一個空格的字元數。結果得出從全名右邊所擷取的字元數。(23 - 6 = 17)

頁面頂端

範例 7:James van Eaton

此範例使用由兩個部分組成的姓氏:van Eaton。第一個空格代表名字的結尾與姓氏的開頭。

在表格中複製儲存格,並貼入 Excel 工作表的 A1 儲存格中。左側的公式會一併顯示公式本身以供您參考,而右側的公式則會由 Excel 自動轉換為正確的結果。

提示   :將資料貼到工作表之前,請先將 A 欄和 B 欄的欄寬設為 250。

範例名稱

描述

James van Eaton

由兩個部分組成的姓氏

公式

結果 (名字)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

公式

結果 (姓氏)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 名字

    名字的開頭是從左邊數來的第一個字元 (J),結尾是第八個字元 (即第一個空格)。公式擷取的是從左邊算起的六個字元。

    用於分隔名字及由兩部分組成之姓氏的公式

    使用 Search 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(6)

  2. 姓氏

    姓氏的開頭是從右邊數來的第九個字元 (v),結尾是右邊數來的第一個字元 (n)。公式擷取的是從全名的右邊開始算起的九個字元。

    用於分隔名字及由兩部分組成之姓氏的公式

    使用 LEN 及 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(6)

  3. 計算 A2 裡文字字串的總長度,然後減去步驟 1 得出之從左邊算到第一個空格的字元數。結果得出從全名右邊所擷取的字元數。(15 - 6 = 9)

頁面頂端

範例 8:Bacon Jr., Dan K.

在此範例中,姓氏在最前面,後面接的是後稱謂。姓氏和後稱謂,名字和中間名縮寫,則是以逗號隔開。

在表格中複製儲存格,並貼入 Excel 工作表的 A1 儲存格中。左側的公式會一併顯示公式本身以供您參考,而右側的公式則會由 Excel 自動轉換為正確的結果。

提示   :將資料貼到工作表之前,請先將 A 欄和 B 欄的欄寬設為 250。

範例名稱

描述

Bacon Jr., Dan K.

姓氏和後稱謂放在前面,逗號在其後

公式

結果 (名字)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

公式

結果 (中間名縮寫)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

公式

結果 (姓氏)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

公式

結果 (後稱謂)

'=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

  1. 名字

    名字的開頭是第十二個字元 (D),結尾是第十五個字元 (即第三個空格)。公式擷取的是從第十二個位置開始算起的三個字元。

    用於擷取「範例 8:Bacon Jr., Dan K.」之名字的公式

    使用巢狀 SEARCH 函數尋找 start_num 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(6)

  2. 加 1 可得出第一個空格後的字元 (J) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格。(6 + 1 = 7)

  3. 在 A2 中搜尋第二個空格,從步驟 2 得出之第七個位置 (J) 開始算起。(11)

  4. 加 1 可得出第二個空格後的字元 (D) 位置。結果得出名字的起始位置。(11 + 1 = 12)

    使用巢狀 SEARCH 函數尋找 num_chars 的值:

    搜尋第二個空格後之字元 (D) 的數值位置。結果得出一字元數,可從該字元數位置開始搜尋第三個空格。(12)

  5. 在 A2 中搜尋第三個空格的數值位置,從左邊開始算起。結果得出名字的結尾位置。(15)

  6. 搜尋第二個空格後之字元 (D) 的數值位置。結果得出名字的起始位置。(12)

  7. 用步驟 6 得出之第三個空格之字元數,減去步驟 7 得出之 "D" 的字元數。結果得出 MID 從文字字串擷取的字元數,從步驟 4 得出之第十二個位置開始算起。(15 - 12 = 3)

  8. 中間名

    中間名的開頭是從右邊數來的第二個字元 (K)。公式擷取的是從右邊開始算起的兩個字元。

    用於擷取「範例 8:Bacon Jr., Dan K.」之中間名的公式 使用巢狀 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(6)

  9. 加 1 可得出第一個空格後的字元 (J) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格。(6 + 1 = 7)

  10. 在 A2 中搜尋第二個空格,從步驟 2 得出之第七個位置 (J) 開始算起。(11)

  11. 加 1 可得出第二個空格後的字元 (D) 位置。結果得出名字的起始位置。(11 + 1 = 12)

  12. 在 A2 中搜尋第三個空格的數值位置,從左邊開始算起。結果得出中間名的結尾位置。(15)

  13. 計算 A2 裡文字字串的總長度,然後減去步驟 5 得出之從左邊算到第三個空格的字元數。結果得出從全名右邊所擷取的字元數。(17 - 15 = 2)

  14. 姓氏

    姓氏的開頭是從左邊數來的第一個字元 (B),結尾是第六個字元 (即第一個空格)。因此,公式擷取的是從左邊算起的六個字元。

    用於擷取「範例 8:Bacon Jr., Dan K.」之姓氏的公式

    使用 Search 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(6)

  15. 後稱謂

    後稱謂的開頭是從左邊數來的第七個字元 (J),結尾是左邊數來的第九個字元 (.)。公式擷取的是從第七個字元開始算起的三個字元。

    用於擷取「範例 8:Bacon Jr., Dan K.」之後稱謂的公式

    使用 SEARCH 函數尋找 start_num 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(6)

  16. 加 1 可得出第一個空格後的字元 (J) 位置。結果得出後稱謂的起始位置。(6 + 1 = 7)

    使用巢狀 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(6)

  17. 加 1 可得出第一個空格後的字元 (J) 之數值位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格。(7)

  18. 在 A2 中搜尋第二個空格的數值位置,從步驟 4 得出之第七個字元開始算起。(11)

  19. 步驟 4 得出之第二個空格的字元數減去 1,即可取得 "," 的字元數。結果得出後稱謂的結尾位置。(11 - 1 = 10)

  20. 搜尋第一個空格的數值位置。(6)

  21. 找到第一個空格後,加 1 即可得出下一個字元 (J),這亦可在步驟 3 及步驟 4 得出。(7)

  22. 用步驟 6 得出之 "," 的字元數,減去步驟 3 及 4 得出之 "J" 的字元數。結果得出 MID 從文字字串擷取的字元數,從步驟 2 得出之第七個位置開始算起。(10 - 7 = 3)

頁面頂端

範例 9:Gary Altman III

在此範例中,名字位於字串的開頭,後稱謂則位於結尾,因此您可以使用與範例 2 相似的公式,亦即用 LEFT 函數擷取名字,用 MID 函數擷取姓氏,用 RIGHT 函數擷取後稱謂。

在表格中複製儲存格,並貼入 Excel 工作表的 A1 儲存格中。左側的公式會一併顯示公式本身以供您參考,而右側的公式則會由 Excel 自動轉換為正確的結果。

提示   :將資料貼到工作表之前,請先將 A 欄和 B 欄的欄寬設為 250。

範例名稱

描述

Gary Altman III

名字與姓氏,含後稱謂

公式

結果 (名字)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

公式

結果 (姓氏)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

公式

結果 (後稱謂)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. 名字

    名字的開頭是從左邊數來的第一個字元 (G),結尾是第五個字元 (即第一個空格)。因此,公式擷取的是從全名的左邊開始算起的五個字元。

    用於分隔名字、姓氏及稱謂的公式

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(5)

  2. 姓氏

    姓氏的開頭是從左邊數來的第六個字元 (A),結尾是第十一個字元 (即第二個空格)。此公式使用巢狀 SEARCH 函數,尋找空格的位置。

    公式擷取的是從第六個字元開始算起的中間六個字元。

    用於分隔名字、姓氏及稱謂的公式

    使用 SEARCH 函數尋找 start_num 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(5)

  3. 加 1 可得出第一個空格後的字元 (A) 位置。結果得出姓氏的起始位置。(5 + 1 = 6)

    使用巢狀 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(5)

  4. 加 1 可得出第一個空格後的字元 (A) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格。(5 + 1 = 6)

  5. 在 A2 中搜尋第二個空格的數值位置,從步驟 4 得出之第六個字元開始算起。此字元數是姓氏的結尾位置。(12)

  6. 搜尋第一個空格的數值位置。(5)

  7. 加 1 以找出位於第一個空格後方字元 (A) 的數值位置,這亦可在步驟 3 及步驟 4 中得出。(6)

  8. 用步驟 5 得出之第二個空格的字元數,減去步驟 6 及 7 得出之 "A" 的字元數。結果得出 MID 從文字字串擷取的字元數,從步驟 2 得出之第六個位置開始算起。(12 - 6 = 6)

  9. 後稱謂

    後稱謂的開頭是從右邊開始算起的三個字元。此公式使用巢狀 SEARCH 函數,尋找空格的位置。

    用於分隔名字、姓氏及稱謂的公式

    使用巢狀 SEARCH 及 LEN 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(5)

  10. 加 1 可得出第一個空格後的字元 (A) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格。(5 + 1 = 6)

  11. 在 A2 中搜尋第二個空格,從步驟 2 得出之第六個位置 (A) 開始算起。(12)

  12. 計算 A2 裡文字字串的總長度,然後減去步驟 3 得出之從左邊算到第二個空格的字元數。結果得出從全名右邊所擷取的字元數。(15 - 12 = 3)

頁面頂端

範例 10:Mr. Ryan Ihrig

在此範例中,全名的開頭是前稱謂,您可以使用與範例 2 相似的公式,亦即用 MID 函數擷取名字,用 RIGHT 函數擷取姓氏。

在表格中複製儲存格,並貼入 Excel 工作表的 A1 儲存格中。左側的公式會一併顯示公式本身以供您參考,而右側的公式則會由 Excel 自動轉換為正確的結果。

提示   :將資料貼到工作表之前,請先將 A 欄和 B 欄的欄寬設為 250。

範例名稱

描述

Mr. Ryan Ihrig

含有前稱謂

公式

結果 (名字)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

公式

結果 (姓氏)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. 名字

    名字的開頭是從左邊算起的第五個字元 (R),結尾是第九個字元 (即第二個空格)。此公式在巢狀結構中放入 SEARCH 函數,藉此尋找空格的位置。這個公式會擷取第五個字元起的四個字元。

    用於擷取「範例 10:Mr. Ryan Ihrig」之名字的公式

    使用 SEARCH 函數尋找 start_num 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(4)

  2. 加 1 可得出第一個空格後方字元 (R) 的位置。結果得出名字的起始位置。(4 + 1 = 5)

    使用巢狀 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(4)

  3. 加 1 可得出第一個空格後的字元 (R) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格。(4 + 1 = 5)

  4. 在 A2 中搜尋第二個空格的數值位置,從步驟 3 及 4 得出之第五個字元開始算起。此字元數是名字的結尾位置。(9)

  5. 搜尋第一個空格。(4)

  6. 加 1 以找出位於第一個空格後方字元 (R) 的數值位置,這亦可在步驟 3 及步驟 4 中得出。(5)

  7. 用步驟 5 得出之第二個空格的字元數,減去步驟 6 及 7 得出之 "R" 的字元數。結果得出 MID 從文字字串所擷取的字元數,從步驟 2 得出之第五個位置開始算起。(9 - 5 = 4)

  8. 姓氏

    姓氏的開頭是從右邊開始算起的第五個字元。此公式使用巢狀 SEARCH 函數,尋找空格的位置。

    用於擷取「範例 10:Mr. Ryan Ihrig」之姓氏的公式 使用巢狀 SEARCH 及 LEN 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(4)

  9. 加 1 可得出第一個空格後的字元 (R) 位置。結果得出一字元數,可從該字元數位置開始搜尋第二個空格。(4 + 1 = 5)

  10. 在 A2 中搜尋第二個空格,從步驟 2 得出之第五個位置 (R) 開始算起。(9)

  11. 計算 A2 裡文字字串的總長度,然後減去步驟 3 得出之從左邊算到第二個空格的字元數。結果得出從全名右邊所擷取的字元數。(14 - 9 = 5)

頁面頂端

範例 11:Julie Taft-Rider

此範例使用的是以連字號連接的姓氏。各個名稱元件以一個空格隔開。

在表格中複製儲存格,並貼入 Excel 工作表的 A1 儲存格中。左側的公式會一併顯示公式本身以供您參考,而右側的公式則會由 Excel 自動轉換為正確的結果。

提示   :將資料貼到工作表之前,請先將 A 欄和 B 欄的欄寬設為 250。

範例名稱

描述

Julie Taft-Rider

以連字號連接的姓氏

公式

結果 (名字)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

公式

結果 (姓氏)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. 名字

    名字的開頭是從左邊數來的第一個字元,結尾是第六個位置 (即第一個空格)。公式擷取的是從左邊算起的六個字元。

    用於擷取「範例 11:Julie Taft-Rider」之名字的公式

    使用 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋第一個空格的數值位置,從左邊開始算起。(6)

  2. 姓氏

    整個姓氏的開頭是從右邊數來的第十個字元 (T),結尾是右邊的第一個字元 (r)。

    用於擷取「範例 11:Julie Taft-Rider」之完整姓氏的公式

    使用 LEN 及 SEARCH 函數尋找 num_chars 的值:

    在 A2 中搜尋空格的數值位置,從左邊第一個字元開始算起。(6)

  3. 計算欲擷取之文字字串的總長度,然後減去步驟 1 得出之從左邊算到第一個空格的字元數。(16 - 6 = 10)

頁面頂端

附註: 機器翻譯免責聲明︰本文係以電腦系統翻譯而成,未經人為介入。Microsoft 提供此等機器翻譯旨在協助非英語系使用者輕鬆閱讀 Microsoft 產品、服務及技術相關內容。基於本文乃由機器翻譯而成,因此文中可能出現詞辭、語法、文法上之錯誤。

請參閱

使用資料剖析精靈將文字分割至不同的欄

這項資訊有幫助嗎?

太好了! 還有其他意見反應嗎?

我們應該如何改進?

感謝您的意見反應!

×