Tổng quan về công thức

Quan trọng   Kết quả được tính toán của công thức và một số hàm trang tính Excel có thể khá khác biệt giữa máy tính chạy Windows sử dụng kiến trúc x86 hoặc x86-64 và máy tính RT chạy Windows sử dụng kiến trúc ARM. Tìm hiểu thêm về các khác biệt.

Nếu bạn mới dùng Excel, bạn sẽ thấy ngay rằng công thức không chỉ là một lưới mà bạn nhập số trong cột hoặc hàng. Vâng, bạn có thể sử dụng Excel để tìm tổng của một cột hoặc hàng số, nhưng bạn cũng có thể tính một khoản thanh toán vay thế chấp, giải toán hoặc các vấn đề kỹ thuật hoặc tìm một kịch bản tốt nhất dựa trên các biến số mà bạn nhập vào.

Excel thực hiện điều này bằng cách sử dụng các công thức trong ô. Một công thức thực hiện các phép tính hoặc các hành động khác trên dữ liệu trong trang tính của bạn. Một công thức luôn luôn bắt đầu với một dấu bằng (=), có thể theo sau là các số, toán tử toán học (như dấu cộng hoặc dấu trừ) và các hàm có thể thật sự tăng cường sức mạnh của công thức.

Ví dụ, công thức sau đây có 2 nhân với 3 và sau đó cộng thêm 5 vào kết quả đáp án là 11.

=2*3+5

Công thức tiếp theo sử dụng hàm PMT để tính toán một khoản thanh toán vay thế chấp ($1.073,64), dựa trên lãi suất là 5% (5% chia cho 12 tháng bằng lãi suất hàng tháng) trong khoảng thời gian 30 năm (360 tháng) cho khoản vay là $200.000:

=PMT(0.05/12,360,200000)

Đây là một số ví dụ thêm về các công thức bạn có thể nhập vào một trang tính.

  • =A1+A2+A3    Thêm giá trị vào các ô A1, A2 và A3.

  • =SQRT(A1)     Dùng hàm SQRT để trả về căn bậc hai của giá trị trong A1.

  • =TODAY()     Trả về ngày hiện tại.

  • =UPPER("hello")     Chuyển đổi văn bản "hello" thành "HELLO" bằng cách sử dụng hàm trang tính UPPER.

  • =IF(A1>0)     Kiểm tra ô A1 để xác định liệu nó có chứa giá trị lớn hơn 0 hay không.

Trong bài viết này

Các phần của một công thức

Dùng hằng số trong công thức

Dùng toán tử tính toán trong các công thức

Các dạng toán tử

Toán tử số học

Toán tử so sánh

Toán tử móc nối văn bản

Toán tử tham chiếu

Thứ tự Excel thực hiện thao tác trong công thức

Thứ tự Tính toán

Ưu tiên Toán tử

Dùng dấu ngoặc đơn

Dùng hàm và hàm được lồng vào trong công thức

Cú pháp hàm

Nhập hàm

Các hàm lồng vào

Dùng tham chiếu trong công thức

Kiểu tham chiếu A1

Sự khác nhau giữa các tham chiếu tuyệt đối, tương đối và hỗn hợp

Kiểu tham chiếu 3-D

Kiểu tham chiếu R1C1

Dùng tên trong công thức

Các ví dụ trong một sổ làm việc

Kiểu tên

Tạo và nhập tên

Dùng công thức mảng và các hằng số mảng

Dùng một công thức mảng để tính một và nhiều kết quả.

Sử dụng các hằng số mảng

Các phần của một công thức

Một công thức có thể cũng bao gồm bất kỳ hoặc tất cả các thành phần sau đây hàm, tham chiếu ô, toán tử và hằng.

Các phần của một công thức

1. Hàm: Hàm PI() trả về giá trị của pi: 3,142...

2. Tham chiếu: A2 trả về giá trị trong ô A2.

3. Hằng số: Các số hoặc giá trị văn bản được nhập trực tiếp vào một công thức, như 2.

4. Toán tử: Toán tử ^ (mũ) nâng một số lên theo một lũy thừa và toán tử (dấu sao) * nhân các số.

Đầu Trang

Dùng hằng số trong công thức

