EĞER işlevi

Excel’in en popüler işlevlerinden biri olan EĞER işlevi, bir değer ile beklediğiniz değer arasında mantıksal karşılaştırmalar yapmanıza olanak tanır. En basit biçimiyle, EĞER işlevi şunu söyler:

  • EĞER(Bir şey Doğru ise, o zaman bir şey yap, değilse başka bir şey yap)

Dolayısıyla, EĞER deyiminin iki sonucu olabilir. İlk sonuç karşılaştırmanızın Doğru olması, ikinci sonuç da karşılaştırmanızın Yanlış olmasıdır.

Birden fazla EĞER deyimi kullanma konusuna geçmek isterseniz bkz. Gelişmiş EĞER işlevleri: İç içe formüller ile çalışma ve hatalardan kaçınma.

Bir koşul doğru olduğunda belirli bir değerin ve yanlış olduğunda başka bir değerin döndürülmesi için, mantıksal işlevlerden biri olan EĞER işlevini kullanın.

Söz dizimi

EĞER(mantıksal_sınama, eğer_doğruysa_değer, [eğer_yanlışsa_değer])

Örneğin:

  • =EĞER(A2>B2,"Bütçeyi Aşıyor","Tamam")

  • =EĞER(A2=B2,B4-A4,"")

Bağımsız değişken adı

Açıklama

mantıksal_sınama    (gerekli)

Sınamak istediğiniz koşul.

eğer_doğruysa_değer    (gerekli)

Mantıksal_sınama sonucu DOĞRU ise döndürülmesini istediğiniz değer.

eğer_yanlışsa_değer    (isteğe bağlı)

Mantıksal_sınama sonucu YANLIŞ ise döndürülmesini istediğiniz değer.

Basit EĞER örnekleri

D2 hücresindeki formül: =EĞER(C2="Evet",1,2)
  • =EĞER(C2=”Evet”,1,2)

Yukarıdaki örnekte, D2 hücresi şunu söylüyor: EĞER(C2 = Evet, o zaman 1 döndür, değilse 2 döndür)

D2 hücresindeki formül: =EĞER(C2=1,"EVET","HAYIR")
  • =EĞER(C2=1,”Evet”,”Hayır”)

Bu örnekte, D2 hücresindeki formül şunu söylüyor: EĞER(C2 = 1, o zaman Evet döndür, değilse Hayır döndür)

Gördüğünüz gibi, EĞER işlevi hem metinleri hem de değerleri karşılaştırmak için kullanılabilir. Ayrıca bu işlevi hataları değerlendirmek için de kullanabilirsiniz. Yapabilecekleriniz bir öğenin başka bir öğeyle eşit olup olmadığına bakmak ve tek bir sonuç döndürmekle sınırlı değildir; matematiksel işleçler kullanabilir ve ölçütlerinize bağlı olarak ek hesaplamalar gerçekleştirebilirsiniz. Bunun dışında, birkaç EĞER işlevini iç içe kullanarak birden çok karşılaştırma da yapabilirsiniz.

Not: Formüllerde metin kullanacaksanız, metni tırnak içine almalısınız (örneğin, “Metin”). Bu kural yalnızca DOĞRU ve YANLIŞ sözcükleri için geçerli değildir; Excel bu sözcükleri otomatik olarak anlar.

Nasıl başlanır?

EĞER deyimini yazmaya başlamanın en iyi yolu, ne yapmaya çalıştığınız hakkında düşünmektir. Hangi karşılaştırmayı yapmaya çalışıyorsunuz? Çoğu zaman EĞER deyimini yazmak, kafanızda mantığını düşünmek kadar basittir: “Bu koşul karşılanırsa ne olur ve karşılanmazsa ne olur?” Adımlarınızın her zaman mantıksal bir şekilde ilerlediğinden emin olmalısınız, aksi takdirde formül beklediğiniz sonucu vermez. Bu, özellikle karmaşık (iç içe) EĞER deyimleri oluştururken çok önemlidir.

Diğer EĞER örnekleri

D2 hücresindeki formül: =EĞER(C2>B2,”Bütçeyi Aşıyor”,”Bütçe İçinde”)
  • =EĞER(C2>B2,”Bütçeyi Aşıyor”,”Bütçe İçinde”)

