แยกข้อความลงในคอลัมน์ต่างๆ ด้วยฟังก์ชัน

แยกข้อความลงในคอลัมน์ต่างๆ ด้วยฟังก์ชัน

คุณสามารถใช้ฟังก์ชันข้อความ LEFT, MID, RIGHT, SEARCH และ LEN เพื่อจัดการกับสตริงข้อความในข้อมูลของคุณ ตัวอย่างเช่น คุณสามารถแจกจ่ายชื่อ ชื่อกลางและนามสกุลจากเซลล์เดียวลงในคอลัมน์สามคอลัมน์ที่แยกกัน

หลักสำคัญในการแจกจ่ายคอมโพเนนต์ของชื่อด้วยฟังก์ชันข้อความ คือ ตำแหน่งของอักขระแต่ละตัวภายในสตริงข้อความ ตำแหน่งของช่องว่างภายในสตริงข้อความก็มีความสำคัญเช่นกัน เนื่องจากตำแหน่งดังกล่าวเป็นตัวระบุจุดเริ่มต้นหรือสิ้นสุดของคอมโพเนนต์ของชื่อในสตริง

ตัวอย่างเช่น ในเซลล์ที่มีเพียงชื่อและนามสกุล นามสกุลจะเริ่มต้นหลังอินสแตนซ์แรกของช่องว่าง บางชื่อในรายชื่อของคุณอาจมีชื่อกลางด้วย ซึ่งในกรณีนี้ นามสกุลจะเริ่มต้นหลังอินสแตนซ์ที่สองของช่องว่าง

บทความนี้จะแสดงให้คุณเห็นวิธีแยกส่วนประกอบต่างๆ ออกจากรูปแบบชื่อต่างๆ โดยใช้ฟังก์ชันที่มีประโยชน์เหล่านี้ คุณยังสามารถแยกข้อความเป็นหลายคอลัมน์ด้วย ตัวช่วนสร้างแปลงข้อควยามเป็นคอลัมน์

ชื่อตัวอย่าง

คำอธิบาย

ชื่อ

ชื่อกลาง

นามสกุล

คำต่อท้าย

1

Jeff Smith

ไม่มีชื่อกลาง

Jeff

Smith

2

Eric S. Kurjan

ชื่อกลางหนึ่งชื่อแบบย่อ

Eric

S.

Kurjan

3

Janaina B. G. Bueno

ชื่อกลางสองชื่อแบบย่อ

Janaina

B. G.

Bueno

4

Kahn, Wendy Beth

นามสกุลขึ้นก่อน โดยมีจุลภาคคั่น

Wendy

Beth

Kahn

5

Mary Kay D. Andersen

ชื่อแบบสองส่วน

Mary Kay

D.

Andersen

6

Paula Barreto de Mattos

นามสกุลแบบสามส่วน

Paula

Barreto de Mattos

7

James van Eaton

นามสกุลแบบสองส่วน

James

van Eaton

8

Bacon Jr., Dan K.

นามสกุลและคำต่อท้ายขึ้นก่อน โดยมีจุลภาคคั่น

Dan

K.

Bacon

Jr.

9

Gary Altman III

มีคำต่อท้าย

Gary

Altman

III

10

Mr. Ryan Ihrig

มีคำนำหน้าชื่อ

Ryan

Ihrig

11

Julie Taft-Rider

นามสกุลที่ใส่เครื่องหมายยัติภังค์

Julie

Taft-Rider

หมายเหตุ: ในกราฟิกในตัวอย่างต่อไปนี้ การไฮไลต์ของชื่อเต็มจะแสดงอักขระที่สูตร SEARCH ที่ตรงกันกำลังค้นหา

ตัวอย่างนี้จะแยกสองคอมโพเนนต์: ชื่อและนามสกุล ช่องว่างเดียวจะคั่นชื่อสองชื่อ

คัดลอกเซลล์ในตารางและวางลงในเวิร์กชีต Excel ที่เซลล์ A1 สูตรที่คุณเห็นทางด้านซ้ายจะแสดงไว้เป็นการอ้างอิง ขณะที่ Excel จะแปลงสูตรทางด้านขวาเป็นผลลัพธ์ที่เหมาะสมโดยอัตโนมัติ

คำแนะนำ    ก่อนที่คุณจะวางข้อมูลลงในเวิร์กชีต ให้ตั้งค่าความกว้างของคอลัมน์ A และ B เป็น 250

ชื่อตัวอย่าง

คำอธิบาย

Jeff Smith

ไม่มีชื่อกลาง

สูตร

ผลลัพธ์ (ชื่อ)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

สูตร

ผลลัพธ์ (นามสกุล)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. ชื่อ

    ชื่อจะเริ่มต้นด้วยอักขระแรกในสตริง (J) และสิ้นสุดที่อักขระที่ห้า (ช่องว่าง) สูตรจะส่งกลับอักขระห้าตัวมาในเซลล์ A2 เริ่มต้นจากด้านซ้าย

    สูตรสำหรับการแยกชื่อ

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย

  2. นามสกุล

    นามสกุลจะเริ่มต้นที่ช่องว่าง เป็นอักขระห้าตัวจากด้านขวา และสิ้นสุดที่อักขระสุดท้ายทางด้านขวา (h) สูตรจะแยกอักขระห้าตัวใน A2 เริ่มต้นจากทางด้านขวา

    สูตรสำหรับการแยกนามสกุล

    ใช้ฟังก์ชัน SEARCH และ LEN เพื่อค้นหาค่า num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (5)

  3. นับความยาวรวมของสตริงข้อความ แล้วลบด้วยจำนวนของอักขระจากด้านซ้ายจนถึงช่องว่างแรก เหมือนที่ได้ในขั้นตอนที่ 1

ตัวอย่างนี้จะมีชื่อ ชื่อกลางแบบย่อ และนามสกุล ช่องว่างคั่นแต่ละคอมโพเนนต์ของชื่อ

คัดลอกเซลล์ในตารางและวางลงในเวิร์กชีต Excel ที่เซลล์ A1 สูตรที่คุณเห็นทางด้านซ้ายจะแสดงไว้เป็นการอ้างอิง ขณะที่ Excel จะแปลงสูตรทางด้านขวาเป็นผลลัพธ์ที่เหมาะสมโดยอัตโนมัติ

คำแนะนำ    ก่อนที่คุณจะวางข้อมูลลงในเวิร์กชีต ให้ตั้งค่าความกว้างของคอลัมน์ A และ B เป็น 250

ชื่อตัวอย่าง

คำอธิบาย

Eric S. Kurjan

มีตัวย่อชื่อกลางหนึ่งตัว

สูตร

ผลลัพธ์ (ชื่อ)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

สูตร

ผลลัพธ์ (ชื่อกลาง)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

สูตร

