DÜŞEYARA işlevi

Tablodaki veya aralıktaki öğeleri satır temelinde arayarak bulmanız gerektiğinde, arama ve başvuru işlevlerinden biri olan DÜŞEYARA’yı kullanın. Örneğin, bir çalışanın numarasına göre soyadını arayabilir veya soyadını arayarak telefon numarasını bulabilirsiniz (aynı bir telefon rehberi gibi).

DÜŞEYARA’nın sırrı, aradığınız değerin (çalışanın soyadı) bulmak istediğiniz dönüş değerinin (çalışanın telefon numarası) solunda yer almasını sağlayacak şekilde verilerinizi düzenlemektir.

Söz Dizimi

DÜŞEYARA(aranan_değer, tablo_dizisi, sütun_indis_sayısı, [aralık_bak])

Örneğin:

  • =DÜŞEYARA(105,A2:C7,2,DOĞRU)

  • =DÜŞEYARA("Fontana",B2:E7,2,YANLIŞ)

Bağımsız değişken adı

Açıklama

aranan_değer    (gerekli)

Aramak istediğiniz değer. Aramak istediğiniz değer, tablo_dizisi olarak belirttiğiniz hücre aralığının ilk sütununda yer almalıdır.

Örneğin, tablo_dizisi B2:D7 arasındaki hücrelere yayılıyorsa, arama değeriniz B sütununda yer almalıdır. Aşağıdaki grafiğe bakın. Aranan_değer, bir değer veya hücre başvurusu olabilir.

tablo_dizisi    (gerekli)

DÜŞEYARA işlevinin aranan_değeri ve dönüş değerini bulmak için arama yapacağı hücre aralığı.

Hücre aralığındaki ilk sütun aranan_değeri içermelidir (örneğin, aşağıdaki resimde Soyadı). Ayrıca, hücre aralığı bulmak istediğiniz dönüş değerini de içermelidir (örneğin, aşağıdaki grafikte Ad).

Çalışma sayfasında aralıkları seçmeyi öğrenin.

sütun_indis_sayısı    (gerekli)

Dönüş değerini içeren sütunun numarası (tablo_dizisinin en solundaki sütun için 1’den başlayarak).

aralık_bak    (isteğe bağlı)

DÜŞEYARA işlevinin tam eşleşme mi yoksa yaklaşık eşleşme mi bulmasını istediğinizi belirten mantıksal değer:

  • DOĞRU, tablodaki ilk sütunun sayısal veya alfabetik olarak sıralandığını varsayar ve en yakın değeri arar. Yöntem belirtmezseniz, varsayılan yöntem olarak bu kullanılır.

  • YANLIŞ, ilk sütunda tam olarak eşleşen değeri arar.

Aşağıdaki resimde, Kim’i döndürmek için çalışma sayfanızı =VLOOKUP("Akers",B2:D5,2,FALSE) ile nasıl ayarlayacağınız gösterilmektedir.

DÜŞEYARA görüntüsü örneği

Örnekler

Bu örnekleri Excel’de kullanmak için verileri aşağıdaki tabloya kopyalayın ve yeni bir çalışma sayfasının A1 hücresine yapıştırın.

Kimlik

Soyadı

Ad

Unvan

Doğum tarihi

101

Mersin

Sibel

Satış Temsilcisi

8/12/1968

102

Salah

Tamer

Satış Bölümü Başkan Yardımcısı

19/2/1952

103

Ersan

Ebru

Satış Temsilcisi

30/8/1963

104

Biber

Tamer

Satış Temsilcisi

19/9/1958

105

Hanif

Kerim

Satış Müdürü

4/3/1955

106

Koçak

Haluk

Satış Temsilcisi

02.07.1963

Formül

Açıklama

=DÜŞEYARA("Salah",B2:E7,2,YANLIŞ)

tablo_dizisi B2:E7’nin ilk sütununda (sütun B) Fontana değerini arar ve tablo_dizisi’nin ikinci sütununda (Sütun C) bulunan Olivier değerini döndürür. Aralık_bak YANLIŞ bir tam eşleşme döndürür.

=DÜŞEYARA(102,A2:C7,2,YANLIŞ)

Sütun A’da aranan_değer102 için soyadının tam eşleşmesini arar. Fontana döndürülür. aranan_değer105 ise Burke döndürülür.

=EĞER(DÜŞEYARA(103,A1:E7,2,YANLIŞ)="Sousa","Bulundu","Bulunamadı")

Kimliği 103 olan Çalışan’ın soyadının Sousa olup olmadığını denetler. 103 numaralı çalışan aslında Leal olduğundan, sonuç Bulunamadı olur. Formülde "Sousa"yı "Leal" olarak değiştirirseniz, sonuç Bulundu olur.

=TAMSAYI(YILORAN(TARİH(2014,6,30), DÜŞEYARA(105,A2:E7,5, YANLIŞ), 1))

2014 mali yılı için kimliği 105 olan çalışanın yaşını bulur. Mali yıl son tarihinden doğum tarihini çıkarmak için YILORAN işlevini kullanır ve TAMSAYI işlevini kullanarak tamsayı biçiminde 59 sonucunu görüntüler.

=EĞER(EYOKSA(DÜŞEYARA(105,A2:E7,2,YANLIŞ)) = DOĞRU, "Çalışan bulunamadı", DÜŞEYARA(105,A2:E7,2,YANLIŞ))

