IF (Hàm IF)

Bài viết này mô tả cú pháp công thức và cách dùng hàmIF trong Microsoft Excel.

Mô tả

Hàm IF trả về một giá trị nếu điều kiện mà bạn chỉ rõ định trị là TRUE, trả về một giá trị khác nếu điều kiện đó định trị là FALSE. Ví dụ, công thức =IF(A1>10,"Trên 10","10 hoặc ít hơn") trả về "Trên 10" nếu A1 lớn hơn 10, trả về "10 hoặc ít hơn" nếu A1 nhỏ hơn hoặc bằng 10.

Cú pháp

IF(logical_test, [value_if_true], [value_if_false])

Cú pháp hàm IF có các tham đối như sau.

  • Logical_test    Bắt buộc. Bất kỳ giá trị hoặc biểu thức nào có thể được định trị là TRUE hoặc FALSE. Ví dụ, A10=100 là một biểu thức lô-gic; nếu giá trị của ô A10 bằng 100, thì biểu thức đó định trị là TRUE. Nếu không, biểu thức định trị là FALSE. Đối số này có thể sử dụng bất kỳ toán tử tính toán so sánh nào.

  • Value_if_true    Tùy chọn. Giá trị mà bạn muốn trả về nếu đối số logical_test định trị là TRUE. Ví dụ, nếu giá trị của đối số này là chuỗi văn bản "Trong dự toán" và đối số logical_test định trị là TRUE, thì hàm IF trả về văn bản "Trong dự toán". Nếu logical_test định trị là TRUE và đối số value_if_true được bỏ qua (tức là chỉ có một dấu phẩy ở sau đối số logical_test), thì hàm IF trả về 0 (không). Để hiển thị từ TRUE, hãy dùng giá trị lô-gic TRUE cho đối số value_if_true.

  • Value_if_false    Tùy chọn. Giá trị mà bạn muốn trả về nếu đối số logical_test định trị là FALSE. Ví dụ, nếu giá trị của đối số này là chuỗi văn bản "Vượt dự toán" và đối số logical_test định trị là FALSE, thì hàm IF trả về văn bản "Vượt dự toán". Nếu logical_test định trị là FALSE và đối số value_if_false được bỏ qua (tức là không có dấu phẩy nào ở sau đối số value_if_true), thì hàm IF trả về giá trị lô-gic FALSE. Nếu logical_test định trị là FALSE và giá trị của đối số value_if_false là trống (tức là chỉ có một dấu phẩy ở sau đối số value_if_true), thì hàm IF trả về giá trị 0 (không).

Ghi chú

  • Có thể lồng tối đa 64 hàm IF làm các đối số Value_if_true và Value_if_false để xây dựng kiểm tra phức tạp hơn. (Hãy xem Ví dụ 3 để biết mẫu hàm IF lồng). Hoặc để kiểm tra nhiều điều kiện, bạn có thể cân nhắc dùng các hàm LOOKUP, VLOOKUP, HLOOKUP hoặc CHOOSE . (Hãy xem ví dụ 4 để biết mẫu hàm LOOKUP).

  • Nếu bất kỳ đối số nào của hàm IF là mảng, thì mọi thành phần của mảng sẽ được định trị khi thực hiện câu lệnh IF.

  • Excel cung cấp một vài hàm bổ sung dùng để phân tích dữ liệu của bạn dựa trên một điều kiện. Ví dụ, để đếm số lần xuất hiện của một chuỗi văn bản hoặc một số trong một phạm vi ô, hãy dùng hàm trang tính COUNTIF hoặc COUNTIFS. Để tính tổng dựa trên một chuỗi văn bản hoặc số trong một phạm vi, hãy dùng hàm trang tính SUMIF hoặc SUMIFS.

Ví dụ

Các sổ làm việc bên dưới sẽ đưa ra những ví dụ về hàm này. Hãy kiểm tra chúng, rồi thay đổi các công thức hiện có hoặc nhập công thức của riêng bạn để tìm hiểu cách thức hoạt động của hàm này.

