Hàm SUM

Hàm SUM, một trong những hàm lượng giác và toán học, cộng các giá trị. Bạn có thể cộng các giá trị riêng lẻ, tham chiếu hoặc phạm vi ô hay kết hợp cả ba.

Ví dụ:

  • =SUM(A2:A10)

  • =SUM(A2:A10, C2:C10)

Trình duyệt của bạn không hỗ trợ video. Hãy cài đặt Microsoft Silverlight, Adobe Flash Player hoặc Internet Explorer 9.

Video này là một phần trong khóa đào tạo có tên Cộng số trong Excel 2013.

SUM(number1,[number2],...)

Tên đối số

Mô tả

number1    . (Bắt buộc)

Số đầu tiên bạn muốn thêm vào. Số đó có thể là 4, tham chiếu ô như B6, hoặc ô phạm vi như B2:B8.

number2-255    (Tùy chọn)

Đây là số thứ hai mà bạn muốn cộng. Bạn có thể chỉ định tối đa 255 số bằng cách này.

Nếu bạn muốn nhanh chóng biết được Tổng của một dải ô, tất cả những gì bạn cần làm là chọn dải ô đó, rồi nhìn vào phía dưới bên tay phải của cửa sổ Excel.

Ảnh chụp màn hình việc chọn một phạm vi ô, sau đó nhìn vào Thanh Trạng thái
Thanh Trạng thái


Đây là Thanh Trạng thái và thanh này sẽ hiển thị thông tin liên quan đến những nội dung bạn đã chọn, dù đó là một ô đơn lẻ hay nhiều ô. Nếu bạn bấm chuột phải vào Thanh Trạng thái thì một hộp thoại tính năng sẽ bật ra, hiển thị tất cả các tùy chọn mà bạn có thể chọn. Lưu ý rằng Thanh Trạng thái cũng sẽ hiển thị các giá trị cho dải ô đã chọn của bạn nếu bạn đã đánh dấu vào các thuộc tính đó. Tìm hiểu thêm về Thanh Trạng thái.

Cách dễ nhất để thêm công thức SUM vào trang tính của bạn là sử dụng Trình hướng dẫn Tự Tính tổng. Chọn trực tiếp một ô trống ở trên hoặc dưới dải ô mà bạn muốn tính tổng, rồi trên tab Trang chủ hoặc Công thức trên Dải băng, nhấn vào Tự Tính tổng > Tổng. Trình hướng dẫn Tự Tính tổng sẽ tự động nhận biết dải ô cần tính tổng, rồi xây dựng công thức cho bạn. Trình hướng dẫn Tự Tính tổng cũng hoạt động theo chiều ngang nếu bạn chọn một ô bên trái hoặc bên phải của dải ô cần tính tổng. Lưu ý rằng hàm này sẽ không hoạt động trên dải ô không liền kề nhưng chúng tôi sẽ xem xét cách thực hiện điều đó trong mục tiếp theo.

Bạn có thể sử dụng Trình hướng dẫn Tự Tính tổng để tự động xây dựng công thức Tổng.  Chọn một phạm vi ở trên/dưới hoặc bên trái/phải của phạm vi cần tính tổng, rồi đi đến tab Công thức trên Dải băng, sau đó chọn Tự Tính tổng & hàm SUM.
Sử dụng Trình hướng dẫn Tự Tính tổng để nhanh chóng tính tổng các phạm vi liền kề


Hộp thoại Tự Tính tổng cũng cho phép bạn chọn các hàm phổ biến khác như:

Tự Tính tổng theo chiều dọc

Ô B6 hiển thị công thức Tổng Tự Tính tổng: =SUM(B2:B5)

