Metni işlevlerle farklı sütunlara bölme

Metni işlevlerle farklı sütunlara bölme

Verilerinizdeki metin dizelerini işlemek için LEFT, MID, RIGHT, SEARCH ve LEN metin işlevlerini kullanabilirsiniz. Örneğin, tek bir hücredeki ad, ikinci ad ve soyadını üç ayrı sütuna dağıtabilirsiniz.

Metin işlevleriyle ad bileşenlerini dağıtmanın püf noktası, her karakterin metin dizesi içindeki konumudur. Dizedeki ad bileşenlerinin başlangıcını veya sonunu belirtmeleri nedeniyle, metin dizesindeki boşlukların konumları da önemlidir.

Örneğin, yalnızca ad ve soyadı içeren bir hücrede, soyadı, ilk boşluk kullanımından sonra başlar. Listenizdeki bazı adlar ikinci ad da içerebilir; bu durumda soyadı, ikinci boşluk kullanımından sonra başlar.

Bu makalede, bu kullanışlı işlevleri kullanarak farklı ad biçimlerinden çeşitli bileşenleri nasıl ayıklayacağınız gösterilmektedir. Ayrıca, Metni Sütunlara Çevirme Sihirbazı ile metni farklı sütunlara ayırabilirsiniz.

Örnek ad

Açıklama

Ad

İkinci ad

Soyadı

Sonek

1

Jeff Smith

İkinci ad yok

Jeff

Smith

2

Eric S. Kurjan

Bir ikinci ad baş harfi

Eric

S.

Kurjan

3

Janaina B. G. Bueno

İki ikinci ad baş harfi

Janaina

B. G.

Bueno

4

Kahn, Wendy Beth

Önce soyadı, virgüllü

Wendy

Beth

Kahn

5

Mary Kay D. Andersen

İki parçalı ad

Mary Kay

D.

Andersen

6

Paula Barreto de Mattos

Üç parçalı soyadı

Paula

Barreto de Mattos

7

James van Eaton

İki parçalı soyadı

James

van Eaton

8

Bacon Jr., Dan K.

Soyadı ve önce sonek, virgüllü

Dan

K.

Bacon

Jr.

9

Gary Altman III

Sonekli

Gary

Altman

III

10

Mr. Ryan Ihrig

Önekli

Ryan

Ihrig

11

Julie Taft-Rider

Tireyle birleştirilmiş soyadı

Julie

Taft-Rider

Not : Aşağıdaki örneklerdeki grafikte, tam addaki vurgu, eşleşen MBUL formülünün aradığı karakteri göstermektedir.

Bu örnekte iki bileşen ayrılır: ad ve soyadı. İki adı tek bir boşluk ayırır.

Tablodaki hücreleri kopyalayın ve Excel çalışma sayfasında A1 hücresine yapıştırın. Solda gördüğünüz formül başvuru amacıyla görüntülenir; bu arada Excel sağdaki formülü otomatik olarak uygun sonuca dönüştürür.

İpucu    Verileri çalışma sayfasına yapıştırmadan önce, A ve B sütunlarının genişliğini 250 olarak ayarlayın.

Örnek ad

Açıklama

Jeff Smith

İkinci ad yok

Formül

Sonuç (ad)

'=SOLDAN(A2, MBUL(" ",A2,1))

=SOLDAN(A2, MBUL(" ",A2,1))

Formül

Sonuç (soyadı)

’=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,1))

=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,1))

  1. Ad

    Ad, dizedeki birinci karakterle (J) başlar ve beşinci karakterde (boşluk) biter. Formül, A2 hücresinde soldan başlayarak beş karakter döndürür.

    Adı ayıklamayı sağlayan formül

    Sayı_karakterlere ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan başlayarak, A2'de boşluğun sayısal konumunu bulun.

  2. Soyadı

    Soyadı boşlukta başlar, sağdan beş karakter devam eder ve sağdaki son karakterde (h) sona erer. Formül, A2'de sağdan başlayarak beş karakter ayıklar.

    Soyadını ayıklamayı sağlayan formül

    Sayı_karakterlere ilişkin değeri bulmak için MBUL ve UZUNLUK işlevini kullanın:

    Soldan başlayarak, A2'de boşluğun sayısal konumunu (5) bulun.

  3. Metin dizesinin toplam uzunluğunu sayın ve sonra 1. adımda bulunduğu gibi, soldan birinci boşluğa kadar olan karakterlerin sayısını çıkarın.

Bu örnekte ad, ikinci adın baş harfi ve soyadı kullanılmaktadır. Her ad bileşeni bir boşlukla ayrılır.

Tablodaki hücreleri kopyalayın ve Excel çalışma sayfasında A1 hücresine yapıştırın. Solda gördüğünüz formül başvuru amacıyla görüntülenir; bu arada Excel sağdaki formülü otomatik olarak uygun sonuca dönüştürür.

İpucu    Verileri çalışma sayfasına yapıştırmadan önce, A ve B sütunlarının genişliğini 250 olarak ayarlayın.

Örnek ad

Açıklama

Eric S. Kurjan

Bir ikinci ad baş harfi

Formül

Sonuç (ad)

'=SOLDAN(A2, MBUL(" ",A2,1))

=SOLDAN(A2, MBUL(" ",A2,1))

Formül

Sonuç (ikinci adının ilk harfi)

’=PARÇAAL(A2,MBUL(" ",A2,1)+1,MBUL(" ",A2,MBUL(" ",A2,1)+1)-MBUL(" ",A2,1))

=PARÇAAL(A2,MBUL(" ",A2,1)+1,MBUL(" ",A2,MBUL(" ",A2,1)+1)-MBUL(" ",A2,1))

Formül

Dinamik Sonuç (soyadı)

’=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,1)+1))

