EĞER işlevi: İç içe formüller ve hatalardan kaçınma

EĞER işlevi: İç içe formüller ve hatalardan kaçınma

Not: En güncel yardım içeriklerini, mümkün olduğunca hızlı biçimde kendi dilinizde size sunmak için çalışıyoruz. Bu sayfanın çevirisi otomasyon aracılığıyla yapılmıştır ve bu nedenle hatalı veya yanlış dil bilgisi kullanımları içerebilir. Amacımız, bu içeriğin sizin için faydalı olabilmesini sağlamaktır. Buradaki bilgilerin faydalı olup olmadığını bu sayfanın sonunda bize bildirebilir misiniz? Kolayca başvurabilmek için İngilizce makaleye buradan ulaşabilirsiniz.

EĞER işlevi, bir koşulu test edip Doğru veya Yanlış sonucunu döndürerek, bir değerle beklediğiniz değer arasında mantıksal karşılaştırma yapmanıza olanak tanır.

  • =EĞER(Bir şey Doğru ise, bir şey yap, değilse başka bir şey yap)

Dolayısıyla, EĞER deyiminin iki sonucu olabilir. İlk sonuç karşılaştırmanızın Doğru olması, ikinci sonuç da karşılaştırmanızın Yanlış olmasıdır.

EĞER deyimleri son derece sağlamdır ve çoğu elektronik tablo modelinin temelini oluşturur, ancak çoğu elektronik tablo sorununun temel sebebi de bunlardır. İdeal olarak bir EĞER deyiminin Erkek/Dişi, Evet/Hayır/Belki gibi basit koşullara uygulanması gerekir, ancak bazen 3’ten çok EĞER işlevini iç içe geçirmenizi* gerektirecek daha karmaşık senaryoları değerlendirmeniz gerekebilir.

* “İç içe geçirme”, birden çok işlevi tek bir formülde birleştirme uygulamasıdır.

Bir koşul doğru olduğunda belirli bir değerin ve yanlış olduğunda başka bir değerin döndürülmesi için, mantıksal işlevlerden biri olan EĞER işlevini kullanın.

Söz dizimi

EĞER(mantıksal_sınama, eğer_doğruysa_değer, [eğer_yanlışsa_değer])

Örneğin:

  • =EĞER(A2>B2,"Bütçeyi Aşıyor","Tamam")

  • =EĞER(A2=B2,B4-A4,"")

Bağımsız değişken adı

Açıklama

mantıksal_sınama   

(gerekli)

Sınamak istediğiniz koşul.

eğer_doğruysa_değer   

(gerekli)

Mantıksal_sınama sonucu DOĞRU ise döndürülmesini istediğiniz değer.

eğer_yanlışsa_değer   

(isteğe bağlı)

Mantıksal_sınama sonucu YANLIŞ ise döndürülmesini istediğiniz değer.

Açıklamalar

Excel’de 64 farklı EĞER işlevini iç içe kullanmanıza mümkündür, ancak bunu yapmanız önerilmez. Neden?

  • Birden çok EĞER deyimini doğru oluşturmak için, çok kapsamlı düşünmek ve mantığının sonuna kadar her koşulda doğru hesaplama yapabileceğinden emin olmak gerekir. Formülünüzü %100 doğru bir şekilde iç içe geçiremezseniz, kullandığınız durumların %75'inde formül doğru çalışabilir ama %25'inde beklenmedik sonuçlar döndürür. Ne yazık ki bu %25’lik kısmı yakalama ihtimaliniz düşüktür.

  • Birden çok EĞER deyiminin bakımı inanılmaz zor olabilir. Özellikle bir süre sonra geri dönüp ne yaptığınızı veya daha da kötüsü başka birinin ne yaptığını anlamaya çalışırsanız, bu çok zor olabilir.

Sonu gelmeyecekmiş gibi büyüyen bir EĞER deyimiyle karşılaşırsanız, farenizi bir kenara koyup stratejinizi yeniden ele alma zamanınız gelmiştir.