Trình hướng dẫn Tự Tính tổng sẽ tự động phát hiện các ô B2: B5 là phạm vi cần tính tổng. Tất cả những gì bạn cần làm là nhấn Enter để xác nhận. Nếu bạn cần thêm/loại trừ nhiều ô thì bạn có thể giữ Phím Shift > phím Mũi tên theo ý bạn cho đến khi vùng chọn khớp với vùng bạn muốn, rồi nhấn Enter khi hoàn tất.

Hướng dẫn hàm Intellisense: thẻ trôi nổi SUM(number1,[number2], ...) bên dưới hàm chính là hướng dẫn Intellisense của hàm. Nếu bạn bấm vào chữ SUM hay tên hàm, chữ đó sẽ biến thành một siêu kết nối màu lam, siêu kết nối sẽ đưa bạn đến chủ đề Trợ giúp cho hàm đó. Nếu bạn bấm vào các thành phần hàm riêng lẻ thì phần đại diện của chúng trong công thức sẽ được tô sáng. Trong trường hợp này, chỉ các ô B2: B5 được tô sáng vì chỉ có một tham chiếu số trong công thức này. Thẻ Intellisense sẽ xuất hiện với mọi hàm.

Tự Tính tổng theo chiều ngang

Ô D2 hiển thị công thức Tổng Tự Tính tổng: =SUM(B2:C2)

Sử dụng hàm SUM với phạm vi không liền kề.  Công thức ở ô C8 là =SUM(C2:C3,C5:C6). Bạn cũng có thể sử dụng Phạm vi có Tên, vì vậy, công thức sẽ là =SUM(Week1,Week2).

Trình hướng dẫn Tự Tính tổng thường chỉ hoạt động đối với phạm vi liền kề, vì vậy nếu bạn có hàng hay cột trống trong phạm vi tính tổng thì Excel sẽ dừng ở khoảng trống đầu tiên. Trong trường hợp đó, bạn sẽ cần TÍNH TỔNG (SUM) theo vùng chọn, tại đó, bạn lần lượt cộng từng phạm vi riêng lẻ. Trong ví dụ này, nếu bạn đã có dữ liệu trong ô B4 thì Excel sẽ tạo =SUM(C2:C6) vì công thức sẽ nhận ra một phạm vi liền kề.

Bạn có thể chọn nhanh nhiều dải ô không liền kề bằng Ctrl+Bấm chuột Trái. Trước tiên, hãy nhập “=SUM(“, rồi chọn các phạm vi khác nhau của bạn và Excel sẽ tự động thêm dấu tách bằng dấu phẩy giữa các dải ô cho bạn. Nhấn enter khi bạn hoàn tất.

MẸO: bạn có thể sử dụng ALT+= để nhanh chóng thêm hàm SUM vào một ô. Sau đó, tất cả những gì bạn cần làm là chọn (các) dải ô của mình.

Lưu ý: bạn có thể nhận thấy cách Excel tô sáng các phạm vi hàm khác nhau bằng màu và màu của các phạm vi khớp với màu trong chính công thức, do đó, C2:C3 có một màu còn C5:C6 có một màu khác. Excel sẽ thực hiện tô sáng phạm vi cho tất cả hàm, trừ khi phạm vi được tham chiếu nằm trên một trang tính khác hoặc trong một sổ làm việc khác. Để nâng cao tính trợ năng bằng công nghệ trợ năng, bạn có thể sử dụng Phạm vi có Tên, như "Week1", "Week2", v.v., rồi tham chiếu chúng trong công thức của bạn:

=SUM(Week1,Week2)

Bạn có thể dễ dàng thực hiện các phép toán toán học bằng Excel và kết hợp với các hàm Excel như hàm SUM. Bảng sau đây liệt kê các toán tử mà bạn có thể sử dụng cùng với một số hàm liên quan. Bạn có thể nhập toán tử từ hàng số trên bàn phím hoặc bàn phím 10 phím nếu bạn có. Ví dụ: Shift+8 sẽ nhập dấu sao (*) cho phép nhân.

Toán tử

Phép toán

Ví dụ

+

Cộng

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

Trừ

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

Nhân

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1,1) - Hàm PRODUCT