ผลลัพธ์ตามเวลาจริง (นามสกุล)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. ชื่อ

    ชื่อจะเริ่มต้นด้วยอักขระแรกจากด้านซ้าย (E) และสิ้นสุดที่อักขระที่ห้า (ช่องว่างแรก) สูตรจะแยกอักขระห้าตัวแรกใน A2 เริ่มต้นจากทางด้านซ้าย

    สูตรสำหรับการแยกชื่อและนามสกุล รวมถึงชื่อกลางแบบย่อ

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (5)

  2. ชื่อกลาง

    ชื่อกลางจะเริ่มต้นที่ตำแหน่งอักขระที่หก (S) และสิ้นสุดที่ตำแหน่งที่แปด (ช่องว่างที่สอง) สูตรนี้ต้องใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาอินสแตนซ์ที่สองของช่องว่าง

    สูตรจะแยกอักขระสามตัว เริ่มต้นจากตำแหน่งที่หก

    รายละเอียดของสูตรสำหรับการแยกชื่อ ชื่อกลางและนามสกุล

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่าของ start_num

    ค้นหาตำแหน่งตัวเลขของช่องว่างแรกใน A2 เริ่มต้นจากอักขระแรกทางด้านซ้าย (5)

  3. บวกไปอีก 1 ตำแหน่งเพื่อไปที่ตำแหน่งของอักขระหลังช่องว่างแรก (S) ตำแหน่งตัวเลขคือตำแหน่งเริ่มต้นของชื่อกลาง (5 + 1 = 6)

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางซ้าย (5)

  4. บวก 1 เพื่อให้ได้ตำหน่งของอักขระหลังจากช่องว่างแรก (S) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มค้นหาอินสแตนซ์ที่สองของช่องว่าง(5 + 1 = 6)

  5. ค้นหาอินสแตนซ์ที่สองของช่องว่างใน A2 เริ่มต้นจากตำแหน่งที่หก (S) ที่ได้ในขั้นตอนที่ 4 หมายเลขของอักขระนี้คือตำแหน่งสิ้นสุดของชื่อกลาง (8)

  6. ค้นหาตำแหน่งตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางด้านซ้าย (5)

  7. นำหมายเลขอักขระของช่องว่างที่สองที่ได้ในขั้นตอนที่ 5 มาลบด้วยหมายเลขอักขระของช่องว่างแรกที่ได้ในขั้นตอนที่ 6 ผลลัพธ์คือหมายเลขของอักขระของ MID จะแยกจากสตริงข้อความเริ่มต้นที่ตำแหน่งที่หกที่ได้ในขั้นตอนที่ 2 (8 – 5 = 3)

  8. นามสกุล

    นามสกุลจะเริ่มต้นด้วยอักขระหกตัวจากด้านขวา (K) และสิ้นสุดที่อักขระแรกจากด้านขวา (n) สูตรนี้ต้องใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาอินสแตนซ์ที่สองและสามของช่องว่าง (ซึ่งอยู่ที่ตำแหน่งที่ห้าและแปดจากด้านซ้าย)

    สูตรจะแยกอักขระหกตัวใน A2 เริ่มต้นจากด้านขวา

    ฟังก์ชัน SEARCH ตัวที่สองในสูตรใช้สำหรับการแยกชื่อ ชื่อกลาง และนามสกุล
  9. ใช้ฟังก์ชัน LEN และฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่า num_chars

    ค้นหาตำแหน่งตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางด้านซ้าย (5)

  10. บวก 1 เพื่อให้ได้ตำหน่งของอักขระหลังจากช่องว่างแรก (S) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มค้นหาอินสแตนซ์ที่สองของช่องว่าง(5 + 1 = 6)

  11. ค้นหาอินสแตนซ์ที่สองของช่องว่างใน A2 เริ่มต้นจากตำแหน่งที่หก (S) ที่ได้ในขั้นตอนที่ 2 หมายเลขอักขระนี้คือตำแหน่งสิ้นสุดของชื่อกลาง (8)

  12. นับความยาวรวมของสตริงข้อความใน A2 จากนั้น แยกจำนวนอักขระออกจากด้านซ้ายจนถึงอินสแตนซ์ที่สองของช่องว่างที่ได้ในขั้นตอนที่ 3 ผลลัพธ์คือจำนวนของอักขระที่จะแยกจากทางด้านขวาของชื่อเต็ม (14 – 8 = 6)

ต่อไปนี้เป็นตัวอย่างของวิธีการแยกชื่อกลางแบบย่อที่มีสองชื่อ อินสแตนซ์แรกและอินสแตนซ์ที่สามของช่องว่างจะคั่นคอมโพเนนต์ของชื่อ

คัดลอกเซลล์ในตารางและวางลงในเวิร์กชีต Excel ที่เซลล์ A1 สูตรที่คุณเห็นทางด้านซ้ายจะแสดงไว้เป็นการอ้างอิง ขณะที่ Excel จะแปลงสูตรทางด้านขวาเป็นผลลัพธ์ที่เหมาะสมโดยอัตโนมัติ

คำแนะนำ    ก่อนที่คุณจะวางข้อมูลลงในเวิร์กชีต ให้ตั้งค่าความกว้างของคอลัมน์ A และ B เป็น 250

ชื่อตัวอย่าง

คำอธิบาย

Janaina B. G. Bueno

มีตัวย่อชื่อกลางสองตัว

สูตร

ผลลัพธ์ (ชื่อ)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

สูตร

ผลลัพธ์ (ตัวย่อชื่อกลาง)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

สูตร