=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,1)+1))

  1. Ad

    Ad, soldan birinci karakterle (E) başlar ve beşinci karakterde (birinci boşluk) biter. Formül, A2'de soldan başlayarak ilk beş karakteri ayıklar.

    Ad, soyadı ve ikinci adın ilk harfini ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan başlayarak, A2'de boşluğun sayısal konumunu (5) bulun.

  2. İkinci ad

    İkinci ad, altıncı karakter konumunda (S) başlar ve sekizinci konumda (ikinci boşluk) biter. Bu formülde, ikinci boşluk kullanımını bulmak için iç içe geçmiş MBUL işlevleri kullanılmaktadır.

    Formül, altıncı konumdan başlayarak üç karakter ayıklar.

    Ad, ikinci ad ve soyadını ayırma formülünün ayrıntıları

    Başlangıç_sayısına ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (5).

  3. Birinci boşluktan sonraki karakterin (S) konumunu bulmak için 1 ekleyin. Bu sayısal konum, ikinci adın başlangıç konumudur. (5 + 1 = 6)

    Sayı_karakterler'e ilişkin değeri bulmak için iç içe geçmiş MBUL işlevlerini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (5)

  4. Birinci boşluktan sonraki karakterin (S) konumunu almak için 1 ekleyin. Sonuç, boşluğun ikinci geçtiği yeri aramayı başlatmak istediğiniz karakter sayısıdır. (5 + 1 = 6)

  5. 4. adımda bulunan altıncı konumdan (S) başlayarak, A2'de boşluğun ikinci kullanılışını arayın. Bu karakter sayısı, ikinci adın bitiş konumudur (8).

  6. Soldan birinci karakterden başlayarak, A2 hücresinde boşluğun sayısal konumunu arayın. (5)

  7. 5. adımda bulunan ikinci boşluğun karakter sayısını alıp, 6. adımda bulunan birinci boşluğun karakter sayısını çıkarın. Sonuç, PARÇAAL'ın, 2. adımda bulunan altıncı konumda başlayan metin dizesinden ayıkladığı karakterlerin sayısıdır. (8 – 5 = 3)

  8. Soyadı

    Soyadı, sağdan altıncı karakterde (K) başlar ve sağdan birinci karakterde (n) biter. Bu formül, ikinci ve üçüncü boşluk kullanımlarını (soldan beşinci ve sekizinci konumlarda) bulmak için MBUL işlevlerinin iç içe geçmelerini gerektirir.

    Formül, A2'de sağdan başlayarak altı karakter ayıklar.

    Ad, ikinci ad ve soyadı ayırma formülünde ikinci ARA işlevi
  9. Sayı_karakterlere ilişkin değeri bulmak için UZUNLUK ve iç içe geçmiş MBUL işlevini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde boşluğun sayısal konumunu arayın. (5)

  10. Birinci boşluktan sonraki karakterin (S) konumunu almak için 1 ekleyin. Sonuç, boşluğun ikinci geçtiği yeri aramayı başlatmak istediğiniz karakter sayısıdır. (5 + 1 = 6)

  11. 2. adımda bulunan altıncı konumdan (S) başlayarak, A2'de boşluğun ikinci kullanılışını arayın. Bu karakter sayısı, ikinci adın bitiş konumudur (8).

  12. A2'de metin dizesinin toplam uzunluğunu sayın ve sonra, soldan, 3. adımda bulunan boşluğun ikinci kullanımına kadar karakterlerin sayısını çıkarın. Sonuç, tam adın sağdan ayıklanacak karakterler sayısıdır. (14 – 8 = 6).

Bu örnekte iki ikinci ad baş harfi vardır. Ad bileşenlerini, birinci ve üçüncü boşluk kullanımları ayırır.

Tablodaki hücreleri kopyalayın ve Excel çalışma sayfasında A1 hücresine yapıştırın. Solda gördüğünüz formül başvuru amacıyla görüntülenir; bu arada Excel sağdaki formülü otomatik olarak uygun sonuca dönüştürür.

İpucu    Verileri çalışma sayfasına yapıştırmadan önce, A ve B sütunlarının genişliğini 250 olarak ayarlayın.

Örnek ad

Açıklama

Janaina B. G. Bueno

İki ikinci ad baş harfi

Formül

Sonuç (ad)

'=SOLDAN(A2, MBUL(" ",A2,1))

=SOLDAN(A2, MBUL(" ",A2,1))

Formül

Sonuç (ikinci adının ilk harfleri)

’=PARÇAAL(A2,MBUL(" ",A2,1)+1,MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1)-MBUL(" ",A2,1))

=PARÇAAL(A2,MBUL(" ",A2,1)+1,MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1)-MBUL(" ",A2,1))

Formül

Dinamik Sonuç (soyadı)

’=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1))

