PrtDevMode Özelliği

Uygulandığı öğe

Form Nesnesi

Report Nesnesi

Yazdır iletişim kutusunda bir form veya rapor için belirtilmiş yazdırma cihazı modu bilgilerini ayarlamak veya döndürmek için PrtDevMode özelliğini kullanabilirsiniz. Okuma/yazma Değişken.

ifade. PrtDevMode

ifade Gerekli. Uygulandığı Öğe listesindeki nesnelerden birini döndüren ifade.

Notlar

PrtDevMode, PrtDevNames ve PrtMip özellikleri hakkındaki tüm belgelere ulaşmak için Win32 Yazılım Geliştirme Seti’ne başvurmanız kesinlikle önerilir.

PrtDevMode özellik ayarı, Win32 Yazılım Geliştirme Seti’nde tanımlanmış DEVMODE yapısıyla aynı olan 94 bayt’lık bir yapıdır. PrtDevMode özellik üyeleriyle ilgili bilgilerin tamamına erişmek için Win32 Yazılım Geliştirme Seti’ne başvurun.

PrtDev Mode özelliği aşağıdaki üyeleri kullanır.

Üye

Açıklama

DeviceName

Sürücünün desteklediği cihazın adını belirten, en fazla 32 bayt boyutlu bir dize; örneğin, belirtilen yazıcı Hewlett-Packard LaserJet IIISi ise "HP LaserJet IIISi". Her yazıcı sürücüsü benzersiz bir dizeye sahiptir.

SpecVersion

Win32 Yazılım Geliştirme Seti’ndeki DEVMODE yapısının sürüm numarasını belirten bir Tamsayı.

DriverVersion

Yazıcı sürücüsünün geliştiricisi tarafından atanmış yazıcı sürücüsü sürüm numarasını belirten bir Tamsayı.

Size

DEVMODE yapısının boyutunu bayt cinsinden belirten bir Tamsayı. (Bu değer, cihaza özgü veriler için bu yapıyı izleyebilecek isteğe bağlı dmDriverData üyesini içermez.) Bir uygulama tarafından verilerin yalnızca sürücüden bağımsız olan bölümü işleniyorsa, bu üyeyi kullanarak farklı sürümleri hesaba katmak zorunda kalmadan bu yapının uzunluğunu öğrenebilirsiniz.

DriverExtra

Cihaza özgü veriler için bu yapıyı izleyebilecek isteğe bağlı dmDriverData üyesinin boyutunu bayt cinsinden belirten bir Tamsayı. Bir uygulama cihaza özgü veriler kullanmıyorsa bu üyeyi 0 olarak ayarlayabilirsiniz.

Fields

DEVMODE yapısında kalan üyelerden hangilerinin başlatıldığını belirten Uzun bir değer.

Orientation

Sayfanın yönünü belirten bir Tamsayı. 1 (dikey) veya 2 (yatay) olabilir.

PaperSize

Üzerine yazdırılacak sayfanın boyutunu belirten bir Tamsayı. Bu üyeyi 0 veya 256 olarak ayarlarsanız sayfanın uzunluğu ve genişliği sırasıyla PaperLength ve PaperWidth üyeleri tarafından belirtilir. Aksi takdirde, PaperSize üyesini önceden tanımlanmış bir değere ayarlayabilirsiniz.

PaperLength

Kağıdın uzunluğunu 0,1 milimetrenin katları şeklinde belirten bir Tamsayı. Bu üye, özel kağıt boyutları veya nokta vuruşlu yazıcılar gibi çeşitli kağıt boyutlarına yazdırabilen cihazlar için PaperSize üyesi tarafından belirtilen kağıt uzunluğunu geçersiz kılar.

PaperWidth

Kağıdın genişliğini 0,1 milimetrenin katları şeklinde belirten bir Tamsayı. Bu üye, PaperSize üyesi tarafından belirtilen kağıt genişliğini geçersiz kılar.

Scale