ผลลัพธ์ตามเวลาจริง (นามสกุล)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. ชื่อ

    ชื่อจะเริ่มต้นด้วยอักขระแรกจากทางด้านซ้าย (J) และสิ้นสุดที่อักขระที่แปด (ช่องว่างแรก) สูตรจะแยกอักขระแปดตัวแรกใน A2 เริ่มต้นจากด้านซ้าย

    สูตรสำหรับการแยกชื่อ นามสกุล ชื่อกลางแบบย่อสองตัว

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (8)

  2. ชื่อกลาง

    ชื่อกลางจะเริ่มต้นที่ตำแหน่งที่เก้า (B) และสิ้นสุดที่ตำแหน่งที่สิบสี่ (ช่องว่างที่สาม) สูตรนี้ต้องใช้ SEARCH ที่ซ้อนกันเพื่อค้นหาอินสแตนซ์แรก อินสแตนซ์ที่สอง และอินสแตนซ์ที่สามของช่องว่างในตำแหน่งที่แปด สิบเอ็ด และสิบสี่

    สูตรจะแยกอักขระห้าตัว เริ่มต้นจากตำแหน่งที่เก้า

    สูตรสำหรับการแยกชื่อ นามสกุล ชื่อกลางแบบย่อสองตัว

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่าของ start_num

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางซ้าย (8)

  3. บวกไปอีก 1 ตำแหน่งเพื่อไปที่ตำแหน่งของอักขระหลังช่องว่างแรก (B) ตำแหน่งตัวเลขนี้คือตำแหน่งเริ่มต้นของชื่อกลาง (8 + 1 = 9)

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางซ้าย (8)

  4. บวก 1 เพื่อให้ได้ตำแหน่งของอักขระหลังจากช่องว่างแรก (B) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มค้นหาอินสแตนซ์ที่สองของช่องว่าง(8 + 1 = 9)

  5. ค้นหาช่องว่างที่สองใน A2 โดยเริ่มจากตำแหน่งที่เก้า (B) ที่พบในขั้นตอนที่ 4 (11)

  6. บวกไปอีก 1 ตำแหน่งเพื่อไปที่ตำแหน่งของอักขระหลังช่องว่างที่สอง (G) หมายเลขอักขระนี้คือตำแหน่งเริ่มต้นที่คุณต้องการเริ่มต้นค้นหาสำหรับช่องว่างที่สาม (11 + 1 = 12)

  7. ค้นหาช่องว่างที่สามใน A2 เริ่มต้นที่ตำแหน่งที่สิบสองที่ได้ในขั้นตอนที่ 6 (14)

  8. ค้นหาตำแหน่งตัวเลขของช่องว่างแรกใน A2 (8)

  9. นำหมายเลขอักขระของช่องว่างที่สามที่ได้ในขั้นตอนที่ 7 มาลบด้วยหมายเลขอักขระของช่องว่างแรกที่ได้ในขั้นตอนที่ 6 ผลลัพธ์คือ MID ของหมายเลขอักขระจะแยกจากสตริงข้อความเริ่มต้นที่ตำแหน่งที่เก้าที่ได้ในขั้นตอนที่ 2

  10. นามสกุล

    นามสกุลจะเริ่มต้นที่อักขระที่ห้าจากด้านขวา (B) และสิ้นสุดที่อักขระแรกจากด้านขวา (o) สูตรนี้ต้องใช้ SEARCH ที่ซ้อนกันเพื่อค้นหาอินสแตนซ์แรก อินสแตนซ์ที่สอง และอินสแตนซ์ที่สามของช่องว่าง

    สูตรจะแยกอักขระห้าตัวใน A2 เริ่มต้นจากด้านขวาของชื่อเต็ม

    สูตรสำหรับการแยกชื่อ นามสกุล ชื่อกลางแบบย่อสองตัว

    ใช้ฟังก์ชัน SEARCH และฟังก์ชัน LEN ที่ซ้อนกันเพื่อค้นหาค่า num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางซ้าย (8)

  11. บวก 1 เพื่อให้ได้ตำแหน่งของอักขระหลังจากช่องว่างแรก (B) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มค้นหาอินสแตนซ์ที่สองของช่องว่าง(8 + 1 = 9)

  12. ค้นหาช่องว่างที่สองใน A2 เริ่มต้นจากตำแหน่งที่เก้า (B) ที่ได้ในขั้นตอนที่ 2 (11)

  13. บวกไปอีก 1 ตำแหน่งเพื่อไปที่ตำแหน่งของอักขระหลังช่องว่างที่สอง (G) หมายเลขอักขระนี้คือตำแหน่งเริ่มต้นที่คุณต้องการเริ่มต้นค้นหาสำหรับอินสแตนซ์ที่สามของช่องว่าง (11 + 1 = 12)

  14. ค้นหาช่องว่างที่สามใน A2 เริ่มต้นที่ตำแหน่งที่สิบสอง (G) ที่ได้ในขั้นตอนที่ 6 (14)

  15. นับความยาวรวมของสตริงข้อความใน A2 แล้วลบด้วยหมายเลขของอักขระจากด้านซ้ายจนถึงช่องว่างที่สามที่ได้ในขั้นตอนที่ 5 ผลลัพธ์คือหมายเลขอักขระที่จะถูกแยกจากด้านขวาของชื่อเต็ม (19 - 14 = 5)

ในตัวอย่างนี้ นามสกุลมาก่อนชื่อ และชื่อกลางปรากฏอยู่ส่วนท้าย เครื่องหมายจุลภาค แสดงถึงจุดสิ้นสุดของนามสกุลและมีช่องว่างคั่นแต่ละคอมโพเนนต์ของชื่อ

คัดลอกเซลล์ในตารางและวางลงในเวิร์กชีต Excel ที่เซลล์ A1 สูตรที่คุณเห็นทางด้านซ้ายจะแสดงไว้เป็นการอ้างอิง ขณะที่ Excel จะแปลงสูตรทางด้านขวาเป็นผลลัพธ์ที่เหมาะสมโดยอัตโนมัติ

คำแนะนำ    ก่อนที่คุณจะวางข้อมูลลงในเวิร์กชีต ให้ตั้งค่าความกว้างของคอลัมน์ A และ B เป็น 250

ชื่อตัวอย่าง

คำอธิบาย

Kahn, Wendy Beth

นามสกุลขึ้นก่อน โดยมีจุลภาคคั่นกลาง

สูตร

ผลลัพธ์ (ชื่อ)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

สูตร

ผลลัพธ์ (ชื่อกลาง)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

สูตร

ผลลัพธ์ตามเวลาจริง (นามสกุล)

'=LEFT(A2, SEARCH(" ",A2,1)-2)