Một hằng số là một giá trị không được tính toán; nó luôn luôn giữ nguyên. Ví dụ: ngày 9/10/2008, số 210 và nội dung "Thu nhập Hàng quý" tất cả là các hằng số. Một biểu thức hay giá trị có được từ biểu thức không phải là một hằng số. Nếu bạn sử dụng hằng số trong một công thức thay vì tham chiếu đến các ô (ví dụ, =30+70+110), kết quả chỉ thay đổi nếu bạn sửa đổi công thức.

Đầu Trang

Dùng toán tử tính toán trong các công thức

Toán tử xác định cụ thể kiểu tính toán mà bạn muốn thực hiện trên các thành phần của một công thức. Các tính toán xuất hiện theo một thứ tự mặc định (theo các quy tắc toán học chung) nhưng bạn có thể thay đổi thứ tự này bằng các sử dụng các dấu ngoặc đơn.

Các dạng toán tử

Có bốn dạng toán tử tính toán khác nhau: số học, so sánh, móc nối văn bản và tham chiếu.

Toán tử số học

Để thực hiện các toán tử toán học căn bản, như cộng, trừ, nhân hoặc chia, kết hợp số và tính ra các kết quả bằng số, hãy sử dụng các toán tử số học sau.

Toán tử số học

Ý nghĩa

Ví dụ

+ (dấu cộng)

Cộng

3+3

- (dấu trừ)

Trừ
Dạng phủ định

3-1
-1

* (dấu sao)

Nhân

3*3

/ (dấu xuyệc ngược)

Chia

3/3

% (dấu phần trăm)

Tỷ lệ phần trăm

20%

^ (mũ)

Nâng lũy thừa

3^2

Toán tử so sánh

Bạn có thể so sánh hai giá trị với các toán tử sau đây. Khi hai giá trị được so sánh bằng cách sử dụng các toán tử này, kết là một giá trị lô-gic — TRUE hoặc FALSE.

Toán tử so sánh.

Ý nghĩa

Ví dụ

= (dấu bằng)

Bằng

A1=B1

> (dấu lớn hơn)

Lớn hơn.

A1>B1

< (dấu nhỏ hơn)

Nhỏ hơn

A1<B1

>= (dấu lớn hơn hoặc bằng)

Lớn hơn hoặc bằng

A1>=B1

<= (dấu nhỏ hơn hoặc bằng)

Nhỏ hơn hoặc bằng

A1<=B1

<> (dấu khác)

Khác

A1<>B1

Toán tử móc nối văn bản

Sử dụng dấu và (&) để móc nối (kết nối) một hoặc nhiều chuỗi văn bản để tạo một đoạn văn bản duy nhất.

Toán tử văn bản

Ý nghĩa

Ví dụ

& (dấu và)

Kết nối hoặc móc nối hai giá trị để tạo thành một giá trị văn bản liên tục

"North"&"wind" kết quả là "Northwind"

Toán tử tham chiếu

Kết nối các phạm vi ô cho các tính toán với các toán tử sau đây.

Toán tử tham chiếu

Ý nghĩa

Ví dụ

: (dấu hai chấm)

Toán tử phạm vi tạo một tham chiếu đến tất cả các ô giữa hai tham chiếu bao gồm cả hai tham chiếu.

B5:B15

, (dấu phẩy)

Toán tử liên kết, kết hợp nhiều tham chiếu thành một tham chiếu

SUM(B5:B15,D5:D15)

(khoảng trống)

Toán tử giao, tạo một tham chiếu đến các ô chung cho hai tham chiếu

B7:D7 C6:C8

Thứ tự Excel thực hiện thao tác trong công thức

Trong một số trường hợp, thứ tự tính toán được thực hiện có thể ảnh hưởng đến giá trị trả lại của công thức, vì vậy việc hiểu thứ tự được xác định thế nào và cách bạn có thể thay đổi thứ tự để đạt kết quả mà bạn muốn rất quan trọng.

Thứ tự Tính toán

Công thức tính toán giá trị theo một thứ tự cụ thể. Một công thức trong Excel luôn bắt đầu bằng dấu bằng (=). Excel sẽ hiểu rằng các ký tự theo sau dấu bằng là một công thức. Theo sau dấu bằng là các thành phần được tính toán (toán hạng), như hằng số hoặc tham chiếu ô. Những thành phần này được phân tách bởi các toán tử tính toán. Excel tính toán công thức từ trái sang phải, theo một thứ tự cụ thể cho mỗi toán tử trong công thức.

Ưu tiên Toán tử

