Функція IF

Одна з найпопулярніших в Excel функція IF дає змогу виконувати логічне порівняння значення й очікуваного результату. Простими словами функція IF працює так:

  • ЯКЩО(якась умова істинна; то виконати певну дію; інакше виконати іншу дію)

Отже, інструкція IF може мати два результати. Перший отримаємо, якщо умова виявиться істинною, другий – якщо вона буде хибна.

Щоб одразу перейти до роботи з кількома інструкціями IF, див. статтю Розширені функції IF: робота з вкладеними формулами та уникнення помилок.

Функція IF, яка відноситься до логічних функцій, повертає одне значення, якщо умова виконується, або інше, якщо вона не виконується.

Синтаксис

IF(логічний_вираз;значення_якщо_істина;[значення_якщо_хибність])

Наприклад:

  • =IF(A2>B2;"Бюджет перевищено";"OK")

  • =IF(A2=B2;B4-A4;"")

Ім’я аргументу

Опис

логічний_вираз    (обов’язковий аргумент)

Умова, яку потрібно перевірити.

значення_якщо_істина    (обов’язковий аргумент)

Значення, яке повертається, якщо результат умови логічний_вираз має значення TRUE.

значення_якщо_хибність    (необов’язковий аргумент)

Значення, яке повертається, якщо результат умови лог_вираз має значення FALSE.

Приклади простої функції IF

Клітинка D2 містить формулу =IF(C2="Так";1;2)
  • =IF(C2="Так";1;2)

У наведеному вище прикладі формула в клітинці D2 означає: ЯКЩО(C2 = "Так"; то повернути 1; інакше повернути 2).

Клітинка D2 містить формулу =IF(C2=1;"Так";"Ні")
  • =IF(C2=1;"Так";"Ні")

У цьому прикладі формула в клітинці D2 означає: ЯКЩО(C2=1; то повернути "Так"; інакше повернути "Ні").

Як бачите, функція IF дає змогу оцінювати як текстові, так і числові значення. Крім того, її можна використовувати, щоб оцінювати помилки. Ви можете не лише перевірити одну рівність і повернути один результат, а й використовувати математичні оператори та виконувати додаткові обчислення залежно від заданих умов. Щоб виконати кілька порівнянь, можна також вкласти кілька функцій IF.

Примітка.: Якщо потрібно використати текст у формулах, візьміть його в лапки (наприклад, "Текст"). Виняток становлять лише значення TRUE та FALSE, які Excel інтерпретує автоматично.

Початок роботи

Перш ніж почати писати інструкцію IF, радимо зрозуміти, чого ви намагаєтеся досягти. Що потрібно порівняти? Якщо ви продумаєте логіку "що має статися, якщо умова виконується, а що – якщо ні", то навряд чи вам буде складно написати інструкцію IF. Усі дії мають розвиватися логічно, інакше формула повертатиме несподіваний результат. Особливо важливо враховувати це, створюючи складні (вкладені) інструкції IF.

Інші приклади функції IF

Клітинка D2 містить формулу =IF(C2>B2;"Перевищення бюджету";"У межах бюджету")
  • =IF(C2>B2;"Бюджет перевищено";"У межах бюджету")

У наведеному вище прикладі функція IF у клітинці D2 означає: ЯКЩО(C2 більше B2; то повернути "Бюджет перевищено"; інакше повернути "У межах бюджету").

Клітинка E2 містить формулу =IF(C2>B2;C2-B2;"")
  • =IF(C2>B2;C2-B2;0)

На знімку екрана вище функція повертатиме не текст, а математичне обчислення. Отже, формула в клітинці E2 означає: ЯКЩО(фактичні витрати перевищують планові; то відняти планові витрати від фактичних; інакше нічого не повертати).

Клітинка F7 містить формулу =IF(E7="Так";F5*0,0825;0)
  • =IF(E7="Так";F5*0,0825;0)

У цьому прикладі формула в клітинці F7 означає: ЯКЩО(E7 = "Так"; то обчислити загальну суму, помноживши F5 на 8,25%; інакше повернути значення 0, тому що акцизний збір не стягується).

Практичні поради з використання констант

В останньому прикладі безпосередньо у формулу введено значення "Так" і ставку акцизного збору (0,0825). Загалом не рекомендується використовувати точні константи (значення, які можуть із часом змінитися), тому що в майбутньому їх може бути складно знайти та змінити. Це буде легше робити, якщо додавати їх до власних клітинок. У нашому випадку використовувати константу у формулі припустимо, оскільки функція IF лише одна, а ставка акцизного збору змінюватиметься нечасто. Та навіть якщо це станеться, змінити її у формулі буде неважко.

Оператори обчислення

Докладні відомості про оператори обчислення, які використовуються у формулах (< менше, > більше, = дорівнює, <> не дорівнює тощо), див. в статті Оператори та пріоритет обчислення.

