Властивість FileDialog

Стосується:

Об’єкт Application

Повертає об’єкт FileDialog, що представляє один екземпляр діалогового вікна файлу.

вираз.FileDialog(dialogType)

вираз – обов’язковий аргумент. Вираз, що повертає один з об’єктів зі списку "Стосується".

dialogType    Обов’язковий аргумент MsoFileDialogType. Тип діалогового вікна файлу.

MsoFileDialogType може бути представлено такими константами:

msoFileDialogFilePicker

msoFileDialogFolderPicker

msoFileDialogOpen Не підтримується в Microsoft Access.

msoFileDialogSaveAs Не підтримується в Microsoft Access.

Зауваження

Константи msoFileDialogOpen і msoFileDialogSaveAs не підтримуються в Microsoft Office Access 2007.

Приклад

На прикладі нижче продемонстровано, як використовувати об'єкт FileDialog, щоб відобразити діалогове вікно, у якому користувач може вибрати один або кілька файлів. Вибрані файли потім додаються до списку FileList.

Private Sub cmdFileDialog_Click()
' Requires reference to Microsoft Office 11.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
' Clear listbox contents.
Me.FileList.RowSource = ""
' Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
' Allow user to make multiple selections in dialog box
.AllowMultiSelect = True
' Set the title of the dialog box.
.Title = "Please select one or more files"
' Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.ACCDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"
' Show the dialog box. If the .Show method returns True, the
' user picked at least one file. If the .Show method returns
' False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub
Удосконалення навичок роботи з Office
Ознайомтеся з навчальними матеріалами
Отримуйте нові функції раніше за інших
Приєднайтеся до оцінювачів Office

Ця інформація корисна?

Дякуємо за ваш відгук!

Дякуємо за відгук! Схоже, вам може стати в нагоді допомога одного з наших спеціалістів служби підтримки Office, з яким ми вас можемо з’єднати.

×