Tách văn bản thành các cột khác nhau với chức năng

Tách văn bản thành các cột khác nhau với chức năng

Lưu ý:  Chúng tôi muốn cung cấp cho bạn nội dung trợ giúp mới nhất ở chính ngôn ngữ của bạn, nhanh nhất có thể. Trang này được dịch tự động nên có thể chứa các lỗi về ngữ pháp hoặc nội dung không chính xác. Mục đích của chúng tôi là khiến nội dung này trở nên hữu ích với bạn. Vui lòng cho chúng tôi biết ở cuối trang này rằng thông tin có hữu ích với bạn không? Dưới đây là bài viết bằng Tiếng Anh để bạn tham khảo dễ hơn.

Bạn có thể sử dụng các hàm văn bản LEFT, MID, RIGHT, SEARCH và LEN để thao tác các chuỗi văn bản trong dữ liệu của mình. Ví dụ như, bạn có thể phân bố tên, tên đệm và họ từ một ô duy nhất vào ba cột riêng biệt.

Yếu tố quan trọng trong việc phân bố các bộ phận của tên bằng các hàm văn bản là vị trí của từng ký tự trong một chuỗi văn bản. Vị trí của các khoảng trắng trong chuỗi văn bản cũng quan trọng vì chúng cho biết vị trí bắt đầu và kết thúc của các bộ phận tên trong một chuỗi.

Ví dụ như, trong một ô chỉ chứa tên và họ, họ sẽ bắt đầu sau thể hiện khoảng trắng đầu tiên. Một số tên trong danh sách của bạn có thể chứa tên đệm, trong trường hợp đó, họ bắt đầu sau thể hiện khoảng trắng thứ hai.

Bài viết này cho bạn cách trích các bộ phận khác nhau từ nhiều định dạng tên bằng cách dùng các hàm thuận tiện. Bạn cũng có thể tách văn bản thành cột khác nhau với Chuyển văn bản thành cột trình hướng dẫn

Tên ví dụ

Mô tả

Tên

Tên đệm

Họ

Tên phụ

1

Jeff Smith

Không có tên đệm

Jeff

Smith

2

Eric S. Kurjan

Một chữ cái đầu tên đệm

Eric

S.

Kurjan

3

Janaina B. G. Bueno

Hai chữ cái đầu tên đệm

Janaina

SINH G.

Bueno

4

Kahn, Wendy Beth

Họ trước tiên, có dấu phẩy

Wendy

Beth

Kahn

5

Mary Kay mất Andersen

Tên hai phần

Mary Kay

MẤT

Andersen

6

Paula Barreto de Mattos

Họ ba phần

Paula

Barreto de Mattos

7

James van Eaton

Họ hai phần

James

Van Eaton

8

Bacon Jr., Dan K.

Họ và tên phụ, có dấu phẩy

Dan

K.

Bacon

Jr.

9

Gary Altman III

Với hậu tố

Gary

Altman

III

10

Ông Ryan Ihrig

Có tiền tố

Ryan

Ihrig

11

Julie Taft-Rider

Họ có gạch nối

Julie

Taft-Rider

Lưu ý: Trong đồ họa trong ví dụ sau, tô sáng trong họ tên hiển thị ký tự thức SEARCH so khớp đang tìm kiếm.

Ví dụ này phân tách hai cấu phần: tên và họ. Một dấu cách phân tách tên hai.

Sao chép các ô trong bảng và dán vào trang tính Excel tại ô A1. Công thức bạn nhìn thấy ở bên trái sẽ được hiển thị cho tham chiếu, trong khi Excel sẽ tự động chuyển đổi công thức ở bên phải vào kết quả thích hợp.

Gợi ý    Trước khi bạn dán dữ liệu vào trang tính, hãy đặt chiều rộng cột của các cột A và B thành 250.

Tên ví dụ

Mô tả

Jeff Smith

Không có tên đệm

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Tên

    Tên bắt đầu bằng ký tự đầu tiên trong chuỗi (J) và kết thúc ở ký tự thứ năm (khoảng trắng). Công thức này sẽ cho ra năm ký tự trong ô A2, bắt đầu từ bên trái.

    Công thức để trích xuất tên

    Dùng hàm SEARCH để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ bên trái.

  2. Họ

    Họ bắt đầu ở khoảng trắng, năm ký tự từ bên phải và kết thúc ở ký tự cuối cùng ở bên phải (h). Công thức này sẽ trích xuất năm ký tự trong ô A2, bắt đầu từ bên phải.

    Công thức để trích xuất họ

    Dùng các hàm SEARCH và LEN để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ bên trái. (5)

  3. Đếm tổng chiều dài của chuỗi văn bản và sau đó trừ số ký tự ở bên trái của khoảng trắng đầu tiên, như được thấy ở bước 1.