Yukarıdaki örnekte, D2 hücresindeki EĞER işlevi şunu söylüyor: EĞER(C2 B2'den Büyükse, o zaman “Bütçeyi Aşıyor” metnini döndür, değilse “Bütçe İçinde” metnini döndür)

E2 hücresindeki formül: =EĞER(C2>B2,C2-B2,"")
  • =EĞER(C2>B2,C2-B2,0)

Yukarıdaki çizimde, metin sonucu yerine matematiksel bir hesaplama döndüreceğiz. Dolayısıyla E2’deki formül şunu söylüyor: EĞER(Gerçek Değeri Bütçelenen Değerinden Büyükse, o zaman Bütçelenen tutarı Gerçek tutardan Çıkar, değilse hiçbir şey döndürme).

F7 hücresindeki formül: EĞER(E7=”Evet”,F5*0,0825,0)
  • =EĞER(E7=”Evet”,F5*0,0825,0)

Bu örnekte F7'deki formül şunu söylüyor: EĞER(E7 = “Evet”, o zaman F5 * %8,25'te Toplam Tutarı hesapla, değilse süresi geçmiş Satış Vergisi yoktur bu nedenle 0 döndür)

En İyi Yöntemler - Sabitler

Son örnekte, hem “Evet” sözcüğünün hem de Satış Vergi Oranının (0,0825) doğrudan formüle girildiğini görüyorsunuz. Genellikle sabit değerleri (zaman içinde değişmesi gerekebilen değerler) formüllere doğrudan yazmak iyi bir yöntem değildir, çünkü gelecekte bunları bulmak ve değiştirmek zor olabilir. Sabitleri, açıkça görülebilecekleri ve kolayca bulunup değiştirilebilecekleri kendi hücrelerine yerleştirmek çok daha iyi bir yöntemdir. Bu örnekte sorun oluşmaz çünkü tek bir EĞER işlevi vardır ve Satış Vergi Oranı nadiren değişir. Değişse bile formülde bu oran kolayca değiştirilebilir.

Hesaplama işleçleri

Formüllerde kullanabileceğiniz farklı hesaplama işleçleri hakkında daha fazla bilgi edinmek isterseniz (< küçüktür, > büyüktür, = eşittir, <> eşit değildir, vb.) şu makaleye bakın: Hesaplama işleçleri ve öncelik.

Hücrenin boş olup olmadığını denetlemek için EĞER kullanma

Bazen bir hücrenin boş olup olmadığını denetlemeniz gerekir; genel olarak bunun nedeni bir formülün girişi olmadan sonuç görüntülemesini istememenizdir.

E2 hücresindeki formül =EĞER(D2=1,"Evet",EĞER(D2=2,"Hayır","Belki"))

Burada EĞER işlevini EBOŞSA işleviyle birlikte kullanıyoruz:

  • =EĞER(EBOŞSA(D2),"Boş","Boş Değil")

Bu formül şunu söylüyor: EĞER(D2 boşsa, o zaman "Boş" döndür, değilse "Boş Değil" döndür). "Boş Değil" koşulu için de aynı şekilde kolayca kendi formülünüzü kullanabilirsiniz. Sonraki örnekte EBOŞSA yerine "" kullanıyoruz. "" temelde "hiçbir şey" anlamına gelir.

Hücrenin boş olup olmadığını denetleme - E2 hücresindeki formül: =EĞER(EBOŞSA(D2),"Boş","Boş Değil")
  • =EĞER(D3="","Boş","Boş Değil")

Bu formül şunu söylüyor: Eğer(D3 hiçbir şeyse, o zaman "Boş" döndür, değilse "Boş Değil" döndür). Aşağıda, bağımlı bir hücre boşsa formülün hesaplama yapmasını önlemek için çok yaygın kullanılan bir "" kullanım yöntemi örneği bulunuyor:

  • =EĞER(D3="","",Formülünüz())

    EĞER(D3 hiçbir şeyse, o zaman hiçbir şey döndürme, değilse formülü hesapla).

İç içe EĞER örneği

Basit bir EĞER işlevinin yalnızca iki sonucu olurken (Doğru veya Yanlış), iç içe EĞER işlevlerinin 3 ile 64 arasında sonucu olabilir.