=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1))

  1. Ad

    Ad, soldan birinci karakterle (J) başlar ve sekizinci karakterde (birinci boşluk) biter. Formül, A2'de soldan başlayarak birinci sekiz karakteri ayıklar.

    Ad, soyadı ve iki adet ikinci ad baş harfini ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (8)

  2. İkinci ad

    İkinci ad, dokuzuncu konumda (B) başlatılır ve ondördüncü konumda (üçüncü boşluk) biter. Bu formül, sekizinci, onbirinci ve ondördüncü konumlardaki birinci, ikinci ve üçüncü boşluk kullanımlarını bulmak için MBUL işlevlerinin iç içe geçmelerini gerektirir.

    Formül, dokuzuncu konumdan başlayarak beş karakter ayıklar.

    Ad, soyadı ve iki adet ikinci ad baş harfini ayırmayı sağlayan formül

    Başlangıç_sayısı'na ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (8)

  3. Birinci boşluktan sonraki karakterin (S) konumunu almak için 1 ekleyin. Bu sayısal konum, ikinci adın başlangıç konumudur. (8 + 1 = 9)

    Sayı_karakterler'e ilişkin değeri bulmak için iç içe geçmiş MBUL işlevlerini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (8)

  4. Birinci boşluktan sonraki karakterin (B) konumunu almak için 1 ekleyin. Sonuç, boşluğun ikinci geçtiği yeri aramayı başlatmak istediğiniz karakter sayısıdır. (8 + 1 = 9)

  5. 4. adımda bulunan dokuzuncu konumdan (B) başlayarak, A2'de ikinci boşluğu bulun. (11).

  6. İkinci boşluktan sonraki karakterin (G) konumunu almak için 1 ekleyin. Bu karakter sayısı, üçüncü boşluk için aramayı başlatmak istediğiniz başlangıç konumudur. (11 + 1 = 12)

  7. 6. adımda bulunan onikinci konumda başlayarak, A2'de üçüncü boşluğu (14) bulun.

  8. A2'de birinci boşluğun sayısal konumunu (8) bulun.

  9. 7. adımda bulunan üçüncü boşluğun karakter sayısını alın ve 6. adımda bulunan birinci boşluğun karakter sayısını çıkarın. Sonuç, PARÇAAL'ın, 2. adımda bulunan dokuzuncu konumda başlayan metin dizesinden ayıkladığı karakterlerin sayısıdır.

  10. Soyadı

    Soyadı sağdan beşinci karakterde (B) başlar ve sağdan birinci karakterde (o) biter. Bu formül, birinci, ikinci ve üçüncü boşluk kullanımlarını bulmak için MBUL işlevlerinin iç içe geçmelerini gerektirir.

    Formül, A2'de tam adın sağından başlayarak beş karakter ayıklar.

    Ad, soyadı ve iki adet ikinci ad baş harfini ayırmayı sağlayan formül

    Sayı_karakterlere ilişkin değeri bulmak için iç içe geçmiş MBUL ve UZUNLUK işlevini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (8)

  11. Birinci boşluktan sonraki karakterin (B) konumunu almak için 1 ekleyin. Sonuç, boşluğun ikinci geçtiği yeri aramayı başlatmak istediğiniz karakter sayısıdır. (8 + 1 = 9)

  12. 2. adımda bulunan dokuzuncu konumdan (B) başlayarak, A2'de ikinci boşluğu (11) bulun.

  13. İkinci boşluktan sonraki karakterin (G) konumunu almak için 1 ekleyin. Bu karakter sayısı, üçüncü boşluk kullanımı için aramayı başlatmak istediğiniz başlangıç konumudur. (11 + 1 = 12)

  14. 6. adımda bulunan onikinci konumda (G) başlayarak, A2'de üçüncü boşluğu (14) bulun.

  15. A2'de metin dizesinin toplam uzunluğunu sayın ve sonra, soldan, 5. adımda bulunan üçüncü boşluğa kadar karakterlerin sayısını çıkarın. Sonuç, tam adın sağdan ayıklanacak karakterler sayısıdır. (19 - 14 = 5)

Bu örnekte, soyadı addan önce gelir ve ikinci ad sonda görünür. Virgül, soyadının sonunu gösterir ve her ad bileşeni bir boşlukla ayrılır.

Tablodaki hücreleri kopyalayın ve Excel çalışma sayfasında A1 hücresine yapıştırın. Solda gördüğünüz formül başvuru amacıyla görüntülenir; bu arada Excel sağdaki formülü otomatik olarak uygun sonuca dönüştürür.

İpucu    Verileri çalışma sayfasına yapıştırmadan önce, A ve B sütunlarının genişliğini 250 olarak ayarlayın.

Örnek ad

Açıklama

Kahn, Wendy Beth

Önce soyadı, virgüllü

Formül

Sonuç (ad)

’=PARÇAAL(A2,MBUL(" ",A2,1)+1,MBUL(" ",A2,MBUL(" ",A2,1)+1)-MBUL(" ",A2,1))

=PARÇAAL(A2,MBUL(" ",A2,1)+1,MBUL(" ",A2,MBUL(" ",A2,1)+1)-MBUL(" ",A2,1))

Formül

Sonuç (ikinci ad)

’=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,1)+1))

=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,1)+1))

Formül

Dinamik Sonuç (soyadı)

’=SOLDAN(A2, MBUL(" ",A2,1)-2)

