EĞERSAY işlevi

İstatistiksel işlevlerden biri olan EĞERSAY işlevini, bir ölçüte uyan hücre sayısını bulmak için kullanın; örneğin, bir müşteri listesinde bir şehrin kaç kez geçtiğini bulmak için kullanabilirsiniz.

En basit haliyle, EĞERSAY şunu belirtir:

  • =EĞERSAY(Nereye bakmak istiyorsunuz?, Ne aramak istiyorsunuz?)

Örneğin:

  • =EĞERSAY(A2:A5,"Londra")

  • =EĞERSAY(A2:A5;A4)

Tarayıcınız video desteklemiyor. Microsoft Silverlight, Adobe Flash Player veya Internet Explorer 9’u yükleyin.

EĞERSAY(aralık, ölçüt)

Bağımsız değişken adı

Açıklama

Aralık    (gerekli)

Saymak istediğiniz hücre grubu. Aralık sayılar, diziler, adlandırılmış aralıklar veya sayı bulunan başvurular içerebilir. Boşluk ve metin değerleri yoksayılır.

Bir çalışma sayfasında aralıkları seçmeyi öğrenin.

Ölçüt    (gerekli)

Hangi hücrelerin sayılacağını belirleyen bir sayı, ifade, hücre başvurusu veya metin dizesidir.

Örneğin, 32 gibi bir sayı, ">32" gibi bir karşılaştırma, B4 gibi bir hücre veya "elmalar" gibi bir sözcük kullanabilirsiniz.

EĞERSAY yalnızca tek bir ölçüt kullanır. Birden fazla ölçüt kullanmak isterseniz ÇOKEĞERSAY’ı kullanın.

Örnekler

Bu örnekleri Excel’de kullanmak için verileri aşağıdaki tabloya kopyalayın ve yeni bir çalışma sayfasının A1 hücresine yapıştırın.

Veri

Veri

elmalar

32

portakallar

54

şeftaliler

75

elmalar

86

Formül

Açıklama

=EĞERSAY(A2:A5;"elmalar")

A2 ile A5 arasında yer alan ve elmalar sözcüğünü içeren hücreleri sayar. Sonuç 2’dir.

=EĞERSAY(A2:A5;A4)

A2 ile A5 arasındaki şeftali içeren hücreleri sayar (A4 içindeki değer). Sonuç 1’dir.

=EĞERSAY(A2:A5,A2)+EĞERSAY(A2:A5,A3)

A2 ile A5 arasındaki hücrelerde elma (A2'deki değer) ve portakalları (A3'teki değer) sayar. Sonuç 3’tür. Bu formülde, ifade başına bir ölçüt olmak üzere birden çok ölçüt belirtmek için EĞERSAY iki kez kullanılır. Ayrıca ÇOKEĞERSAY işlevini de kullanabilirsiniz.

=EĞERSAY(B2:B5;">55"))

B2 ile B5 arasında yer alan ve 55'ten büyük bir değer içeren hücreleri sayar. Sonuç 2’dir.

=EĞERSAY(B2:B5;"<>"&B4)

B2 ile B5 arasında yer alan ve değeri 75'e eşit olmayan hücreleri sayar. Ve işareti (&), (<>) karşılaştırma işlecini (eşit değildir) ve B4’teki değeri birleştirerek şu şekilde görünür: =EĞERSAY(B2:B5,"<>75"). Sonuç 3’tür.

=EĞERSAY(B2:B5;">=32")-EĞERSAY(B2:B5;">85")

B2 ile B5 arasında yer alan ve değeri 32'ye eşit (=) veya bundan büyük (>) ya da 85'ten küçük (<) veya buna eşit (=) olan hücreleri sayar. Sonuç 3’tür.

=EĞERSAY(A2:A5,"*")

A2 ile A5 arasında yer alan ve metin içeren hücreleri sayar. Yıldız işareti (*), herhangi bir karakteri eşleştirmek için joker karakter olarak kullanılır. Sonuç 4’tür.

=EĞERSAY(A2:A5,"?????es")

A2 ile A5 arasındaki hücrelerde, tam olarak 7 karakter içeren ve “es” harfleriyle biten hücreleri sayar. Soru işareti (?), tek tek karakterleri eşleştirmek için joker karakter olarak kullanılır. Sonuç 2’dir.

Sık Karşılaşılan Sorunlar

Sorun

Nerede sorun çıktı?

Uzun dizeler için yanlış değer döndürdü.

255 karakterden uzun dizeleri eşleştirecek şekilde kullandığınızda EĞERSAY işlevi hatalı değerler verir.

255 karakterden uzun dizeleri eşleştirmek için BİRLEŞTİR işlevini veya birleştir işlecini (&) kullanın. Örneğin, =EĞERSAY(A2:A5,"uzun dize"&"başka bir uzun dize").

Bir değer beklediğiniz halde değer döndürülmedi.

