Sử dụng các hàm IF với AND, OR và NOT

Hàm IF cho phép bạn tạo một so sánh lô-gic giữa một giá trị và một giá trị dự kiến bằng cách kiểm tra một điều kiện và trả về kết quả rằng điều kiện đó là True (đúng) hay False (sai).

  • =IF(Điều gì đó là True, thì làm gì, nếu không thì làm gì khác)

Nhưng nếu bạn cần kiểm tra nhiều điều kiện, trong đó giả sử tất cả điều kiện đều phải là True hoặc False (AND) hoặc chỉ cần một điều kiện là True hoặc False (OR) hoặc nếu bạn muốn kiểm tra xem một điều kiện có không (NOT) đáp ứng tiêu chí của bạn hay không thì sao? Cả 3 hàm đều có thể sử dụng riêng nhưng trường hợp dùng cặp với hàm IF phổ biến hơn.

Sử dụng hàm IF cùng với AND, OR và NOT để thực hiện nhiều đánh giá xem các điều kiện là True hay False.

Cú pháp

  • IF(AND()) - IF(AND(logical1, [logical2], ...), value_if_true, [value_if_false]))

  • IF(OR()) - IF(OR(logical1, [logical2], ...), value_if_true, [value_if_false]))

  • IF(NOT()) - IF(NOT(logical1), value_if_true, [value_if_false]))

Tên đối số

Mô tả

logical_test (bắt buộc)

Điều kiện bạn muốn kiểm tra.

value_if_true (bắt buộc)

Giá trị bạn muốn trả về nếu kết quả của logical_test là TRUE.

value_if_false (tùy chọn)

Giá trị bạn muốn trả về nếu kết quả của logical_test là FALSE.

Dưới đây là tổng quan về cách cấu trúc từng hàm AND, ORNOT. Khi bạn kết hợp từng hàm đó với một câu lệnh IF thì nội dung hàm sẽ như sau:

  • AND – =IF(AND(Điều gì đó là True, Điều gì đó khác là True), Giá trị nếu True, Giá trị nếu False)

  • OR – =IF(OR(Điều gì đó là True, Điều gì đó khác là True), Giá trị nếu True, Giá trị nếu False)

  • NOT – = IF (NOT(Điều gì đó là True), Giá trị nếu True, Giá trị nếu False)

Ví dụ

Sau đây là ví dụ về một số câu lệnh lồng IF(AND()), IF(OR()) và IF(NOT()) phổ biến. Các hàm AND và OR có thể hỗ trợ tối đa 255 điều kiện riêng lẻ nhưng dùng quá nhiều hàm không phải cách làm tốt vì việc xây dựng, kiểm tra và duy trì các công thức lồng ghép, phức tạp có thể sẽ trở nên khó khăn. Hàm NOT chỉ chứa một điều kiện.

Ví dụ về việc sử dụng IF với AND, OR và NOT để đánh giá các giá trị số và văn bản

Dưới đây là cách diễn giải các công thức theo lô-gic:

Công thức

Mô tả

=IF(AND(A2>0,B2<100),TRUE, FALSE)

Nếu (IF) A2 (25) lớn hơn 0 và (AND) B2 (75) nhỏ hơn 100 thì trả về TRUE, nếu không thì trả về FALSE. Trong trường hợp này cả hai điều kiện đều đúng, vì vậy trả về TRUE.

=IF(AND(A3="Red",B3="Green"),TRUE,FALSE)

Nếu (IF) A3 (“Blue”) = “Red” và (AND) B3 (“Green”) là “Green” thì trả về TRUE, nếu không thì trả về FALSE. Trong trường hợp này chỉ có điều kiện thứ hai đúng, vì vậy trả về FALSE.

=IF(OR(A4>0,B4<50),TRUE, FALSE)

Nếu (IF) A4 (25) lớn hơn 0 hoặc (OR) B4 (75) nhỏ hơn 50 thì trả về TRUE, nếu không thì trả về FALSE. Trong trường hợp này, chỉ có điều kiện đầu tiên là TRUE, nhưng vì OR chỉ yêu cầu một tham đối đúng nên công thức trả về TRUE.

=IF(OR(A5="Red",B5="Green"),TRUE,FALSE)

Nếu (IF) A5 (“Blue”) = “Red” hoặc (OR) B5 (“Green”) là “Green” thì trả về TRUE, nếu không thì trả về FALSE. Trong trường hợp này, tham đối thứ hai đúng, vì vậy công thức trả về TRUE.

=IF(NOT(A6>50),TRUE,FALSE)

Nếu (IF) A6 (25) không (NOT) lớn hơn 50 thì trả về TRUE, nếu không thì trả về FALSE. Trong trường hợp này, 25 không lớn hơn 50, vì vậy công thức trả về TRUE.

=IF(NOT(A7="Red"),TRUE,FALSE)

Nếu (IF) A7 (“Blue”) không (NOT) là “Red” thì trả về TRUE, nếu không thì trả về FALSE.

Lưu ý rằng trong tất cả ví dụ, sau mỗi điều kiện tương ứng được nhập đều có dấu đóng ngoặc đơn. Các tham đối True/False còn lại sau đó được giữ làm một phần của câu lệnh IF bên ngoài. Bạn cũng có thể thay thế các giá trị Văn bản hoặc Số vào các giá trị TRUE/FALSE được trả về trong các ví dụ.

Sau đây là một số ví dụ về việc sử dụng AND, OR và NOT để đánh giá các ngày.