=LEFT(A2, SEARCH(" ",A2,1)-2)

  1. ชื่อ

    ชื่อจะเริ่มต้นด้วยอักขระที่เจ็ดจากด้านซ้าย (W) และสิ้นสุดที่อักขระที่สิบสอง (ช่องว่างที่สอง) เนื่องจากชื่ออยู่ตรงกลางของชื่อเต็ม คุณจึงจำเป็นต้องใช้ฟังก์ชัน MID เพื่อแยกชื่อ

    สูตรจะแยกอักขระหกตัว เริ่มต้นจากตำแหน่งที่เจ็ด

    สูตรสำหรับการแยกนามสกุลตามด้วยชื่อและชื่อกลาง

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่าของ start_num

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางซ้าย (6)

  2. บวกไปอีก 1 ตำแหน่งเพื่อไปที่ตำแหน่งของอักขระหลังช่องว่างแรก (W) ตำแหน่งตัวเลขนี้คือตำแหน่งเริ่มต้นของชื่อ (6 + 1 = 7)

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางซ้าย (6)

  3. บวก 1 เพื่อให้ได้ตำหน่งของอักขระหลังจากช่องว่างแรก (W) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มค้นหาช่องว่างที่สอง(6 + 1 = 7)

    ค้นหาช่องว่างที่สองใน A2 เริ่มต้นจากตำแหน่งที่เจ็ด (W) ที่ได้ในขั้นตอนที่ 4 (12)

  4. ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางซ้าย (6)

  5. นำหมายเลขอักขระของช่องว่างที่สองที่ได้ในขั้นตอนที่ 5 มาลบด้วยหมายเลขอักขระของช่องว่างแรกที่ได้ในขั้นตอนที่ 6 ผลลัพธ์คือหมายเลขของอักขระของ MID จะแยกจากสตริงข้อความเริ่มต้นที่ตำแหน่งที่เจ็ดที่ได้ในขั้นตอนที่ 2(12 - 6 = 6)

  6. ชื่อกลาง

    ชื่อกลางเริ่มต้นที่อักขระที่สี่จากด้านขวา (B) และสิ้นสุดที่อักขระแรกจากด้านขวา (h) สูตรนี้ต้องใช้ SEARCH ที่ซ้อนกันเพื่อค้นหาอินสแตนซ์แรกและอินสแตนซ์ที่สองของช่องว่างในตำแหน่งที่หกและสิบสองจากด้านซ้าย

    สูตรจะแยกอักขระสี่ตัว เริ่มต้นทางด้านขวา

    สูตรสำหรับการแยกนามสกุลตามด้วยชื่อและชื่อกลาง

    ใช้ฟังก์ชัน SEARCH และฟังก์ชัน LEN ที่ซ้อนกันเพื่อค้นหาค่า start_num

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางซ้าย (6)

  7. บวก 1 เพื่อให้ได้ตำหน่งของอักขระหลังจากช่องว่างแรก (W) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มค้นหาช่องว่างที่สอง(6 + 1 = 7)

  8. ค้นหาอินสแตนซ์ที่สองของช่องว่างใน A2 เริ่มต้นจากตำแหน่งที่เจ็ด (W) ที่ได้ในขั้นตอนที่ 2 (12)

  9. นับความยาวรวมของสตริงข้อความใน A2 แล้วลบด้วยหมายเลขอักขระจากด้านซ้ายจนถึงช่องว่างที่สองที่ได้ในขั้นตอนที่ 3 ผลลัพธ์คือหมายเลขอักขระที่จะถูกแยกจากด้านขวาของชื่อเต็ม (16 - 12 = 4)

  10. นามสกุล

    นามสกุลจะเริ่มต้นด้วยอักขระแรกทางด้านซ้าย (K) และสิ้นสุดที่อักขระที่สี่ (n) สูตรจะแยกอักขระสี่ตัว เริ่มต้นจากด้านซ้าย

    สูตรสำหรับการแยกนามสกุลตามด้วยชื่อและชื่อกลาง

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางซ้าย (6)

  11. ลบไป 2 ตำแหน่งเพื่อไปที่ตำแหน่งตัวเลขของตัวอักขระสุดท้ายของนามสกุล (n) ผลลัพธ์คือหมายเลขของอักขระที่คุณต้องการให้ LEFT แยก (6 - 2 =4)

ตัวอย่างนี้จะมีชื่ออยู่สองส่วน คือ Mary Kay ช่องว่างที่สองและสามจะคั่นแต่ละคอมโพเนนต์ของชื่อ

คัดลอกเซลล์ในตารางและวางลงในเวิร์กชีต Excel ที่เซลล์ A1 สูตรที่คุณเห็นทางด้านซ้ายจะแสดงไว้เป็นการอ้างอิง ขณะที่ Excel จะแปลงสูตรทางด้านขวาเป็นผลลัพธ์ที่เหมาะสมโดยอัตโนมัติ

คำแนะนำ    ก่อนที่คุณจะวางข้อมูลลงในเวิร์กชีต ให้ตั้งค่าความกว้างของคอลัมน์ A และ B เป็น 250

ชื่อตัวอย่าง

คำอธิบาย

Mary Kay D. Andersen

ชื่อแบบสองส่วน

สูตร

ผลลัพธ์ (ชื่อ)

LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

สูตร

ผลลัพธ์ (ชื่อกลาง)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

สูตร

ผลลัพธ์ตามเวลาจริง (นามสกุล)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. ชื่อ

    ชื่อจะเริ่มต้นด้วยอักขระแรกทางด้านซ้ายและสิ้นสุดที่อักขระที่เก้า (ช่องว่างที่สอง) สูตรนี้ต้องใช้ SEARCH ที่ซ้อนกันเพื่อค้นหาอินสแตนซ์ที่สองของช่องว่างจากด้านซ้าย

    สูตรจะแยกอักขระเก้าตัว เริ่มต้นจากด้านซ้าย

    สูตรสำหรับการแยกชื่อ ชื่อกลาง ชื่อกลางแบบย่อ และนามสกุล

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางซ้าย (5)

  2. บวกไปอีก 1 ตำแหน่งเพื่อไปที่ตำแหน่งของอักขระหลังช่องว่างแรก (K) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มต้นค้นหาอินสแตนซ์ที่สองของช่องว่าง (5 + 1 = 6)

  3. ค้นหาอินสแตนซ์ที่สองของช่องว่างใน A2 เริ่มต้นจากตำแหน่งที่หก (K) ที่ได้ในขั้นตอนที่ 2 ผลลัพธ์คือหมายเลขของอักขระ LEFT จะแยกจากสตริงข้อความ (9)

  4. ชื่อกลาง

    ชื่อกลางเริ่มต้นที่ตำแหน่งที่สิบ (D) และสิ้นสุดที่ตำแหน่งที่สิบสอง (ช่องว่างที่สาม) สูตรนี้ต้องใช้ SEARCH ที่ซ้อนกันเพื่อค้นหาอินสแตนซ์แรก อินสแตนซ์ที่สอง และอินสแตนซ์ที่สามของช่องว่าง

    สูตรจะแยกอักขระสองตัวจากตรงกลาง เริ่มต้นจากตำแหน่งที่สิบ

    สูตรสำหรับการแยกชื่อ ชื่อกลาง ชื่อกลางแบบย่อ และนามสกุล

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่าของ start_num

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางซ้าย (5)

  5. บวกไปอีก 1 ตำแหน่งเพื่อไปที่อักขระหลังช่องว่างแรก (K) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มต้นค้นหาสำหรับช่องว่างที่สอง (5 + 1 = 6)

  6. ค้นหาตำแหน่งของอินสแตนซ์ที่สองของช่องว่างใน A2 เริ่มต้นจากตำแหน่งที่หก (K) ที่ได้ในขั้นตอนที่ 2 ผลลัพธ์คือหมายเลขของอักขระ LEFT จะแยกจากด้านซ้าย (9)

  7. บวกไปอีก 1 ตำแหน่งเพื่อไปที่อักขระหลังช่องว่างที่สอง (D) ผลลัพธ์คือตำแหน่งเริ่มต้นของชื่อกลาง (9 + 1 = 10)

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งตัวเลขของอักขระหลังช่องว่างแรก (D) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มต้นค้นหาช่องว่างที่สาม (10)

  8. ค้นหาตำแหน่งตัวเลขของช่องว่างที่สามใน A2 เริ่มต้นจากด้านซ้าย ผลลัพธ์คือตำแหน่งสิ้นสุดของชื่อกลาง (12)

  9. ค้นหาตำแหน่งตัวเลขของอักขระหลังช่องว่างที่สอง (D) ผลลัพธ์คือตำแหน่งเริ่มต้นของชื่อกลาง (10)

  10. นำหมายเลขอักขระของช่องว่างที่สามที่ได้ในขั้นตอนที่ 6 มาลบด้วยหมายเลขอักขระของ “D” ที่ได้ในขั้นตอนที่ 7 ผลลัพธ์คือ MID ของหมายเลขของอักขระที่แยกจากสตริงข้อความที่ตำแหน่งที่สิบที่ได้ในขั้นตอนที่ 4(12 - 10 = 2)

  11. นามสกุล

    นามสกุลจะเริ่มต้นที่อักขระที่แปดจากทางด้านขวา สูตรนี้ต้องใช้ SEARCH ที่ซ้อนกันเพื่อค้นหาอินสแตนซ์แรก อินสแตนซ์ที่สอง และอินสแตนซ์ที่สามของช่องว่างในตำแหน่งที่ห้า เก้า และสิบสอง

    สูตรจะแยกอักขระแปดตัวจากด้านขวา

    สูตรสำหรับการแยกชื่อ ชื่อกลาง ชื่อกลางแบบย่อ และนามสกุล

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันและฟังก์ชัน LEN เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (5)

  12. บวกไปอีก 1 ตำแหน่งเพื่อไปที่อักขระหลังช่องว่างแรก (K) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มต้นค้นหาสำหรับช่องว่าง (5 + 1 = 6)

  13. ค้นหาช่องว่างที่สองใน A2 เริ่มต้นจากตำแหน่งที่หก (K) ที่ได้ในขั้นตอนที่ 2 (9)

  14. บวกไปอีก 1 ตำแหน่งเพื่อไปที่ตำแหน่งของอักขระหลังช่องว่างที่สอง (D) ผลลัพธ์คือตำแหน่งเริ่มต้นของชื่อกลาง (9 + 1 = 10)

  15. ค้นหาตำแหน่งตัวเลขของช่องว่างที่สามใน A2 เริ่มต้นจากด้านซ้าย ผลลัพธ์คือตำแหน่งสิ้นสุดของชื่อกลาง (12)

  16. นับความยาวรวมของสตริงข้อความใน A2 แล้วลบด้วยหมายเลขอักขระจากด้านซ้ายจนถึงช่องว่างที่สามที่ได้ในขั้นตอนที่ 5 ผลลัพธ์คือหมายเลขของอักขระที่จะถูกแยกจากทางขวาของชื่อเต็ม (20 - 12 = 8)