Ví dụ này sử dụng tên, chữ cái đầu tên đệm và họ. Một khoảng trắng sẽ tách từng bộ phận của tên.

Sao chép các ô trong bảng và dán vào trang tính Excel tại ô A1. Công thức bạn nhìn thấy ở bên trái sẽ được hiển thị cho tham chiếu, trong khi Excel sẽ tự động chuyển đổi công thức ở bên phải vào kết quả thích hợp.

Gợi ý    Trước khi bạn dán dữ liệu vào trang tính, hãy đặt chiều rộng cột của các cột A và B thành 250.

Tên ví dụ

Mô tả

Eric S. Kurjan

Một chữ cái đầu tên đệm

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (chữ cái đầu tên đệm)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Công thức

Kết quả Thực (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Tên

    Tên bắt đầu bằng ký tự đầu tiên từ bên trái (E) và kết thúc ở ký tự thứ năm (khoảng trắng đầu tiên). Công thức này sẽ trích năm ký tự đầu tiên trong ô A2, bắt đầu từ bên trái.

    Công thức để tách một tên và họ, cộng với chữ cái đầu tên đệm

    Dùng hàm SEARCH để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ bên trái. (5)

  2. Tên đệm

    Tên đệm bắt đầu ở vị trí ký tự thứ sáu (S) và kết thúc ở vị trí ký tự thứ tám (khoảng trắng thứ hai). Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ hai.

    Công thức này trích ba ký tự, bắt đầu từ vị trí thứ sáu.

    Chi tiết về công thức tách tên, tên đệm và họ

    Dùng hàm SEARCH để tìm giá trị start_num:

    Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ bên trái. (5).

  3. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (S). Vị trí số này là điểm bắt đầu của tên đệm. (5 + 1 = 6)

    Sử dụng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (5)

  4. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (S). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ hai. (5 + 1 = 6)

  5. Tìm kiếm thể hiện khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (S) được tìm thấy ở bước 4. Số ký tự này là vị trí kết thúc của tên đệm. (8)

  6. Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (5)

  7. Lấy số ký tự của khoảng trắng thứ hai được tìm thấy ở bước 5 và trừ số ký tự của khoảng trắng đầu tiên được tìm thấy ở bước 6. Kết quả là số các ký tự mà MID trích từ chuỗi văn bản bắt đầu ở vị trí thứ sáu được tìm thấy ở bước 2. (8 – 5 = 3)

  8. Họ

    Họ bắt đầu ở sáu ký tự từ bên phải (K) và kết thúc ở ký tự đầu tiên từ bên phải (n). Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ hai và thứ ba (ở vị trí thứ năm và thứ 8 từ bên trái).

    Công thức này sẽ trích sáu ký tự trong ô A2, bắt đầu từ bên phải.

    Hàm tìm kiếm thứ hai trong một công thức để tách tên đầu tiên, tên đệm và họ
  9. Sử dụng các hàm LEN và SEARCH đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (5)

  10. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (S). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ hai. (5 + 1 = 6)

  11. Tìm kiếm thể hiện khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (S) được tìm thấy ở bước 2. Số ký tự này là vị trí kết thúc của tên đệm. (8)

  12. Đếm tổng chiều dài của chuỗi văn bản trong ô A2, và sau đó trừ số ký tự từ bên trái đến bản thứ hai của khoảng trắng được tìm thấy trong bước 3. Kết quả là số ký tự được trích xuất từ bên phải của tên đầy đủ. (14 – 8 = 6).

Sau đây là ví dụ về cách trích hai chữ cái đầu tên đệm. Thể hiện khoảng trắng thứ nhất và thứ ba tách các bộ phận của tên.

Sao chép các ô trong bảng và dán vào trang tính Excel tại ô A1. Công thức bạn nhìn thấy ở bên trái sẽ được hiển thị cho tham chiếu, trong khi Excel sẽ tự động chuyển đổi công thức ở bên phải vào kết quả thích hợp.

Gợi ý    Trước khi bạn dán dữ liệu vào trang tính, hãy đặt chiều rộng cột của các cột A và B thành 250.

Tên ví dụ

Mô tả

Janaina B. G. Bueno

Hai chữ cái đầu tên đệm

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (các chữ cái đầu tên đệm)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

Công thức

Kết quả Thực (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. Tên

    Tên bắt đầu bằng ký tự đầu tiên từ bên trái (J) và kết thúc ở ký tự thứ tám (khoảng trắng đầu tiên). Công thức này sẽ trích tám ký tự đầu tiên trong ô A2, bắt đầu từ bên trái.

    Công thức để tách tên, họ và hai chữ cái đầu tên đệm

    Dùng hàm SEARCH để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ bên trái. (8)

  2. Tên đệm

    Tên đệm bắt đầu ở vị trí ký tự thứ chín (B) và kết thúc ở vị trí ký tự thứ mười bốn (khoảng trắng thứ ba). Công thức này bao gồm việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ nhất, thứ hai và thứ ba ở các vị trí thứ tám, thứ mười một và thứ mười bốn.

    Công thức này trích năm ký tự, bắt đầu từ vị trí thứ chín.

    Công thức để tách tên, họ và hai chữ cái đầu tên đệm

    Dùng hàm SEARCH để tìm giá trị start_num:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (8)

  3. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (B). Vị trí số này là điểm bắt đầu của tên đệm. (8 + 1 = 9)

    Sử dụng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (8)

  4. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (B). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ hai. (8 + 1 = 9)

  5. Tìm kiếm cho không gian thứ hai trong ô A2, bắt đầu từ vị trí thứ chín (B) được tìm thấy trong bước 4. (11).

  6. Cộng 1 để có vị trí của ký tự sau khoảng trắng thứ hai (G). Số ký tự này là vị trí bắt đầu ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ ba. (11 + 1 = 12)

  7. Tìm kiếm khoảng trắng thứ ba trong A2, bắt đầu từ vị trí thứ mười hai được tìm thấy ở bước 6. (14)

  8. Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2. (8)

  9. Lấy số ký tự của khoảng trắng thứ ba được tìm thấy ở bước 7 và trừ số ký tự của khoảng trắng đầu tiên được tìm thấy ở bước 6. Kết quả là số các ký tự mà MID trích từ chuỗi văn bản bắt đầu ở vị trí thứ chín được tìm thấy ở bước 2.

  10. Họ

    Họ bắt đầu ở năm ký tự từ bên phải (K) và kết thúc ở ký tự đầu tiên từ bên phải (n). Công thức này bao gồm việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ nhất, thứ hai và thứ ba.

    Công thức này sẽ trích năm ký tự trong ô A2, bắt đầu từ bên phải của họ tên.

    Công thức để tách tên, họ và hai chữ cái đầu tên đệm

    Sử dụng các hàm SEARCH và LEN đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (8)

  11. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (B). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ hai. (8 + 1 = 9)

  12. Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ chín (B) được tìm thấy ở bước 2. (11)

  13. Cộng 1 để có vị trí của ký tự sau khoảng trắng thứ hai (G). Số ký tự này là vị trí bắt đầu ở đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ ba. (11 + 1 = 12)

  14. Tìm kiếm khoảng trắng thứ ba trong A2, bắt đầu từ vị trí thứ mười hai (G) được tìm thấy ở bước 6. (14)

  15. Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến thể hiện khoảng trắng thứ hai được thấy ở bước 3. Kết quả là số ký tự được trích từ bên phải của họ tên. (19 - 14 = 5)

Trong ví dụ này, họ đứng trước tên và tên đệm xuất hiện ở phần cuối. Dấu phẩy đánh dấu phần cuối của họ và một khoảng trắng tách từng bộ phận của tên.

Sao chép các ô trong bảng và dán vào trang tính Excel tại ô A1. Công thức bạn nhìn thấy ở bên trái sẽ được hiển thị cho tham chiếu, trong khi Excel sẽ tự động chuyển đổi công thức ở bên phải vào kết quả thích hợp.

Gợi ý    Trước khi bạn dán dữ liệu vào trang tính, hãy đặt chiều rộng cột của các cột A và B thành 250.

Tên ví dụ

Mô tả

Kahn, Wendy Beth

Họ trước tiên, có dấu phẩy

Công thức

Kết quả (tên)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Công thức

Kết quả (tên đệm)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Công thức

Kết quả Thực (họ)

'=LEFT(A2, SEARCH(" ",A2,1)-2)

=LEFT(A2, SEARCH(" ",A2,1)-2)

  1. Tên

    Tên bắt đầu bằng ký tự thứ bảy từ bên trái (W) và kết thúc ở ký tự thứ mười hai (khoảng trắng thứ hai). Vì tên xuất hiện ở giữa họ tên, bạn cần phải sử dụng hàm MID để trích tên.

    Công thức này trích sáu ký tự, bắt đầu từ vị trí thứ bảy.

    Công thức để tách họ theo sau là tên và tên đệm

    Dùng hàm SEARCH để tìm giá trị start_num:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (6)

  2. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (W). Vị trí số này là điểm bắt đầu của tên. (6 + 1 = 7)

    Dùng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (6)

  3. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (W). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (6 + 1 = 7)

    Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ bảy (W) được tìm thấy ở bước 4. (12)

  4. Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (6)

  5. Lấy số ký tự của khoảng trắng thứ hai được tìm thấy ở bước 5 và trừ số ký tự của khoảng trắng đầu tiên được tìm thấy ở bước 6. Kết quả là số các ký tự mà MID trích xuất từ chuỗi văn bản bắt đầu ở vị trí thứ bảy được tìm thấy ở bước 2. (12 - 6 = 6)

  6. Tên đệm

    Tên đệm bắt đầu ở bốn ký tự từ bên phải (B) và kết thúc ở ký tự đầu tiên từ bên phải (h). Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ nhất và thứ hai ở vị trí thứ sáu và thứ mười hai từ bên trái.

    Công thức này trích bốn ký tự, bắt đầu từ bên phải.

    Công thức để tách họ theo sau là tên và tên đệm

    Dùng các hàm SEARCH và LEN đã lồng để tìm giá trị cho start_num:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (6)

  7. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (W). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (6 + 1 = 7)

  8. Tìm kiếm thể hiện khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ bảy (W) được tìm thấy ở bước 2. (12)

  9. Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến thể hiện khoảng trắng thứ hai được thấy ở bước 3. Kết quả là số ký tự được trích xuất từ bên phải của họ tên. (16 - 12 = 4)

  10. Họ

    Họ bắt đầu bằng ký tự đầu tiên từ bên trái (K) và kết thúc ở ký tự thứ tư (n). Công thức này trích xuất bốn ký tự, bắt đầu từ bên trái.

    Công thức để tách họ theo sau là tên và tên đệm

    Dùng hàm SEARCH để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (6)

  11. Trừ 2 để lấy số vị trí của ký tự kết thúc của họ (n). Kết quả là số ký tự bạn muốn hàm LEFT trích xuất. (6 - 2 = 4)

Ví dụ này sử dụng tên có hai phần, Mary Kay. Khoảng trắng thứ hai và thứ ba tách từng bộ phận của tên.

Sao chép các ô trong bảng và dán vào trang tính Excel tại ô A1. Công thức bạn nhìn thấy ở bên trái sẽ được hiển thị cho tham chiếu, trong khi Excel sẽ tự động chuyển đổi công thức ở bên phải vào kết quả thích hợp.

Gợi ý    Trước khi bạn dán dữ liệu vào trang tính, hãy đặt chiều rộng cột của các cột A và B thành 250.

Tên ví dụ

Mô tả

Mary Kay D. Andersen

Tên hai phần

Công thức

Kết quả (tên)

LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Công thức

Kết quả (chữ cái đầu tên đệm)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Công thức

Kết quả Thực (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. Tên

    Tên bắt đầu bằng ký tự đầu tiên từ bên trái và kết thúc ở ký tự thứ chín (khoảng trắng thứ hai). Công thức này gồm có việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ hai.

    Công thức này trích chín ký tự, bắt đầu từ bên trái.

    Công thức để tách tên, tên đệm, chữ cái đầu tên đệm và họ

    Sử dụng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (5)

  2. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (K). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm thể hiện khoảng trắng thứ hai. (5 + 1 = 6)

  3. Tìm kiếm thể hiện khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (K) được tìm thấy ở bước 2. Kết quả là số ký tự mà hàm LEFT trích từ chuỗi văn bản. (9)

  4. Tên đệm

    Tên đệm bắt đầu ở vị trí ký tự thứ mười (D) và kết thúc ở vị trí ký tự thứ mười hai (khoảng trắng thứ ba). Công thức này bao gồm việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ nhất, thứ hai và thứ ba.

    Công thức này trích hai ký tự từ phần giữa, bắt đầu từ vị trí thứ mười.

    Công thức để tách tên, tên đệm, chữ cái đầu tên đệm và họ

    Dùng hàm SEARCH lồng nhau để tìm giá trị num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ ký tự đầu tiên từ bên trái. (5)

  5. Cộng 1 để có ký tự sau khoảng trắng đầu tiên (K). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (5 + 1 = 6)

  6. Tìm kiếm vị trí của thể hiện khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (K) được tìm thấy ở bước 2. Kết quả là số ký tự mà hàm LEFT trích từ bên trái. (9)

  7. Cộng 1 để có ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí bắt đầu của tên đệm. (9 + 1 = 10)

    Sử dụng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí của ký tự sau khoảng trắng thứ hai (D). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ ba. (10)

  8. Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ bên trái. Kết quả là vị trí kết thúc của tên đệm. (12)

  9. Tìm kiếm vị trí của ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí bắt đầu của tên đệm. (10)

  10. Lấy số ký tự của khoảng trắng thứ ba được tìm thấy ở bước 6 và trừ số ký tự của "D" được tìm thấy ở bước 7. Kết quả là số các ký tự mà MID trích từ chuỗi văn bản bắt đầu ở vị trí thứ mười được tìm thấy ở bước 4. (12 - 10 = 2)

  11. Họ

    Họ bắt đầu tám ký tự từ bên phải. Công thức này bao gồm việc lồng hàm SEARCH để tìm thể hiện khoảng trắng thứ nhất, thứ hai và thứ ba ở các vị trí thứ năm, thứ chín và thứ mười hai.

    Công thức này trích tám ký tự từ bên phải.

    Công thức để tách tên, tên đệm, chữ cái đầu tên đệm và họ

    Sử dụng các hàm SEARCH và LEN đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (5)

  12. Cộng 1 để có ký tự sau khoảng trắng đầu tiên (K). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng. (5 + 1 = 6)

  13. Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (K) được tìm thấy ở bước 2. (9)

  14. Cộng 1 để có vị trí của ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí bắt đầu của tên đệm. (9 + 1 = 10)

  15. Tìm kiếm vị trí số của khoảng trắng thứ ba trong A2, bắt đầu từ bên trái. Kết quả là vị trí kết thúc của tên đệm. (12)

  16. Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến thể hiện khoảng trắng thứ hai được thấy ở bước 3. Kết quả là số ký tự được trích từ bên phải của họ tên. (20 - 12 = 8)

Ví dụ này sử dụng họ có ba phần: Barreto de Mattos. Khoảng trắng đầu tiên đánh dấu vị trí kết thúc của tên và vị trí bắt đầu của họ.

Sao chép các ô trong bảng và dán vào trang tính Excel tại ô A1. Công thức bạn nhìn thấy ở bên trái sẽ được hiển thị cho tham chiếu, trong khi Excel sẽ tự động chuyển đổi công thức ở bên phải vào kết quả thích hợp.

Gợi ý    Trước khi bạn dán dữ liệu vào trang tính, hãy đặt chiều rộng cột của các cột A và B thành 250.

Tên ví dụ

Mô tả

Paula Barreto de Mattos

Họ ba phần

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (họ)

RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Tên

    Tên bắt đầu bằng ký tự đầu tiên từ bên trái (P) và kết thúc ở ký tự thứ sáu (khoảng trắng đầu tiên). Công thức này trích sáu ký tự từ bên trái.

    Công thức để tách tên và họ ba phần

    Dùng hàm SEARCH để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)

  2. Họ

    Họ bắt đầu ở mười bảy ký tự từ bên phải (B) và kết thúc ở ký tự đầu tiên từ bên phải (s). Công thức này trích mười bảy ký tự từ bên phải.

    Công thức để tách tên và họ ba phần

    Sử dụng các hàm LEN và SEARCH để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)

  3. Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến thể hiện khoảng trắng thứ hai được thấy ở bước 3. Kết quả là số ký tự được trích từ bên phải của họ tên. (23 - 6 = 17)

Ví dụ này sử dụng họ có hai phần, van Eaton. Khoảng trắng đầu tiên đánh dấu vị trí kết thúc của tên và vị trí bắt đầu của họ.

Sao chép các ô trong bảng và dán vào trang tính Excel tại ô A1. Công thức bạn nhìn thấy ở bên trái sẽ được hiển thị cho tham chiếu, trong khi Excel sẽ tự động chuyển đổi công thức ở bên phải vào kết quả thích hợp.

Gợi ý    Trước khi bạn dán dữ liệu vào trang tính, hãy đặt chiều rộng cột của các cột A và B thành 250.

Tên ví dụ

Mô tả

James van Eaton

Họ hai phần

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Tên

    Tên bắt đầu bằng ký tự đầu tiên từ bên trái (J) và kết thúc ở ký tự thứ tám (khoảng trắng đầu tiên). Công thức này trích sáu ký tự từ bên trái.

    Công thức để tách tên và họ có hai phần

    Sử dụng hàm SEARCH để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)

  2. Họ

    Họ bắt đầu bằng ký tự thứ chín từ bên phải (v) và kết thúc ở ký tự đầu tiên từ bên phải (n). Công thức này sẽ trích chín ký tự từ bên phải của họ tên.

    Công thức để tách tên và họ có hai phần

    Sử dụng các hàm LEN và SEARCH để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)

  3. Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến thể hiện khoảng trắng thứ hai được thấy ở bước 3. Kết quả là số ký tự được trích từ bên phải của họ tên. (15 - 6 = 9)