Boş hücre denetimi yapmak için "" kullanma - E3 hücresindeki formül: =EĞER(D3="","Boş","Boş Değil")
  • =EĞER(D2=1,”EVET”,EĞER(D2=2,”Hayır”,”Belki”))

Yukarıdaki çizimde, E2'deki formül şunu söylüyor: EĞER(D2 1'e eşitse o zaman “Evet” döndür, değilse EĞER(D2 2'ye eşitse o zaman “Hayır” döndür, değilse “Belki” döndür)). Formülün sonunda iki kapatma parantezi olduğuna dikkat edin. Her iki EĞER işlevini de kapatmak için bunlar gereklidir ve formülü iki kapatma parantezi olmadan girmeye çalışırsanız, Excel sizin için bunu düzeltmeyi dener.

Bir uyarı

Excel’de 64 farklı EĞER işlevini iç içe kullanmanıza mümkündür, ancak bunu yapmanız önerilmez. Neden?

  • Birden çok EĞER deyimini doğru oluşturmak için çok kapsamlı düşünmek ve mantığının sonuna kadar her koşulda doğru hesaplama yapabileceğinden emin olmak gerekir. EĞER deyimlerinizi %100 doğru bir şekilde iç içe yerleştirmezseniz kullandığınız durumların %75’inde formül doğru çalışabilir ama %25’inde beklenmedik sonuçlar döndürür. Ne yazık ki %25’e yakalanma ihtimaliniz vardır.

  • Birden çok EĞER deyiminin bakımı çok zor olabilir. Özellikle bir süre sonra geri gelip ne yaptığınızı anlamaya çalışırsanız veya daha da kötüsü başka birisi bunu anlamaya çalışırsa çok zorlanabilir.

  • Birden çok EĞER deyimi için birden çok açma ve kapatma parantezi () gerekir ve formülünüzün ne kadar karmaşık hale geldiğine bağlı olarak bunları yönetmek zor olabilir.

Sık karşılaşılan sorunlar

Sorun

Nerede sorun çıktı

Hücrede 0 (sıfır) var

Eğer_doğruysa_değer ve eğer_yanlışsa_değer bağımsız değişkenlerinden biri yoktur. Döndürülen doğru değeri görmek için, iki bağımsız değişkene de bağımsız değişken metni ekleyin veya bağımsız değişkene DOĞRU veya YANLIŞ ekleyin.

Hücrede #AD? var

Bu çoğunlukla formülde yazım hatası olduğu anlamına gelir.

Daha fazla yardım mı gerekiyor?

Sorularınızı Excel Teknoloji Topluluğu’ndaki uzmanlara sorabilir, Yanıt topluluğu’ndan destek alabilir ya da Excel için UserVoice platformuna yeni bir özellik veya iyileştirme önerisi sunabilirsiniz.

Ayrıca bkz.

Video: Gelişmiş EĞER işlevleri

ÇOKEĞER işlevi (Office 365, Excel 2016 ve sonrası)

Gelişmiş EĞER işlevleri: İç içe formüller ile çalışma ve hatalardan kaçınma

Eğitim Videoları: Gelişmiş EĞER işlevleri

EĞERSAY işlevi, değerleri tek bir ölçüte göre sayar

ÇOKEĞERSAY işlevi, değerleri birden fazla ölçüte göre sayar

ETOPLA işlevi, değerleri tek bir ölçüte göre toplar

ÇOKETOPLA işlevi, değerleri birden fazla ölçüte göre toplar

VE işlevi

YADA işlevi

DÜŞEYARA işlevi

Excel’deki formüllere genel bakış

Bozuk formülleri önleme

Formüllerdeki hataları saptamak için hata denetimini kullanma

Mantıksal İşlevler

Excel işlevleri (alfabetik)

Excel işlevleri (kategoriye göre)

Office yeteneklerinizi geliştirin
Eğitimleri keşfedin
Yeni özellikleri ilk olarak siz edinin
Office Insider Programına Katılın

Bu bilgi yararlı oldu mu?

Görüşleriniz için teşekkür ederiz!

Geri bildiriminiz için teşekkürler! Office destek temsilcilerimizden biriyle görüşmeniz yararlı olabilir.

×