ตัวอย่างนี้มีนามสกุลอยู่สามส่วน คือ Barreto de Mattos ช่องว่างแรกจะหมายถึงจุดสิ้นสุดของชื่อและจุดเริ่มต้นของนามสกุล

คัดลอกเซลล์ในตารางและวางลงในเวิร์กชีต Excel ที่เซลล์ A1 สูตรที่คุณเห็นทางด้านซ้ายจะแสดงไว้เป็นการอ้างอิง ขณะที่ Excel จะแปลงสูตรทางด้านขวาเป็นผลลัพธ์ที่เหมาะสมโดยอัตโนมัติ

คำแนะนำ    ก่อนที่คุณจะวางข้อมูลลงในเวิร์กชีต ให้ตั้งค่าความกว้างของคอลัมน์ A และ B เป็น 250

ชื่อตัวอย่าง

คำอธิบาย

Paula Barreto de Mattos

นามสกุลแบบสามส่วน

สูตร

ผลลัพธ์ (ชื่อ)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

สูตร

ผลลัพธ์ (นามสกุล)

RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. ชื่อ

    ชื่อจะเริ่มต้นด้วยอักขระแรกทางด้านซ้าย (P) และสิ้นสุดที่อักขระที่หก (ช่องว่างแรก) สูตรจะแยกหกอักขระจากด้านซ้าย

    สูตรสำหรับการแยกชื่อและนามสกุลที่มีสามส่วน

    ใช้ฟังก์ชัน Search เพื่อค้นหาค่า num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (6)

  2. นามสกุล

    นามสกุลจะเริ่มต้นจากอักขระสิบเจ็ดตัวจากด้านขวา (B) และลงท้ายด้วยอักขระแรกจากด้านขวา (s) สูตรจะแยกอักขระสิบเจ็ดตัวจากด้านขวา

    สูตรสำหรับการแยกชื่อและนามสกุลที่มีสามส่วน

    ใช้ฟังก์ชัน LEN และฟังก์ชัน SEARCH เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (6)

  3. นับความยาวรวมของสตริงข้อความใน A2 แล้วลบด้วยหมายเลขของอักขระจากด้านซ้ายจนถึงช่องว่างแรกที่ได้ในขั้นตอนที่ 1 ผลลัพธ์คือหมายเลขของอักขระที่จะถูกแยกจากด้านขวาของชื่อเต็ม (23 - 6 = 17)

ตัวอย่างนี้มีนามสกุลอยู่สองส่วน คือ van Eaton ช่องว่างแรกจะหมายถึงจุดสิ้นสุดของชื่อและจุดเริ่มต้นของนามสกุล

คัดลอกเซลล์ในตารางและวางลงในเวิร์กชีต Excel ที่เซลล์ A1 สูตรที่คุณเห็นทางด้านซ้ายจะแสดงไว้เป็นการอ้างอิง ขณะที่ Excel จะแปลงสูตรทางด้านขวาเป็นผลลัพธ์ที่เหมาะสมโดยอัตโนมัติ

คำแนะนำ    ก่อนที่คุณจะวางข้อมูลลงในเวิร์กชีต ให้ตั้งค่าความกว้างของคอลัมน์ A และ B เป็น 250

ชื่อตัวอย่าง

คำอธิบาย

James van Eaton

นามสกุลแบบสองส่วน

สูตร

ผลลัพธ์ (ชื่อ)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

สูตร

ผลลัพธ์ (นามสกุล)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. ชื่อ

    ชื่อจะเริ่มต้นด้วยอักขระแรกจากด้านซ้าย (J) และสิ้นสุดที่อักขระที่แปด (ช่องว่างแรก) สูตรจะแยกอักขระหกตัวจากด้านซ้าย

    สูตรสำหรับการแยกชื่อและนามสกุลที่มีสองส่วน

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (6)

  2. นามสกุล

    นามสกุลจะเริ่มต้นด้วยอักขระที่เก้าจากด้านขวา (v) และสิ้นสุดที่อักขระแรกจากด้านขวา (n) สูตรจะแยกอักขระเก้าตัวจากด้านขวาของชื่อเต็ม

    สูตรสำหรับการแยกชื่อและนามสกุลที่มีสองส่วน

    ใช้ฟังก์ชัน LEN และฟังก์ชัน SEARCH เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (6)

  3. นับความยาวรวมของสตริงข้อความใน A2 แล้วลบด้วยหมายเลขของอักขระจากด้านซ้ายจนถึงช่องว่างแรกที่ได้ในขั้นตอนที่ 1 ผลลัพธ์คือหมายเลขของอักขระที่จะถูกแยกจากด้านขวาของชื่อเต็ม (15 - 6 = 9)

