Hàm COUNTIF

Sử dụng COUNTIF, một trong các hàm thống kê, để đếm số lượng ô đáp ứng một tiêu chí; ví dụ như để đếm số lần một thành phố nhất định xuất hiện trong danh sách khách hàng.

Trong biểu mẫu đơn giản nhất, COUNTIF cho biết:

  • =COUNTIF(Bạn muốn tìm ở đâu?, Bạn muốn tìm giá trị nào?)

Ví dụ:

  • =COUNTIF(A2:A5,"London")

  • =COUNTIF(A2:A5,A4)

Trình duyệt của bạn không hỗ trợ video. Hãy cài đặt Microsoft Silverlight, Adobe Flash Player hoặc Internet Explorer 9.

Hàm COUNTIF(phạm vi, tiêu chí)

Tên đối số

Mô tả

range    (bắt buộc)

Nhóm các ô mà bạn muốn đếm. Phạm vi có thể chứa số, mảng, phạm vi có tên hoặc tham chiếu có chứa số. Các giá trị trống và giá trị văn bản được bỏ qua.

Tìm hiểu cách chọn phạm vi trong một trang tính.

criteria    (bắt buộc)

Số, biểu thức, tham chiếu ô hoặc chuỗi văn bản xác định ô nào sẽ được đếm.

Ví dụ: bạn có thể sử dụng một số như 32, một so sánh như "> 32", một ô như B4, hoặc một từ như "táo".

COUNTIF chỉ sử dụng một tiêu chí duy nhất. Sử dụng COUNTIFS nếu bạn muốn dùng nhiều tiêu chí.

Ví dụ

Để dùng các ví dụ này trong Excel, hãy sao chép dữ liệu trong bảng bên dưới rồi dán vào ô A1 của trang tính mới.

Dữ liệu

Dữ liệu

táo

3^2

cam

5,4

đào

75 $

táo

86

Công thức

Mô tả

=COUNTIF(A2:A5,"táo")

Đếm số ô có chứa táo trong các ô từ A2 tới A5. Kết quả là 2.

=COUNTIF(A2:A5,A4)

Đếm số ô chứa đào (giá trị trong A4) trong các ô từ A2 tới A5. Kết quả là 1.

=COUNTIF(A2:A5,A2)+COUNTIF(A2:A5,A3)

Đếm số táo (giá trị trong A2) và cam (giá trị trong A3) trong các ô từ A2 tới A5. Kết quả là 3. Công thức này sử dụng COUNTIF hai lần để xác định nhiều tiêu chí, mỗi tiêu chí ứng với một biểu thức. Bạn cũng có thể sử dụng hàm COUNTIFS.

=COUNTIF(B2:B5,">55")

Đếm số ô có giá trị lớn hơn 55 trong các ô từ B2 tới B5. Kết quả là 2.

=COUNTIF(B2:B5,"<>"&B4)

Đếm số ô có giá trị khác 75 trong các ô từ B2 tới B5. Dấu và (&) sáp nhập toán tử so sánh khác với (<>) và giá trị trong B4 để đọc =COUNTIF(B2:B5,"<>75"). Kết quả là 3.

=COUNTIF(B2:B5,">=32")-COUNTIF(B2:B5,">85")

Đếm số ô có giá trị lớn hơn (>) hoặc bằng (=) 32 và nhỏ hơn (<) hoặc bằng (=) 85 trong các ô từ B2 tới B5. Kết quả là 3.

=COUNTIF(A2:A5,"*")

Đếm số ô có chứa bất kỳ văn bản nào trong các ô từ A2 tới A5. Dấu sao (*) là ký tự đại diện được dùng để khớp với bất kỳ ký tự nào. Kết quả là 4.

=COUNTIF(A2:A5,"?áo")

Đếm số ô có đúng 3 ký tự và kết thúc bằng các chữ cái "áo" trong các ô từ A2 tới A5. Dấu chấm hỏi (?) được sử dụng làm ký tự đại diện được dùng để khớp với từng ký tự riêng lẻ. Kết quả là 2.

Các vấn đề Chung

Sự cố

Đã xảy ra lỗi gì

Trả về giá trị sai đối với chuỗi dài.

Hàm COUNTIF trả về kết quả sai khi bạn dùng nó để khớp các chuỗi dài hơn 255 ký tự.

Để khớp các chuỗi dài hơn 255 ký tự, hãy dùng hàm CONCATENATE hoặc toán tử ghép nối &. Ví dụ: =COUNTIF(A2:A5,"chuỗi dài"&"chuỗi dài khác").

Không trả về kết quả khi bạn mong đợi có kết quả.

Đảm bảo có ghi đối số criteria trong dấu ngoặc.