Yazdırılan çıktının ölçek faktörünü belirten bir Tamsayı. Görünen sayfa ölçeği, fiziksel sayfa boyutundan ölçek/100 faktörüyle ölçeklenir. Örneğin, 8,5 X 11 inç (mektup boyutu) ölçülerine sahip, Ölçek değeri 50 olan bir kağıttaki çıktı metni ve grafikleri özgün yükseklik ve genişliklerinin yarısı büyüklüğünde olacağından, bu kağıt 17 X 22 inç ölçülerindeki bir sayfayla aynı miktarda veri içerebilir.

Copies

Yazdırma cihazı çok sayfalı kopyalamayı destekliyorsa yazdırılacak kopya sayısını belirten bir Tamsayı.

DefaultSource

Kağıtların beslendiği varsayılan kutuyu belirten bir Tamsayı.

PrintQuality

Yazıcının çözünürlüğünü belirten bir Tamsayı. Değerler şunlardır: –4 (yüksek), –3 (orta), –2 (düşük) ve –1 (taslak).

Color

Bir Tamsayı. Renkli yazıcılarda çıktının renkli yazdırılıp yazdırılmayacağını belirtir. Değerler 1 (renkli) ve 2 (tek renkli) şeklindedir.

Duplex

Bir Tamsayı. Çift yönlü yazdırabilen yazıcılarda, çıktının kağıdın her iki yüzüne de yazdırılıp yazdırılmayacağını belirtir. Değerler 1 (tek yönlü), 2 (yatay) ve 3 (dikey) şeklindedir.

YResolution

Yazıcının y eksenindeki nokta/inç (dpi) çözünürlüğünü belirten bir Tamsayı. Yazıcı bu öğeyi başlatırsa, yazıcının x eksenindeki dpi çözünürlüğünü PrintQuality üyesi belirtir.

TTOption

TrueType yazı tiplerinin nasıl yazdırılacağını belirten bir Tamsayı.

Collate

Birden çok kopya yazdırılırken harmanlama kullanılıp kullanılmayacağını belirten bir Tamsayı. Harmanlanmamış kopyalar kullanıldığında veriler yazıcıya yalnızca bir kere gönderildiğinden daha hızlı, daha verimli çıktı sağlanır.

FormName

Kullanılacak kağıdın boyutunu belirten ve en fazla 16 karakterden oluşan bir dize; örneğin, "Letter" veya "Legal".

Pad

Gelecek sürümler için boşlukları, karakterleri veya değerleri doldurmak için kullanılan Uzun bir değer.

Bits

Görüntü cihazının renk çözünürlüğünü piksel başına bit cinsinden belirten Uzun bir değer.

PW

Görünür cihaz yüzeyinin (ekran veya yazıcı) genişliğini piksel cinsinden belirten Uzun bir değer.

PH

Görünür cihaz yüzeyinin (ekran veya yazıcı) yüksekliğini piksel cinsinden belirten Uzun bir değer.

DFI

Cihazın görüntüleme modunu belirten Uzun bir değer.

DFR

Belirli bir modda görüntüleme cihazının frekansını hertz (saniye başına döngü) cinsinden belirten Uzun bir değer.


Not : PrtDevMode özelliğini Visual Basic for Applications (VBA) kodu kullanarak ayarlayabilirsiniz.

Bu özellik ayarı Tasarım görünümü veya Düzen görünümünde okuma/yazma, diğer görünümlerde salt okunur olur.

Yazıcı sürücüleri, DEVMODE yapısına ait 94 bayt’ın hemen arkasına cihaza özgü veriler ekleyebilir. Bu nedenle, yukarıda ana hatlarıyla açıklanan DEVMODE verileri 94 bayt’ı aşmamalıdır.

DEVMODE yapısını yalnızca ExtDeviceMode işlevini dışarı aktaran yazıcılar kullanır.

