将 IF 函数与 AND、OR 以及 NOT 函数配合使用

注意: 我们希望能够尽快以你的语言为你提供最新的帮助内容。本页面是自动翻译的,可能包含语法错误或不准确之处。我们的目的是使此内容能对你有所帮助。可以在本页面底部告诉我们此信息是否对你有帮助吗?请在此处查看本文的英文版本以便参考。

IF 函数允许通过测试某个条件并返回该条件为 True 或 False 的结果,从而对某个值和预期值进行逻辑对比。

  • =IF(内容为 True,则执行某些操作,否则就执行其他操作)

但是, 如果你需要测试多个条件, 其中假设所有条件都必须为 true 或 false (), 或者只有一个条件需要为 true 或 false (或者), 或者如果你想要检查条件是否符合你的条件?所有3个函数都可以单独使用, 但更常见的是将其与 IF 函数配对更常见。

将 IF 函数与 AND、OR 和 NOT 配合使用以执行条件是否为 True 或 False 的多项计算。

语法

  • IF(AND()) - IF(AND(logical1, [logical2], ...), value_if_true, [value_if_false]))

  • IF(OR()) - IF(OR(logical1, [logical2], ...), value_if_true, [value_if_false]))

  • IF(NOT()) - IF(NOT(logical1), value_if_true, [value_if_false]))

参数名称

说明

logical_test(必需)

要测试的条件。

value_if_true(必需)

logical_test 的结果为 TRUE 时你希望返回的值。

value_if_false(可选)

logical_test 的结果为 FALSE 时你希望返回的值。

下面概述了如何单独构造函数 ORNOT函数。当你将其中每个文件与 IF 语句合并时, 它们将按如下方式读取:

  • AND – =IF(AND(Something is True, Something else is True), Value if True, Value if False)

  • OR – =IF(OR(Something is True, Something else is True), Value if True, Value if False)

  • NOT – =IF(NOT(Something is True), Value if True, Value if False)

示例

以下是一些常见的嵌套 IF (AND ())、if (或 ()) 语句的示例。and 和 OR 函数最多可以支持255个条件, 但由于复杂、嵌套的公式可能非常难以生成、测试和维护, 因此不是一种很好的使用方法。NOT 函数只接受一个条件。

将 IF 函数与 AND、OR 和 NOT 函数配合使用计算数字值和文本的示例

下面是根据它们的逻辑写出的公式:

公式

说明

=IF(AND(A2>0,B2<100),TRUE, FALSE)

如果 A2 (25) 大于 0, 而 B2 (75) 小于 100, 则返回 TRUE, 否则返回 FALSE。在此情况下, 这两个条件都为 true, 因此返回 true。

=IF(AND(A3="Red",B3="Green"),TRUE,FALSE)

如果 A3 ("Blue") = "Red", 则 B3 ("绿色") 等于 "绿色", 则返回 TRUE, 否则返回 FALSE。在此情况下, 仅第一个条件为 true, 因此返回 FALSE。

=IF(OR(A4>0,B4<50),TRUE, FALSE)

如果 A4 (25) 大于 0, 或 B4 (75) 小于 50, 则返回 TRUE, 否则返回 FALSE。在这种情况下, 仅第一个条件为 true, 但由于或仅要求一个参数为 true, 公式将返回 true。

=IF(OR(A5="Red",B5="Green"),TRUE,FALSE)

如果 A5 ("Blue") 等于 "Red", 或 B5 ("绿色") 等于 "绿色", 则返回 TRUE, 否则返回 FALSE。在这种情况下, 第二个参数为 true, 因此公式返回 true。

=IF(NOT(A6>50),TRUE,FALSE)

如果 A6 (25) 不大于 50, 则返回 TRUE, 否则返回 FALSE。在本例中, 25 不大于 50, 因此公式返回 TRUE。

=IF(NOT(A7="Red"),TRUE,FALSE)

如果 A7(“蓝色”)不等于“红色”,则返回 TRUE,否则返回 FALSE。

