TEXT (Hàm TEXT)

Người đóng góp: Chris "Smitty" Smith Dave Ludwig

Hàm TEXT giúp bạn thay đổi cách số hiển thị bằng cách áp dụng định dạng cho số bằng mã định dạng. Điều này hữu ích trong những trường hợp bạn muốn hiển thị số ở định dạng dễ đọc hơn hay bạn muốn kết hợp số với văn bản hoặc ký hiệu.

Ghi chú: Hàm TEXT sẽ chuyển đổi số thành văn bản, điều này có thể khiến việc tham chiếu trong các tính toán sau này trở nên khó khăn. Tốt nhất bạn nên giữ giá trị gốc của mình ở một ô, rồi sử dụng hàm TEXT trong một ô khác. Sau đó, nếu bạn cần xây dựng các công thức khác, hãy luôn tham chiếu giá trị gốc và không tham chiếu kết quả hàm TEXT.

Cú pháp

TEXT(value, format_text)

Cú pháp hàm TEXT có các tham đối sau:

Tên Tham đối

Mô tả

giá trị

Giá trị số mà bạn muốn được chuyển đổi thành văn bản.

định dạng_văn bản

Một chuỗi văn bản xác định định dạng mà bạn muốn được áp dụng cho giá trị được cung cấp.

Tổng quan

Ở dạng đơn giản nhất, hàm TEXT cho biết:

  • =TEXT (Giá trị bạn muốn định dạng, "Mã định dạng bạn muốn áp dụng")

Dưới đây là một số ví dụ phổ biến mà bạn có thể sao chép trực tiếp vào Excel để thử nghiệm với chính mình. Lưu ý các mã định dạng trong dấu ngoặc kép.

Công thức

Mô tả

=TEXT(1234.567,"$#,##0.00")

Tiền tệ với dấu tách phần nghìn và 2 số thập phân, chẳng hạn như $1.234,57. Lưu ý rằng Excel làm tròn giá trị tới 2 chữ số thập phân.

=TEXT(TODAY(),"MM/DD/YY")

Ngày hôm nay có định dạng DD/MM/YY, chẳng hạn như 14/03/12

=TEXT(TODAY(),"DDDD")

Hôm nay là ngày trong tuần, chẳng hạn như Thứ 2

=TEXT(NOW(),"H:MM SA/CH")

Múi giờ hiện tại, chẳng hạn như 1:29 CH

=TEXT(0.285,"0,0%")

Phần trăm, chẳng hạn như 28,5 %

=TEXT(4,34 ,"# ?/?")

Phân số, chẳng hạn như 4 1/3

=TRIM(TEXT(0,34,"# ?/?"))

Phân số, chẳng hạn như 1/3. Lưu ý phân số này sử dụng hàm TRIM để loại bỏ dấu cách đầu dòng bằng một giá trị thập phân.

=TEXT(12200000,"0.00E+00")

Ký hiệu khoa học, chẳng hạn như 1,22E + 07

=TEXT(1234567898,"[<=9999999]###-####;(###) ###-####")

Đặc biệt (Số điện thoại), chẳng hạn như (123) 456-7898

=TEXT(1234,"0000000")

Thêm số các 0 đứng đầu (0), chẳng hạn như 0001234

=TEXT(123456,"##0° 00' 00''")

Tùy chỉnh - Vĩ độ/Kinh độ

Ghi chú: Mặc dù bạn có thể sử dụng hàm TEXT để thay đổi định dạng nhưng đó không phải là cách duy nhất. Bạn có thể thay đổi định dạng mà không cần công thức bằng cách nhấn CTRL + 1 (hoặc Hình ảnh biểu tượng nút Command trong MAC +1 trên máy Mac), rồi chọn định dạng bạn muốn từ hộp thoại Định dạng Ô > Số.

Tải xuống ví dụ của chúng tôi

Bạn có thể tải xuống sổ làm việc ví dụ chứa tất cả các ví dụ về hàm TEXT mà bạn sẽ tìm thấy trong bài viết này, cộng thêm một số nội dung bổ sung khác. Bạn có thể theo dõi hoặc tạo mã định dạng hàm TEXT của riêng mình.

Tải xuống ví dụ về hàm văn TEXT trong Excel

Các mã định dạng sẵn dùng khác