Ölçüt bağımsız değişkenini tırnak içine aldığınızdan emin olun.

EĞERSAY formülü başka bir çalışma sayfasına başvurulduğunda #DEĞER! hatası alır.

İşlevi içeren formül kapalı bir çalışma kitabındaki hücrelere veya aralığa başvurduğunda bu hata oluşur ve hücreler hesaplanır. Bu özelliğin çalışması için, diğer çalışma kitabının açık olması gerekir.

En iyi yöntemler

Bunu yapın

Neden?

EĞERSAY işlevinin metin dizelerindeki büyük ve küçük harfleri yok saydığını unutmayın.

Ölçütler büyük/küçük harfe duyarlı değildir. Başka bir deyişle, "elmalar" dizesi de "ELMALAR" dizesi de aynı hücreleri eşleştirir.

Joker karakterler kullanın.

Ölçütte soru işareti (?) ve yıldız işareti (*) gibi joker karakterler kullanılabilir. Soru işareti herhangi bir tek karakteri eşleştirir. Yıldız işareti bir dizi karakteri eşleştirir. Gerçek bir soru işaretini veya yıldız işaretini bulmak istiyorsanız, karakterden önce bir tilde işareti (~) koyun.

Örneğin, =EĞERSAY(A2:A5,"elma?") ifadesi, sonunda değişen bir harf bulunan "elma" sözcüğünün her tekrarını sayar.

Verilerinizde hatalı karakterler kullanılmadığından emin olun.

Metin değerlerini sayarken, verilerin başında boşluklar, sonunda boşluklar, tutarsız kullanılmış düz ve kıvrımlı tırnak işaretleri veya yazdırılamayan karakterler bulunmadığından emin olun. Bunlar varsa, EĞERSAY beklenmeyen bir değer verebilir.

TEMİZ işlevini veya KIRP işlevini kullanmayı deneyin.

Kolaylık açısından, adlandırılmış aralıkları kullanın

EĞERSAY, formüllerde adlandırılmış aralıkları destekler (örneğin, =EĞERSAY(meyve,">=32")-EĞERSAY(meyve,">85"). Adlandırılmış aralık geçerli çalışma sayfasında, aynı çalışma kitabının başka bir çalışma sayfasında veya başka bir çalışma kitabında yer alıyor olabilir. Başka bir çalışma kitabına başvurmak için, bu ikinci çalışma kitabının açık olması gerekir.

Not : EĞERSAY işlevi, hücreleri, hücre arka planına veya yazı tipi rengine göre saymaz. Ancak Excel, Microsoft Visual Basic for Applications (VBA) işlemlerini kullanarak hücreler üzerinde arka plan veya yazı tipi rengine göre çalışan Kullanıcı Tanımlı İşlevleri (UDF’ler) destekler. Burada VBA kullanarak belirli bir hücre rengine sahip hücre sayısını sayma işlemini nasıl gerçekleştirebileceğinizi gösteren bir örnek yer almaktadır.

Daha fazla yardım mı gerekiyor?

Sorularınızı Excel Teknoloji Topluluğu’ndaki uzmanlara sorabilir, Yanıt topluluğu’ndan destek alabilir ya da Excel için UserVoice platformuna yeni bir özellik veya iyileştirme önerisi sunabilirsiniz.

Ayrıca Bkz:

Boş olmayan hücreleri saymak için, BAĞ_DEĞ_DOLU_SAY işlevini kullanın.

Birden çok ölçüt kullanarak hücreleri saymak için ÇOKEĞERSAY işlevini kullanın.

ÇOKEĞERSAY işlevinin kullanımını gösteren bir video izleyin

ETOPLA işlevi yalnızca tek bir ölçüte uyan değerleri toplar

ÇOKETOPLA işlevi yalnızca birden çok ölçüte uyan değerleri toplar

ÇOKEĞER işlevi (Office 365, Excel 2016 ve sonraki sürümler)

Hücrelerin başındaki ve sonundaki boşlukları kaldırmak için KIRP işlevini kullanın

Hücrelerdeki yazdırılamayan karakterleri kaldırmak için TEMİZ işlevini kullanın

Excel’deki formüllere genel bakış

Bozuk formülleri önleme

Formüllerdeki hataları algılama

İstatistik işlevleri

Excel işlevleri (alfabetik)

Excel işlevleri (Kategoriye göre)

Verileri hızla çözümlemek için ETOPLA, EĞERSAY ve ilişkili işlevleri kullanma (ücretsiz önizleme sürümü)

Yeteneklerinizi geliştirin
Eğitimleri keşfedin
Yeni özellikleri ilk olarak siz edinin
Office Insider Programına Katılın

Bu bilgi yararlı oldu mu?

Görüşleriniz için teşekkür ederiz!

Geri bildiriminiz için teşekkürler! Office destek temsilcilerimizden biriyle görüşmeniz yararlı olabilir.

×