Kimliği 105 olan bir çalışan varsa, çalışanın Burke olan soyadını görüntüler. Böyle bir çalışan yoksa, Çalışan bulunamadı iletisini görüntüler. DÜŞEYARA işlevi #YOK hata değerini döndürdüğünde EYOKSA işlevi (bkz. IS işlevleri DOĞRU değerini döndürür.

=DÜŞEYARA(104,A2:E7,3,YANLIŞ) & " " & DÜŞEYARA(104,A2:E7,2,YANLIŞ) & " bir " & DÜŞEYARA(104,A2:E7,4,YANLIŞ)

Kimliği 104 olan çalışan için, üç hücrenin değerlerini art arda ekleyerek (birleştirerek) Michael Patten bir Satış Temsilcisi ifadesini oluşturur.

Sık Karşılaşılan Sorunlar

Sorun

Nerede sorun çıktı?

Yanlış değer verdi

Aralık_bak değeri DOĞRU ise veya boş bırakılmışsa, ilk sütunun alfabetik veya sayısal olarak sıralanması gerekir. İlk sütun sıralanmamışsa, verilen değer beklenmedik bir şey olabilir. İlk sütunu sıralayın veya tam eşleşme için YANLIŞ değerini kullanın.

Hücrede #YOK değeri

  • Aralık_bak değeri DOĞRU ise, aranan_değer bağımsız değişkenindeki değer tablo_dizisi’nin ilk sütunundaki en küçük değerden daha küçük olduğunda #YOK hata değerini alırsınız.

  • Aralık_bak YANLIŞ ise, #YOK hata değeri tam sayının bulunamadığını gösterir.

Çalışma sayfalarındaki #YOK, #BAŞV ve diğer hatalar hakkında daha fazla bilgi edinin.

Hücrede #BAŞV! değeri

Sütun_indis_sayısı değeri tablo-dizisi içindeki sütunların sayısından büyükse, #BAŞV! hata değerini alırsınız.

Hücrede #DEĞER! değeri

Tablo_dizisi 1’den küçükse, #DEĞER! hata değerini alırsınız.

Hücrede #AD? değeri

#AD? hata değeri, çoğunlukla formülde tırnak işaretlerinin eksik olduğu anlamına gelir. Bir kişinin adını aramak için, formüldeki adda tırnak işaretlerini kullandığınızdan emin olun. Örneğin, =DÜŞEYARA("Fontana",B2:E7,2,YANLIŞ) içinde adı "Fontana" olarak girin.

En iyi yöntemler

Bunu yapın

Neden?

Aralık_bak için mutlak başvurular kullanın

Mutlak başvurular kullanmak, formülü her zaman tam olarak aynı arama aralığına bakacak şekilde aşağı doğru doldurmanıza olanak tanır.

Mutlak hücre başvurularının nasıl kullanıldığını öğrenin.

Sayı veya tarih değerlerini metin olarak depolamayın.

Sayı veya tarih değerlerini ararken tablo_dizisinin ilk sütunundaki verilerin metin değerleri olarak depolanmamış olduğundan emin olun. Yoksa, DÜŞEYARA yanlış veya beklenmeyen bir değer verebilir.

İlk sütunu sıralayın

aralık_bak değeri DOĞRU olduğunda, DÜŞEYARA’yı kullanmadan önce tablo_dizisi değerinin ilk sütununu sıralayın.

Joker karakterler kullanın

aralık_bak YANLIŞ'sa ve aranan_değer metinse, aranan_değer’de joker karakterler, soru işareti (?) ve yıldız işareti (*) kullanabilirsiniz. Soru işareti tek karakter bulurken, yıldız işareti bir dizi karakter bulur. Gerçek bir soru işaretini veya yıldız işaretini bulmak istiyorsanız, karakterin önüne bir tilde işareti (~) koyun.

Örneğin, =VLOOKUP("Fontan?",B2:E7,2,FALSE) son harfi değişken olabilecek şekilde tüm Fontana örneklerini arar.

Verilerinizde hatalı karakterler kullanılmadığından emin olun.

İlk sütundaki metin değerlerini ararken, ilk sütunda metnin başında boşluklar, sonunda boşluklar, tutarsız kullanılmış düz ( ' veya " ) ya da kıvrımlı ( ‘ veya “) tırnak işaretleri veya yazdırılamayan karakterler bulunmadığından emin olun. Bunlar varsa, DÜŞEYARA beklenmeyen bir değer verebilir.

Doğru sonuçlar almak için, hücrede tablo değerlerini izleyen sondaki boşlukları kaldırmak üzere TEMİZ işlevini veya KIRP işlevini kullanmayı deneyin.

İlgili

İlgili Uygulamalar: Excel 2010, Excel 2007, Excel 2016 for Mac, Excel 2013, Excel Online, Excel Starter



Bu bilgi yararlı oldu mu?

Evet Hayır

Özellikleri nasıl daha iyi hale getirebiliriz?

255 kalan karakter sayısı

Gizliliğinizi korumak için lütfen görüşlerinize iletişim bilgilerinizi eklemeyin. Şunu gözden geçirin: gizlilik ilkesi.

Görüşleriniz için teşekkür ederiz!

Destek kaynakları

Dili değiştir