=SOLDAN(A2, MBUL(" ",A2,1)-2)

  1. Ad

    Ad, soldan yedinci karakterle (W) başlar ve onikinci karakterde (ikinci boşluk) biter. Ad, tam adın ortasında kullanıldığından, birinci adı ayıklamak için PARÇAAL işlevini kullanmanız gerekir.

    Formül, yedinci konumdan başlayarak altı karakter ayıklar.

    soyadını izleyen ad ve ikinci adı ayırmak için formül

    Başlangıç_sayısı'na ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  2. Birinci boşluktan sonraki karakterin (W) konumunu bulmak için 1 ekleyin. Bu sayısal konum, ikinci adın başlangıç konumudur. (6 + 1 = 7)

    Sayı_karakterler'e ilişkin değeri bulmak için iç içe geçmiş MBUL işlevlerini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  3. Birinci boşluktan sonraki karakterin (W) konumunu almak için 1 ekleyin. Sonuç, ikinci boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (6 + 1 = 7)

    4. adımda bulunan yedinci konumdan (W) başlayarak, A2'de ikinci boşluğu (12) bulun.

  4. Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  5. 5. adımda bulunan ikinci boşluğun karakter sayısını alıp, 6. adımda bulunan birinci boşluğun karakter sayısını çıkarın. Sonuç, PARÇAAL'ın, 2. adımda bulunan yedinci konumda başlayan metin dizesinden ayıkladığı karakterlerin sayısıdır. (12 - 6 = 6)

  6. İkinci ad

    İkinci ad sağdan dördüncü karakterde (B) başlar ve sağdan birinci karakterde (h) biter. Bu formülde, soldan altıncı ve onikinci konumlarda birinci ve ikinci boşluk kullanımlarını bulmak için iç içe geçmiş MBUL işlevleri yer alır.

    Formül, sağdan başlayarak dört karakter ayıklar.

    Soyadını izleyen ad ve ikinci adı ayırmayı sağlayan formül

    Başlangıç_sayısına ilişkin değeri bulmak için iç içe geçmiş MBUL ve UZUNLUK işlevini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  7. Birinci boşluktan sonraki karakterin (W) konumunu almak için 1 ekleyin. Sonuç, ikinci boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (6 + 1 = 7)

  8. 2. adımda bulunan yedinci konumdan (W) başlayarak, A2'de ikinci boşluk kullanımını (12) bulun.

  9. A2'de metin dizesinin toplam uzunluğunu sayın ve sonra, soldan, 3. adımda bulunan ikinci boşluğa kadar karakterlerin sayısını çıkarın. Sonuç, tam adın sağdan ayıklanacak karakterler sayısıdır. (16 - 12 = 4)

  10. Soyadı

    Soyadı, soldan birinci karakterle (K) başlar ve dördüncü karakterde (n) biter. Formül, soldan başlayarak dört karakter ayıklar.

    Soyadını izleyen ad ve ikinci adı ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  11. Soyadının bitiş karakterinin (n) sayısal konumunu elde etmek için 2 çıkarın. Sonuç, SOLDAN işlevinin ayıklamasını istediğiniz karakter sayısıdır. (6 - 2 =4)

Bu örnekte iki kısımlı bir ad (Mary Kay) kullanılmaktadır. İkinci ve üçüncü boşluklar, her ad bileşenini ayırır.

Tablodaki hücreleri kopyalayın ve Excel çalışma sayfasında A1 hücresine yapıştırın. Solda gördüğünüz formül başvuru amacıyla görüntülenir; bu arada Excel sağdaki formülü otomatik olarak uygun sonuca dönüştürür.

İpucu    Verileri çalışma sayfasına yapıştırmadan önce, A ve B sütunlarının genişliğini 250 olarak ayarlayın.

Örnek ad

Açıklama

Mary Kay D. Andersen

İki parçalı ad

Formül

Sonuç (ad)

SOLDAN(A2, MBUL(" ",A2,MBUL(" ",A2,1)+1))

=SOLDAN(A2, MBUL(" ",A2,MBUL(" ",A2,1)+1))

Formül

Sonuç (ikinci adının ilk harfi)

’=PARÇAAL(A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1,MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1)-(MBUL(" ",A2,MBUL(" ",A2,1)+1)+1))

=PARÇAAL(A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1,MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1)-(MBUL(" ",A2,MBUL(" ",A2,1)+1)+1))

Formül

Dinamik Sonuç (soyadı)

’=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1))

=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1))

  1. Ad

    Ad, soldan birinci karakterle başlar ve dokuzuncu karakterde (ikinci boşluk) biter. Bu formülde, soldan ikinci boşluk kullanımını bulmak için iç içe geçmiş MBUL işlevi kullanılır.

    Formül, soldan başlayarak dokuz karakter ayıklar.

    Ad, ikinci ad, ikinci adın baş harfi ve soyadını ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için iç içe geçmiş MBUL işlevlerini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (5)

  2. Birinci boşluktan sonraki karakterin (K) konumunu almak için 1 ekleyin. Sonuç, boşluğun ikinci kullanılışını aramayı başlatmak istediğiniz karakter sayısıdır. (5 + 1 = 6)

  3. 2. adımda bulunan altıncı konumdan (K) başlayarak, A2'de boşluğun ikinci kullanılışını arayın. Sonuç, SOLDAN işlevinin metin dizesinden ayıkladığı karakter sayısıdır (9).

  4. İkinci ad

    İkinci ad, onuncu konumda (D) başlar ve onikinci konumda (üçüncü boşluk) biter. Bu formülde, birinci, ikinci ve üçüncü boşluk kullanımlarını bulmak için iç içe geçmiş MBUL işlevleri yer alır.

    Formül, onuncu konumdan başlayarak, ortadan iki karakter ayıklar.

    ad, ikinci ad, ikinci adın baş harfi ve soyadını ayırmak için formül

    Başlangıç_sayısı'na ilişkin değeri bulmak için iç içe geçmiş MBUL işlevlerini kullanın:

    Soldan birinci karakterden başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (5)

  5. Birinci boşluktan sonraki karakteri (K) elde etmek için 1 ekleyin. Sonuç, ikinci boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (5 + 1 = 6)

  6. 2. adımda bulunan altıncı konumdan (K) başlayarak, A2'de ikinci boşluk kullanımının konumunu arayın. Sonuç, SOLDAN işlevinin soldan ayıkladığı karakter sayısıdır (9).

  7. İkinci boşluktan sonraki karakteri (D) elde etmek için 1 ekleyin. Sonuç, ikinci adın başlangıç konumudur. (9 + 1 = 10)

    Sayı_karakterler'e ilişkin değeri bulmak için iç içe geçmiş MBUL işlevlerini kullanın:

    İkinci boşluktan sonraki karakterin (D) sayısal konumunu arayın. Sonuç, üçüncü boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (10)

  8. Soldan başlayarak, A2 hücresinde üçüncü boşluğun sayısal konumunu bulun. Sonuç, ikinci adın bitiş konumudur. (12)

  9. İkinci boşluktan sonraki karakterin (D) sayısal konumunu arayın. Sonuç, ikinci adın başlangıç konumudur. (10)

  10. 6. adımda bulunan üçüncü boşluğun karakter sayısını alıp, 7. adımda bulunan "D"nin karakter sayısını çıkarın. Sonuç, PARÇAAL'ın, 4. adımda bulunan onuncu konumda başlayan metin dizesinden ayıkladığı karakterlerin sayısıdır. (12 - 10 = 2)

  11. Soyadı

    Soyadı, sağdan sekizinci karakterde başlar. Bu formül, beşinci, dokuzuncu ve onikinci konumlardaki birinci, ikinci ve üçüncü boşluk kullanımlarını bulmak için MBUL işlevlerinin iç içe geçmelerini gerektirir.

    Formül, sağdan sekiz karakter ayıklar.

    Ad, ikinci ad, ikinci adın baş harfi ve soyadını ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için iç içe geçmiş MBUL ve UZUNLUK işlevlerini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (5)

  12. Birinci boşluktan sonraki karakteri (K) elde etmek için 1 ekleyin. Sonuç, boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (5 + 1 = 6)

  13. 2. adımda bulunan altıncı konumdan (K) başlayarak, A2'de ikinci boşluğu (9) bulun.

  14. İkinci boşluktan sonraki karakterin (D) konumunu bulmak için 1 ekleyin. Sonuç, ikinci adın başlangıç konumudur. (9 + 1 = 10)

  15. Soldan başlayarak, A2 hücresinde üçüncü boşluğun sayısal konumunu bulun. Sonuç, ikinci adın bitiş konumudur. (12)

  16. A2'de metin dizesinin toplam uzunluğunu sayın ve sonra, soldan, 5. adımda bulunan üçüncü boşluğa kadar karakterlerin sayısını çıkarın. Sonuç, tam adın sağdan ayıklanacak karakterler sayısıdır. (20 - 12 = 8)