Nếu bạn kết hợp một số toán tử trong một công thức, Excel thực hiện các thao tác theo thứ tự được hiển thị trong bảng sau. Nếu một công thức bao gồm các toán tử với ưu tiên giống nhau — ví dụ, nếu một công thức bao gồm toán tử nhân và chia — Excel sẽ đánh giá các toán tử từ trái sang phải.

Toán tử

Mô tả

: (dấu hai chấm)

(dãn cách đơn)

, (dấu phẩy)

Toán tử tham chiếu

Dạng phủ định (như trong –1)

%

Tỷ lệ phần trăm

^

Nâng lũy thừa

* và /

Phép nhân và chia

+ và –

Phép cộng và trừ

&

Kết nối hai chuỗi văn bản (móc nối)

=
< >
<=
>=
<>

So sánh

Dùng dấu ngoặc đơn

Để thay đổi thứ tự đánh giá, hãy đặt phần công thức cần được tính toán trước trong dấu ngoặc đơn. Ví dụ, công thức sau đây cho kết quả là 11 bởi vì Excel thực hiện phép nhân trước phép cộng. Công thức có 2 nhân với 3 và sau đó cộng thêm 5 vào kết quả.

=5+2*3

Ngược lại, nếu bạn sử dụng dấu ngoặc đơn để thay đổi cú pháp, Excel cộng 5 và 2 với nhau và nhân kết quả với 3 ra kết quả là 21.

=(5+2)*3

Trong ví dụ sau đây, phần đầu tiên của công thức được đặt trong dấu ngoặc đơn bắt buộc Excel tính B4+25 trước và sau đó chia kết quả cho tổng các giá trị trong các ô D5, E5 và F5.

=(B4+25)/SUM(D5:F5)

Đầu Trang

Dùng hàm và hàm được lồng vào trong công thức

Hàm là công thức được định sẵn thực hiện tính toán bằng cách sử dụng các giá trị cụ thể, gọi là các đối số theo một thứ tự hoặc cấu trúc cụ thể. Hàm có thể được sử dụng để thực hiện các tính toán đơn giản hoặc phức tạp.

Cú pháp hàm

Ví dụ sau đây của hàm ROUND làm tròn một số trong ô A10 minh họa cú pháp của một hàm.

Cấu trúc của một hàm

1. Cấu trúc. Cấu trúc của một hàm bắt đầu với dấu bằng (=), theo sau bởi tên hàm, một dấu ngoặc đơn mở, các đối số cho hàm được phân tách bởi dấu phẩy và dấu ngoặc đơn đóng.

2. Tên hàm. Đối với danh sách các hàm sẵn dùng, hãy bấm một ô và bấm SHIFT+F3.

3. Đối số. Đối số có thể là số, văn bản, giá trị lô-gic như TRUE hoặc FALSE, mảng, giá trị lỗi như #N/A, hoặc tham chiếu ô. Đối số mà bạn chỉ định phải tạo giá trị hợp lệ cho đối số đó. Đối số cũng có thể là hằng, công thức hoặc hàm khác.