ในตัวอย่างนี้ นามสกุลมาเป็นลำดับแรก ตามด้วยคำต่อท้าย จุลภาคจะคั่นนามสกุลและคำต่อท้ายจากชื่อและชื่อกลางแบบย่อ

คัดลอกเซลล์ในตารางและวางลงในเวิร์กชีต Excel ที่เซลล์ A1 สูตรที่คุณเห็นทางด้านซ้ายจะแสดงไว้เป็นการอ้างอิง ขณะที่ Excel จะแปลงสูตรทางด้านขวาเป็นผลลัพธ์ที่เหมาะสมโดยอัตโนมัติ

คำแนะนำ    ก่อนที่คุณจะวางข้อมูลลงในเวิร์กชีต ให้ตั้งค่าความกว้างของคอลัมน์ A และ B เป็น 250

ชื่อตัวอย่าง

คำอธิบาย

Bacon Jr., Dan K.

นามสกุลและคำต่อท้ายขึ้นก่อน โดยมีจุลภาคคั่นกลาง

สูตร

ผลลัพธ์ (ชื่อ)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

สูตร

ผลลัพธ์ (ชื่อกลาง)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

สูตร

ผลลัพธ์ (นามสกุล)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

สูตร

ผลลัพธ์ (คำต่อท้าย)

'=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

  1. ชื่อ

    ชื่อจะเริ่มต้นด้วยอักขระที่สิบสอง (D) และลงท้ายด้วยอักขระที่สิบห้า (ช่องว่างที่สาม) สูตรจะแยกอักขระสามตัว เริ่มต้นจากตำแหน่งที่สิบสอง

    สูตรสำหรับการแยกนามสกุลและคำต่อท้ายขึ้นก่อน โดยมีจุลภาคคั่นกลาง

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่าของ start_num

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (6)

  2. บวก 1 เพื่อให้ได้ตำหน่งของอักขระหลังจากช่องว่างแรก (J) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มค้นหาช่องว่างที่สอง(6 + 1 = 7)

  3. ค้นหาช่องว่างที่สองใน A2 เริ่มต้นจากตำแหน่งที่ 7 (J) ที่พบในขั้นตอนที่ 2 (11)

  4. บวก 1 เพื่อให้ได้ตำหน่งของอักขระหลังจากช่องว่างที่สอง (D) ผลลัพธ์คือตำแหน่งเริ่มต้นของชื่อ(11 + 1 = 12)

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งตัวเลขของอักขระหลังช่องว่างแรก (D) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มต้นค้นหาช่องว่างที่สาม (12)

  5. ค้นหาตำแหน่งตัวเลขของช่องว่างที่สามใน A2 เริ่มต้นจากด้านซ้าย ผลลัพธ์คือตำแหน่งสิ้นสุดของชื่อ (15)

  6. ค้นหาตำแหน่งตัวเลขของอักขระหลังช่องว่างที่สอง (D) ผลลัพธ์คือตำแหน่งเริ่มต้นของชื่อ (12)

  7. นำหมายเลขอักขระของช่องว่างที่สามที่ได้ในขั้นตอนที่ 6 มาลบด้วยหมายเลขอักขระของ “D” ที่ได้ในขั้นตอนที่ 7 ผลลัพธ์คือ MID ของหมายเลขของอักขระที่แยกจากสตริงข้อความที่ตำแหน่งที่สิบสองที่ได้ในขั้นตอนที่ 4 (15 - 12 = 3)

  8. ชื่อกลาง

    ชื่อกลางจะเริ่มต้นด้วยอักขระที่สองจากด้านขวา (K) สูตรจะแยกอักขระสองตัวจากด้านขวา

    สูตรสำหรับการแยกนามสกุลและคำต่อท้ายขึ้นก่อน โดยมีจุลภาคคั่นกลาง

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (6)

  9. บวก 1 เพื่อให้ได้ตำหน่งของอักขระหลังจากช่องว่างแรก (J) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มค้นหาช่องว่างที่สอง(6 + 1 = 7)

  10. ค้นหาช่องว่างที่สองใน A2 เริ่มต้นจากตำแหน่งที่ 7 (J) ที่พบในขั้นตอนที่ 2 (11)

  11. บวก 1 เพื่อให้ได้ตำหน่งของอักขระหลังจากช่องว่างที่สอง (D) ผลลัพธ์คือตำแหน่งเริ่มต้นของชื่อ(11 + 1 = 12)

  12. ค้นหาตำแหน่งตัวเลขของช่องว่างที่สามใน A2 เริ่มต้นจากด้านซ้าย ผลลัพธ์คือตำแหน่งสิ้นสุดของชื่อ (15)

  13. นับความยาวรวมของสตริงข้อความใน A2 แล้วลบด้วยหมายเลขของอักขระจากด้านซ้ายจนถึงช่องว่างที่สามที่ได้ในขั้นตอนที่ 5 ผลลัพธ์คือหมายเลขของอักขระที่จะถูกแยกจากด้านขวาของชื่อเต็ม (17 - 15 = 2)

  14. นามสกุล

    นามสกุลจะเริ่มต้นที่อักขระแรกจากด้านซ้าย (B) และสิ้นสุดที่อักขระที่หก (ช่องว่างแรก) ดังนั้น สูตรจะแยกอักขระหกตัวจากด้านซ้าย

    สูตรสำหรับการแยกนามสกุลและคำต่อท้ายขึ้นก่อน โดยมีจุลภาคคั่นกลาง

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (6)

  15. คำต่อท้าย

    คำต่อท้ายจะเริ่มต้นที่อักขระที่เจ็ดจากด้านซ้าย (J) และสิ้นสุดที่อักขระที่เก้าจากด้านซ้าย (.) สูตรจะแยกอักขระสามตัว เริ่มต้นจากอักขระที่เจ็ด

    สูตรสำหรับการแยกนามสกุลและคำต่อท้ายขึ้นก่อน โดยมีจุลภาคคั่นกลาง

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่าของ start_num

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (6)

  16. บวกไปอีก 1 ตำแหน่งเพื่อไปที่อักขระหลังช่องว่างแรก (J) ผลลัพธ์คือตำแหน่งเริ่มต้นของคำต่อท้าย (6 + 1 = 7)

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (6)

  17. บวกไปอีก 1 ตำแหน่งเพื่อไปที่ตำแหน่งตัวเลขของอักขระหลังช่องว่างแรก (J) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มต้นค้นหาช่องว่างที่สอง (7)

  18. ค้นหาตำแหน่งตัวเลขของช่องว่างที่สองใน A2 เริ่มต้นจากอักขระที่เจ็ดที่ได้ในขั้นตอนที่ 4 (11)

  19. ลบไป 1 อักขระจากหมายเลขอักขระของช่องว่างที่สองที่ได้ในขั้นตอนที่ 4 เพื่อไปที่หมายเลขอักขระของ “,” ผลลัพธ์คือตำแหน่งสิ้นสุดของคำต่อท้าย (11 - 1 = 10)

  20. ค้นหาตำแหน่งตัวเลขของช่องว่างแรก (6)

  21. หลังจากค้นหาช่องว่างแรก ให้บวกไปอีก 1 เพื่อค้นหาอักขระถัดไป (J) ที่ได้ในขั้นตอนที่ 3 และ 4 (7)

  22. นำหมายเลขอักขระของ “,” ที่ได้ในขั้นตอนที่ 6 มาลบด้วยหมายเลขอักขระของ “J” ที่ได้ในขั้นตอนที่ 3 และ 4 ผลลัพธ์คือ MID ของหมายเลขของอักขระจะแยกจากสตริงข้อความที่ตำแหน่งที่เจ็ดที่ได้ในขั้นตอนที่ 2 (10 - 7 = 3)

