Microsoft hesabıyla oturum açın
Oturum açın veya hesap oluşturun.
Merhaba,
Farklı bir hesap seçin.
Birden çok hesabınız var
Oturum açmak istediğiniz hesabı seçin.
EĞER işlevi: İç içe formüller ve hatalardan kaçınma

EĞER işlevi, bir koşulu test edip Doğru veya Yanlış sonucunu döndürerek, bir değerle beklediğiniz değer arasında mantıksal karşılaştırma yapmanıza olanak tanır.

  • =EĞER(Bir şey Doğru ise, bir şey yap, değilse başka bir şey yap)

Dolayısıyla, EĞER deyiminin iki sonucu olabilir. İlk sonuç karşılaştırmanızın Doğru olması, ikinci sonuç da karşılaştırmanızın Yanlış olmasıdır.

EĞER deyimleri son derece sağlamdır ve çoğu elektronik tablo modelinin temelini oluşturur, ancak çoğu elektronik tablo sorununun temel sebebi de bunlardır. İdeal olarak bir EĞER deyiminin Erkek/Dişi, Evet/Hayır/Belki gibi basit koşullara uygulanması gerekir, ancak bazen 3’ten çok EĞER işlevini iç içe geçirmenizi* gerektirecek daha karmaşık senaryoları değerlendirmeniz gerekebilir.

* “İç içe geçirme”, birden çok işlevi tek bir formülde birleştirme uygulamasıdır.

Bir koşul doğru olduğunda belirli bir değerin ve yanlış olduğunda başka bir değerin döndürülmesi için, mantıksal işlevlerden biri olan EĞER işlevini kullanın.

Söz dizimi

EĞER(mantıksal_sınama, eğer_doğruysa_değer, [eğer_yanlışsa_değer])

Örneğin:

  • =EĞER(A2>B2,"Bütçeyi Aşıyor","Tamam")

  • =EĞER(A2=B2,B4-A4,"")

Bağımsız değişken adı

Açıklama

mantıksal_sınama   

(gerekli)

Sınamak istediğiniz koşul.

eğer_doğruysa_değer   

(gerekli)

Mantıksal_sınama sonucu DOĞRU ise döndürülmesini istediğiniz değer.

eğer_yanlışsa_değer   

(isteğe bağlı)

Mantıksal_sınama sonucu YANLIŞ ise döndürülmesini istediğiniz değer.

Açıklamalar

Excel en çok 64 farklı EĞER işlevini iç içe kullanmanıza izin verse de, bunu yapmanız pek önerilmez. Neden?

  • Birden çok EĞER deyimini doğru oluşturmak için, çok kapsamlı düşünmek ve mantığının sonuna kadar her koşulda doğru hesaplama yapabileceğinden emin olmak gerekir. Formülünüzü %100 doğru bir şekilde iç içe geçiremezseniz, kullandığınız durumların %75'inde formül doğru çalışabilir ama %25'inde beklenmedik sonuçlar döndürür. Ne yazık ki bu %25’lik kısmı yakalama ihtimaliniz düşüktür.

  • Birden çok EĞER deyiminin bakımı inanılmaz zor olabilir. Özellikle bir süre sonra geri dönüp ne yaptığınızı veya daha da kötüsü başka birinin ne yaptığını anlamaya çalışırsanız, bu çok zor olabilir.

Sonu gelmeyecekmiş gibi büyüyen bir EĞER deyimiyle karşılaşırsanız, farenizi bir kenara koyup stratejinizi yeniden ele alma zamanınız gelmiştir.

Birden çok EĞER deyimi kullanarak iç içe geçirilmiş karmaşık bir EĞER deyimi oluşturmanın doğru yoluna bakalım ve Excel cephanesindeki başka bir araca geçme zamanının geldiğini nasıl anlayacağımızı açıklayalım.

Örnekler

