ฟังก์ชัน TEXT ช่วยให้คุณสามารถเปลี่ยนลักษณะที่ปรากฏของตัวเลขโดยนําการจัดรูปแบบไปใช้กับตัวเลขด้วยรหัสรูปแบบ ซึ่งมีประโยชน์ในกรณีที่คุณต้องการแสดงตัวเลขในรูปแบบที่อ่านได้มากขึ้น หรือคุณต้องการรวมตัวเลขกับข้อความหรือสัญลักษณ์
หมายเหตุ: ฟังก์ชัน TEXT จะแปลงตัวเลขเป็นข้อความ ซึ่งอาจทําให้ยากต่อการอ้างอิงในการคํานวณในภายหลัง วิธีที่ดีที่สุดคือเก็บค่าเดิมของคุณไว้ในเซลล์หนึ่ง แล้วใช้ฟังก์ชัน TEXT ในเซลล์อื่น จากนั้น ถ้าคุณต้องการสร้างสูตรอื่นๆ ให้อ้างอิงค่าเดิมเสมอไม่ใช่ผลลัพธ์ของฟังก์ชัน TEXT
ไวยากรณ์
TEXT(value, format_text)
ไวยากรณ์ของฟังก์ชัน TEXT มีอาร์กิวเมนต์ดังนี้
|
ชื่ออาร์กิวเมนต์ |
คำอธิบาย |
|
value |
ค่าตัวเลขที่คุณต้องการแปลงเป็นข้อความ |
|
format_text |
สตริงข้อความที่ระบุการจัดรูปแบบที่คุณต้องการนำไปใช้กับค่าที่ระบุ |
ภาพรวม
ในรูปแบบที่ง่ายที่สุด ฟังก์ชัน TEXT จะระบุว่า:
-
=TEXT(ค่าที่คุณต้องการจัดรูปแบบ, "จัดรูปแบบโค้ดที่คุณต้องการนำไปใช้")
ต่อไปนี้เป็นตัวอย่างยอดนิยมบางตัวอย่าง ซึ่งคุณสามารถคัดลอกลงใน Excel ได้โดยตรงเพื่อทดลองด้วยตัวคุณเอง โปรดสังเกตโค้ดรูปแบบภายในเครื่องหมายอัญประกาศ
|
สูตร |
คำอธิบาย |
|---|---|
|
=TEXT(1234.567,"$#,##0.00") |
สกุลเงินที่มีตัวคั่นหลักพันและทศนิยม 2 ตําแหน่ง เช่น $1,234.57 โปรดทราบว่า Excel จะปัดเศษค่าเป็นทศนิยม 2 ตําแหน่ง |
|
=TEXT(TODAY(),"MM/DD/YY") |
วันที่ของวันนี้ในรูปแบบ MM/DD/YY เช่น 03/14/12 |
|
=TEXT(TODAY(),"DDDD") |
วันของวันนี้ในสัปดาห์ เช่น วันจันทร์ |
|
=TEXT(NOW(),"H:MM AM/PM") |
เวลาปัจจุบัน เช่น 13:29 น. |
|
=TEXT(0.285,"0.0%") |
เปอร์เซ็นต์ เช่น 28.5% |
|
=TEXT(4.34 ,"# ?/?") |
เศษส่วน เช่น 4 1/3 |
|
=TRIM(TEXT(0.34,"# ?/?")) |
เศษส่วน เช่น 1/3 โปรดสังเกตว่าฟังก์ชันนี้ใช้ฟังก์ชัน TRIM เพื่อเอาช่องว่างนําหน้าที่มีค่าทศนิยมออก |
|
=TEXT(12200000,"0.00E+00") |
เครื่องหมายทางวิทยาศาสตร์ เช่น 1.22E+07 |
|
=TEXT(1234567898,"[<=9999999]###-####;(###) ###-####") |
พิเศษ (หมายเลขโทรศัพท์), เช่น (123) 456-7898 |
|
=TEXT(1234,"0000000") |
เพิ่มเลขศูนย์นำหน้า (0) เช่น 0001234 |
|
=TEXT(123456,"##0° 00' 00''") |
กำหนดเอง - ละติจูด/ลองจิจูด |
หมายเหตุ: แม้ว่าคุณจะสามารถใช้ฟังก์ชัน TEXT เพื่อเปลี่ยนแปลงการจัดรูปแบบ แต่ยังมีวิธีอื่นอีก คุณสามารถเปลี่ยนรูปแบบโดยไม่มีสูตรได้โดยการกด CTRL+1 (หรือ 
ดาวน์โหลดตัวอย่างของเรา
คุณสามารถดาวน์โหลดตัวอย่างเวิร์กบุ๊กที่มีตัวอย่างฟังก์ชัน TEXT ทั้งหมดที่คุณจะพบได้ในบทความนี้ พร้อมกับส่วนเพิ่มเติม คุณสามารถทำตาม หรือสร้างโค้ดรูปแบบของฟังก์ชัน TEXT ของคุณเอง
ดาวน์โหลดตัวอย่างฟังก์ชัน TEXT ของ Excel
โค้ดรูปแบบอื่นๆ ที่พร้อมใช้งาน
คุณสามารถใช้กล่องโต้ตอบ จัดรูปแบบเซลล์ เพื่อค้นหาโค้ดรูปแบบที่พร้อมใช้งานอื่นๆ:
-
กด Ctrl+1 (
-
เลือกรูปแบบที่คุณต้องการจากแท็บ ตัวเลข
-
เลือกตัวเลือก กําหนดเอง
-
โค้ดรูปแบบที่คุณต้องการจะแสดงอยู่ในกล่อง ชนิด ในกรณีนี้ ให้เลือกทุกอย่างจากกล่อง ชนิด ยกเว้นเครื่องหมายอัฒภาค (สัญลักษณ์ ;) และ @ ในตัวอย่างด้านล่าง เราเลือกและคัดลอก mm/dd/yy
-
กด Ctrl+C เพื่อคัดลอกโค้ดรูปแบบ แล้วกด ยกเลิก เพื่อยกเลิกกล่องโต้ตอบ จัดรูปแบบเซลล์
-
ตอนนี้ สิ่งที่คุณต้องทําคือกด Ctrl+V เพื่อวางโค้ดรูปแบบลงในสูตร TEXT ของคุณ เช่น: =TEXT(B2,"mm/dd/yy") ตรวจสอบให้แน่ใจว่าคุณวางโค้ดรูปแบบภายในเครื่องหมายอัญประกาศ ("โค้ดรูปแบบ") มิฉะนั้น Excel จะให้ข้อความแสดงข้อผิดพลาดแก่คุณ
จัดรูปแบบโค้ดตามประเภท
ต่อไปนี้เป็นตัวอย่างของวิธีการที่คุณสามารถนํารูปแบบตัวเลขที่ต่างกันไปใช้กับค่าของคุณโดยใช้กล่องโต้ตอบ จัดรูปแบบเซลล์ แล้วใช้ตัวเลือก กําหนดเอง เพื่อคัดลอก โค้ดรูปแบบ เหล่านั้นไปยังฟังก์ชัน TEXT ของคุณ
ทำไม Excel ลบเลข 0 นำหน้าของฉัน
Excel ถูกออกแบบให้มองหาตัวเลขที่ใส่ในเซลล์ ไม่ใช่ตัวเลขที่ดูเหมือนข้อความ และหมายเลขชิ้นส่วนหรือ SKU เมื่อต้องการเก็บรักษาเลขศูนย์นำหน้า จัดรูปแบบช่วงข้อมูลที่ป้อนเป็นข้อความ ก่อนที่คุณจะวางหรือใส่ค่า เลือกคอลัมน์ หรือช่วงที่คุณจะใส่ค่า แล้วใช้ CTRL+1 เพื่อแสดงกล่องโต้ตอบ รูปแบบ > เซลล์ และบน แท็บตัวเลข ให้เลือก ข้อความ ในตอนนี้ Excel จะเก็บเลข 0 นำหน้าของคุณ
ถ้าคุณใส่ข้อมูลแล้ว และ Excel ได้เอาเลข 0 นําหน้าของคุณออก คุณสามารถใช้ฟังก์ชัน TEXT เพื่อเพิ่มเลข 0 เหล่านั้นกลับเข้าไปได้ คุณสามารถอ้างอิงเซลล์บนสุดที่มีค่าและใช้ =TEXT(value,"00000") โดยที่จํานวน 0 ในสูตรแสดงจํานวนรวมของอักขระที่คุณต้องการ แล้วคัดลอกและวางลงในส่วนที่เหลือของช่วงของคุณ
ถ้าคุณต้องการแปลงค่าข้อคความกลับเป็นตัวเลขที่คุฯสามารถคูณด้วย 1 เช่น =D4*1 หรือใช้ตัวดำเนินการเอกภาคสองตัว (--) เช่น =--D4
Excel จะคั่นหลักพันด้วยเครื่องหมายจุลภาค ถ้ารูปแบบมีเครื่องหมายจุลภาค (,) ที่อยู่ในเครื่องหมายตัวเลข (#) หรือด้วยศูนย์ ตัวอย่างเช่น ถ้าสตริงรูปแบบเป็น "#,###" Excel จะแสดงตัวเลข 12200000 เป็น 12,200,000
เครื่องหมายจุลภาคที่อยู่หลังตัวยึดตัวเลขจะปรับมาตราส่วนตัวเลขด้วย 1,000 ตัวอย่างเช่น ถ้าสตริงรูปแบบเป็น "#,###.0," Excel จะแสดงตัวเลข 12200000 เป็น 12,200.0
หมายเหตุ:
-
ตัวคั่นหลักพันจะขึ้นอยู่กับการตั้งค่าภูมิภาคของคุณ ในสหรัฐอเมริกา จะเป็นเครื่องหมายจุลภาค แต่ในตําแหน่งที่ตั้งอื่นๆ อาจเป็นเครื่องหมายมหัพภาค (.)
-
ตัวคั่นหลักพันจะพร้อมใช้งานสำหรับรูปแบบตัวเลข สกุลเงิน และบัญชี
ต่อไปนี้คือตัวอย่างของรูปแบบตัวเลขมาตรฐาน (ตัวคั่นหลักพันและทศนิยมเท่านั้น) สกุลเงินและบัญชี รูปแบบสกุลเงินช่วยให้คุณสามารถแทรกสัญลักษณ์สกุลเงินที่คุณเลือกและจัดแนวให้อยู่ถัดจากค่าของคุณ ในขณะที่รูปแบบทางบัญชีจะจัดแนวสัญลักษณ์สกุลเงินทางด้านซ้ายของเซลล์และค่าไปทางขวา โปรดสังเกตความแตกต่างระหว่างรหัสรูปแบบสกุลเงินและบัญชีด้านล่าง ซึ่งบัญชีใช้เครื่องหมายดอกจัน (*) เพื่อสร้างการแยกระหว่างสัญลักษณ์และค่า
เมื่อต้องการค้นหาโค้ดรูปแบบสำหรับสัญลักษณ์สกุลเงิน ให้กด Ctrl+1 (หรือ
แล้วคลิก กำหนดเอง ทางด้านซ้ายจากส่วน ประเภท และคัดลอกโค้ดรูปแบบ รวมถึงสัญลักษณ์สกุลเงิน
หมายเหตุ: ฟังก์ชัน TEXT ไม่สนับสนุนการจัดรูปแบบสี ดังนั้น ถ้าคุณคัดลอกโค้ดรูปแบบตัวเลขจากกล่องโต้ตอบการจัดรูปแบบเซลล์ที่มีสี ดังนี้: $#,##0.00_);[สีแดง]($#,##0.00) ฟังก์ชัน TEXT จะยอมรับโค้ดรูปแบบ แต่จะไม่แสดงสี
คุณสามารถเปลี่ยนวิธีการแสดงวันที่โดยใช้การผสมของ "M" สำหรับเดือน "D" วัน และ "Y" สำหรับปี
โค้ดรูปแบบในฟังก์ชัน TEXT จะไม่สนใจตัวพิมพ์ของตัวอักษร เพื่อให้คุณสามารถใช้ "M" หรือ "m", "D" หรือ "d", "Y" หรือ "y"
|
|
Mynda แนะนำว่า... ถ้าคุณแชร์ไฟล์และรายงาน Excel กับผู้ใช้จากประเทศต่างๆ แล้วคุณต้องการให้พวกเขาได้รับรายงานเป็นภาษาของพวกเขา Excel MVP, Mynda Treacy มีโซลูชันที่ยอดเยี่ยมในบทความ วันที่ Excel ที่แสดงเป็นภาษาต่างๆ นี้ ซึ่งยังมีเวิร์กบุ๊กตัวอย่างที่คุณสามารถดาวน์โหลดได้ |
คุณสามารถเปลี่ยนวิธีการแสดงเวลาโดยใช้การผสมของ "H" สำหรับชั่วโมง "M" สำหรับนาที หรือ "S" สำหรับวินาที และ "AM/PM" สำหรับนาฬิกาแบบ 12 ชั่วโมง
ถ้าคุณปล่อยให้เป็น "AM/PM" หรือ " A/P " เวลาจะแสดงตามนาฬิกาแบบ 24 ชั่วโมง
โค้ดรูปแบบในฟังก์ชัน TEXT จะไม่สนใจตัวพิมพ์ของตัวอักษร เพื่อให้คุณสามารถใช้ "H" หรือ "h", "M" หรือ "m", "S" หรือ "s", "AM/PM" หรือ "am/pm"
คุณสามารถเปลี่ยนแปลงการแสดงค่าทศนิยมด้วยรูปแบบเปอร์เซ็นต์ (%)
คุณสามารถเปลี่ยนวิธีแสดงค่าทศนิยมด้วยเศษส่วน (?/?) รูป แบบ
เครื่องหมายทางวิทยาศาสตร์ คือวิธีการแสดงตัวเลขในรูปแบบทศนิยมระหว่าง 1 และ 10 คูณด้วยเลขยกกําลัง 10 ซึ่งมักจะใช้เพื่อทําให้การแสดงตัวเลขจํานวนมากสั้นลง
Excel มีรูปแบบพิเศษ 4 รูปแบบ:
-
รหัสไปรษณีย์ - "00000"
-
รหัสไปรษณีย์ + 4 - "00000-0000"
-
หมายเลขโทรศัพท์ - "[<=9999999]###-####;(###) ###-####"
-
หมายเลขประกันสังคม - "000-00-0000"
รูปแบบพิเศษจะแตกต่างกันขึ้นอยู่กับตำแหน่งที่ตั้ง แต่ถ้าไม่มีรูปแบบพิเศษสำหรับตำแหน่งที่ตั้งของคุณ หรือถ้ารูปแบบเหล่านี้ไม่ใช่สิ่งที่คุณต้องการ คุณสามารถสร้างรูปแบบของคุณเองผ่านทาง จัดรูปแบบเซลล์ > กล่องข้อความ กำหนดเอง
สถานการณ์ทั่วไป
ฟังก์ชัน TEXT จะถูกใช้ด้วยตัวฟังก์ชันน้อยครั้ง และจะถูกใช้บ่อยครั้งในการรวมกับสิ่งอื่น สมมติว่าคุณต้องการรวมข้อความกับค่าตัวเลข เช่น “พิมพ์รายงานเมื่อ: 03/14/12" หรือ "รายได้รายสัปดาห์: $66,348.72" คุณสามารถพิมพ์ข้อมูลนั้นลงใน Excel ได้ด้วยตนเอง แต่จะเป็นการยกเลิกวัตถุประสงค์ให้ Excel ทำงานนี้ให้คุณ น่าเสียดาย เมื่อคุณรวมข้อความและตัวเลขที่มีการจัดรูปแบบ เช่น วันที่ เวลา สกุลเงิน เป็นต้น แล้ว Excel ไม่ทราบว่าคุณต้องการแสดง จึงละการจัดรูปรูปแบบตัวเลข นี่คือจุดที่ฟังก์ชัน TEXT มีประโยชน์มาก เนื่องจากจะทำให้คุณบังคับให้ Excel จัดรูปแบบค่าด้วยวิธีที่คุณต้องการโดยใช้ โค้ดรูปแบบ เช่น "MM/DD/YY" สำหรับรูปแบบวันที่
ในตัวอย่างต่อไปนี้ คุณจะเห็นสิ่งที่เกิดขึ้นถ้าคุณลองรวมข้อความกับตัวเลขโดยไม่ใช้ฟังก์ชัน TEXT ในกรณีนี้ เราจะใช้ เครื่องหมาย (&) ในการเรียงสตริงข้อความ ช่องว่าง (“ “) และค่าให้ต่อกันด้วย =A2&” “&B2
อย่างที่คุณเห็น Excel ได้เอาการจัดรูปแบบออกจากวันที่ในเซลล์ B2 ในตัวอย่างถัดไป คุณจะเห็นว่าฟังก์ชัน TEXT ช่วยให้คุณนํารูปแบบที่คุณต้องการไปใช้ได้อย่างไร
สูตรที่อัปเดตของเราคือ:
-
เซลล์ C2:=A2&" "&TEXT(B2,"mm/dd/yy") - รูปแบบข้อมูล
คำถามที่ถามบ่อย
น่าเสียดายที่คุณไม่สามารถทําสิ่งนั้นได้ด้วยฟังก์ชัน TEXT คุณจําเป็นต้องใช้โค้ด Visual Basic for Applications (VBA) ลิงก์ต่อไปนี้มีวิธีการ: วิธีแปลงค่าตัวเลขเป็นคําภาษาอังกฤษใน Excel
ได้ แต่จะต้องทำตามขั้นตอน ก่อนอื่น ให้เลือกเซลล์ที่คุณต้องการให้เกิดเหตุการณ์เช่นนี้ และใช้ Ctrl+1 เพื่อแสดงกล่องโต้ตอบ รูปแบบ > เซลล์ จากนั้น การจัดแนว > ตัวควบคุมข้อความ > เลือกตัวเลือก ตัดข้อความ จากนั้น ให้ปรับฟังก์ชัน TEXT ที่สมบูรณ์ของคุณเพื่อรวมฟังก์ชัน ASCII CHAR (10) ที่คุณต้องการใช้ตัวแบ่งบรรทัด คุณอาจต้องปรับความกว้างคอลัมน์ของคุณ โดยขึ้นอยู่กับวิธีการจัดแนวของผลลัพธ์สุดท้าย
ในกรณีนี้ เราใช้: =”Today is: “&CHAR(10)&TEXT(TODAY(),”mm/dd/yy”)
สิ่งนี้เรียกว่า เครื่องหมายทางวิทยาศาสตร์ และ Excel จะแปลงตัวเลขที่มีความยาวมากกว่า 12 หลักโดยอัตโนมัติ ถ้าเซลล์ถูกจัดรูปแบบเป็น ทั่วไป และ 15 หลัก ถ้าเซลล์ถูกจัดรูปแบบเป็น ตัวเลข ถ้าคุณต้องการใส่สตริงตัวเลขที่ยาว แต่ไม่ต้องการให้แปลง ให้จัดรูปแบบเซลล์ที่มีปัญหาเป็น ข้อความ ก่อนที่คุณจะใส่หรือวางค่าของคุณลงใน Excel
|
|
Mynda แนะนำว่า... ถ้าคุณแชร์ไฟล์และรายงาน Excel กับผู้ใช้จากประเทศต่างๆ แล้วคุณต้องการให้พวกเขาได้รับรายงานเป็นภาษาของพวกเขา Excel MVP, Mynda Treacy มีโซลูชันที่ยอดเยี่ยมในบทความ วันที่ Excel ที่แสดงเป็นภาษาต่างๆ นี้ ซึ่งยังมีเวิร์กบุ๊กตัวอย่างที่คุณสามารถดาวน์โหลดได้ |
ดูเพิ่มเติม
สร้างหรือลบรูปแบบตัวเลขแบบกำหนดเอง
