Hàm Eval

Chú thích

Bạn có thể sử dụng hàm Eval trong một điều khiển được tính toán trên biểu mẫu hoặc báo cáo hay trong macro hay mô-đun. Hàm Eval trả về một Biến_thể là một chuỗi hoặc kiểu số.

Chuỗi đối sốc phải là một biểu thức được lưu trữ trong một chuỗi. Nếu bạn truyền đến hàm Eval một chuỗi không chứa biểu thức số hoặc tên hàm mà chỉ có một chuỗi văn bản đơn giản, một chuỗi lỗi thời gian chạy sẽ xảy ra. Ví dụ: Eval("Smith") dẫn đến lỗi.

Bạn có thể sử dụng hàm Eval để xác định giá trị được lưu trữ trong thuộc tính Value của điều khiển. Ví dụ sau đây truyền một chuỗi chứa tham chiếu đầy đủ tới một điều khiển tới hàm Eval . Sau đó, nó sẽ hiển thị giá trị hiện tại của điều khiển trong hộp thoại.

Dim ctl As Control
Dim strCtl As String
Set ctl = Forms!Employees!LastName
strCtl = "Forms!Employees!LastName"
MsgBox ("The current value of " & ctl.Name & _
    " is " & Eval(strCtl))

Bạn có thể sử dụng hàm Eval để truy nhập các toán tử biểu thức thường không sẵn dùng trong mô-đun Visual Basic for Applications (VBA). Ví dụ: bạn không thể sử dụng toán tử SQL Between... Và hoặc In trực tiếp trong mã của bạn, nhưng bạn có thể sử dụng chúng trong một biểu thức được chuyển đến hàm Eval .

Ví dụ tiếp theo xác định xem giá trị của điều khiển Khu vực Vận chuyển trên biểu mẫu Đơn hàng có phải là một trong một vài chữ viết tắt trạng thái đã xác định hay không. Nếu trường có chứa một trong các từ viết tắt, intState sẽ là True (–1). Lưu ý rằng bạn sử dụng dấu nháy đơn (') để đưa một chuỗi vào trong một chuỗi khác.

Dim intState As Integer
intState = Eval("Forms!Orders!ShipRegion In " _
    & "('AK', 'CA', 'ID', 'WA', 'MT', 'NM', 'OR')")

Ví dụ về truy vấn

Ví dụ về VBA

Ví dụ sau đây giả định rằng bạn có một chuỗi 50 hàm được xác định là A1, A2, v.v. Ví dụ này sử dụng hàm Eval để gọi mỗi hàm trong chuỗi.

Sub CallSeries()
    Dim intI As Integer
    For intI = 1 To 50
        Eval("A" & intI & "()")
    Next intI
End Sub

Ví dụ tiếp theo kích hoạt sự kiện Click như thể người dùng đã bấm vào một nút trên biểu mẫu. Nếu giá trị thuộc tính OnClick của nút bắt đầu bằng dấu bằng (=), nghĩa là nó là tên của một hàm, hàm Eval sẽ gọi hàm, hàm này tương đương với việc kích hoạt sự kiện Click . Nếu giá trị không bắt đầu bằng dấu bằng thì giá trị đó phải đặt tên cho macro. Phương pháp RunMacro của đối tượng DoCmd sẽ chạy macro có tên.

Dim ctl As Control
Dim varTemp As Variant
Set ctl = Forms!Contacts!HelpButton
If (Left(ctl.OnClick, 1) = "=") Then
    varTemp = Eval(Mid(ctl.OnClick,2))
Else
    DoCmd.RunMacro ctl.OnClick
End If