ในตัวอย่างนี้ ชื่ออยู่ที่จุดเริ่มต้นของสตริงและคำต่อท้ายอยู่ที่ส่วนท้ายสุด คุณจึงสามารถใช้สูตรคล้ายกับตัวอย่างที่ 2 คือ ใช้ฟังก์ชัน LEFT เพื่อแยกชื่อ ฟังก์ชัน MID เพื่อแยกนามสกุล และฟังก์ชัน RIGHT เพื่อแยกคำต่อท้าย

คัดลอกเซลล์ในตารางและวางลงในเวิร์กชีต Excel ที่เซลล์ A1 สูตรที่คุณเห็นทางด้านซ้ายจะแสดงไว้เป็นการอ้างอิง ขณะที่ Excel จะแปลงสูตรทางด้านขวาเป็นผลลัพธ์ที่เหมาะสมโดยอัตโนมัติ

คำแนะนำ    ก่อนที่คุณจะวางข้อมูลลงในเวิร์กชีต ให้ตั้งค่าความกว้างของคอลัมน์ A และ B เป็น 250

ชื่อตัวอย่าง

คำอธิบาย

Gary Altman III

ชื่อและนามสกุลที่มีคำต่อท้าย

สูตร

ผลลัพธ์ (ชื่อ)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

สูตร

ผลลัพธ์ (นามสกุล)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

สูตร

ผลลัพธ์ (คำต่อท้าย)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. ชื่อ

    ชื่อจะเริ่มต้นที่อักขระแรกจากด้านซ้าย (G) และสิ้นสุดที่อักขระที่ห้า (ช่องว่างแรก) ดังนั้น สูตรจะแยกอักขระห้าตัวจากด้านซ้ายของชื่อเต็ม

    สูตรสำหรับการแยกชื่อและนามสกุลที่ตามด้วยคำต่อท้าย

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างแรกใน A2 เริ่มต้นจากทางซ้าย (5)

  2. นามสกุล

    นามสกุลจะเริ่มต้นที่อักขระที่หกจากด้านซ้าย (A) และสิ้นสุดที่อักขระที่สิบเอ็ด (ช่องว่างที่สอง) สูตรนี้ต้องใช้ SEARCH ที่ซ้อนกันเพื่อค้นหาตำแหน่งของช่องว่าง

    สูตรจะแยกอักขระหกตัวจากตรงกลาง เริ่มต้นจากอักขระที่หก

    สูตรสำหรับการแยกชื่อและนามสกุลที่ตามด้วยคำต่อท้าย

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่าของ start_num

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (5)

  3. บวกไปอีก 1 ตำแหน่งเพื่อไปที่ตำแหน่งของอักขระหลังช่องว่างแรก (A) ผลลัพธ์คือตำแหน่งเริ่มต้นของนามสกุล (5 + 1 = 6)

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (5)

  4. บวกไปอีก 1 ตำแหน่งเพื่อไปที่ตำแหน่งของอักขระหลังช่องว่างแรก (A) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มต้นค้นหาช่องว่างที่สอง (5 + 1 = 6)

  5. ค้นหาตำแหน่งตัวเลขของช่องว่างที่สองใน A2 เริ่มต้นจากอักขระที่หกที่ได้ในขั้นตอนที่ 4 หมายเลขอักขระนี้คือตำแหน่งสิ้นสุดของนามสกุล (12)

  6. ค้นหาตำแหน่งตัวเลขของช่องว่างแรก (5)

  7. บวกไปอีก 1 ตำแหน่งเพื่อค้นหาตำแหน่งตัวเลขของอักขระหลังช่องว่างแรก (A) ที่ได้ในขั้นตอนที่ 3 และ 4 (6)

  8. นำหมายเลขอักขระของช่องว่างที่สองที่ได้ในขั้นตอนที่ 5 มาลบด้วยหมายเลขอักขระของ “A” ที่ได้ในขั้นตอนที่ 6 และ 7 ผลลัพธ์คือ MID ของหมายเลขอักขระจะแยกจากสตริงข้อความ เริ่มต้นที่ตำแหน่งที่หกที่ได้ในขั้นตอนที่ 2 (12 - 6 = 6)

  9. คำต่อท้าย

    คำต่อท้ายเริ่มต้นที่อักขระที่สามจากด้านขวา สูตรนี้ต้องใช้ SEARCH ที่ซ้อนกันเพื่อค้นหาตำแหน่งของช่องว่าง

    สูตรสำหรับการแยกชื่อและนามสกุลที่ตามด้วยคำต่อท้าย

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันและฟังก์ชัน LEN เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (5)

  10. บวกไปอีก 1 ตำแหน่งเพื่อไปที่อักขระหลังช่องว่างแรก (A) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มต้นค้นหาช่องว่างที่สอง (5 + 1 = 6)

  11. ค้นหาช่องว่างที่สองใน A2 เริ่มต้นจากตำแหน่งที่หก (A) ที่ได้ในขั้นตอนที่ 2 (12)

  12. นับความยาวรวมของสตริงข้อความใน A2 แล้วลบด้วยหมายเลขของอักขระจากด้านซ้ายจนถึงช่องว่างที่สองที่ได้ในขั้นตอนที่ 3 ผลลัพธ์คือหมายเลขของอักขระที่จะถูกแยกจากด้านขวาของชื่อเต็ม (15 - 12 = 3)

ในตัวอย่างนี้ มีคำนำหน้าอยู่ข้างหน้าชื่อเต็ม และคุณใช้สูตรคล้ายกับตัวอย่างที่ 2 คือ ฟังก์ชัน MID เพื่อแยกชื่อ ฟังก์ชัน RIGHT เพื่อแยกนามสกุล

คัดลอกเซลล์ในตารางและวางลงในเวิร์กชีต Excel ที่เซลล์ A1 สูตรที่คุณเห็นทางด้านซ้ายจะแสดงไว้เป็นการอ้างอิง ขณะที่ Excel จะแปลงสูตรทางด้านขวาเป็นผลลัพธ์ที่เหมาะสมโดยอัตโนมัติ

คำแนะนำ    ก่อนที่คุณจะวางข้อมูลลงในเวิร์กชีต ให้ตั้งค่าความกว้างของคอลัมน์ A และ B เป็น 250