Bir uygulama, DeviceCapabilities işlevine DC_PAPERS, DC_PAPERSIZE ve DC_PAPERNAMES değerleriyle çağrı yaparak yazıcı tarafından desteklenen kağıt boyutlarını ve adlarını alabilir.

Uygulamalar TTOption üyesinin değerini ayarlamadan önce DC_TRUETYPE değeriyle DeviceCapabilities işlevine çağrı yaparak yazıcı sürücüsünün TrueType yazı tiplerini nasıl kullanabildiğini öğrenmelidir.

Örnek

Aşağıdaki örnekte bir raporun kullanıcı tarafından tanımlanan sayfa boyutunu değerlendirmek için PrtDevMode özelliği kullanılmıştır:

Private Type str_DEVMODE
RGB As String * 94
End Type
Private Type type_DEVMODE
strDeviceName As String * 32
intSpecVersion As Integer
intDriverVersion As Integer
intSize As Integer
intDriverExtra As Integer
lngFields As Long
intOrientation As Integer
intPaperSize As Integer
intPaperLength As Integer
intPaperWidth As Integer
intScale As Integer
intCopies As Integer
intDefaultSource As Integer
intPrintQuality As Integer
intColor As Integer
intDuplex As Integer
intResolution As Integer
intTTOption As Integer
intCollate As Integer
strFormName As String * 32
lngPad As Long
lngBits As Long
lngPW As Long
lngPH As Long
lngDFI As Long
lngDFr As Long
End Type
Public Sub CheckCustomPage(ByVal rptName As String)
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
Dim intResponse As Integer
' Opens report in Design view.
DoCmd.OpenReport rptName, acDesign
Set rpt = Reports(rptName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
' Gets current DEVMODE structure.
DevString.RGB = strDevModeExtra
LSet DM = DevString
If DM.intPaperSize = 256 Then
' Display user-defined size.
intResponse = MsgBox("The current custom page size is " & _
DM.intPaperWidth / 254 & " inches wide by " & _
DM.intPaperLength / 254 & " inches long. Do you want " & _
"to change the settings?", vbYesNo + vbQuestion)
Else
' Currently not user-defined.
intResponse = MsgBox("The report does not have a custom page size. " & _
"Do you want to define one?", vbYesNo + vbQuestion)
End If
If intResponse = vbYes Then
' User wants to change settings. Initialize fields.
DM.lngFields = DM.lngFields Or DM.intPaperSize Or _
DM.intPaperLength Or DM.intPaperWidth
' Set custom page.
DM.intPaperSize = 256
' Prompt for length and width.
DM.intPaperLength = InputBox("Please enter page length in inches.") * 254
DM.intPaperWidth = InputBox("Please enter page width in inches.") * 254
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
End If
Set rpt = Nothing
End Sub

Aşağıdaki örnekte, raporun yönünün nasıl değiştirileceği gösterilmiştir. Bu örnekte, raporun geçerli yönünün yatay veya dikey olmasına bağlı olarak sayfa yönü dikey veya yatay olarak değiştirilecektir.

Public Sub SwitchOrient(ByVal strName As String)
Const DM_PORTRAIT = 1
Const DM_LANDSCAPE = 2
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
' Opens report in Design view.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
DevString.RGB = strDevModeExtra
LSet DM = DevString
DM.lngFields = DM.lngFields Or DM.intOrientation
' Initialize fields.
If DM.intOrientation = DM_PORTRAIT Then
DM.intOrientation = DM_LANDSCAPE
Else
DM.intOrientation = DM_PORTRAIT
End If
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
Set rpt = Nothing
End Sub
Yeteneklerinizi geliştirin
Eğitimleri keşfedin
Yeni özellikleri ilk olarak siz edinin
Office Insider Programına Katılın

Bu bilgi yararlı oldu mu?

Görüşleriniz için teşekkür ederiz!

Geri bildiriminiz için teşekkürler! Office destek temsilcilerimizden biriyle görüşmeniz yararlı olabilir.

×