Aşağıdaki örnekte, öğrencilerin test puanlarının harf notuna dönüştürülmesi için kullanılan standart sayılabilecek bir iç içe EĞER deyimi gösterilmektedir.

Karmaşık iç içe Eğer deyimi - E2’deki formül =EĞER(B2>97,"A+",EĞER(B2>93,"A",EĞER(B2>89,"A-",EĞER(B2>87,"B+",EĞER(B2>83,"B",EĞER(B2>79,"B-",EĞER(B2>77,"C+",EĞER(B2>73,"C",EĞER(B2>69,"C-",EĞER(B2>57,"D+",EĞER(B2>53,"D",EĞER(B2>49,"D-","F"))))))))))))
  • =EĞER(D2>89,"A",EĞER(D2>79,"B",EĞER(D2>69,"C",EĞER(D2>59,"D","F"))))

    Bu karmaşık iç içe EĞER deyimi, kolayca anlaşılabilecek bir mantığı izler:

  1. Test Puanı (D2 hücresi) 89’dan büyükse, öğrenci A alır

  2. Test Puanı 79’dan büyükse, öğrenci B alır

  3. Test Puanı 69’dan büyükse, öğrenci C alır

  4. Test Puanı 59’dan büyükse, öğrenci D alır

  5. Diğer durumlarda ise öğrenci F alır

Test puanları ile harf notları arasındaki bağıntının değişme ihtimali düşük olduğundan, bu örnekteki deyim oldukça güvenli ve fazla bakım gerektirmez. Ancak notları A+, A ve A- şeklinde bölümlendirmeniz gerektiğinde ne olacağına bakalım. Dört koşullu EĞER deyiminizin 12 koşul içerecek şekilde yeniden yazılması gerekir! Formülünüz artık şöyle görünecektir:

  • =EĞER(B2>97,"A+",EĞER(B2>93,"A",EĞER(B2>89,"A-",EĞER(B2>87,"B+",EĞER(B2>83,"B",EĞER(B2>79,"B-", EĞER(B2>77,"C+",EĞER(B2>73,"C",EĞER(B2>69,"C-",EĞER(B2>57,"D+",EĞER(B2>53,"D",EĞER(B2>49,"D-","F"))))))))))))

İşlevsel olarak doğru ve beklendiği gibi çalışacak olmasına rağmen yazılması ve istediğinizi yaptığından emin olmak amacıyla test edilmesi daha uzun sürer. Göze çarpan bir diğer büyük sorun, puanları ve karşılık gelen notları el ile girmeniz gerekmesidir. Yanlışlıkla bir yazım hatası yapma ihtimaliniz nedir? Şimdi de aynısını, daha karmaşık koşullarla 64 kez yapmanız gerektiğini hayal etmeye çalışın. Tabii ki imkansız değil, ancak gerçekten de kendinizi bu boyutta bir çabaya ve fark edilmesi çok zor olan muhtemel hatalara maruz bırakmak ister misiniz?

İpucu: Excel'deki her işlev bir açılış ve kapanış parantezi () gerekir. Excel, formülü düzenlediğiniz sırada formülün farklı kısımlarını renklendirerek öğelerin nereye ekleneceğini anlamanıza yardımcı olmaya çalışır. Örneğin, yukarıdaki formül düzenlenirken, imlecinizi “)” şeklindeki kapanış parantezlerinden her birinin üzerinden geçirdiğiniz sırada buna karşılık gelen açılış parantezi de aynı rengi alır. Bu, özellikle karmaşık iç içe formüllerde, yeterince eşleşen parantez ekleyip eklemediğinizi anlamaya çalışırken işinize yarayabilir.

Ek örnekler

Aşağıda, ulaşılan Gelir düzeyine bağlı olarak Satış Komisyonu hesaplama için kullanılan çok yaygın bir örnek verilmiştir.