请注意, 在输入各自条件之后, 所有示例都有一个右括号。其余的 True/False 参数将作为 outer IF 语句的一部分保留。你还可以将文本或数字值替换为在示例中返回的 TRUE/FALSE 值。

以下是使用 AND、OR 和 NOT 函数计算日期的示例。

将 IF 函数与 AND、OR 和 NOT 函数配合使用计算日期的示例

下面是根据它们的逻辑写出的公式:

公式

说明

=IF(A2>B2,TRUE,FALSE)

如果 A2 大于 B2, 则返回 TRUE, 否则返回 FALSE。03/12/14 大于 01/01/14, 因此公式返回 TRUE。

=IF(AND(A3>B2,A3<C2),TRUE,FALSE)

如果 a3 大于 B2 且 a3 小于 C2, 则返回 TRUE, 否则返回 FALSE。在此情况下, 这两个参数均为 true, 因此公式返回 true。

=IF(OR(A4>B2,A4<B2+60),TRUE,FALSE)

如果 a4 大于 b2 或 a4 小于 b2 + 60, 则返回 TRUE, 否则返回 FALSE。在这种情况下, 第一个参数为 true, 但第二个参数为 false。因为或者仅需要一个参数为 true, 所以公式返回 true。如果使用 "公式" 选项卡上的 "公式求值" 向导, 您将看到 Excel 对公式进行评估的方式。

=IF(NOT(A5>B2),TRUE,FALSE)

如果 A5 不大于 B2, 则返回 TRUE, 否则返回 FALSE。在这种情况下, A5 大于 B2, 因此公式返回 FALSE。

公式求值向导示例

将 AND、OR 和 NOT 与条件格式配合使用

你也可以使用 AND、OR 以及 NOT 将条件格式条件设置为 "公式" 选项。当你执行此操作时, 你可以省略 IF 函数, 并使用 and、OR 和 NOT 本身。

在 "开始" 选项卡上, 单击 "条件格式" > "新建规则"。接下来, 选择 "使用公式确定要设置格式的单元格" 选项, 输入公式, 并应用所选的格式。

条件格式 > 编辑规则对话框(显示公式方法)

使用早期版本的“日期”示例时,公式应如下所示。

将 AND、OR 和 NOT 函数用作条件格式测试的示例

公式

说明

=A2>B2

如果 A2 大于 B2,则设置单元格格式,否则不执行任何操作。

=AND(A3>B2,A3<C2)

如果 A3 大于 B2 且 A3 小于 C2,则设置单元格格式,否则不执行任何操作。

=OR(A4>B2,A4<B2+60)

如果 A4 大于 B2 或 A4 小于 B2 超过 60(天),则设置单元格格式,否则不执行任何操作。

=NOT(A5>B2)

如果 A5 不大于 B2, 则设置单元格格式, 否则不执行任何操作。在此情况下, A5 大于 B2, 因此结果将返回 FALSE。如果要将公式更改为= NOT (B2>A5) , 则它将返回 TRUE, 并且单元格将被格式化。

注意: 常见错误是在不使用等号 (=) 的条件格式中输入公式。如果你执行此操作, 你将看到 "条件格式" 对话框将把等号和引号添加到公式中: = "OR (A4>B2, A4<B2 + 60)", 因此你需要删除引号, 然后公式才能正确响应。

页面顶端

需要更多帮助吗?

可随时在 Excel 技术社区中咨询专家,在解答社区获得支持,或在 Excel User Voice 上建议新功能或功能改进。

另请参阅

有关如何使用 IF 函数的视频, 请参阅

了解如何在公式中使用嵌套函数

IF 函数

AND 函数

OR 函数

NOT 函数

Excel 中的公式概述

如何避免损坏的公式

检测公式中的错误

Excel for Windows 中的键盘快捷方式

Excel for Mac 中的键盘快捷方式

逻辑函数(参考)

Excel 函数(按字母顺序)

Excel 函数(按类别列出)

扩展你的 Office 技能
了解培训
抢先获得新功能
加入 Office 预览体验计划

此信息是否有帮助?

谢谢您的反馈!

谢谢你的反馈! 可能需要转接到 Office 支持专员。

×