/

Chia

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1,1) - Hàm QUOTIENT

^

Phép lũy thừa

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1,1) - Hàm POWER

Để biết thêm thông tin, hãy xem mục Sử dụng Excel làm máy tính tay của bạn.

Ví dụ Khác

  1. Giả sử bạn muốn áp dụng Chiết khấu Phần trăm cho một phạm vi ô mà bạn đã tính tổng.

    Sử dụng Toán tử với hàm SUM.  Công thức trong ô B16 là =SUM(A2:A14)*-25%.  Công thức sẽ được xây dựng hợp lý nếu thay vào đó, -25% là tham chiếu ô, như =SUM(A2:A14)*E2
    • =SUM(A2:A14)*-25%

    Sẽ cho bạn 25% của phạm vi đã tính tổng, tuy nhiên hàm mã hóa cứng 25% trong công thức và có thể khó tìm thấy sau này nếu bạn cần thay đổi. Tốt hơn, bạn nên đưa 25% vào một ô, rồi tham chiếu ô để thay thế, làm như vậy thì số liệu được công khai và dễ dàng thay đổi, như sau:

    • =SUM(A2:A14)*E2

    Để chia thay vì nhân, bạn chỉ cần thay thế “*” bằng “/”: =SUM(A2:A14)/E2

  2. Cộng hoặc Trừ từ hàm SUM

    i. Bạn có thể dễ dàng Cộng hoặc Trừ từ Tổng bằng cách sử dụng + hoặc - như sau:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

Mục này sẽ thảo luận một số biện pháp tốt nhất để làm việc với hàm SUM. Hầu hết các biện pháp này đều có thể áp dụng để làm việc với các hàm khác.