Birden çok EĞER deyimi kullanarak iç içe geçirilmiş karmaşık bir EĞER deyimi oluşturmanın doğru yoluna bakalım ve Excel cephanesindeki başka bir araca geçme zamanının geldiğini nasıl anlayacağımızı açıklayalım.

Örnekler

Aşağıdaki örnekte, öğrencilerin test puanlarının harf notuna dönüştürülmesi için kullanılan standart sayılabilecek bir iç içe EĞER deyimi gösterilmektedir.

Karmaşık iç içe Eğer deyimi - E2’deki formül =EĞER(B2>97,"A+",EĞER(B2>93,"A",EĞER(B2>89,"A-",EĞER(B2>87,"B+",EĞER(B2>83,"B",EĞER(B2>79,"B-",EĞER(B2>77,"C+",EĞER(B2>73,"C",EĞER(B2>69,"C-",EĞER(B2>57,"D+",EĞER(B2>53,"D",EĞER(B2>49,"D-","F"))))))))))))
  • =EĞER(D2>89,"A",EĞER(D2>79,"B",EĞER(D2>69,"C",EĞER(D2>59,"D","F"))))

    Bu karmaşık iç içe EĞER deyimi, kolayca anlaşılabilecek bir mantığı izler:

  1. Test Puanı (D2 hücresi) 89’dan büyükse, öğrenci A alır

  2. Test Puanı 79’dan büyükse, öğrenci B alır

  3. Test Puanı 69’dan büyükse, öğrenci C alır

  4. Test Puanı 59’dan büyükse, öğrenci D alır

  5. Diğer durumlarda ise öğrenci F alır

Kadar bakım gerektiren kalmamaları için büyük olasılıkla bağıntı arasındaki puan test edin ve harf dereceleri değiştirecek, olmadığı için bu belirli güvenli oldukça örneğidir. Burada, ancak ne notlarını A + arasında bölmek için size gereken bir düşünce – A ve A - (vb.)? Artık, dört koşul Eğer deyimi 12 koşullar için yazılması gerekir! İşte ne formülünüz şimdi gibi görünebilir:

  • =EĞER(B2>97,"A+",EĞER(B2>93,"A",EĞER(B2>89,"A-",EĞER(B2>87,"B+",EĞER(B2>83,"B",EĞER(B2>79,"B-", EĞER(B2>77,"C+",EĞER(B2>73,"C",EĞER(B2>69,"C-",EĞER(B2>57,"D+",EĞER(B2>53,"D",EĞER(B2>49,"D-","F"))))))))))))

İşlevsel olarak doğru ve beklendiği gibi çalışacak olmasına rağmen yazılması ve istediğinizi yaptığından emin olmak amacıyla test edilmesi daha uzun sürer. Göze çarpan bir diğer büyük sorun, puanları ve karşılık gelen notları el ile girmeniz gerekmesidir. Yanlışlıkla bir yazım hatası yapma ihtimaliniz nedir? Şimdi de aynısını, daha karmaşık koşullarla 64 kez yapmanız gerektiğini hayal etmeye çalışın. Tabii ki imkansız değil, ancak gerçekten de kendinizi bu boyutta bir çabaya ve fark edilmesi çok zor olan muhtemel hatalara maruz bırakmak ister misiniz?

İpucu: Excel'deki her işlev bir açılış ve kapanış parantezi () gerekir. Excel, formülü düzenlediğiniz sırada formülün farklı kısımlarını renklendirerek öğelerin nereye ekleneceğini anlamanıza yardımcı olmaya çalışır. Örneğin, yukarıdaki formül düzenlenirken, imlecinizi “)” şeklindeki kapanış parantezlerinden her birinin üzerinden geçirdiğiniz sırada buna karşılık gelen açılış parantezi de aynı rengi alır. Bu, özellikle karmaşık iç içe formüllerde, yeterince eşleşen parantez ekleyip eklemediğinizi anlamaya çalışırken işinize yarayabilir.