D9 hücresindeki formül, EĞER(C9>15000,%20,EĞER(C9>12500,%17,5,EĞER(C9>10000,%15,EĞER(C9>7500,%12,5,EĞER(C9>5000,%10,0)))))
  • =EĞER(C9>15000,20%,EĞER(C9>12500,17.5%,EĞER(C9>10000,15%,EĞER(C9>7500,12.5%,EĞER(C9>5000,10%,0)))))

Formülde şu denmektedir: EĞER(C9 hücresi 15.000’den Büyükse %20 döndür, EĞER(C9 hücresi 12.500’den büyükse %17,5 döndür gibi...

Önceki Notlar örneğine oldukça benzer olsa da, bu formül büyük EĞER deyimlerini korumanın ne kadar zor olabileceğini gösteren harika bir örnektir. Kuruluşunuz yeni ücret düzeyleri eklemeye ve hatta mevcut dolar veya yüzde değerlerini değiştirmeye karar verirse ne yapmanız gerekir? Elinizde çok iş var!

İpucu: Formül çubuğuna satır sonları ekleyerek uzun formüllerin okunmasını kolaylaştırabilirsiniz. Yeni bir satıra kaydırmak istediğiniz metnin hemen önünde ALT+ENTER tuşlarına basmanız yeterlidir.

Aşağıda mantığın yanlış sırayla verildiği bir komisyon senaryosu örneği verilmiştir:

D9 hücresindeki formül düzen dışıdır =EĞER(C9>5000,10%,EĞER(C9>7500,12.5%,EĞER(C9>10000,15%,EĞER(C9>12500,17.5%,EĞER(C9>15000,20%,0)))))

Sorunun ne olduğunu görebiliyor musun? Gelir karşılaştırmalarının sırasını önceki örnekle karşılaştırın. Bu hangi yöne gidiyor? Doğru, aşağıdan yukarıya (5.000$ ile 15.000$) doğru gidiyor, tam tersi değil. Ama neden bu kadar önemli bir şey? Bu önemli bir durum çünkü formül 5.000 TL'nin üzerindeki herhangi bir değer için ilk değerlendirmeyi geçemiyor. 12.500 ABD doları gelire sahip olduğunuzu varsayalım; IF deyimi 5.000 TL'den büyük olduğundan %10 döndürür ve orada durur. Bu durum inanılmaz derecede sorunlu olabilir çünkü birçok durumda bu tür hatalar olumsuz bir etki bırakana kadar fark edilmeden gider. Peki karmaşık iç içe EĞER deyimleriyle bazı ciddi tuzaklar olduğunu bilerek ne yapabilirsiniz? Çoğu durumda, EĞER işleviyle karmaşık bir formül oluşturmak yerine DÜŞEYARA işlevini kullanabilirsiniz. DÜŞEYARA'yı kullanarak önce bir başvuru tablosu oluşturmanız gerekir:

D2 hücresindeki formül =DÜŞEYARA(C2,C5:D17,2,DOĞRU)
  • =DÜŞEYARA(C2,C5:D17,2,DOĞRU)

Bu formül, C5:C17 aralığında C2 hücresinde değerin aranmasını söyler. Değer bulunursa, aynı satırdaki karşılık gelen değer D sütununda döndürülür.

D9 hücresindeki formül =DÜŞEYARA(B9,B2:C6,2,DOĞRU)
  • =DÜŞEYARA(B9,B2:C6,2,DOĞRU)

Benzer şekilde, bu formül B2:B22 aralığında B9 hücresinde değeri arar. Değer bulunursa, aynı satırdaki karşılık gelen değer C sütununda döndürülür.

Not: Bu DÜŞEYARA işlevlerinin ikisinde de formüllerin sonunda DOĞRU bağımsız değişkeni kullanılır ve bu, formüllerin yaklaşık bir eşleşme aramasını istediğimiz anlamına gelir. Başka bir deyişle, arama tablosundaki tam değerlerin yanı sıra bu değerler arasında kalan tüm değerleri eşleştirir. Bu durumda, arama tablolarının en düşükten başlayıp en büyüğe gidecek şekilde Artan düzende sıralanması gerekir.

DÜŞEYARA burada çok daha ayrıntılı olarak ele alınmıştır, ancak bu, 12 düzeyli, karmaşık iç içe EĞER deyiminden çok daha basit olduğundan emin olun! Bu kadar belirgin olmamakla birlikte başka avantajlar da vardır:

  • DÜŞEYARA başvuru tabloları açıkça görülebilir ve kolayca anlaşılabilir.

  • Tablo değerleri kolayca güncelleştirilebilir ve koşullarınız değişmediği sürece formülünüze hiç dokunmanız gerekmez.

  • Başkalarının başvuru tablonuzu görmesini ya da tabloyu etkileyecek işlemler yapmasını engellemek istiyorsanız tabloyu başka bir çalışma sayfasına koymanız yeterlidir.

Biliyor muydunuz?

Artık birden çok iç içe EĞER deyimini tek bir işlevle değiştirebilen bir EĞERS işlevi vardır. Dolayısıyla, aşağıdaki 4 EĞER işlevini içeren ilk not örneğimiz:

  • =EĞER(D2>89,"A",EĞER(D2>79,"B",EĞER(D2>69,"C",EĞER(D2>59,"D","F"))))

Tek bir ÇOKEĞER işlevi ile çok daha basit bir hale getirilebilir:

  • =ÇOKEĞER(D2>89,"A",D2>79,"B",D2>69,"C",D2>59,"D",DOĞRU,"F")

ÇOKEĞER işlevi çok kullanışlıdır, çünkü EĞER deyimleriyle ve parantezlerle uğraşmanıza gerek kalmaz.

Not: Bu özellik yalnızca Microsoft 365 aboneliğiniz varsa kullanılabilir. Microsoft 365 abonesiyseniz, en son Office sürümüne sahip olduğunuzdan emin olun.

Microsoft 365’i satın alın veya deneyin

Daha fazla yardım mı gerekiyor?

Her zaman Excel Teknik Topluluğu sayfasında bir uzmana soru sorabilir veya Topluluklar sayfasından destek alabilirsiniz.

İlgili Konular

Video: Gelişmiş EĞER işlevleri
EĞERSAY işlevi (Microsoft 365, Excel 2016 ve üzeri)
EĞERSAY işlevi değerleri tek bir ölçüte göre sayar ÇOKEĞERSAY işlevi birden çok ölçüte

göre değerleri sayarÇOKETOPLA işlevi, değerleri tek bir ölçüte
göretoplar ÇOKETOPLA işlevi, birden çok ölçüte
göre değerleri toplarVE işlevi
VEYA işlevi
DÜŞEYARA işlevi
Excel'deki
formüllere genel bakışBozuk formülleri
önlemeFormüllerdeki
hataları algılamaMantıksal işlevler
Excel işlevleri (alfabetik)
Excel işlevleri (kategoriye göre)

Daha fazla yardıma mı ihtiyacınız var?

Daha fazla seçenek mi istiyorsunuz?

Abonelik avantajlarını keşfedin, eğitim kurslarına göz atın, cihazınızın güvenliğini nasıl sağlayacağınızı öğrenin ve daha fazlasını yapın.

Topluluklar, soru sormanıza ve soruları yanıtlamanıza, geri bildirimde bulunmanıza ve zengin bilgiye sahip uzmanlardan bilgi almanıza yardımcı olur.

Bu bilgi yararlı oldu mu?

Dil kalitesinden ne kadar memnunsunuz?
Deneyiminizi ne etkiledi?
Gönder’e bastığınızda, geri bildiriminiz Microsoft ürün ve hizmetlerini geliştirmek için kullanılır. BT yöneticiniz bu verileri toplayabilecek. Gizlilik Bildirimi.

Geri bildiriminiz için teşekkürler!

×