Phương pháp =1+2 hoặc =A+B – Mặc dù bạn có thể nhập =1+2+3 hoặc =A1+B1+C2 và nhận được kết quả đầy đủ, chính xác nhưng các phương pháp này dễ dẫn đến lỗi vì một vài lý do:

  1. Lỗi chính tả – Hãy tưởng tượng bạn cố gắng nhập thêm giá trị và/hoặc nhập giá trị lớn hơn nhiều như sau:

    • =14598.93+65437.90+78496.23

    Sau đó, cố gắng xác thực rằng mục nhập của bạn là chính xác. Sẽ dễ dàng hơn nhiều nếu đặt các giá trị này vào các ô riêng lẻ, rồi dùng công thức SUM. Ngoài ra, bạn có thể định dạng các giá trị khi ở trong ô, làm cho các giá trị dễ đọc hơn nhiều so với khi ở trong công thức.

    Sử dụng hàm SUM thay cho các giá trị mã hóa cứng trong công thức.  Công thức trong ô D5 là =SUM(D2:D4)
  2. Lỗi #VALUE! do tham chiếu văn bản thay vì số

    Nếu bạn sử dụng công thức có dạng:

    • =A1+B1+C1 hoặc =A1+A2+A3

    Ví dụ xây dựng công thức kém.  Công thức trong ô D2 là =A2+B2+C2

    Công thức của bạn có thể bị hỏng nếu có bất kỳ giá trị nào không phải dạng số (văn bản) trong các ô được tham chiếu, lúc này công thức sẽ trả về lỗi #VALUE!. Hàm SUM sẽ bỏ qua giá trị văn bản và chỉ cung cấp cho bạn tổng các giá trị số.

    Xây dựng công thức phù hợp.  Thay vì =A2+B2+C2, công thức của ô D2 là =SUM(A2:C2)
  3. Lỗi #REF! do xóa hàng hoặc cột

    Lỗi #REF! xảy ra do việc xóa một cột.  Công thức đã thay đổi thành =A2+#REF!+B2

    Nếu bạn xóa một hàng hoặc cột thì công thức sẽ không cập nhật để loại trừ hàng đã xóa và công thức sẽ trả về lỗi #REF!, trong khi hàm SUM sẽ tự động cập nhật.

    Hàm SUM sẽ tự động điều chỉnh cho các hàng và cột đã chèn hoặc đã xóa
  4. Công thức sẽ không cập nhật các tham chiếu khi chèn hàng hoặc cột

    Công thức =A+B+C sẽ không cập nhật nếu bạn thêm hàng

    Nếu bạn chèn một hàng hay cột thì công thức sẽ không cập nhật để bao gồm hàng mới được thêm vào, trong khi hàm SUM sẽ tự động cập nhật (miễn là bạn không nằm ngoài phạm vi được tham chiếu trong công thức). Điều này đặc biệt quan trọng nếu bạn mong đợi công thức của mình được cập nhật và điều này không xảy ra, vì công thức sẽ cho bạn các kết quả không hoàn chỉnh mà bạn có thể không nắm được.

    Ví dụ mô tả công thức SUM sẽ tự động bung rộng từ =SUM(A2:C2) thành =SUM(A2:D2) khi một cột được chèn vào
  5. Hàm SUM kết hợp cùng Tham chiếu Ô riêng lẻ so với Phạm vi

    Sử dụng công thức có dạng:

    • =SUM(A1,A2,A3,B1,B2,B3)

    Cũng dễ bị lỗi tương đương khi chèn hoặc xóa các hàng trong phạm vi được tham chiếu vì cùng lý do. Tốt hơn, bạn nên sử dụng các phạm vi riêng lẻ, như:

    • =SUM(A1:A3,B1:B3)

    Công thức sẽ cập nhật khi thêm hoặc xóa hàng.

  1. Bạn hoàn toàn có thể sử dụng hàm SUM với các hàm khác. Sau đây là ví dụ tạo phép tính trung bình hàng tháng:

    Sử dụng hàm SUM với các hàm khác.  Công thức trong ô M2 là =SUM(A2:L2)/COUNTA(A2:L2).  Lưu ý: cột Tháng 5-Tháng 11 được ẩn để tầm nhìn rõ ràng hơn.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. Công thức lấy TỔNG (SUM) của A2:L2 chia cho số lượng ô không trống trong A2:L2 (Từ tháng 5 đến tháng 12 là trống).

  1. Đôi khi, bạn cần tính tổng một ô cụ thể trên nhiều trang tính. Bạn có thể bấm vào từng trang tính và vào ô bạn muốn, chỉ cần sử dụng “+” để cộng giá trị các ô, nhưng cách đó rất nhàm chán và dễ dẫn đến lỗi.

    • =Sheet1!A1+Sheet2!A1+Sheet3!A1

    Bạn có thể thực hiện việc này dễ dàng hơn với phương pháp SUM 3D hay 3 Chiều:

    Sum 3D - Công thức ở ô D2 là =SUM(Sheet1:Sheet3!A2)
    • =SUM(Sheet1:Sheet3!A1)

    Sẽ tính tổng ô A1 trong tất cả trang tính từ Trang tính 1 đến Trang tính 3.

    Phương pháp này đặc biệt hữu ích trong tình huống khi bạn có một trang tính riêng cho mỗi tháng (Tháng 1-Tháng 12) và bạn cần tính tổng chúng trên một trang tính tóm tắt.

    SUM 3d trên Các trang tính có Tên.  Công thức ở D2 là =SUM(January:December!A2)
    • =SUM(January:December!A2)

    Sẽ tính tổng ô A2 ở mỗi trang tính từ Tháng 1 đến Tháng 12.

    Ghi chú: Nếu trang tính của bạn có khoảng trống trong tên, chẳng hạn như "January Sales" thì khi đó, bạn cần dùng nháy đơn khi tham chiếu tên trang tính trong công thức. Chú ý nháy đơn TRƯỚC tên trang tính đầu tiên và một nháy nữa SAU tên trang tính cuối cùng.

    • =SUM(‘January Sales:December Sales’!A2)

    Phương pháp 3D cũng sẽ hoạt động với các hàm khác, chẳng hạn như hàm AVERAGE, hàm MIN, hàm MAX, v.v.:

    • =AVERAGE(Sheet1:Sheet3!A1)

    • =MIN(Sheet1:Sheet3!A1)

    • =MAX(Sheet1:Sheet3!A1)