Bu örnekte üç parçalı bir soyadı kullanılmaktadır: Barreto de Mattos. Birinci boşluk adın sonunu ve soyadının başlangıcını bildirir.

Tablodaki hücreleri kopyalayın ve Excel çalışma sayfasında A1 hücresine yapıştırın. Solda gördüğünüz formül başvuru amacıyla görüntülenir; bu arada Excel sağdaki formülü otomatik olarak uygun sonuca dönüştürür.

İpucu    Verileri çalışma sayfasına yapıştırmadan önce, A ve B sütunlarının genişliğini 250 olarak ayarlayın.

Örnek ad

Açıklama

Paula Barreto de Mattos

Üç parçalı soyadı

Formül

Sonuç (ad)

'=SOLDAN(A2, MBUL(" ",A2,1))

=SOLDAN(A2, MBUL(" ",A2,1))

Formül

Sonuç (soyadı)

SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,1))

=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,1))

  1. Ad

    Ad, soldan birinci karakterle (P) başlar ve altıncı karakterde (birinci boşluk) biter. Formül, soldan altı karakter ayıklar.

    Ad ve üç bölümden oluşan soyadını ayırmayı sağlayan formül

    Sayı_karakterlere ilişkin değeri bulmak için Arama işlevini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  2. Soyadı

    Soyadı sağdan on yedinci karakterde (B) başlar ve sağdan birinci karakterle (s) biter. Formül, sağdan on yedi karakter ayıklar.

    Ad ve üç bölümden oluşan soyadını ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için UZUNLUK ve MBUL işlevlerini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  3. A2'de metin dizesinin toplam uzunluğunu sayın ve sonra, soldan, 1. adımda bulunan birinci boşluğa kadar karakterlerin sayısını çıkarın. Sonuç, tam adın sağdan ayıklanacak karakterler sayısıdır. (23 - 6 = 17)

Bu örnekte, iki parçalı bir soyadı kullanılmaktadır: van Eaton. Birinci boşluk adın sonunu ve soyadının başlangıcını bildirir.

Tablodaki hücreleri kopyalayın ve Excel çalışma sayfasında A1 hücresine yapıştırın. Solda gördüğünüz formül başvuru amacıyla görüntülenir; bu arada Excel sağdaki formülü otomatik olarak uygun sonuca dönüştürür.

İpucu    Verileri çalışma sayfasına yapıştırmadan önce, A ve B sütunlarının genişliğini 250 olarak ayarlayın.

Örnek ad

Açıklama

James van Eaton

İki parçalı soyadı

Formül

Sonuç (ad)

'=SOLDAN(A2, MBUL(" ",A2,1))

=SOLDAN(A2, MBUL(" ",A2,1))

Formül

Sonuç (soyadı)

’=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,1))

=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,1))

  1. Ad

    Ad, soldan birinci karakterle (J) başlar ve sekizinci karakterde (birinci boşluk) biter. Formül, soldan altı karakter ayıklar.

    Ad ve iki bölümlü soyadını ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  2. Soyadı

    Soyadı, sağdan dokuzuncu karakterle (v) başlar ve sağdan birinci karakterde (n) biter. Formül, tam adın sağından dokuz karakter ayıklar.

    Ad ve iki bölümlü soyadını ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için UZUNLUK ve MBUL işlevlerini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  3. A2'de metin dizesinin toplam uzunluğunu sayın ve sonra, soldan, 1. adımda bulunan birinci boşluğa kadar karakterlerin sayısını çıkarın. Sonuç, tam adın sağdan ayıklanacak karakterler sayısıdır. (15 - 6 = 9)

Bu örnekte soyadı önce gelir, onu sonek izler. Virgül, soyadını ve soneki, ad ve ikinci addan ayırır.

Tablodaki hücreleri kopyalayın ve Excel çalışma sayfasında A1 hücresine yapıştırın. Solda gördüğünüz formül başvuru amacıyla görüntülenir; bu arada Excel sağdaki formülü otomatik olarak uygun sonuca dönüştürür.