4. Mẹo công cụ về đối số. Một mẹo công cụ với cú pháp và đối số xuất hiện khi bạn nhập hàm. Ví dụ, nhập =ROUND( và mẹo công cụ xuất hiện. Mẹo công cụ chỉ xuất hiện cho các hàm dựng sẵn.

Nhập hàm

Khi bạn tạo một công thức có bao gồm một hàm, bạn có thể sử dụng hộp thoại Chèn Hàm để giúp bạn nhập các hàm cho trang tính. Khi bạn nhập một hàm vào một công thức, hộp thoại Chèn Hàm hiển thị tên của hàm, mỗi đối số của hàm, một phần mô tả của hàm và mỗi đối số, kết quả hiện tại của hàm và kết quả hiện tại của toàn bộ công thức.

Để giúp tạo và sửa các công thức dễ dàng hơn và giảm thiểu lỗi gõ nhập và cú pháp, hãy dùng Formula AutoComplete (Tự động Điền Công thức). Sau khi bạn gõ = (dấu bằng) và chữ cái bắt đầu hoặc lẫy hiển thị, dưới ô đó, Excel hiển thị danh sách động thả xuống gồm các hàm hợp lệ, đối số và tên khớp với các chữ cái hoặc lẫy. Bạn có thể chèn một mục từ danh sách thả xuống này vào công thức.

Các hàm lồng vào

Trong trường hợp nhất định, bạn có thể cần sử dụng một hàm như một trong các tham đối của hàm khác. Ví dụ, công thức sau đây sử dụng một hàm được lồng vào AVERAGE và so sánh kết quả với giá trị 50.

1. Các hàm AVERAGE và SUM được lồng vào trong hàm IF.

Giá trị trả về hợp lệ     Khi một hàm lồng được sử dụng như một đối số, hàm lồng phải trả về dạng giá trị giống với giá trị mà đối số sử dụng. Ví dụ, nếu một hàm trả về giá trị TRUE hoặc FALSE, hàm được lồng vào phải trả về giá trị TRUE hoặc FALSE. Nếu một hàm không trả về, Excel sẽ hiển thị giá trị lỗi #VALUE! .

Giới hạn mức độ lồng    Một công thức có thể chứa đến bảy mức độ hàm lồng. Khi một hàm (chúng ta sẽ gọi là Hàm B) được sử dụng như một đối số trong một hàm khác (chúng ta sẽ gọi là Hàm A), Hàm B đóng vai trò một hàm mức hai. Ví dụ, cả hàm AVERAGE và hàm SUM đều là hai hàm mức hai nếu chúng được sử dụng như các đối số của hàm IF. Một hàm được lồng vào trong hàm AVERAGE đã được lồng khi đó sẽ là hàm mức ba và v.v.

Đầu Trang

Dùng tham chiếu trong công thức

Một tham chiếu nhận dạng một ô hoặc một phạm vi ô trên trang tính và cho Excel biết chỗ tìm giá trị hoặc dữ liệu mà bạn muốn dùng trong công thức. Bạn có thể sử dụng các tham chiếu để sử dụng các dữ liệu được bao gồm trong các phần khác của một trang tính trong một công thức hoặc sử dụng giá trị từ một ô trong một số công thức. Bạn cũng có thể tham chiếu đến trang tính khác trong cùng một sổ làm việc và đến các sổ làm việc khác. Các tham chiếu đến ô trong các sổ làm việc khác được gọi là các nối kết hoặc tham chiếu ngoài.

Kiểu tham chiếu A1

Kiểu tham chiếu mặc định    Theo mặc định, Excel dùng kiểu tham chiếu A1, tham chiếu đến cột có chữ cái (từ A đến XFD, tổng cộng 16.384 cột) và tham chiếu đến hàng có số ( từ 1 đến 1.048.576). Các chữ và số này được gọi là các tiêu đề hàng và cột. Để tham chiếu đến một ô, hãy nhập chữ cái của cột theo sau là số của hàng. Ví dụ, B2 tham chiếu đến ô xuất hiện ở phần giao cắt giữa cột B và hàng 2.

Để tham chiếu đến

Sử dụng

Ô trong cột A và hàng 10

A10

Phạm vi ô giữa cột A và các hàng từ 10 đến 20

A10:A20

Phạm vi ô giữa hàng 15 và các cột từ B đến E

B15:E15

Tất cả các ô trong hàng 5

5:5

Tất cả các ô trong hàng 5 đến 10

5:10

Tất cả các ô trong cột H

H:H

Tất cả các ô trong cột từ H đến J

H:J

Phạm vi ô trong cột A đến E và các hàng từ 10 đến 20

A10:E20

Tạo tham chiếu đến một trang tính khác     Trong ví dụ sau đây, hàm trang tính AVERAGE tính giá trị trung bình cho phạm vi B1:B10 trên trang tính có tên là Tiếp thị trong cùng sổ làm việc.

Tham chiếu một khoảng ô trên một trang tính khác trong cùng sổ làm việc

1. Tham chiếu trang tính có tên là Tiếp thị

2. Tham chiếu khoảng ô giữa B1 và B10, bao gồm cả hai ô này

3. Phân tách tham chiếu trang tính với tham chiếu phạm vi ô

Sự khác nhau giữa các tham chiếu tuyệt đối, tương đối và hỗn hợp

Tham chiếu tương đối     Một tham chiếu ô tương đối trong công thức như A1, được dựa trên vị trí tương đối của ô chứa công thức và ô được tham chiếu đến. Nếu vị trí ô bao gồm các thay đổi công thức, tham chiếu được thay đổi. Nếu bạn sao chép hoặc điền công thức qua hàng ngang hoặc cột dọc, tham chiếu tự động điều chỉnh. Theo mặc định, các công thức mới sử dụng tham chiếu tương đối. Ví dụ, nếu bạn sao chép hoặc điền một tham chiếu tương đối trong ô B2 đến ô B3, nó sẽ tự động điều chỉnh từ =A1 sang =A2.

Công thức được sao chép với tham chiếu tương đối

Tham chiếu tuyệt đối     Một tham chiếu ô tuyệt đối trong một công thức, như $A$1, luôn luôn tham chiếu đến một ô tại một vị trí cụ thể. Nếu vị trí ô bao gồm các thay đổi công thức, tham chiếu được thay đổi, tham chiếu tuyệt đối vẫn giữ nguyên. Nếu bạn sao chép hoặc điền công thức qua hàng ngang hoặc cột dọc, tham chiếu tuyệt đối sẽ không điều chỉnh. Theo mặc định, các công thức mới sử dụng các tham chiếu tương đối, vì vậy bạn có thể cần chuyển chúng sang các tham chiếu tuyệt đối. Ví dụ, nếu bạn sao chép hoặc điền một tham chiếu tuyệt đối trong ô B2 đến ô B3, nó sẽ giữ nguyên trong cả hai ô: =$A$1.

Công thức được sao chép với tham chiếu tuyệt đối

Tham chiếu hỗn hợp     Một tham chiếu hỗn hợp có một cột tuyệt đối hoặc một hàng tương đối, hoặc hàng tuyệt đối và cột tương đối. Một tham chiếu cột tuyệt đối có dạng $A1, $B1 và v.v. Một tham chiếu hàng tuyệt đối có dạng A$1, B$1 và v.v. Nếu vị trí ô bao gồm các thay đổi công thức, tham chiếu tương đối được thay đổi và tham chiếu tuyệt đối không thay đổi. Nếu bạn sao chép hoặc điền công thức qua hàng ngang hoặc cột dọc, tham chiếu tương đối tự động điều chỉnh và tham chiếu tuyệt đối sẽ không điều chỉnh. Ví dụ, nếu bạn sao chép hoặc điền một tham chiếu hỗn hợp từ ô A2 đến B3, nó sẽ điều chỉnh từ =A$1 sang =B$1.

Công thức được sao chép với tham chiếu hỗn hợp

Kiểu tham chiếu 3-D

Tham chiếu thuận tiện nhiều trang tính     Nếu bạn muốn phân tích dữ liệu trong cùng một ô hoặc phạm vi các ô trên nhiều trang tính trong một sổ làm việc, hãy dùng tham chiếu 3-D. Một tham chiếu 3-D bao gồm tham chiếu ô hoặc phạm vi, trước đó là một phạm vi tên trang tính. Excel sử dụng bất kỳ trang tính nào được lưu giữa tên mở đầu và kết thúc của một tham chiếu. Ví dụ, =SUM(Sheet2:Sheet13!B5) thêm tất cả các giá trị được bao gồm trong ô B5 trên tất cả các trang tính ở giữa và bao gồm Trang 2 và Trang 13.

  • Bạn có thể sử dụng các tham chiếu 3-D để tham chiếu đến các ô trên trang tính khác, để xác định tên và để tạo công thức bằng cách sử dụng các hàm sau đây: SUM, AVERAGE, AVERAGEA, COUNT, COUNTA, MAX, MAXA, MIN, MINA, PRODUCT, STDEV.P, STDEV.S, STDEVA, STDEVPA, VAR.P, VAR.S, VARA và VARPA.

  • Không thể dùng tham chiếu 3-D trong công thức mảng.

  • Không thể dùng tham chiếu 3-D với toán tử phần giao (một khoảng trắng) hoặc trong các công thức sử dụng giao cắt ngầm.

Điều gì xảy ra khi bạn di chuyển, sao chép, chèn, hoặc xóa trang tính     Ví dụ sau giải thích những gì xảy ra khi bạn di chuyển, sao chép, chèn, hoặc xóa trang tính nằm trong một tham chiếu 3-D. Các ví dụ sử dụng công thức =SUM(Sheet2:Sheet6!A2:A5) để thêm các ô từ A2 đến A5 trên các trang tính từ 2 đến 6.

  • Chèn hoặc sao chép     Nếu bạn chèn hoặc sao chép các trang tính từ Trang 2 đến Trang 6 (điểm kết thúc trong ví dụ này), Excel bao gồm tất cả giá trị trong ô A2 đến A5 từ các trang được thêm vào trong phần tính toán.

  • Xóa     Nếu bạn xóa các trang tính nằm giữa Trang 2 và Trang 6, Excel sẽ loại bỏ các giá trị khỏi phép tính.

  • Di chuyển     Nếu bạn di chuyển các trang từ giữa Trang 2 và Trang 6 đến một vị trí ngoài phạm vi trang tính được tham chiếu, Excel sẽ loại bỏ các giá trị của trang khỏi phép tính.

  • Di chuyển điểm cuối     Nếu bạn di chuyển Trang 2 hoặc Trang 6 đến vị trí khác trong cùng sổ làm việc, Excel điều chỉnh tính toán cho phù hợp với một phạm vi trang tính mới giữa chúng.

  • Xóa điểm cuối     Nếu bạn xóa Trang 2 hoặc Trang 6, Excel điều chỉnh tính toán để phù hợp với một phạm vi trang tính giữa chúng.

Kiểu tham chiếu R1C1

Bạn cũng có thể sử dụng một kiểu tham chiếu có cả hàng và cột trên trang tính được đánh số. Kiểu tham chiếu R1C1 có ích trong việc tính toán các vị trí hàng và cột trong macro. Trong kiểu R1C1, Excel chỉ ra vị trí của một ô với một "R" theo sau là số của hàng và một "C" theo sau là số của cột.

Tham chiếu

Ý nghĩa

R[-2]C

Một tham chiếu tương đối đến ô ở trên hai hàng và trong cùng cột

R[2]C[2]

Một tham chiếu tương đối đến ô ở dưới hai hàng và hai cột bên phải

R2C2

Một tham chiếu ô tuyệt đối đến ô trong hàng thứ hai và trong cột thứ hai.

R[-1]

Một tham chiếu tương đối đến toàn bộ hàng trên ô hiện hoạt

R

Một tham chiếu tuyệt đối đến hàng hiện tại

Khi bạn ghi một macro, Excel ghi một số lệnh bằng cách sử dụng kiểu tham chiếu R1C1. Ví dụ, nếu bạn ghi một lệnh, như bấm nút AutoSum để chèn một công thức thêm một phạm vi ô, Excel ghi công thức bằng cách dùng kiểu tham chiếu R1C1, không phải kiểu A1.

Bạn có thể bật hay tắt tham chiếu R1C1 bằng cách thiết đặt hoặc xóa hộp kiểm Kiểu tham chiếu R1C1 dưới phần Làm việc với công thức trong hộp thoại Công thức, thể loại Tùy chọn. Để hiển thị hộp thoại này, hãy bấm tab Tệp.

Đầu Trang

Dùng tên trong công thức

Bạn có thể tạo tên xác định để đại diện ô, phạm vi ô, công thức, hằng số hoặc các bảng Excel. Tên là một tên tắt có ý nghĩa giúp dễ dàng hơn hiểu mục đích của tham chiếu ô, hằng số, công thức, hoặc bảng, mà mỗi đối tượng này có thể khó hiểu lúc mới nhìn qua. Thông tin sau đây hiển thị các ví dụ tên thường gặp và việc sử dụng chúng trong các công thức có thể cải thiện tính rõ nghĩa và giúp công thức dễ hiểu hơn.

Kiểu ví dụ

Ví dụ, sử dụng phạm vi thay vì tên

Ví dụ, sử dụng tên

Tham chiếu

=SUM(A16:A20)

=SUM(Sales)

Hằng số

=PRODUCT(A12,9.5%)

=PRODUCT(Price,KCTaxRate)

Công thức

=TEXT(VLOOKUP(MAX(A16,A20),A16:B20,2,FALSE),"m/dd/yyyy")

=TEXT(VLOOKUP(MAX(Sales),SalesInfo,2,FALSE),"m/dd/yyyy")

Bảng

A22:B25

=PRODUCT(Price,Table1[@Tax Rate])

Các ví dụ trong một sổ làm việc

Các sổ làm việc bên dưới sẽ đưa ra những ví dụ về hàm này. Hãy kiểm tra chúng, rồi thay đổi các công thức hiện có hoặc nhập công thức của riêng bạn để tìm hiểu cách thức hoạt động của hàm này.

Sao chép dữ liệu của ví dụ trong bảng sau đây và dán vào ô A1 của một trang tính Excel mới. Để công thức hiển thị kết quả, hãy chọn chúng, nhấn F2 và sau đó nhấn Enter. Nếu cần, bạn có thể điều chỉnh độ rộng cột để xem tất cả dữ liệu.

Kiểu ví dụ

Ví dụ, không sử dụng tên

Ví dụ, sử dụng tên

Công thức và kết quả, sử dụng tên

Tham chiếu

'=SUM(A9:A13)

'=SUM(Sales)

=SUM(Sales)

Công thức

'=TEXT(VLOOKUP(MAX(A9:13),A9:B13,2,FALSE),"m/dd/yyyy")

'=TEXT(VLOOKUP(MAX(Sales),SalesInfo,2,FALSE),"m/dd/yyyy")

=TEXT(VLOOKUP(MAX(Sales),SalesInfo,2,FALSE),"m/dd/yyyy")

Giá

$995

Doanh số

Ngày Bán

$249

17/03/11

$399

02/04/2011

$643

23/04/2011

$275

30/04/2011

$447

04/05/2011

Ghi chú: Trong công thức trong các cột C và D, tên "Sales" xác định thay thế cho tham chiếu đến (phạm vi) A9:A13 và tên "SalesInfo" thay thế cho phạm vi A9:B13.

Để làm việc chuyên sâu hơn với dữ liệu mẫu trong Excel, hãy tải xuống sổ làm việc được nhúng vào máy tính của bạn, rồi mở trong Excel.

Kiểu tên

Có một vài kiểu tên mà bạn có thể tạo và sử dụng.

Tên xác định    Một tên đại diện cho một ô, phạm vi các ô, công thức, hoặc giá trị hằng số. Bạn có thể tạo tên xác định của riêng mình. Excel thỉnh thoảng tạo tên xác định cho bạn, như khi bạn thiết lập một vùng in.

Tên bảng     Một tên cho bảng Excel, là một tập hợp dữ liệu về một chủ đề cụ thể được lưu trữ trong các bản ghi (hàng) và trường (cột). Excel tạo một tên bảng Excel mặc định là "Table1", "Table2" v.v. mỗi lần bạn chèn một bảng Excel, nhưng bạn có thể đổi các tên này để nó có ý nghĩa hơn.

Để biết thêm thông tin về các bảng Excel, hãy xem Sử dụng các tham chiếu được cấu trúc với các bảng Excel.

Tạo và nhập tên

Bạn có thể tạo tên bằng cách dùng:

  • Hộp tên trên thanh công thức     Hiệu quả nhất khi dùng để tạo tên cấp độ sổ làm việc cho phạm vi được chọn.

  • Tạo tên từ vùng chọn    Bạn có thể dễ dàng tạo tên từ nhãn hàng và cột hiện có bằng cách dùng một vùng chọn ô trong trang tính.

  • Tên hộp thoại mới     Hiệu quả nhất khi bạn muốn linh hoạt hơn trong việc tạo tên, như xác định phạm vi mức độ trang tính cục bộ hoặc tạo chú thích tên.

Ghi chú   Theo mặc định, tên sử dụng tham chiếu ô tuyệt đối.

Bạn có thể nhập tên bằng cách:

  • Nhập     Nhập tên, ví dụ như là một đối số trong công thức.

  • Dùng Tự động điền Công thức     Dùng danh sách thả xuống Tự động điền Công thức, trong đó các tên hợp lệ sẽ tự động được liệt kê cho bạn.

  • Lựa chọn câu lệnh Dùng Công thức    Chọn một tên xác đinh từ danh sách có sẵn từ câu lệnh Dùng Công thức trong nhóm Tên Xác định trên tab Công thức.

Để biết thêm thông tin, hãy xem Xác định và dùng tên trong công thức.

Đầu Trang

Dùng công thức mảng và các hằng số mảng

Một công thức mảng có thể thực hiện nhiều tính toán và sau đó trả về một kết quả hoặc nhiều kết quả. Các công thức mảng hoạt động trên hai hoặc nhiều tập giá trị được gọi là đối số mảng. Mỗi đối số mảng phải có cùng số lượng hàng và cột. Bạn có thể tạo các công thức mảng giống như cách bạn tạo các công thức khác ngoại trừ CTRL+SHIFT+ENTER để nhập công thức. Một số hàm dựng sãn là các công thức mảng và phải được nhập như các mảng để có kết quả đúng.

Có thể sử dụng hằng số mảng thay cho tham chiếu khi bạn không cần nhập mỗi giá trị hằng số trong một ô riêng trên trang tính.

Dùng một công thức mảng để tính một và nhiều kết quả.

Khi bạn nhập một công thức mảng, Excel tự động chèn công thức giữa { } (dấu ngoặc nhọn).

Để tính toán một kết quả đơn lẻ     Loại công thức mảng này có thể đơn giản hóa kiểu trang tính bằng cách thay thế một số công thức khác nhau bằng một công thức mảng đơn.

Ví dụ, công thức sau tính toán tổng giá trị của một mảng giá cổ phiếu và cổ phần mà không dùng hàng ô để tính toán và hiển thị giá trị riêng lẻ của mỗi cổ phiếu.

Công thức mảng cho kết quả duy nhất

Khi bạn nhập công thức ={SUM(B2:D2*B3:D3)} như một công thức mảng, nó nhân Cổ phiếu và Giá cho mỗi cổ phiếu và sau đó cộng kết quả của các tính toán với nhau.

Để tính toán nhiều kết quả     Một số hàm trang tính trả về mảng giá trị hoặc yêu cầu một mảng giá trị làm đối số. Để tính toán nhiều kết quả bằng cách dùng công thức mảng, bạn phải nhập mảng vào phạm vi ô có số hàng và cột giống như đối số mảng.

Ví dụ, với chuỗi ba số liệu bán hàng (cột B) cho chuỗi ba tháng (cột A), hàm TREND sẽ xác định các giá trị đường thẳng cho các số liệu bán hàng. Để hiển thị tất cả các kết quả của công thức, hãy nhập vào ba ô trong cột C (C1:C3).

Công thức mảng cho nhiều kết quả

Khi bạn nhập công thức =TREND(B1:B3,A1:A3) làm công thức mảng, nó sẽ tạo các kết quả riêng biệt (22196, 17079 và 11962) dựa trên ba số liệu bán hàng và ba tháng.

Sử dụng các hằng số mảng

Trong một công thức thông thường, bạn có thể nhập tham chiếu đến ô bao gồm một giá trị hoặc chính giá trị đó, còn gọi là hằng số. Tương tự, trong một công thức mảng, bạn có thể nhập một tham chiếu đến một mảng hoặc nhập mảng giá trị được bao gồm trong ô, còn gọi là hằng số mảng. Các công thức mảng chấp nhận các hằng số theo cách giống như các công thức không mảng, nhưng bạn phải nhập vào các hằng số mảng theo định dạng nhất định.

Hằng số mảng có thể chứa số, văn bản, giá trị lô-gic chẳng hạn như TRUE và FALSE và giá trị lỗi, chẳng hạn như #N/A. Có thể có các dạng giá trị khác nhau trong cùng hằng số mảng  — ví dụ, {1,3,4;TRUE,FALSE,TRUE}. Các số trong hằng số mảng có thể là theo định dạng số nguyên, thập phân hoặc khoa học. Văn bản phải được bao gồm trong dấu ngoặc kép — ví dụ, "Thứ ba".

Hằng số mảng không thể bao gồm các tham chiếu ô, cột hoặc hàng có độ dài không bằng nhau, công thức hoặc các ký tự đặc biệt $ (dấu đôla), dấu ngoặc đơn hoặc dấu phần trăm (%).

Khi bạn định dạng các hằng số mảng, hãy đảm bảo bạn:

  • Bỏ chúng vào trong một dấu ngoặc nhọn ( { } ).

  • Phân tách các giá trị trong các cột khác nhau bằng cách sử dụng dấu phẩy (,). Ví dụ, để đại diện các giá trị 10, 20, 30 và 40, bạn nhập {10,20,30,40}. Hằng số mảng này được biết như là một mảng 1 x 4 và tương đương với một tham chiếu 1 hàng x 4 cột.

  • Phân tách các giá trị trong các cột khác nhau bằng cách sử dụng dấu chấm phẩy (;). Ví dụ, để đại diện các giá trị 10, 20, 30 và 40 trong một hàng và 50, 60, 70 và 80 trong hàng ngay bên dưới, bạn nhập một hằng số mảng 2 x 4: {10,20,30,40;50,60,70,80}.

Đầu Trang

Áp dụng Cho: Excel 2013



Thông tin này có hữu ích không?

Không

Chúng tôi có thể cải thiện như thế nào?

255 ký tự còn lại

Để bảo vệ sự riêng tư của bạn, vui lòng không đưa thông tin liên hệ trong phản hồi của bạn. Xem xét chính sách về quyền riêng tư.

Cảm ơn phản hồi của bạn!

Tài nguyên hỗ trợ

Thay đổi ngôn ngữ