Bạn có thể sử dụng hộp thoại Định dạng Ô để tìm các mã định dạng sẵn dùng khác:

  1. Nhấn Ctrl+1 ( Hình ảnh biểu tượng nút Command trong MAC +1 trên máy Mac) để hiển thị hộp thoại Định dạng Ô.

  2. Chọn định dạng mà bạn muốn từ tab Số .

  3. Chọn tùy chọn Tùy chỉnh,

  4. Mã định dạng mà hiện bạn muốn được hiển thị trong hộp Kiểu. Trong trường hợp này, hãy chọn tất cả mọi thứ từ hộp Kiểu ngoại trừ dấu chấm phẩy (;) và ký hiệu @. Trong ví dụ dưới đây, chúng tôi đã chọn và sao chép chỉ dd/mm/yy.

  5. Nhấn Ctrl+C để sao chép mã định dạng, rồi nhấn Hủy bỏ để bỏ qua hộp thoại Định dạng Ô.

  6. Bây giờ, tất cả những gì bạn cần làm là nhấn Ctrl+V để dán mã định dạng vào công thức TEXT, chẳng hạn như: =TEXT(B2,"dd/mm/yy"). Đảm bảo rằng bạn dán mã định dạng trong dấu ngoặc kép ("mã định dạng"), nếu không Excel sẽ loại bỏ thông báo lỗi.

Ví dụ về việc sử dụng hộp thoại Định dạng > Ô > Số > Tùy chỉnh để yêu cầu Excel tạo chuỗi định dạng cho bạn.

Mã định dạng theo thể loại

Dưới đây là một số ví dụ về cách bạn có thể áp dụng các định dạng số khác nhau cho các giá trị của bạn bằng cách sử dụng hộp thoại Định dạng Ô, rồi sử dụng tùy chọn Tùy chỉnh để sao chép các mã định dạng đó vào hàm TEXT của bạn.

Tại sao Excel xóa những số 0 đứng đầu của tôi?

Excel được thiết lập để tìm kiếm các số đã nhập trong ô, chứ không phải các số trông giống như văn bản, chẳng hạn như số phần hay SKU. Để duy trì những số 0 đứng đầu, hãy định dạng dải nhập làm Văn bản trước khi bạn dán hoặc nhập các giá trị. Chọn cột hoặc dải ô mà bạn sẽ nhập các giá trị, rồi sử dụng CTRL+1 để hiển thị hộp thoại Định dạng> Ô và trên tab Số, chọn Văn bản. Bây giờ, Excel sẽ giữ các số 0 đứng đầu của bạn.