Sự cố

Đã xảy ra lỗi gì

Hàm SUM của tôi hiển thị ##### chứ không hiển thị kết quả.

Kiểm tra chiều rộng cột của bạn. ##### thường có nghĩa là cột quá hẹp, không hiển thị được kết quả công thức.

Hàm SUM của tôi chỉ hiển thị công thức dưới dạng văn bản chứ không hiển thị kết quả.

Kiểm tra chắc chắn rằng ô không phải là định dạng văn bản. Chọn ô hoặc phạm vi được đề cập và sử dụng Ctrl+1 để hiển thị hộp thoại Định dạng Ô, rồi bấm vào tab Số và chọn định dạng bạn muốn. Nếu ô đã được định dạng là văn bản và không thay đổi sau khi bạn thay đổi định dạng thì bạn có thể cần sử dụng F2 > Enter để buộc định dạng thay đổi.

Hàm SUM của tôi không cập nhật.

Hãy đảm bảo rằng Tính toán được đặt là Tự động. Trên tab Công thức, đi đến Tùy chọn Tính toán. Bạn cũng có thể sử dụng F9 để buộc trang tính tính toán.

Hãy đảm bảo rằng tính toán được đặt là Tự động.  Từ tab Công thức, đi đến Tùy chọn Tính toán.

Một số giá trị không được cộng.

Chỉ có thể cộng các giá trị số trong tham chiếu hàm hoặc phạm vi. Ô trống, giá trị lô-gic như TRUE hoặc văn bản sẽ bị bỏ qua.

Lỗi #NAME? xuất hiện thay vì kết quả mong đợi.

Lỗi này thường có nghĩa là công thức bị sai chính tả, chẳng hạn như =sume(A1:A10) thay vì =SUM(A1:A10).

Hàm SUM của tôi chỉ hiển thị một số nguyên, trong khi hàm nên hiển thị số thập phân