ชื่อตัวอย่าง

คำอธิบาย

Mr. Ryan Ihrig

มีคำนำหน้า

สูตร

ผลลัพธ์ (ชื่อ)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

สูตร

ผลลัพธ์ (นามสกุล)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. ชื่อ

    ชื่อจะเริ่มต้นด้วยอักขระที่ห้าจากทางซ้าย (R) และสิ้นสุดที่อักขระที่เก้า (ช่องว่างที่สอง) สูตร SEARCH ที่ซ้อนกันเพื่อค้นหาตำแหน่งของช่องว่าง สูตรจะแยกอักขระสี่ตัว เริ่มต้นจากตำแหน่งที่ห้า

    สูตรสำหรับการแยกชื่อที่นำหน้าด้วยคำนำหน้า

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่า start_num

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (4)

  2. บวกไปอีก 1 ตำแหน่งเพื่อไปที่ตำแหน่งของอักขระหลังช่องว่างแรก (R) ผลลัพธ์คือตำแหน่งเริ่มต้นของชื่อ (4 + 1 = 5)

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันเพื่อค้นหาค่า num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (4)

  3. บวก 1 เพื่อให้ได้ตำหน่งของอักขระหลังจากช่องว่างแรก (R) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มค้นหาช่องว่างที่สอง(4 + 1 = 5)

  4. ค้นหาตำแหน่งตัวเลขของช่องว่างที่สองใน A2 เริ่มต้นจากอักขระที่ห้าที่ได้ในขั้นตอนที่ 3 และ 4 หมายเลขอักขระนี้คือตำแหน่งสิ้นสุดของชื่อ (9)

  5. ค้นหาช่องว่างแรก (4)

  6. บวกไปอีก 1 เพื่อค้นหาตำแหน่งตัวเลขของอักขระหลังช่องว่างแรก (R) ที่ได้ในขั้นตอนที่ 3 และ 4 (5)

  7. นำหมายเลขอักขระของช่องว่างที่สองที่ได้ในขั้นตอนที่ 5 มาลบด้วยหมายเลขอักขระของ “R” ที่ได้ในขั้นตอนที่ 6 และ 7 ผลลัพธ์คือ MID ของหมายเลขอักขระจะแยกจากสตริงข้อความ เริ่มต้นที่ตำแหน่งที่ห้าที่ได้ในขั้นตอนที่ 2 (9 - 5 = 4)

  8. นามสกุล

    นามสกุลจะเริ่มต้นที่อักขระที่ห้าจากด้านขวา สูตรนี้ต้องใช้ SEARCH ที่ซ้อนกันเพื่อค้นหาตำแหน่งของช่องว่าง

    สูตรสำหรับการแยกชื่อที่นำหน้าด้วยคำนำหน้า

    ใช้ฟังก์ชัน SEARCH ที่ซ้อนกันและฟังก์ชัน LEN เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (4)

  9. บวก 1 เพื่อให้ได้ตำหน่งของอักขระหลังจากช่องว่างแรก (R) ผลลัพธ์คือหมายเลขอักขระที่คุณต้องการเริ่มค้นหาช่องว่างที่สอง(4 + 1 = 5)

  10. ค้นหาช่องว่างที่สองใน A2 เริ่มต้นจากตำแหน่งที่หก (R) ที่ได้ในขั้นตอนที่ 2 (9)

  11. นับความยาวรวมของสตริงข้อความใน A2แล้วลบด้วยหมายเลขของอักขระจากด้านซ้ายจนถึงช่องว่างที่สองที่ได้ในขั้นตอนที่ 3 ผลลัพธ์คือหมายเลขของอักขระที่จะถูกแยกจากด้านขวาของชื่อเต็ม (14 - 9 = 5)

ตัวอย่างนี้ นามสกุลมีเครื่องหมายยัติภังค์ ช่องว่างคั่นแต่ละคอมโพเนนต์ของชื่อ

คัดลอกเซลล์ในตารางและวางลงในเวิร์กชีต Excel ที่เซลล์ A1 สูตรที่คุณเห็นทางด้านซ้ายจะแสดงไว้เป็นการอ้างอิง ขณะที่ Excel จะแปลงสูตรทางด้านขวาเป็นผลลัพธ์ที่เหมาะสมโดยอัตโนมัติ

คำแนะนำ    ก่อนที่คุณจะวางข้อมูลลงในเวิร์กชีต ให้ตั้งค่าความกว้างของคอลัมน์ A และ B เป็น 250

ชื่อตัวอย่าง

คำอธิบาย

Julie Taft-Rider

นามสกุลที่มีเครื่องหมายยัติภังค์

สูตร

ผลลัพธ์ (ชื่อ)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

สูตร

ผลลัพธ์ (นามสกุล)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. ชื่อ

    ชื่อจะเริ่มต้นที่อักขระแรกจากด้านซ้ายและสิ้นสุดที่ตำแหน่งที่หก (ช่องว่างแรก) สูตรจะแยกหกอักขระจากด้านซ้าย

    สูตรสำหรับการแยกชื่อและนามสกุลที่ใส่เครื่องหมายยัติภังค์

    ใช้ฟังก์ชัน SEARCH เพื่อค้นหาค่า num_chars

    ค้นหาตำแหน่งเป็นตัวเลขของช่องว่างใน A2 เริ่มต้นจากทางซ้าย (6)

  2. นามสกุล

    นามสกุลทั้งหมดจะเริ่มต้นที่อักขระที่สิบจากด้านขวา (T) และสิ้นสุดที่อักขระแรกจากด้านขวา (r)

    สูตรสำหรับการแยกชื่อและนามสกุลที่ใส่เครื่องหมายยัติภังค์

    ใช้ฟังก์ชัน LEN และฟังก์ชัน SEARCH เพื่อค้นหาค่าของ num_chars

    ค้นหาตำแหน่งตัวเลขของช่องว่างใน A2 เริ่มต้นจากอักขระแรกทางด้านซ้าย (6)

  3. นับความยาวรวมของสตริงข้อความที่จะถูกแยก แล้วลบด้วยหมายเลขของอักขระจากด้านซ้ายจนถึงช่องว่างแรกที่ได้ในขั้นตอนที่ 1 (16 - 6 = 10)

ดูเพิ่มเติม

แยกข้อความเป็นหลายคอลัมน์ด้วยตัวช่วยสร้างแปลงข้อความเป็นคอลัมน์

ขยายทักษะของคุณ
สำรวจการฝึกอบรม
รับฟีเจอร์ใหม่ก่อนใคร
เข้าร่วม Office Insider

ข้อมูลนี้เป็นประโยชน์หรือไม่

ขอบคุณสำหรับคำติชมของคุณ!

ขอขอบคุณสำหรับคำติชมของคุณ! เราคิดว่าอาจเป็นประโยชน์ที่จะให้คุณได้ติดต่อกับหนึ่งในตัวแทนฝ่ายสนับสนุน Office ของเรา

×