İpucu    Verileri çalışma sayfasına yapıştırmadan önce, A ve B sütunlarının genişliğini 250 olarak ayarlayın.

Örnek ad

Açıklama

Bacon Jr., Dan K.

Soyadı ve önce sonek, virgüllü

Formül

Sonuç (ad)

’=PARÇAAL(A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1,MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1)-MBUL(" ",A2,MBUL(" ",A2,1)+1))

=PARÇAAL(A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1,MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1)-MBUL(" ",A2,MBUL(" ",A2,1)+1))

Formül

Sonuç (ikinci adının ilk harfi)

’=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1))

=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,MBUL(" ",A2,1)+1)+1))

Formül

Sonuç (soyadı)

'=SOLDAN(A2, MBUL(" ",A2,1))

=SOLDAN(A2, MBUL(" ",A2,1))

Formül

Sonuç (sonek)

'=PARÇAAL(A2,MBUL(" ", A2,1)+1,(MBUL(" ",A2,MBUL(" ",A2,1)+1)-2)-MBUL(" ",A2,1))

=PARÇAAL(A2,MBUL(" ", A2,1)+1,(MBUL(" ",A2,MBUL(" ",A2,1)+1)-2)-MBUL(" ",A2,1))

  1. Ad

    Ad, onikinci karakterle (D) başlar ve on beşinci karakterle (üçüncü boşluk) biter. Formül, onikinci konumdan başlayarak üç karakter ayıklar.

    Önce soyadı ve son eki virgülle ayırmayı sağlayan formül

    Başlangıç_sayısı'na ilişkin değeri bulmak için iç içe geçmiş MBUL işlevlerini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  2. Birinci boşluktan sonraki karakteri (J) almak için 1 ekleyin. Sonuç, ikinci boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (6 + 1 = 7)

  3. 2. adımda bulunan yedinci konumdan (J) başlayarak, A2 hücresinde ikinci boşluğu arayın. (11)

  4. İkinci boşluktan sonraki karakteri (D) elde etmek için 1 ekleyin. Sonuç, adın başlangıç konumudur. (11 + 1 = 12)

    Sayı_karakterler'e ilişkin değeri bulmak için iç içe geçmiş MBUL işlevlerini kullanın:

    İkinci boşluktan sonraki karakterin (D) sayısal konumunu arayın. Sonuç, üçüncü boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (12)

  5. Soldan başlayarak, A2'de üçüncü boşluğun sayısal konumunu bulun. Sonuç, adın bitiş konumudur. (15)

  6. İkinci boşluktan sonraki karakterin (D) sayısal konumunu arayın. Sonuç, adın başlangıç konumudur. (12)

  7. 6. adımda bulunan üçüncü boşluğun karakter sayısını alıp, 7. adımda bulunan "D"nin karakter sayısını çıkarın. Sonuç, PARÇAAL'ın, 4. adımda bulunan onikinci konumda başlayan metin dizesinden ayıkladığı karakterlerin sayısıdır. (15 - 12 = 3)

  8. İkinci ad

    İkinci ad, sağdan ikinci karakterle (K) başlar. Formül, sağdan iki karakter ayıklar.

    Önce soyadı ve son eki virgülle ayırmayı sağlayan formül

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  9. Birinci boşluktan sonraki karakteri (J) almak için 1 ekleyin. Sonuç, ikinci boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (6 + 1 = 7)

  10. 2. adımda bulunan yedinci konumdan (J) başlayarak, A2 hücresinde ikinci boşluğu arayın. (11)

  11. İkinci boşluktan sonraki karakteri (D) elde etmek için 1 ekleyin. Sonuç, adın başlangıç konumudur. (11 + 1 = 12)

  12. Soldan başlayarak, A2'de üçüncü boşluğun sayısal konumunu bulun. Sonuç, ikinci adın bitiş konumudur. (15)

  13. A2'de metin dizesinin toplam uzunluğunu sayın ve sonra, soldan, 5. adımda bulunan üçüncü boşluğa kadar karakterlerin sayısını çıkarın. Sonuç, tam adın sağdan ayıklanacak karakterler sayısıdır. (17 - 15 = 2)

  14. Soyadı

    Soyadı, soldan birinci karakterde (B) başlar ve altıncı karakterde (birinci boşluk) biter. Dolayısıyla formül, soldan altı karakter ayıklar.

    Önce soyadı ve son eki virgülle ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  15. Sonek

    Sonek, soldan yedinci karakterde (J) başlar ve soldan dokuzuncu karakterde (.) biter. Formül, yedinci karakterden başlayarak üç karakter ayıklar.

    Önce soyadı ve son eki virgülle ayırmayı sağlayan formül

    Başlangıç_sayısı'na ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  16. Birinci boşluktan sonraki karakteri (J) elde etmek için 1 ekleyin. Sonuç, sonekin başlangıç konumudur. (6 + 1 = 7)

    Sayı_karakterler'e ilişkin değeri bulmak için iç içe geçmiş MBUL işlevlerini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  17. Birinci boşluktan sonraki karakterin (J) sayısal konumunu almak için 1 ekleyin. Sonuç, ikinci boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (7)

  18. 4. adımda bulunan yedinci karakterden başlayarak, A2'de ikinci boşluğun sayısal konumunu (11) bulun.

  19. “,” işaretinin karakter sayısını elde etmek için, 4. adımda bulunan ikinci boşluğun karakter sayısından 1 çıkarın. Sonuç, sonekin bitiş konumudur. (11 - 1 = 10)

  20. Birinci boşluğun sayısal konumunu bulun. (6)

  21. İlk boşluğu bulduktan sonra, bir sonraki karakteri (J) bulmak için 1 ekleyin (3 ve 4. adımda da bulunmuştu). (7)

  22. 6. adımda bulunan "," işaretinin karakter sayısını alın ve 3. ve 4. adımlarda bulunan "J"nin karakter sayısını çıkarın. Sonuç, PARÇAAL'ın, 2. adımda bulunan yedinci konumda başlayan metin dizesinden ayıkladığı karakterlerin sayısıdır. (10 - 7 = 3)