Kiểm tra định dạng ô của bạn để đảm bảo rằng bạn đang hiển thị số thập phân. Chọn ô hoặc dải ô được đề cập và sử dụng Ctrl+1 để hiển thị hộp thoại Định dạng Ô, rồi bấm vào tab Số và chọn định dạng bạn muốn, đảm bảo chỉ ra được số chữ số thập phân mà bạn muốn.

  1. Tôi chỉ muốn Cộng/Trừ/Nhân/Chia số Xem chuỗi video về Toán học Cơ bản trong Excel hoặc Sử dụng Excel làm máy tính tay của bạn này.

  2. Làm thế nào để tôi có thể hiển thị thêm/bớt chữ số thập phân? Bạn có thể thay đổi định dạng số của mình. Chọn ô hoặc dải ô được đề cập và sử dụng Ctrl+1 để hiển thị Hộp thoại Định dạng Ô, rồi bấm vào tab Số và chọn định dạng bạn muốn, đảm bảo chỉ ra được số chữ số thập phân mà bạn muốn.

  3. Làm thế nào để cộng hoặc trừ Thời gian? Bạn có thể cộng và trừ thời gian theo một số cách khác nhau. Ví dụ: để tính chênh lệch giữa 8:00 SA - 12:00 CH cho mục đích tính lương, bạn nên sử dụng: =("12:00 PM"-"8:00 AM")*24, lấy thời gian kết thúc trừ đi thời gian bắt đầu. Lưu ý rằng Excel tính toán thời gian dưới dạng phân số của một ngày, vì vậy, bạn cần nhân với 24 để biết được tổng số giờ. Trong ví dụ đầu tiên, chúng tôi sử dụng =((B2-A2)+(D2-C2))*24 để tính tổng giờ từ khi bắt đầu đến khi hoàn tất, trừ thời gian nghỉ trưa (tổng 8,50 giờ).

    Nếu bạn chỉ cộng thêm giờ và phút, đồng thời muốn hiển thị theo giờ và phút thì khi đó bạn có thể tính tổng mà không cần nhân với 24, vì vậy, trong ví dụ thứ hai, chúng tôi sử dụng =SUM(A6:C6) vì chúng ta chỉ cần tổng số giờ và phút cho các tác vụ đã gán (5:36 hay 5 giờ 36 phút).

    Tính toán thời gian

    Để biết thêm thông tin, hãy xem: Cộng hoặc trừ thời gian.

  4. Làm thế nào để tôi có thể biết được sự chênh lệch giữa các ngày? Tương tự với thời gian, bạn có thể cộng và trừ ngày. Sau đây là một ví dụ rất phổ biến về việc đếm số ngày giữa hai ngày. Đơn giản là =B2-A2. Chìa khóa để làm việc với cả Ngày và Giờ là bạn sử dụng Ngày/Giờ Kết thúc trừ đi Ngày/Giờ Bắt đầu.

    Tính toán chênh lệch giữa các ngày

    Để biết thêm cách làm việc với ngày, vui lòng tham khảo: Tính toán số ngày giữa hai ngày.

  5. Làm thế nào để chỉ tính tổng các ô hiển thị? Đôi lúc, khi bạn ẩn thủ công các hàng hoặc sử dụng tính năng Tự Lọc để chỉ hiển thị một số dữ liệu nhất định, đồng thời cũng chỉ muốn tính tổng các ô hiển thị. Bạn có thể sử dụng Hàm SUBTOTAL. Nếu bạn đang sử dụng một hàng tổng trong bảng Excel, mọi hàm bạn chọn từ danh sách thả xuống Tổng sẽ được tự động nhập dưới dạng một tổng phụ. Xem thêm về cách Tính tổng dữ liệu trong một bảng Excel.

Bạn cần thêm trợ giúp?

Bạn luôn có thể nhờ chuyên gia trong Cộng đồng Kỹ thuật Excel, tìm sự hỗ trợ trongCộng đồng Giải pháp hoặc đề xuất tính năng hay cải tiến mới trên Excel User Voice.

Xem Thêm

Xem video về cách sử dụng Hàm SUM

Hàm SUMIF chỉ cộng các giá trị đáp ứng được một tiêu chí duy nhất

Hàm SUMIFS chỉ cộng các giá trị đáp ứng được nhiều tiêu chí

Hàm COUNTIF chỉ đếm các giá trị đáp ứng được một tiêu chí duy nhất

Hàm COUNTIFS chỉ đếm các giá trị đáp ứng được nhiều tiêu chí

Tổng quan về các công thức trong Excel

Cách tránh các công thức hỏng

Tìm và sửa lỗi trong công thức

Các phím tắt trong Excel for Windows

Các phím tắt trong Excel for Mac

Các hàm Toán & Lượng giác

Các hàm Excel (theo bảng chữ cái)

Các hàm Excel (theo Thể loại)

Thêm công thức và hàm (bản xem trước miễn phí)

Phát triển các kỹ năng của bạn
Khám phá nội dung đào tạo
Sở hữu tính năng mới đầu tiên
Tham gia Người dùng nội bộ Office

Thông tin này có hữu ích không?

Cảm ơn phản hồi của bạn!

Cảm ơn bạn đã phản hồi! Để trợ giúp tốt hơn, có lẽ chúng tôi sẽ kết nối bạn với một trong những nhân viên hỗ trợ Office của chúng tôi.

×