Thuộc tính FileDialog

Áp dụng cho

Đối tượng Application

Trả về đối tượng FileDialog đại diện cho một phiên bản riêng lẻ của hộp thoại tệp.

expression.FileDialog(dialogType)

Cần có expression. Một biểu thức trả về một trong các đối tượng thuộc danh sách Áp dụng Cho.

dialogType    Bắt buộc MsoFileDialogType. Kiểu hộp thoại tệp.

MsoFileDialogType có thể là một trong các hằng số MsoFileDialogType.

msoFileDialogFilePicker

msoFileDialogFolderPicker

msoFileDialogOpen không được hỗ trợ trong Microsoft Access.

msoFileDialogSaveAs Không được hỗ trợ trong Microsoft Access.

Ghi chú

Các hằng số msoFileDialogOpenmsoFileDialogSaveAs không được hỗ trợ trong Microsoft Office Access 2007.

Ví dụ

Ví dụ này minh họa cách sử dụng đối tượng FileDialog để hiển thị một hộp thoại cho phép người dùng chọn một hoặc nhiều tệp. Các tệp được chọn sau đó sẽ được thêm vào một hộp danh sách có tên là FileList.

Private Sub cmdFileDialog_Click()
' Requires reference to Microsoft Office 11.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
' Clear listbox contents.
Me.FileList.RowSource = ""
' Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
' Allow user to make multiple selections in dialog box
.AllowMultiSelect = True
' Set the title of the dialog box.
.Title = "Please select one or more files"
' Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.ACCDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"
' Show the dialog box. If the .Show method returns True, the
' user picked at least one file. If the .Show method returns
' False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub
Phát triển kỹ năng Office của bạn
Khám phá nội dung đào tạo
Sở hữu tính năng mới đầu tiên
Tham gia Người dùng nội bộ Office

Thông tin này có hữu ích không?

Cảm ơn phản hồi của bạn!

Cảm ơn bạn đã phản hồi! Để trợ giúp tốt hơn, có lẽ chúng tôi sẽ kết nối bạn với một trong những nhân viên hỗ trợ Office của chúng tôi.

×