Nếu bạn đã nhập dữ liệu và Excel loại bỏ các số 0 đứng đầu, bạn có thể sử dụng hàm TEXT để thêm lại chúng. Bạn có thể tham chiếu ô trên cùng với các giá trị, đồng thời sử dụng =TEXT(value,"00000", trong đó số lượng số 0 trong công thức thể hiện tổng số ký tự mà bạn muốn, rồi sao chép và dán vào phần còn lại của dải ô.

Ví dụ về việc sử dụng TEXT để định dạng các số 0 đứng đầu.  =TEXT(A2,"00000")

Nếu vì một số lý do, bạn cần chuyển đổi các giá trị văn bản về số thì bạn có thể nhân với 1, chẳng hạn như =D4*1 hoặc sử dụng toán tử đơn phân kép (--), chẳng hạn như =--D4.

Excel phân tách hàng nghìn bằng dấu phẩy nếu định dạng có chứa một dấu phẩy (,) được đặt giữa các ký hiệu số (#) hoặc số 0. Ví dụ: nếu chuỗi định dạng là "#,###", Excel sẽ hiển thị số 12200000 dưới dạng 12.200.000.

Dấu phẩy theo sau chỗ dành sẵn chữ số sẽ phân tách số theo 1.000. Ví dụ: nếu chuỗi định dạng là "#.###, 0.", Excel sẽ hiển thị số 12200000 dưới dạng 12.200,0.

Ví dụ về các hàm TEXT sử dụng dấu tách Hàng nghìn

Ghi chú: 

  • Dấu tách hàng nghìn phụ thuộc vào thiết đặt khu vực của bạn. Ở Hoa Kỳ, đó là dấu phẩy nhưng ở các khu vực khác đó có thể là dấu chấm (.).

  • Dấu tách hàng nghìn khả dụng cho các định dạng số, tiền tệ và kế toán.

Dưới đây là ví dụ về số tiêu chuẩn (chỉ dấu tách hàng nghìn và số thập phân), các định dạng tiền tệ và kế toán. Định dạng tiền tệ cho phép bạn chèn ký hiệu tiền tệ mà bạn lựa chọn, rồi sắp xếp ký hiệu này cạnh giá trị của bạn, trong khi định dạng kế toán sẽ sắp xếp ký hiệu tiền tệ về phía bên trái của ô và giá trị về phía bên phải. Lưu ý điểm khác biệt giữa các mã định dạng tiền tệ và kế toán dưới đây, trong đó, kế toán sử dụng dấu sao (*) để tạo phân tách giữa ký hiệu và giá trị.

Ví dụ về các hàm TEXT có định dạng Số, Tiền tệ và Kế toán

Để tìm mã định dạng cho một ký hiệu tiền tệ, trước tiên hãy nhấn Ctrl + 1 (hoặc Hình ảnh biểu tượng nút Command trong MAC +1 trên máy Mac), chọn định dạng bạn muốn, rồi chọn một biểu tượng từ danh sách thả xuống Ký hiệu:

Tuyển tập Ký hiệu Tiền tệ từ hộp thoại Định dạng Ô

Sau đó, bấm vào Tùy chỉnh ở bên trái mục Thể loại và sao chép mã định dạng, gồm cả ký hiệu tiền tệ.

Hàm TEXT - Tùy chỉnh tiền tệ với ký hiệu

Ghi chú: Hàm TEXT không hỗ trợ định dạng màu nên nếu bạn sao chép mã định dạng số từ hộp thoại Định dạng Ô, bao gồm màu, có dạng như sau: $#.##0,00_);[Red]($#.##0,00), hàm TEXT sẽ chấp nhận mã định dạng nhưng sẽ không hiển thị màu.

Bạn có thể thay đổi cách hiển thị ngày tháng bằng cách dùng kết hợp "M" cho tháng, "D" cho ngày và "Y" cho năm.

Mã định dạng Tháng, Ngày và Năm

Mã định dạng trong hàm TEXT không phân biệt chữ hoa chữ thường nên bạn có thể sử dụng"M" hoặc "m", "D" hoặc "d", "Y" hoặc "y".

Excel MVP Mynda Treacy

Mynda Đề xuất...

Nếu bạn chia sẻ tệp và báo cáo Excel với người dùng ở các quốc gia khác, khi đó, bạn có thể muốn cung cấp báo cáo bằng ngôn ngữ của họ. Excel MVP, Mynda Treacy có một giải pháp tuyệt vời trong bài viết Ngày Excel Được hiển thị ở Ngôn ngữ Khác này. Có sẵn cả sổ làm việc mẫu để bạn tải xuống.

Bạn có thể thay đổi cách hiển thị thời gian bằng cách sử dụng kết hợp "H" cho giờ, "M" cho phút hoặc "S" cho giây và "SA/CH" cho định dạng 12 giờ.

Định dạng thời gian cho giờ, phút và giây

Nếu bạn bỏ "SA/CH" hoặc "S/C" thì thời gian sẽ hiển thị dựa theo định dạng 24 giờ.

Mã định dạng trong hàm TEXT không phân biệt chữ hoa chữ thường nên bạn có thể sử dụng "H" hoặc "h", "M" hoặc "m", "S" hoặc "s", "SA/CH" hoặc "sa/ch".

Bạn có thể thay đổi cách hiển thị các giá trị thập phân với các định dạng phần trăm (%).

Mã định dạng cho Phần trăm

Bạn có thể thay đổi cách hiển thị các giá trị thập phân với các định dạng phân số (?/?).

Mã định dạng cho Phân số

Ký hiệu khoa học là một cách hiển thị số dưới dạng số thập phân trong khoảng từ 1 đến 10, nhân với lũy thừa của 10. Ký hiệu khoa học thường được sử dụng để rút gọn cách hiển thị các số lớn.

Mã định dạng cho ký hiệu Khoa học

Excel cung cấp 4 định dạng đặc biệt:

  • Mã Zip - "00000"

  • Mã Zip + 4 - "00000-0000"

  • Số Điện thoại - "[<=9999999]###-####;(###) ###-####"

  • Số An sinh Xã hội - "000-00-0000"

Các định dạng đặc biệt cho hàm TEXT

Cách định dạng đặc biệt sẽ khác nhau tùy theo khu vực nhưng nếu không có bất kỳ định dạng đặc biệt nào cho khu vực của bạn hoặc nếu những định dạng này không đáp ứng được nhu cầu của bạn thì bạn có thể tạo định dạng riêng của mình thông qua hộp thoại Định dạng Ô > Tùy chỉnh.

Kịch bản phổ biến

Hàm TEXT hiếm khi được sử dụng một mình và hàm này thường được sử dụng kết hợp với hàm khác. Giả sử bạn muốn kết hợp văn bản với một giá trị số, chẳng hạn như “Báo cáo Được in vào ngày: 14/03/12" hoặc "Doanh thu Hàng tuần: $66.348,72". Bạn có thể nhập giá trị đó vào Excel bằng cách thủ công nhưng như vậy sẽ không đạt mục đích là để Excel thực hiện cho bạn. Rất tiếc, khi bạn kết hợp văn bản với các số được định dạng, như ngày tháng, thời gian, tiền tệ, v.v., Excel không biết cách bạn muốn hiển thị chúng nên Excel sẽ sử dụng định dạng số. Đây là nơi hàm TEXT phát huy giá trị vì hàm này cho phép bạn buộc Excel phải định dạng các giá trị theo cách bạn muốn bằng mã định dạng, như định dạng "DD/MM/YY" cho định dạng ngày tháng.

Trong ví dụ sau, bạn sẽ thấy điều gì sẽ xảy ra nếu bạn tìm cách kết hợp văn bản với số mà không sử dụng hàm TEXT. Trong trường hợp này, chúng tôi đang sử dụng dấu và (&) để ghép một chuỗi văn bản, một dấu cách (" ") và một giá trị với =A2&" "&B2.

Ví dụ về việc ghép văn bản không sử dụng hàm TEXT

Như bạn có thể thấy, Excel đã loại bỏ định dạng khỏi ngày tháng trong ô B2. Trong ví dụ tiếp theo, bạn sẽ thấy cách hàm TEXT giúp bạn áp dụng định dạng bạn muốn.

Ví dụ về việc ghép văn bản sử dụng hàm TEXT

Công thức cập nhật của chúng tôi là:

  • Ô C2: =A2&" "&TEXT(B2,"dd/mm/yy") - Định dạng ngày tháng

Các Câu hỏi Thường gặp

Rất tiếc, bạn không thể thực hiện điều đó với hàm TEXT, bạn cần sử dụng mã Visual Basic for Applications (VBA). Liên kết sau chứa một phương pháp: Làm thế nào để tôi có thể chuyển đổi một giá trị số thành từ tiếng Anh trong Excel

Có, bạn có thể sử dụng các hàm UPPER, LOWERPROPER. Ví dụ: =UPPER("hello") sẽ trả về "HELLO".

Có, nhưng bạn phải thực hiện một vài bước. Trước tiên, hãy chọn ô hoặc các ô mà bạn muốn điều này xảy ra và sử dụng Ctrl+1 để hiển thị hộp thoại Định dạng> Ô, rồi Căn chỉnh > Quản lý văn bản > đánh dấu vào tùy chọn Ngắt dòng Văn bản. Tiếp theo, điều chỉnh hàm TEXT đã hoàn thiện của bạn để tích hợp hàm ASCII CHAR(10) vào nơi bạn muốn có ngắt dòng. Có thể bạn cần phải điều chỉnh độ rộng của cột tùy theo cách căn chỉnh kết quả cuối cùng.

Ví dụ về việc sử dụng TEXT với CHAR(10) để chèn ngắt dòng. = "Hôm nay là:" & CHAR(10)) & TEXT(TODAY(),"MM/DD/YY")

Trong trường hợp này, chúng tôi đã sử dụng: ="Hôm nay là: "&CHAR(10)&TEXT(TODAY(),"dd/mm/yy")

Đây được gọi là Ký hiệu Khoa học và Excel sẽ tự động chuyển đổi các số dài hơn 12 chữ số nếu (các) ô được định dạng dưới dạng Chung và 15 chữ số nếu (các) ô được định dạng dưới dạng Số. Nếu bạn cần nhập các chuỗi số dài nhưng không muốn chuyển đổi chúng thì hãy định dạng các ô đang cân nhắc dưới dạng Văn bản trước khi bạn nhập hoặc dán các giá trị của mình vào Excel.

Excel MVP Mynda Treacy

Mynda Đề xuất...

Nếu bạn chia sẻ tệp và báo cáo Excel với người dùng ở các quốc gia khác, khi đó, bạn có thể muốn cung cấp báo cáo bằng ngôn ngữ của họ. Excel MVP, Mynda Treacy có một giải pháp tuyệt vời trong bài viết Ngày Excel Được hiển thị ở Ngôn ngữ Khác này. Có sẵn cả sổ làm việc mẫu để bạn tải xuống.

Xem Thêm

Tạo hoặc xóa một định dạng số tùy chỉnh

Chuyển đổi văn bản thành số

Tất cả các hàm Excel (theo danh mục)

Phát triển các kỹ năng của bạn
Khám phá nội dung đào tạo
Sở hữu tính năng mới đầu tiên
Tham gia Người dùng nội bộ Office

Thông tin này có hữu ích không?

Cảm ơn phản hồi của bạn!

Cảm ơn bạn đã phản hồi! Để trợ giúp tốt hơn, có lẽ chúng tôi sẽ kết nối bạn với một trong những nhân viên hỗ trợ Office của chúng tôi.

×