Bu örnekte, ilk ad dizenin başında ve sonek ise sondadır; böylece, Örnek 2'ye benzer formüller kullanabilirsiniz: İlk adı ayıklamak için SOLDAN işlevini, soyadını ayıklamak için PARÇAAL işlevini ve soneki ayırmak için de SAĞDAN işlevini kullanın.

Tablodaki hücreleri kopyalayın ve Excel çalışma sayfasında A1 hücresine yapıştırın. Solda gördüğünüz formül başvuru amacıyla görüntülenir; bu arada Excel sağdaki formülü otomatik olarak uygun sonuca dönüştürür.

İpucu    Verileri çalışma sayfasına yapıştırmadan önce, A ve B sütunlarının genişliğini 250 olarak ayarlayın.

Örnek ad

Açıklama

Gary Altman III

Sonekle birlikte ad ve soyadı

Formül

Sonuç (ad)

'=SOLDAN(A2, MBUL(" ",A2,1))

=SOLDAN(A2, MBUL(" ",A2,1))

Formül

Sonuç (soyadı)

'=PARÇAAL(A2,MBUL(" ",A2,1)+1,MBUL(" ",A2,MBUL(" ",A2,1)+1)-(MBUL(" ",A2,1)+1))

=PARÇAAL(A2,MBUL(" ",A2,1)+1,MBUL(" ",A2,MBUL(" ",A2,1)+1)-(MBUL(" ",A2,1)+1))

Formül

Sonuç (sonek)

’=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,1)+1))

=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,1)+1))

  1. Ad

    Ad, soldan birinci karakterde (G) başlar ve beşinci karakterde (birinci boşluk) biter. Dolayısıyla formül, tam adın soldan beş karakterini ayıklar.

    Ad ve son ek almış bir soyadını ayırmayı sağlayan formül

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (5)

  2. Soyadı

    Soyadı, soldan altıncı karakterde (A) başlar ve onbirinci karakterde (ikinci boşluk) biter. Bu formül, boşlukların konumlarını bulmak için MBUL işlevlerinin iç içe geçmelerini gerektirir.

    Formül, altıncı karakterden başlayarak, ortadan altı karakter ayıklar.

    Ad ve son ek almış bir soyadını ayırmayı sağlayan formül

    Başlangıç_sayısı'na ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (5)

  3. Birinci boşluktan sonraki karakterin (A) konumunu almak için 1 ekleyin. Sonuç, soyadın başlangıç konumudur. (5 + 1 = 6)

    Sayı_karakterler'e ilişkin değeri bulmak için iç içe geçmiş MBUL işlevlerini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (5)

  4. Birinci boşluktan sonraki karakterin (A) konumunu almak için 1 ekleyin. Sonuç, ikinci boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (5 + 1 = 6)

  5. 4. adımda bulunan altıncı karakterden başlayarak, A2'de ikinci boşluğun sayısal konumunu arayın. Bu karakter sayısı soyadının bitiş konumudur (12).

  6. Birinci boşluğun sayısal konumunu bulun. (5)

  7. Birinci boşluktan sonraki karakterin (A) (3. ve 4. adımlarda da bulunur) sayısal konumunu bulmak için 1 ekleyin. (6)

  8. 5. adımda bulunan ikinci boşluğun karakter sayısını alıp, sonra 6. ve 7. adımda bulunan "A" harfinin karakter sayısını çıkarın. Sonuç, PARÇAAL'ın, 2. adımda bulunan altıncı konumda başlayan metin dizesinden ayıkladığı karakterlerin sayısıdır. (12 - 6 = 6)

  9. Sonek

    Sonek, sağdan üçüncü karakterde başlatılır. Bu formül, boşlukların konumlarını bulmak için MBUL işlevlerinin iç içe geçmelerini gerektirir.

    Ad ve son ek almış bir soyadını ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için iç içe geçmiş MBUL ve UZUNLUK işlevlerini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (5)

  10. Birinci boşluktan sonraki karakteri (A) elde etmek için 1 ekleyin. Sonuç, ikinci boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (5 + 1 = 6)

  11. 2. adımda bulunan altıncı konumdan (A) başlayarak, A2'de ikinci boşluğu (12) bulun.

  12. A2'de metin dizesinin toplam uzunluğunu sayın ve sonra, soldan, 3. adımda bulunan ikinci boşluğa kadar karakterlerin sayısını çıkarın. Sonuç, tam adın sağdan ayıklanacak karakterler sayısıdır. (15 - 12 = 3)

Bu örnekte, tam adın önünde bir önek bulunmaktadır ve Örnek 2'ye benzer formüller kullanırsınız: İlk adı ayıklamak için PARÇAAL işlevi ve soyadını ayıklamak için SAĞDAN işlevi.

Tablodaki hücreleri kopyalayın ve Excel çalışma sayfasında A1 hücresine yapıştırın. Solda gördüğünüz formül başvuru amacıyla görüntülenir; bu arada Excel sağdaki formülü otomatik olarak uygun sonuca dönüştürür.

İpucu    Verileri çalışma sayfasına yapıştırmadan önce, A ve B sütunlarının genişliğini 250 olarak ayarlayın.

Örnek ad

Açıklama

Mr. Ryan Ihrig

Önekli

Formül

Sonuç (ad)