Công thức COUNTIF gặp lỗi #VALUE! khi tham chiếu tới một trang tính khác.

Lỗi này xảy ra khi công thức có chứa hàm tham chiếu đến ô hoặc phạm vi trong một sổ làm việc đóng và các ô được tính toán. Để tính năng này hoạt động, sổ làm việc khác phải được mở.

Những cách thực hành tốt nhất

Làm thế này

Tại sao

Nhớ rằng COUNTIF không phân biệt chữ hoa, chữ thường trong chuỗi văn bản.

Criteria không phân biệt chữ hoa/thường. Nói cách khác, chuỗi "táo" và chuỗi "TÁO" sẽ khớp với cùng các ô giống nhau.

Dùng ký tự đại diện

Có thể dùng ký tự đại diện—dấu chấm hỏi (?) và dấu sao (*)—trong criteria. Một dấu chấm hỏi khớp với một ký tự đơn lẻ bất kỳ. Một dấu sao khớp với chuỗi ký tự bất kỳ. Nếu bạn muốn tìm dấu chấm hỏi hay dấu sao thực sự, hãy nhập một dấu sóng (~) trước ký tự đó.

Ví dụ: =COUNTIF(A2:A5,"tá?") sẽ tìm mọi trường hợp có "tá" với chữ cái cuối cùng có thể thay đổi.

Hãy bảo đảm dữ liệu của bạn không chứa các ký tự không đúng.

Khi đếm giá trị văn bản, hãy đảm bảo dữ liệu không chứa khoảng trắng ở đầu, khoảng trắng ở cuối, việc sử dụng không thống nhất dấu trích dẫn thẳng và cong hoặc ký tự không in ra. Trong những trường hợp này, COUNTIF có thể trả về giá trị không mong muốn.

Thử sử dụng hàm CLEAN hoặc hàm TRIM.

Để thuận tiện, sử dụng phạm vi có tên

COUNTIF hỗ trợ các phạm vi có tên trong công thức (chẳng hạn như = COUNTIF (trái cây,"> = 32")-COUNTIF (trái cây,"> 85"). Phạm vi có tên có thể nằm trong trang tính hiện tại, một trang tính khác trong cùng sổ làm việc hoặc từ sổ làm việc khác. Để tham chiếu từ một sổ làm việc khác, sổ làm việc thứ hai đó cũng phải được mở.

Ghi chú: Hàm COUNTIF sẽ không đếm các ô dựa trên màu phông chữ hoặc nền ô. Tuy nhiên, Excel hỗ trợ Hàm do Người dùng Xác định (UDF) bằng cách sử dụng các thao tác Microsoft Visual Basic for Applications (VBA) trên các ô dựa trên màu phông chữ hoặc nền. Đây là ví dụ về cách bạn có thể Đếm số ô có màu ô cụ thể bằng cách sử dụng VBA.

Bạn cần thêm trợ giúp?

Bạn luôn có thể nhờ chuyên gia trong Cộng đồng Kỹ thuật Excel, tìm sự hỗ trợ trongCộng đồng Giải pháp hoặc đề xuất tính năng hay cải tiến mới trên Excel User Voice.

Xem Thêm

Để đếm các ô không trống, sử dụng hàm COUNTA

Để đếm các ô sử dụng nhiều tiêu chí, sử dụng hàm COUNTIFS

Xem video về cách sử dụng hàm COUNTIFS

Hàm SUMIF chỉ cộng các giá trị đáp ứng được một tiêu chí duy nhất

Hàm SUMIFS chỉ cộng các giá trị đáp ứng được nhiều tiêu chí

Hàm IFS (Office 365, Excel 2016 trở lên)

Sử dụng hàm TRIM để loại bỏ khoảng trống đầu dòng và cuối dòng khỏi các ô

Sử dụng hàm CLEAN để loại bỏ ký tự không in khỏi ô

Tổng quan về các công thức trong Excel

Cách tránh các công thức bị hỏng

Phát hiện lỗi trong các công thức

Hàm thống kê

Hàm Excel (theo bảng chữ cái)

Hàm Excel (theo Thể loại)

Sử dụng hàm SUMIF, COUNTIF và các hàm liên quan để phân tích nhanh dữ liệu (bản xem trước miễn phí)

Phát triển các kỹ năng của bạn
Khám phá nội dung đào tạo
Sở hữu tính năng mới đầu tiên
Tham gia Người dùng nội bộ Office

Thông tin này có hữu ích không?

Cảm ơn phản hồi của bạn!

Cảm ơn bạn đã phản hồi! Để trợ giúp tốt hơn, có lẽ chúng tôi sẽ kết nối bạn với một trong những nhân viên hỗ trợ Office của chúng tôi.

×