Sao chép dữ liệu của ví dụ trong bảng sau đây và dán vào ô A1 của một trang tính Excel mới. Để công thức hiển thị kết quả, hãy chọn chúng, nhấn F2 và sau đó nhấn Enter. Nếu cần, bạn có thể điều chỉnh độ rộng cột để xem tất cả dữ liệu..

Dữ liệu

50

23

33175

Công thức

Mô tả

Kết quả

=IF(A2<=100,"Trong dự toán","Vượt dự toán")

Nếu số trong ô A2 nhỏ hơn hoặc bằng 100, thì hàm trả về "Trong dự toán". Nếu không, hàm hiển thị "Vượt dự toán".

Trong dự toán

=IF(A2=100,A2+B2,"")

Nếu số trong ô A2 bằng 100, thì tính toán và trả về A2 + B2. Nếu không, trả về văn bản trống ("").

0

=IF(3<1,"OK")

Nếu kết quả là False và không có đối số value_if_false nào được cung cấp cho kết quả False, thì trả về FALSE.

FALSE

Nếu kết quả là False và đối số value_if_false trống được cung cấp cho kết quả False (một dấu phẩy ở sau đối số value_if_true), thì trả về 0.

0

Để làm việc chuyên sâu hơn với dữ liệu mẫu trong Excel, hãy tải sổ làm việc được nhúng về máy tính của bạn, rồi mở trong Excel..

Ví dụ 2

Chi phí Thực tế

Chi phí Dự kiến

$1.500

$900

$500

$900

$500

$925

Công thức

Mô tả

Kết quả

=IF(A2>B2,"Vượt dự toán","OK")

Kiểm tra xem chi phí thực tế trong hàng 2 có lớn hơn chi phí dự kiến hay không. Trả về "Vượt Dự toán" vì kết quả của phép thử này là True.

Vượt Dự toán

=IF(A3>B3,"Vượt Dự toán","OK")

Kiểm tra xem chi phí thực tế trong hàng 3 có lớn hơn chi phí dự kiến hay không. Trả về "OK" vì kết quả của phép thử này là False.

OK)

Ví dụ 3

Điểm

45

90

78

Công thức

Mô tả

Kết quả

=IF(A2>89,"A",IF(A2>79,"B", IF(A2>69,"C",IF(A2>59,"D","F"))))

Dùng các điều kiện IF lồng để gán điểm bằng chữ vào điểm số trong ô A2.

F

=IF(A3>89,"A",IF(A3>79,"B", IF(A3>69,"C",IF(A3>59,"D","F"))))

Dùng các điều kiện IF lồng để gán điểm bằng chữ vào điểm số trong ô A3.

A

=IF(A4>89,"A",IF(A4>79,"B", IF(A4>69,"C",IF(A4>59,"D","F"))))

Dùng các điều kiện IF lồng để gán điểm bằng chữ vào điểm số trong ô A4.

C

Ví dụ 4

Điểm

45

90

78

Công thức

Mô tả

Kết quả

=LOOKUP(A2,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})

Thay vì dùng nhiều hàm IF lồng, công thức này dùng hàm LOOKUP để tìm điểm bằng chữ tương ứng với điểm bằng số lưu giữ trong một mảng của công thức.

F

=LOOKUP(A3,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})

Thay vì dùng nhiều hàm IF lồng, công thức này dùng hàm LOOKUP để tìm điểm bằng chữ tương ứng với điểm bằng số lưu giữ trong một mảng của công thức.

A-

=LOOKUP(A4,{0,60,63,67,70,73,77,80,83,87,90,93,97},{"F","D-","D","D+","C-","C","C+","B-","B","B+","A-","A","A+"})

Thay vì dùng nhiều hàm IF lồng, công thức này dùng hàm LOOKUP để tìm điểm bằng chữ tương ứng với điểm bằng số lưu giữ trong một mảng của công thức.

C+

Áp dụng Cho: Excel 2013, Excel Online



Thông tin này có hữu ích không?

Không

Chúng tôi có thể cải thiện như thế nào?

255 ký tự còn lại

Để bảo vệ sự riêng tư của bạn, vui lòng không đưa thông tin liên hệ trong phản hồi của bạn. Xem xét chính sách về quyền riêng tư.

Cảm ơn phản hồi của bạn!

Tài nguyên hỗ trợ

Thay đổi ngôn ngữ