'=PARÇAAL(A2,MBUL(" ",A2,1)+1,MBUL(" ",A2,MBUL(" ",A2,1)+1)-(MBUL(" ",A2,1)+1))

=PARÇAAL(A2,MBUL(" ",A2,1)+1,MBUL(" ",A2,MBUL(" ",A2,1)+1)-(MBUL(" ",A2,1)+1))

Formül

Sonuç (soyadı)

’=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,1)+1))

=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,MBUL(" ",A2,1)+1))

  1. Ad

    Ad, soldan beşinci karakterde (R) başlar ve dokuzuncu karakterde (ikinci boşluk) biter. Formül, boşlukların konumlarını bulmak için MBUL işlevlerinin iç içe kullanır. Beşinci konumdan başlayarak dört karakter ayıklar.

    Önünde ek olan bir adı ayırmayı sağlayan formül

    Başlangıç_sayısına ilişkin değeri bulmak için MBUL işlevini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (4)

  2. Birinci boşluktan sonraki karakterin (R) konumunu elde etmek için 1 ekleyin. Sonuç, adın başlangıç konumudur. (4 + 1 = 5)

    Sayı_karakterlere ilişkin değeri bulmak için iç içe geçmiş MBUL işlevini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (4)

  3. Birinci boşluktan sonraki karakterin (R) konumunu almak için 1 ekleyin. Sonuç, ikinci boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (4 + 1 = 5)

  4. 3. ve 4. adımlarda bulunan beşinci karakterden başlayarak, A2'de ikinci boşluğun sayısal konumunu arayın. Bu karakter sayısı adın bitiş konumudur (9).

  5. İlk boşluğu arayın. (4)

  6. Birinci boşluktan sonraki karakterin (R) (3. ve 4. adımlarda da bulunur) sayısal konumunu bulmak için 1 ekleyin. (5)

  7. 5. adımda bulunan ikinci boşluğun karakter sayısını alıp, sonra 6. ve 7. adımda bulunan "R" harfinin karakter sayısını çıkarın. Sonuç, PARÇAAL'ın, 2. adımda bulunan beşinci konumda başlayan metin dizesinden ayıkladığı karakterlerin sayısıdır. (9 - 5 = 4)

  8. Soyadı

    Soyadı, sağdan beşinci karakterde başlatılır. Bu formül, boşlukların konumlarını bulmak için MBUL işlevlerinin iç içe geçmelerini gerektirir.

    Önünde ek olan bir adı ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için iç içe geçmiş MBUL ve UZUNLUK işlevlerini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (4)

  9. Birinci boşluktan sonraki karakterin (R) konumunu almak için 1 ekleyin. Sonuç, ikinci boşluğu aramayı başlatmak istediğiniz karakter sayısıdır. (4 + 1 = 5)

  10. 2. adımda bulunan beşinci konumdan (R) başlayarak, A2'de ikinci boşluğu (9) bulun.

  11. A2'de metin dizesinin toplam uzunluğunu sayın ve sonra, soldan, 3. adımda bulunan ikinci boşluğa kadar karakterlerin sayısını çıkarın. Sonuç, tam adın sağdan ayıklanacak karakterler sayısıdır. (14 - 9 = 5)

Bu örnekte kısa çizgiyle birleştirilen bir soyadı kullanılmaktadır. Her ad bileşeni bir boşlukla ayrılır.

Tablodaki hücreleri kopyalayın ve Excel çalışma sayfasında A1 hücresine yapıştırın. Solda gördüğünüz formül başvuru amacıyla görüntülenir; bu arada Excel sağdaki formülü otomatik olarak uygun sonuca dönüştürür.

İpucu    Verileri çalışma sayfasına yapıştırmadan önce, A ve B sütunlarının genişliğini 250 olarak ayarlayın.

Örnek ad

Açıklama

Julie Taft-Rider

Kısa çizgiyle birleştirilmiş soyadı

Formül

Sonuç (ad)

'=SOLDAN(A2, MBUL(" ",A2,1))

=SOLDAN(A2, MBUL(" ",A2,1))

Formül

Sonuç (soyadı)

’=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,1))

=SAĞDAN(A2,UZUNLUK(A2)-MBUL(" ",A2,1))

  1. Ad

    Ad, soldan birinci karakterde başlar ve altıncı konumda (birinci boşluk) biter. Formül, soldan altı karakter ayıklar.

    Ad ve tireyle birleştirilmiş soyadını ayırmayı sağlayan formül

    Sayı_karakterlerinin değerini bulmak için MBUL işlevini kullanın:

    Soldan başlayarak, A2 hücresinde ilk boşluğun sayısal konumunu arayın. (6)

  2. Soyadı

    Soyadının tümü, sağdan onuncu karakterde (T) başlar ve sağdan birinci karakterde (r) biter.

    Ad ve tireyle birleştirilmiş soyadını ayırmayı sağlayan formül

    Sayı_karakterler'e ilişkin değeri bulmak için UZUNLUK ve MBUL işlevlerini kullanın:

    Soldan birinci karakterden başlayarak, A2'de boşluğun sayısal konumunu (6) bulun.

  3. Ayıklanacak metin dizesinin toplam uzunluğunu sayın ve sonra, 1. adımda bulunan, soldan birinci boşluğa kadar olan karakterlerin sayısını çıkarın. (16 - 6 = 10)

Ayrıca Bkz:

Metni Sütunlara Çevirme Sihirbazı ile metni farklı sütunlara ayırma

Yeteneklerinizi geliştirin
Eğitimleri keşfedin
Yeni özellikleri ilk olarak siz edinin
Office Insider Programına Katılın

Bu bilgi yararlı oldu mu?

Görüşleriniz için teşekkür ederiz!

Geri bildiriminiz için teşekkürler! Office destek temsilcilerimizden biriyle görüşmeniz yararlı olabilir.

×