Trong ví dụ này, họ xuất hiện trước, sau đó là tên phụ. Dấu phẩy tách họ và tên phụ với tên và tên đệm.

Sao chép các ô trong bảng và dán vào trang tính Excel tại ô A1. Công thức bạn nhìn thấy ở bên trái sẽ được hiển thị cho tham chiếu, trong khi Excel sẽ tự động chuyển đổi công thức ở bên phải vào kết quả thích hợp.

Gợi ý    Trước khi bạn dán dữ liệu vào trang tính, hãy đặt chiều rộng cột của các cột A và B thành 250.

Tên ví dụ

Mô tả

Bacon Jr., Dan K.

Họ và tên phụ, có dấu phẩy

Công thức

Kết quả (tên)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Công thức

Kết quả (chữ cái đầu tên đệm)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Công thức

Kết quả (họ)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (tên phụ)

'=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

  1. Tên

    Tên bắt đầu bằng ký tự thứ mười hai (D) và kết thúc bằng ký tự thứ mười lăm (khoảng trắng thứ ba). Công thức này trích ba ký tự, bắt đầu từ vị trí thứ mười hai.

    Công thức để tách cuối cùng một tên và tên phụ, có dấu phẩy

    Dùng hàm SEARCH lồng nhau để tìm giá trị num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)

  2. Cộng 1 để có ký tự sau khoảng trắng đầu tiên (J). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (6 + 1 = 7)

  3. Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ bảy (J) được tìm thấy ở bước 2. (11)

  4. Cộng 1 để có ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí bắt đầu của tên. (11 + 1 = 12)

    Sử dụng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí của ký tự sau khoảng trắng thứ hai (D). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ ba. (12)

  5. Tìm kiếm vị trí số của khoảng trắng thứ ba trong A2, bắt đầu từ bên trái. Kết quả là vị trí kết thúc của tên. (15)

  6. Tìm kiếm vị trí của ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí bắt đầu của tên. (12)

  7. Lấy số ký tự của khoảng trắng thứ ba được tìm thấy ở bước 6 và trừ số ký tự của "D" được tìm thấy ở bước 7. Kết quả là số các ký tự mà MID trích từ chuỗi văn bản bắt đầu ở vị trí thứ mười hai được tìm thấy ở bước 4. (15 - 12 = 3)

  8. Tên đệm

    Tên đệm bắt đầu bằng ký tự thứ hai từ bên phải (K). Công thức này trích hai ký tự từ bên phải.

    Công thức để tách cuối cùng một tên và tên phụ, có dấu phẩy

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)

  9. Cộng 1 để có ký tự sau khoảng trắng đầu tiên (J). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (6 + 1 = 7)

  10. Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ bảy (J) được tìm thấy ở bước 2. (11)

  11. Cộng 1 để có ký tự sau khoảng trắng thứ hai (D). Kết quả là vị trí bắt đầu của tên. (11 + 1 = 12)

  12. Tìm kiếm vị trí số của khoảng trắng thứ ba trong ô A2, bắt đầu từ bên trái. Kết quả là vị trí kết thúc của tên đệm. (15)

  13. Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến thể hiện khoảng trắng thứ hai được thấy ở bước 3. Kết quả là số ký tự được trích từ bên phải của họ tên. (17 - 15 = 2)

  14. Họ

    Họ bắt đầu ở ký tự đầu tiên từ bên trái (B) và kết thúc ở ký tự thứ sáu (khoảng trắng đầu tiên). Do đó, công thức này trích sáu ký tự từ bên trái.

    Công thức để tách cuối cùng một tên và tên phụ, có dấu phẩy

    Dùng hàm SEARCH để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)

  15. Tên phụ

    Tên phụ bắt đầu ở ký tự thứ bảy từ bên trái (J) và kết thúc ở ký tự thứ chín từ bên trái (.). Công thức này trích ba ký tự, bắt đầu từ ký tự thứ bảy.

    Công thức để tách cuối cùng một tên và tên phụ, có dấu phẩy

    Dùng hàm SEARCH để tìm giá trị start_num:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)

  16. Cộng 1 để có ký tự sau khoảng trắng đầu tiên (J). Kết quả là vị trí bắt đầu của tên phụ. (6 + 1 = 7)

    Sử dụng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)

  17. Cộng 1 để có vị trí số của ký tự sau khoảng trắng đầu tiên (J). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (7)

  18. Tìm kiếm vị trí số của khoảng trắng thứ hai trong A2, bắt đầu từ ký tự thứ bảy được tìm thấy ở bước 4. (11)

  19. Trừ 1 từ số ký tự của khoảng trắng thứ hai được tìm thấy ở bước 4 để có số ký tự của “,”. Kết quả là vị trí kết thúc của tên phụ. (11 - 1 = 10)

  20. Tìm kiếm vị trí số của khoảng trắng đầu tiên. (6)

  21. Sau khi tìm khoảng trắng đầu tiên, cộng 1 để tìm ký tự tiếp theo (J), cũng được tìm thấy ở các bước 3 và 4. (7)

  22. Lấy số ký tự của "," được tìm thấy ở bước 6 và trừ số ký tự của "J" được tìm thấy ở các bước 3 và 4. Kết quả là số các ký tự mà MID trích từ chuỗi văn bản bắt đầu ở vị trí thứ bảy được tìm thấy ở bước 2. (10 - 7 = 3)