Ek örnekler

Aşağıda, ulaşılan Gelir düzeyine bağlı olarak Satış Komisyonu hesaplama için kullanılan çok yaygın bir örnek verilmiştir.

D9 hücresindeki formül, EĞER(C9>15000,%20,EĞER(C9>12500,%17,5,EĞER(C9>10000,%15,EĞER(C9>7500,%12,5,EĞER(C9>5000,%10,0)))))
  • =EĞER(C9>15000,20%,EĞER(C9>12500,17.5%,EĞER(C9>10000,15%,EĞER(C9>7500,12.5%,EĞER(C9>5000,10%,0)))))

Formülde şu denmektedir: EĞER(C9 hücresi 15.000’den Büyükse %20 döndür, EĞER(C9 hücresi 12.500’den büyükse %17,5 döndür gibi...

Bu formül bir önceki Notlar örneğine son derece benzer olsa da, büyük EĞER deyimlerinin bakımını yapmanın ne kadar zor olduğu konusunda harika bir örnektir. Kuruluşunuz yeni ödeme düzeyleri eklemeye, hatta mevcut Dolar veya yüzdelik değerlerini değiştirmeye karar verirse ne olacak? Çok uğraşmanız gerekir!

İpucu: Formül çubuğuna satır sonları ekleyerek uzun formüllerin okunmasını kolaylaştırabilirsiniz. Yeni bir satıra kaydırmak istediğiniz metnin hemen önünde ALT+ENTER tuşlarına basmanız yeterlidir.

Aşağıda mantığın yanlış sırayla verildiği bir komisyon senaryosu örneği verilmiştir:

D9 hücresindeki formül düzen dışıdır =EĞER(C9>5000,10%,EĞER(C9>7500,12.5%,EĞER(C9>10000,15%,EĞER(C9>12500,17.5%,EĞER(C9>15000,20%,0)))))

Neyin yanlış olduğunu görebilir miyim? Önceki örnekte için gelir karşılaştırmalar sırasını karşılaştırın. Bu bir giderek hangi yolu var mı? Sağdan, bunu altından yukarı (5.000 TL için 15.000 TL), değil diğer yönden olacaksa olmasıdır. Ancak, bu gibi büyük anlaşma neden olmalı? Formülün ilk değerlendirme için herhangi bir değer üzerinde 5.000 TL geçirmek yapamazsınız büyük anlaşma demektir. Diyelim ki gelir $12.500 var – Eğer deyimi % 10 5000'den büyük olduğundan, ve orada durdurur döndürür. Bunlar olumsuz etkisi buluncaya kadar çok durumların içinde bu türde hataları gözden kaçan gidin çünkü bu son derece sorunlu olabilir. Bazı önemli sorunları karmaşık iç içe geçmiş Eğer deyimleri ile haberiniz olmasını sağlamak, ne yapabilirsiniz? Çoğu durumda, eğer işlevinin karmaşık bir formülle oluşturmak yerine, DÜŞEYARA işlevini kullanabilirsiniz. DÜŞEYARA İŞLEVİNİkullanarak, ilk başvuru tablo oluşturmanız gerekir:

D2 hücresindeki formül =DÜŞEYARA(C2,C5:D17,2,DOĞRU)
  • =DÜŞEYARA(C2,C5:D17,2,DOĞRU)

Bu formül, C2 değeri C5:C17 aralıktaki aramak diyor. Değer bulunursa, sonra buna karşılık gelen sütun d aynı satırındaki dönüş değeri

D9 hücresindeki formül =DÜŞEYARA(B9,B2:C6,2,DOĞRU)
  • =DÜŞEYARA(B9,B2:C6,2,DOĞRU)

Benzer şekilde, bu formül B2:B22 aralığında B9 hücresinde değeri arar. Değer bulunursa, aynı satırdaki karşılık gelen değer C sütununda döndürülür.

Not: Bu DÜŞEYARA işlevlerinin ikisinde de formüllerin sonunda DOĞRU bağımsız değişkeni kullanılır ve bu, formüllerin yaklaşık bir eşleşme aramasını istediğimiz anlamına gelir. Başka bir deyişle, arama tablosundaki tam değerlerin yanı sıra bu değerler arasında kalan tüm değerleri eşleştirir. Bu durumda, arama tablolarının en düşükten başlayıp en büyüğe gidecek şekilde Artan düzende sıralanması gerekir.

DÜŞEYARA işlevi burada çok daha ayrıntılı incelenmiştir, ancak 12 düzeyli, karmaşık bir iç içe EĞER deyiminden çok daha basit olduğundan emin olabilirsiniz. Bu kadar belirgin olmamakla birlikte başka avantajlar da vardır:

  • DÜŞEYARA başvuru tabloları açıkça görülebilir ve kolayca anlaşılabilir.

  • Tablo değerleri kolayca güncelleştirilebilir ve koşullarınız değişmediği sürece formülünüze hiç dokunmanız gerekmez.

  • Başkalarının başvuru tablonuzu görmesini ya da tabloyu etkileyecek işlemler yapmasını engellemek istiyorsanız tabloyu başka bir çalışma sayfasına koymanız yeterlidir.

Biliyor muydunuz?

Birden çok, değiştirebilir bir IFS işlevi iç içe Eğer ekstreleri ve tek bir işlevi artık yoktur. Bu nedenle ilk notlarını Örneğimiz yerine, hangi 4 iç içe Eğer işlevleri bulunur:

  • =EĞER(D2>89,"A",EĞER(D2>79,"B",EĞER(D2>69,"C",EĞER(D2>59,"D","F"))))

Tek bir ÇOKEĞER işlevi ile çok daha basit bir hale getirilebilir:

  • =ÇOKEĞER(D2>89,"A",D2>79,"B",D2>69,"C",D2>59,"D",DOĞRU,"F")

ÇOKEĞER işlevi çok kullanışlıdır, çünkü EĞER deyimleriyle ve parantezlerle uğraşmanıza gerek kalmaz.

Not: Bu özelliği kullanabilmek için Office 365 aboneliğiniz olmalıdır. Office 365 abonesiyseniz, Office'in en son sürümünü kullandığınızdan emin olun.

Office 365’i veya Excel’in en son sürümünü deneyin

Daha fazla yardım mı gerekiyor?

Sorularınızı Excel Teknoloji Topluluğu’ndaki uzmanlara sorabilir, Yanıt topluluğu’ndan destek alabilir ya da Excel için UserVoice platformuna yeni bir özellik veya iyileştirme önerisi sunabilirsiniz.

İlgili Konular

Video: Gelişmiş Eğer işlevleri
IFS işlevi (Office 365, Excel 2016 ve sonrası)
EĞERSAY işlevini tek bir ölçüte dayalı olarak değerleri saymak
ÇOKEĞERSAY işlevini çoklu dayalı olarak değerleri saymak Ölçüt
ETOPLA işlevi tek bir ölçüte dayalı olarak değerleri toplama
ÇOKETOPLA işlevini birden çok ölçüte dayalı olarak değerleri toplama
ve işlevi
yada işlevini
DÜŞEYARA işlevini
Excel'deki formüllere genel bakış
bozuk formülleri önleme
Formüllerdeki hataları Algıla
mantıksal işlevler
Excel işlevleri (alfabetik)
Excel işlevleri (kategoriye göre)

Office yeteneklerinizi geliştirin
Eğitimleri keşfedin
Yeni özellikleri ilk olarak siz edinin
Office Insider Programına Katılın

Bu bilgi yararlı oldu mu?

Görüşleriniz için teşekkür ederiz!

Geri bildiriminiz için teşekkürler! Office destek temsilcilerimizden biriyle görüşmeniz yararlı olabilir.

×