Використання функції IF для перевірки наявності вмісту в клітинці

Іноді потрібно перевірити, чи клітинка пуста, переважно для того, щоб формула не повернула пустий результат.

Клітинка E2 містить формулу =IF(D2=1;"Так";IF(D2=2;"Ні";"Можливо"))

У такому разі слід скористатися функцію IF із функцією ISBLANK:

  • =IF(ISBLANK(D2);"Пуста";"Не пуста")

Це означає: ЯКЩО(клітинка D2 пуста; то повернути "Пуста"; інакше повернути "Не пуста"). Замість умови "Не пуста" так само легко можна використати власну формулу. У наступному прикладі замість функції ISBLANK використовуються пусті лапки "". Пусті лапки, по суті, означають "нічого".

Перевірка наявності вмісту в клітинці; клітинка E2 містить формулу =IF(ISBLANK(D2);"Пуста";"Не пуста")
  • =IF(D3="";"Пуста";"Не пуста")

Ця формула означає: ЯКЩО(клітинка D3 нічого не містить; то повернути "Пуста"; інакше повернути "Не пуста"). Нижче наведено приклад того, як часто використовують пусті лапки "", щоб формула не перевіряла наявність вмісту в залежних клітинках:

  • =IF(D3="";"";ваша_формула())

    ЯКЩО(клітинка D3 нічого не містить; то нічого не повертати; інакше обчислити формулу).

Приклад вкладеної функції IF

Проста функція IF має лише два результати (істина або хибність), а вкладені функції IF можуть мати від 3 до 64 результатів.

За допомогою лапок "" перевіряється, чи клітинка пуста; клітинка E3 містить формулу =IF(D3="";"Пуста";"Не пуста")
  • =IF(D2=1;"Так";IF(D2=2;"Ні";"Можливо"))

На знімку екрана вище формула в клітинці E2 означає: ЯКЩО(D2 дорівнює 1, повернути "Так"; інакше ЯКЩО(D2 дорівнює 2, повернути "Ні"; інакше повернути "Можливо")). Зверніть увагу на дві праві дужки в кінці формули. Без них обидві функції IF не працюватимуть. Якщо ввести формулу без них, Excel інтерпретує це як помилку та спробує виправити її.

Застереження

В Excel можна вкласти до 64 різних функцій IF, але робити цього не варто. Чому?

  • Щоб належним чином поєднати кілька інструкцій IF, усе має бути продумано так, щоб за їхньою логікою правильно обчислювалася кожна умова, аж до останньої. Якщо не вкласти інструкції IF абсолютно точно, формула може працювати здебільшого правильно, але за певних умов повертатиме несподівані результати. На жаль, одразу виявити ці умови малоймовірно.

  • Оновлювати багато інструкцій IF може виявитися зовсім непросто, особливо коли ви повернетеся до формули через деякий час і намагатиметеся збагнути, що ви (або ще гірше – хтось інший) намагалися зробити.

  • Якщо є кілька інструкцій IF, потрібно додати відповідну кількість пар дужок (), а це може ускладнити формулу.

Поширені проблеми

Проблема

Причина

0 (нуль) у клітинці

Не вказано значення для аргументу значення_якщо_істина або значення_якщо_хибність. Щоб побачити правильне значення, додайте текст для обох аргументів або додайте до аргументу значення TRUE чи FALSE.

У клітинці відображається #NAME?

Зазвичай це означає, що формулу введено неправильно.

Потрібна додаткова довідка?

Ви завжди можете поставити запитання експерту в спільноті Tech (у розділі Excel), отримати підтримку в спільноті, що допомагає знайти відповіді на запитання, або запропонувати нову функцію чи вдосконалення на форумі Excel User Voice.

Див. також

Розширені функції IF (відео)

Функція IFS (Office 365, Excel 2016 і пізніших версій)

Розширені функції IF: робота з вкладеними формулами та уникнення помилок

Відеокурс: "Розширені функції IF"

Обчислення значень за допомогою функції COUNTIF на основі однієї умови

Обчислення значень за допомогою функції COUNTIFS на основі кількох умов

Підсумування значень за допомогою функції SUMIF на основі однієї умови

Підсумування значень за допомогою функції SUMIFS на основі кількох умов

Функція AND

Функція OR

Функція VLOOKUP

Огляд формул в Excel

Способи уникнення недійсних формул

Виявлення помилок у формулах за допомогою функції перевірки помилок

Логічні функції

Функції Excel (за алфавітом)

Функції Excel (за категоріями)

Удосконалення навичок роботи з Office
Ознайомтеся з навчальними матеріалами
Отримуйте нові функції раніше за інших
Приєднайтеся до оцінювачів Office

Ця інформація корисна?

Дякуємо за ваш відгук!

Дякуємо за відгук! Схоже, вам може стати в нагоді допомога одного з наших спеціалістів служби підтримки Office, з яким ми вас можемо з’єднати.

×