Ví dụ về việc sử dụng IF với AND, OR và NOT để đánh giá ngày

Dưới đây là cách diễn giải các công thức theo lô-gic:

Công thức

Mô tả

=IF(A2>B2,TRUE,FALSE)

Nếu (IF) A2 lớn hơn B2 thì trả về TRUE, nếu không thì trả về FALSE. Ngày 12/03/14 lớn hơn (sau) ngày 01/01/14, vì vậy công thức trả về TRUE.

=IF(AND(A3>B2,A3<C2),TRUE,FALSE)

Nếu (IF) A3 lớn hơn B2 và (AND) A3 nhỏ hơn C2 thì trả về TRUE, nếu không thì trả về FALSE. Trong trường hợp này, cả hai tham đối đều đúng, vì vậy công thức trả về TRUE.

=IF(OR(A4>B2,A4<B2+60),TRUE,FALSE)

Nếu (IF) A4 lớn hơn B2 hoặc (OR) A4 nhỏ hơn B2 + 60 thì trả về TRUE, nếu không thì trả về FALSE. Trong trường hợp này, tham đối đầu tiên đúng nhưng tham đối thứ hai sai. Vì OR chỉ cần một trong các tham đối đúng nên công thức trả về TRUE. Nếu bạn sử dụng Trình hướng dẫn Đánh giá Công thức từ tab Công thức thì bạn sẽ thấy cách Excel sẽ đánh giá công thức.

=IF(NOT(A5>B2),TRUE,FALSE)

Nếu (IF) A5 không (NOT) lớn hơn B2 thì trả về TRUE, nếu không thì trả về FALSE. Trong trường hợp này, A5 lớn hơn B2, do vậy công thức trả về FALSE.

Ví dụ về Trình hướng dẫn Đánh giá Công thức

Sử dụng AND, OR và NOT cùng Định dạng Có điều kiện

Bạn cũng có thể dùng AND, OR và NOT để thiết lập tiêu chí Định dạng Có điều kiện với tùy chọn công thức. Khi thực hiện việc này, bạn có thể bỏ hàm IF và sử dụng riêng AND, OR và NOT.

Từ tab Trang đầu, bấm vào Định dạng Có điều kiện > Quy tắc Mới. Tiếp theo, chọn tùy chọn “Sử dụng công thức để xác định ô cần định dạng”, nhập công thức, rồi áp dụng định dạng mà bạn lựa chọn.

Hộp thoại Định dạng Có điều kiện > Chỉnh sửa Quy tắc hiển thị phương pháp Công thức

Sử dụng ví dụ Ngày khi nãy, sau đây là những công thức cần dùng.

Ví dụ về việc sử dụng AND, OR và NOT dưới dạng bài kiểm tra Định dạng Có điều kiện


Công thức

Mô tả

=A2>B2

Nếu A2 lớn hơn B2 thì định dạng ô đó, nếu không thì không làm gì cả.

=AND(A3>B2,A3<C2)

Nếu A3 lớn hơn B2 và (AND) A3 nhỏ hơn C2 thì định dạng ô đó, nếu không thì không làm gì cả.

=OR(A4>B2,A4<B2+60)

Nếu A4 lớn hơn B2 hoặc (OR) A4 nhỏ hơn B2 cộng 60 (ngày) thì định dạng ô đó, nếu không thì không làm gì cả.

=NOT(A5>B2)

Nếu A5 không (NOT) lớn hơn B2 thì định dạng ô đó, nếu không thì không làm gì cả. Trong trường hợp này, A5 lớn hơn B2, vì vậy kết quả trả về FALSE. Nếu bạn thay đổi công thức thành =NOT(B2>A5) thì công thức sẽ trả về TRUE và ô sẽ được định dạng.

Ghi chú: Một lỗi phổ biến là nhập công thức vào Định dạng Có điều kiện mà không có dấu bằng (=). Nếu làm vậy, bạn sẽ thấy hộp thoại Định dạng Có điều kiện sẽ thêm dấu bằng và dấu ngoặc kép vào công thức - ="OR(A4>B2,A4<B2+60)", vì vậy bạn sẽ cần xóa các dấu ngoặc kép để công thức có thể phản hồi đúng.

Đầu Trang

Bạn cần thêm trợ giúp?

Bạn luôn có thể nhờ chuyên gia trong Cộng đồng Kỹ thuật Excel, tìm sự hỗ trợ trongCộng đồng Giải pháp hoặc đề xuất tính năng hay cải tiến mới trên Excel User Voice.

Xem Thêm

Xem video về cách sử dụng hàm IF

Tìm hiểu cách sử dụng hàm lồng trong công thức

Hàm IF

Hàm AND

Hàm OR

Hàm NOT

Tổng quan về các công thức trong Excel

Cách tránh công thức bị hỏng

Sử dụng biện pháp kiểm tra lỗi để phát hiện lỗi trong công thức

Phím tắt trong Excel for Windows

Phím tắt trong Excel for Mac

Các hàm lô-gic (tham khảo)

Các hàm Excel (theo bảng chữ cái)

Các hàm Excel (theo thể loại)

Phát triển các kỹ năng của bạn
Khám phá nội dung đào tạo
Sở hữu tính năng mới đầu tiên
Tham gia Người dùng nội bộ Office

Thông tin này có hữu ích không?

Cảm ơn phản hồi của bạn!

Cảm ơn bạn đã phản hồi! Để trợ giúp tốt hơn, có lẽ chúng tôi sẽ kết nối bạn với một trong những nhân viên hỗ trợ Office của chúng tôi.

×