Trong ví dụ này, tên nằm ở phần đầu của chuỗi và tên phụ nằm ở phần cuối, do đó bạn có thể sử dụng các công thức tương tự như Ví dụ 2: Sử dụng hàm LEFT để trích tên, hàm MID để trích họ và hàm RIGHT để trích tên phụ.

Sao chép các ô trong bảng và dán vào trang tính Excel tại ô A1. Công thức bạn nhìn thấy ở bên trái sẽ được hiển thị cho tham chiếu, trong khi Excel sẽ tự động chuyển đổi công thức ở bên phải vào kết quả thích hợp.

Gợi ý    Trước khi bạn dán dữ liệu vào trang tính, hãy đặt chiều rộng cột của các cột A và B thành 250.

Tên ví dụ

Mô tả

Gary Altman III

Tên và họ có tên phụ

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (họ)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Công thức

Kết quả (tên phụ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Tên

    Tên bắt đầu ở ký tự đầu tiên từ bên trái (G) và kết thúc ở ký tự thứ năm (khoảng trắng đầu tiên). Do đó, công thức này sẽ trích năm ký tự từ bên trái của họ tên.

    Công thức để tách một đầu tiên và họ theo sau là hậu tố

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong ô A2, bắt đầu từ bên trái. (5)

  2. Họ

    Họ bắt đầu ở ký tự sáu từ bên trái (A) và kết thúc ở ký tự thứ bảy (khoảng trắng thứ hai). Công thức này gồm có việc lồng hàm SEARCH để tìm vị trí của các khoảng trắng.

    Công thức này trích sáu ký tự từ phần giữa, bắt đầu từ vị trí thứ sáu.

    Công thức để tách một đầu tiên và họ theo sau là hậu tố

    Dùng hàm SEARCH để tìm giá trị start_num:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (5)

  3. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (A). Kết quả là vị trí bắt đầu của họ. (5 + 1 = 6)

    Sử dụng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (5)

  4. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (A). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (5 + 1 = 6)

  5. Tìm kiếm vị trí số của khoảng trắng thứ hai trong A2, bắt đầu từ ký tự thứ bảy được tìm thấy ở bước 4. Số ký tự này là vị trí kết thúc của họ. (12)

  6. Tìm kiếm vị trí số của khoảng trắng đầu tiên. (5)

  7. Cộng 1 để tìm vị trí số của ký tự sau khoảng trắng đầu tiên (A), cũng được tìm thấy ở các bước 3 và 4. (6)

  8. Lấy số ký tự của khoảng trắng thứ hai được tìm thấy ở bước 5 và trừ số ký tự của "A" được tìm thấy ở các bước 6 và 7. Kết quả là số các ký tự mà MID trích từ chuỗi văn bản bắt đầu ở vị trí thứ sáu được tìm thấy ở bước 2. (12 - 6 = 6)

  9. Tên phụ

    Tên phụ bắt đầu ba ký tự từ bên phải. Công thức này gồm có việc lồng hàm SEARCH để tìm vị trí của các khoảng trắng.

    Công thức để tách một đầu tiên và họ theo sau là hậu tố

    Sử dụng các hàm SEARCH và LEN đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (5)

  10. Cộng 1 để có ký tự sau khoảng trắng đầu tiên (A). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (5 + 1 = 6)

  11. Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ sáu (A) được tìm thấy ở bước 2. (12)

  12. Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến thể hiện khoảng trắng thứ hai được thấy ở bước 3. Kết quả là số ký tự được trích từ bên phải của họ tên. (15 - 12 = 3)

Trong ví dụ này, họ tên theo sau tên tiền tố và bạn có thể sử dụng các công thức tương tự như Ví dụ 2: hàm MID để trích tên, hàm RIGHT để trích họ.

Sao chép các ô trong bảng và dán vào trang tính Excel tại ô A1. Công thức bạn nhìn thấy ở bên trái sẽ được hiển thị cho tham chiếu, trong khi Excel sẽ tự động chuyển đổi công thức ở bên phải vào kết quả thích hợp.

Gợi ý    Trước khi bạn dán dữ liệu vào trang tính, hãy đặt chiều rộng cột của các cột A và B thành 250.

Tên ví dụ

Mô tả

Mr. Ryan Ihrig

Có tiền tố

Công thức

Kết quả (tên)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Công thức

Kết quả (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Tên

    Tên bắt đầu bằng ký tự thứ năm từ bên trái (R) và kết thúc ở ký tự thứ chín (khoảng trắng thứ hai). Công thức này lồng hàm SEARCH để tìm vị trí của các khoảng trắng. Công thức này trích bốn ký tự, bắt đầu từ vị trí thứ năm.

    Formula for extracting the first name có tiền tố đơn phía trước

    Sử dụng hàm SEARCH để tìm giá trị cho start_num:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (4)

  2. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (R). Kết quả là vị trí bắt đầu của tên. (4 + 1 = 5)

    Sử dụng hàm SEARCH đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (4)

  3. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (R). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (4 + 1 = 5)

  4. Tìm kiếm vị trí số của khoảng trắng thứ hai trong A2, bắt đầu từ ký tự thứ năm được tìm thấy ở bước 3 và 4. Số ký tự này là vị trí kết thúc của tên. (9)

  5. Tìm khoảng trắng đầu tiên. (4)

  6. Cộng 1 để tìm vị trí số của ký tự sau khoảng trắng đầu tiên (A), cũng được tìm thấy ở các bước 3 và 4. (5)

  7. Lấy số ký tự của khoảng trắng thứ hai được tìm thấy ở bước 5 và trừ số ký tự của "R" được tìm thấy ở các bước 6 và 7. Kết quả là số các ký tự mà MID trích từ chuỗi văn bản bắt đầu ở vị trí thứ năm được tìm thấy ở bước 2. (9 - 5 = 4)

  8. Họ

    Họ bắt đầu năm ký tự từ bên phải. Công thức này gồm có việc lồng hàm SEARCH để tìm vị trí của các khoảng trắng.

    Formula for extracting the first name có tiền tố đơn phía trước

    Sử dụng các hàm SEARCH và LEN đã lồng để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (4)

  9. Cộng 1 để có vị trí của ký tự sau khoảng trắng đầu tiên (R). Kết quả là số ký tự ở đó bạn muốn bắt đầu tìm kiếm khoảng trắng thứ hai. (4 + 1 = 5)

  10. Tìm kiếm khoảng trắng thứ hai trong A2, bắt đầu từ vị trí thứ năm (R) được tìm thấy ở bước 2. (9)

  11. Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến thể hiện khoảng trắng thứ hai được thấy ở bước 3. Kết quả là số ký tự được trích từ bên phải của họ tên. (14 - 9 = 5)

Ví dụ này sử dụng họ có gạch nối. Một khoảng trắng sẽ tách từng bộ phận của tên.

Sao chép các ô trong bảng và dán vào trang tính Excel tại ô A1. Công thức bạn nhìn thấy ở bên trái sẽ được hiển thị cho tham chiếu, trong khi Excel sẽ tự động chuyển đổi công thức ở bên phải vào kết quả thích hợp.

Gợi ý    Trước khi bạn dán dữ liệu vào trang tính, hãy đặt chiều rộng cột của các cột A và B thành 250.

Tên ví dụ

Mô tả

Julie Taft-Rider

Họ có gạch nối

Công thức

Kết quả (tên)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Công thức

Kết quả (họ)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Tên

    Tên bắt đầu ở ký tự đầu tiên từ bên trái và kết thúc ở vị trí thứ sáu (khoảng trắng đầu tiên). Công thức này trích sáu ký tự từ bên trái.

    Công thức để tách một đầu tiên và cuối cùng tên gạch nối

    Sử dụng hàm SEARCH để tìm giá trị của num_chars:

    Tìm kiếm vị trí số của khoảng trắng đầu tiên trong A2, bắt đầu từ bên trái. (6)

  2. Họ

    Toàn bộ họ bắt đầu ở mười ký tự từ bên phải (T) và kết thúc ở ký tự đầu tiên từ bên phải (r).

    Công thức để tách một đầu tiên và cuối cùng tên gạch nối

    Sử dụng các hàm LEN và SEARCH để tìm giá trị cho num_chars:

    Tìm kiếm vị trí số của khoảng trắng trong A2, bắt đầu từ bên trái. (6)

  3. Đếm tổng chiều dài của chuỗi văn bản trong A2 và sau đó trừ số ký tự từ bên trái đến thể hiện khoảng trắng thứ hai được thấy ở bước 3. (16 - 6 = 10)

Xem Thêm

Tách văn bản thành các cột khác nhau với chuyển văn bản thành cột trình hướng dẫn

Phát triển kỹ năng Office của bạn
Khám phá nội dung đào tạo
Sở hữu tính năng mới đầu tiên
Tham gia Người dùng nội bộ Office

Thông tin này có hữu ích không?

Cảm ơn phản hồi của bạn!

Cảm ơn bạn đã phản hồi! Để trợ giúp tốt hơn, có lẽ chúng tôi sẽ kết nối bạn với một trong những nhân viên hỗ trợ Office của chúng tôi.

×