ฟังก์ชัน TEXT

ผู้สนับสนุน: Chris "Smitty" Smith Dave Ludwig

ฟังก์ชัน TEXT จะช่วยให้คุณเปลี่ยนวิธีการแสดงตัวเลขโดยการนำการจัดรูปแบบไปใช้ด้วย โค้ดรูปแบบ ซึ่งจะมีประโยชน์ในกรณีที่คุณต้องการแสดงตัวเลขในรูปแบบที่อ่านได้ง่ายขึ้น หรือคุณต้องการรวมตัวเลขกับข้อความหรือสัญลักษณ์

หมายเหตุ: ฟังก์ชัน TEXT จะแปลงตัวเลขเป็นข้อความ ซึ่งอาจทำให้ยากในการอ้างอิงในการคำนวณในภายหลัง คุณควรเก็บรักษาค่าดั้งเดิมของคุณไว้ในหนึ่งเซลล์ แล้วใช้ฟังก์ชัน TEXT ในเซลล์อื่น จากนั้น ถ้าคุณต้องการสร้างสูตรอื่นๆ ให้อ้างอิงค่าดั้งเดิมเสมอและไม่ใช่ผลลัพธ์ของฟังก์ชัน TEXT

ไวยากรณ์

TEXT(value, format_text)

ไวยากรณ์ของฟังก์ชัน TEXT มีอาร์กิวเมนต์ดังนี้

ชื่ออาร์กิวเมนต์

คำอธิบาย

value

ค่าตัวเลขที่คุณต้องการแปลงเป็นข้อความ

format_text

สตริงข้อความที่ระบุการจัดรูปแบบที่คุณต้องการนำไปใช้กับค่าที่ระบุ

ภาพรวม

ในรูปแบบที่ง่ายที่สุด ฟังก์ชัน TEXT จะระบุว่า:

  • =TEXT(ค่าที่คุณต้องการจัดรูปแบบ, "จัดรูปแบบโค้ดที่คุณต้องการนำไปใช้")

ต่อไปนี้คือตัวอย่างที่ได้รับความนิยมบางส่วน ซึ่งคุณสามารถคัดลอกลงใน Excel เพื่อทดลองด้วยตัวคุณเอง ดูโค้ดรูปแบบภายในเครื่องหมายอัญประกาศ

สูตร

คำอธิบาย

=TEXT(1234.567,"$#,##0.00")

สกุลเงินที่ตัวคั่นหลักพันและทศนิยม 2 ตำแหน่ง เช่น $1,234.57 โปรดสังเกตว่า Excel จะปัดค่าเป็นทศนิยม 2 ตำแหน่ง

=TEXT(TODAY(),"MM/DD/YY")

วันที่ของวันนี้ในรูปแบบ MM/DD/YY เช่น 03/14/12

=TEXT(TODAY(),"DDDD")

วันของวันนี้ในสัปดาห์ เช่น วันจันทร์

=TEXT(NOW(),"H:MM AM/PM")

เวลาปัจจุบัน เช่น 13:29 น.

=TEXT(0.285,"0.0%")

เปอร์เซ็นต์ เช่น 28.5%

=TEXT(4.34 ,"# ?/?")

เศษส่วน เช่น 4 1/3

=TRIM(TEXT(0.34,"# ?/?"))

เศษส่วน เช่น 1/3 โปรดทราบว่าใช้ฟังก์ชัน TRIM เพื่อนำช่องว่างนำหน้าที่มีค่าเลขทศนิยมออก

=TEXT(12200000,"0.00E+00")

เครื่องหมายทางวิทยาศาสตร์ เช่น 1.22E+07

=TEXT(1234567898,"[<=9999999]###-####;(###) ###-####")

พิเศษ (หมายเลขโทรศัพท์), เช่น (123) 456-7898

=TEXT(1234,"0000000")

เพิ่มเลขศูนย์นำหน้า (0) เช่น 0001234

=TEXT(123456,"##0° 00' 00''")

กำหนดเอง - ละติจูด/ลองจิจูด

หมายเหตุ: แม้ว่าคุณจะสามารถใช้ฟังก์ชัน TEXT เพื่อเปลี่ยนแปลงการจัดรูปแบบ แต่ยังมีวิธีอื่นอีก คุณสามารถเปลี่ยนรูปแบบโดยไม่มีสูตรโดยการกด CTRL+1 (หรือ รูปไอคอนปุ่ม Command ของ MAC +1 บน Mac) แล้วเลือกรูปแบบที่คุณต้องการจาก จัดรูปแบบเซลล์ > กล่องโต้ตอบ ตัวเลข

ดาวน์โหลดตัวอย่างของเรา

คุณสามารถดาวน์โหลดตัวอย่างเวิร์กบุ๊กที่มีตัวอย่างฟังก์ชัน TEXT ทั้งหมดที่คุณจะพบได้ในบทความนี้ พร้อมกับส่วนเพิ่มเติม คุณสามารถทำตาม หรือสร้างโค้ดรูปแบบของฟังก์ชัน TEXT ของคุณเอง

ดาวน์โหลดตัวอย่างของฟังก์ชัน TEXT ใน Excel

โค้ดรูปแบบอื่นๆ ที่พร้อมใช้งาน

คุณสามารถใช้กล่องโต้ตอบ จัดรูปแบบเซลล์ เพื่อค้นหาโค้ดรูปแบบที่พร้อมใช้งานอื่นๆ:

  1. กด Ctrl+1 ( รูปไอคอนปุ่ม Command ของ MAC +1 บน Mac) เพื่อแสดงกล่องโต้ตอบ จัดรูปแบบเซลล์

  2. เลือกรูปแบบที่คุณต้องการจากแท็บ ตัวเลข

  3. เลือกตัวเลือก กำหนดเอง

  4. โค้ดรูปแบบที่คุณต้องการจะแสดงอยู่ในกล่อง ชนิด ในกรณีนี้ ให้เลือกทุกรายการจากกล่อง ชนิด ยกเว้นเครื่องหมายอัฒภาค (;) และเครื่องหมาย @ ในตัวอย่างด้านล่าง เราเลือกและคัดลอก mm/dd/yy

  5. กด Ctrl+C เพื่อคัดลอกโค้ดรูปแบบ แล้วกด ยกเลิก เพื่อปิดกล่องโต้ตอบ จัดรูปแบบเซลล์

  6. ในตอนนี้ สิ่งที่คุณต้องทำคือกด Ctrl+V เพื่อวางโค้ดรูปแบบลงในสูตร TEXT ของคุณ เช่น: =TEXT (B2,"mm/dd/yy") ตรวจสอบให้แน่ใจว่าคุณวางโค้ดรูปแบบภายในเครื่องหมายอัญประกาศ ("โค้ดรูปแบบ") มิฉะนั้น Excel จะแสดงข้อผิดพลาด

ตัวอย่างของการใช้กล่องโต้ตอบ รูปแบบ > เซลล์ > หมายเลข > กำหนดเอง เพื่อให้ Excel สร้างสตริงรูปแบบให้คุณ

จัดรูปแบบโค้ดตามประเภท

ต่อไปนี้คือตัวอย่างของวิธีการที่คุณสามารถนำรูปแบบตัวเลขต่างๆ ไปใช้กับค่าของคุณโดยใช้กล่องโต้ตอบ จัดรูปแบบเซลล์ แล้วใช้ตัวเลือก กำหนดเอง เพื่อคัดลอก โค้ดรูปแบบ เหล่านั้นไปยังฟังก์ชัน TEXT ของคุณ

ทำไม Excel ลบเลข 0 นำหน้าของฉัน

Excel ถูกออกแบบให้มองหาตัวเลขที่ใส่ในเซลล์ ไม่ใช่ตัวเลขที่ดูเหมือนข้อความ และหมายเลขชิ้นส่วนหรือ SKU เมื่อต้องการเก็บรักษาเลขศูนย์นำหน้า จัดรูปแบบช่วงข้อมูลที่ป้อนเป็นข้อความ ก่อนที่คุณจะวางหรือใส่ค่า เลือกคอลัมน์ หรือช่วงที่คุณจะใส่ค่า แล้วใช้ CTRL+1 เพื่อแสดงกล่องโต้ตอบ รูปแบบ > เซลล์ และบน แท็บตัวเลข ให้เลือก ข้อความ ในตอนนี้ Excel จะเก็บเลข 0 นำหน้าของคุณ

ถ้าคุณใส่ข้อมูลแล้ว Excel นำเลข 0 นำหน้าของคุณออก คุณสามารถใช้ฟังก์ชัน TEXT เพื่อเพิ่มเลขศูนย์คืนได้ คุณสามารถอ้างอิงเซลล์ด้านบนที่มีค่าและใช้ =TEXT(value,”00000”) ที่ตัวเลข 0 ในสูตรแสดงถึงจำนวนรวมของอักขระที่คุณต้องการ แล้วคัดลอกและวางลงในส่วนที่เหลือของช่วง

ตัวอย่างของการใช้ TEXT เพื่อจัดรูปแบบเลขศูนย์นำหน้า =TEXT(A2,”00000”)

ถ้าคุณต้องการแปลงค่าข้อคความกลับเป็นตัวเลขที่คุฯสามารถคูณด้วย 1 เช่น =D4*1 หรือใช้ตัวดำเนินการเอกภาคสองตัว (--) เช่น =--D4

Excel จะคั่นหลักพันด้วยเครื่องหมายจุลภาค ถ้ารูปแบบมีเครื่องหมายจุลภาค (,) ที่อยู่ระหว่างเครื่องหมายตัวเลข (#) หรือเลขศูนย์ ตัวอย่างเช่น ถ้าสตริงรูปแบบเป็น "#,###" Excel จะแสดงตังเลข 12200000 เป็น 12,200,000

เครื่องหมายจุลภาคที่ตามหลังตัวแทนตัวเลขจะปรับขนาดตัวเลขด้วย 1,000 ตัวอย่างเช่น ถ้าเป็นสตริงรูปแบบ "#,###.0," Excel จะแสดงจำนวน 12200000 เป็น 12,200.0

ตัวอย่างของฟังก์ชัน TEXT ที่ใช้ตัวคั่น Thousands

หมายเหตุ: 

  • ตัวคั่นหลักพันจะขึ้นอยู่กับการตั้งค่าภูมิภาคของคุณ ในประเทศสหรัฐอเมริกา จะเป็นเครื่องหมายจุลภาค แต่ในตำแหน่งอื่น อาจเป็นเครื่องหมายมหัพภาค (.)

  • ตัวคั่นหลักพันจะพร้อมใช้งานสำหรับรูปแบบตัวเลข สกุลเงิน และบัญชี

ต่อไปนี้คือตัวอย่างของรูปแบบตัวเลข (ตัวคั่นหลักพันและทศนิยมเท่านั้น) สกุลเงิน และบัญชีมาตรฐาน รูปแบบสกุลเงินจะช่วยให้คุณสามารถแทรกสัญลักษณ์สกุลเงินที่คุณเลือกและจัดแนวถัดจากค่าของคุณ ขณะที่รูปแบบบัญชีจะจัดแนวสัญลักษณ์สกุลเงินไว้ทางด้านซ้ายของเซลล์และค่าอยู่ทางด้านขวา สังเกตความแตกต่างระหว่างโค้ดรูปแบบสกุลเงินและบัญชีทางด้านล่าง ซึ่งบัญชีจะใช้เครื่องหมายดอกจัน (*) เพื่อสร้างการแบ่งระหว่างสัญลักษณ์และค่า

ตัวอย่างของฟังก์ชันข้อความที่มีรูปแบบตัวเลข สกุลเงิน และบัญชี

เมื่อต้องการค้นหาโค้ดรูปแบบสำหรับสัญลักษณ์สกุลเงิน ให้กด Ctrl+1 (หรือ รูปไอคอนปุ่ม Command ของ MAC +1 บน Mac) เลือกรูปแบบที่คุณต้องการ แล้วเลือกสัญลักษณ์จากเมนูดรอปดาวน์ สัญลักษณ์:

เลือกสัญลักษณ์สกุลเงินจากกล่องโต้ตอบการจัดรูปแบบเซลล์

แล้วคลิก กำหนดเอง ทางด้านซ้ายจากส่วน ประเภท และคัดลอกโค้ดรูปแบบ รวมถึงสัญลักษณ์สกุลเงิน

ฟังก์ชัน TEXT - สกุลเงินแบบกำหนดเองพร้อมสัญลักษณ์

หมายเหตุ: ฟังก์ชัน TEXT ไม่สนับสนุนการจัดรูปแบบสี ดังนั้น ถ้าคุณคัดลอกโค้ดรูปแบบตัวเลขจากกล่องโต้ตอบการจัดรูปแบบเซลล์ที่มีสี ดังนี้: $#,##0.00_);[สีแดง]($#,##0.00) ฟังก์ชัน TEXT จะยอมรับโค้ดรูปแบบ แต่จะไม่แสดงสี

คุณสามารถเปลี่ยนวิธีการแสดงวันที่โดยใช้การผสมของ "M" สำหรับเดือน "D" วัน และ "Y" สำหรับปี

รหัสรูปแบบเดือน วัน และปี

โค้ดรูปแบบในฟังก์ชัน TEXT จะไม่สนใจตัวพิมพ์ของตัวอักษร เพื่อให้คุณสามารถใช้ "M" หรือ "m", "D" หรือ "d", "Y" หรือ "y"

Excel MVP Mynda Treacy

Mynda แนะนำว่า...

ถ้าคุณแชร์ไฟล์และรายงาน Excel กับผู้ใช้จากประเทศต่างๆ แล้วคุณต้องการให้พวกเขาได้รับรายงานเป็นภาษาของพวกเขา Excel MVP, Mynda Treacy มีโซลูชันที่ยอดเยี่ยมในบทความ วันที่ Excel ที่แสดงเป็นภาษาต่างๆ นี้ ซึ่งยังมีเวิร์กบุ๊กตัวอย่างที่คุณสามารถดาวน์โหลดได้

คุณสามารถเปลี่ยนวิธีการแสดงเวลาโดยใช้การผสมของ "H" สำหรับชั่วโมง "M" สำหรับนาที หรือ "S" สำหรับวินาที และ "AM/PM" สำหรับนาฬิกาแบบ 12 ชั่วโมง

รูปแบบเวลาสำหรับชั่วโมง นาที และวินาที

ถ้าคุณปล่อยให้เป็น "AM/PM" หรือ " A/P " เวลาจะแสดงตามนาฬิกาแบบ 24 ชั่วโมง

โค้ดรูปแบบในฟังก์ชัน TEXT จะไม่สนใจตัวพิมพ์ของตัวอักษร เพื่อให้คุณสามารถใช้ "H" หรือ "h", "M" หรือ "m", "S" หรือ "s", "AM/PM" หรือ "am/pm"

คุณสามารถเปลี่ยนแปลงการแสดงค่าทศนิยมด้วยรูปแบบเปอร์เซ็นต์ (%)

จัดรูปแบบรหัสสำหรับเปอร์เซ็นต์

คุณสามารถเปลี่ยนแปลงการแสดงค่าทศนิยมด้วยรูปแบบเศษส่วน (?/?)

จัดรูปแบบรหัสสำหรับเศษส่วน

เครื่องหมายทางวิทยาศาสตร์ คือวิธีการแสดงตัวเลขเป็นทศนิยมระหว่าง 1 ถึง 10 ยกกำลังด้วย 10 บ่อยครั้ง จะใช้เพื่อทำให้การแสดงตัวเลขจำนวนมากสั้นลง

รหัสรูปแบบสำหรับเครื่องหมายทางวิทยาศาสตร์

Excel มีรูปแบบพิเศษ 4 รูปแบบ:

  • รหัสไปรษณีย์ - "00000"

  • รหัสไปรษณีย์ + 4 - "00000-0000"

  • หมายเลขโทรศัพท์ - "[<=9999999]###-####;(###) ###-####"

  • หมายเลขประกันสังคม - "000-00-0000"

รูปแบบพิเศษสำหรับฟังก์ชัน TEXT

รูปแบบพิเศษจะแตกต่างกันขึ้นอยู่กับตำแหน่งที่ตั้ง แต่ถ้าไม่มีรูปแบบพิเศษสำหรับตำแหน่งที่ตั้งของคุณ หรือถ้ารูปแบบเหล่านี้ไม่ใช่สิ่งที่คุณต้องการ คุณสามารถสร้างรูปแบบของคุณเองผ่านทาง จัดรูปแบบเซลล์ > กล่องข้อความ กำหนดเอง

สถานการณ์ทั่วไป

ฟังก์ชัน TEXT จะถูกใช้ด้วยตัวฟังก์ชันน้อยครั้ง และจะถูกใช้บ่อยครั้งในการรวมกับสิ่งอื่น สมมติว่าคุณต้องการรวมข้อความกับค่าตัวเลข เช่น “พิมพ์รายงานเมื่อ: 03/14/12" หรือ "รายได้รายสัปดาห์: $66,348.72" คุณสามารถพิมพ์ข้อมูลนั้นลงใน Excel ได้ด้วยตนเอง แต่จะเป็นการยกเลิกวัตถุประสงค์ให้ Excel ทำงานนี้ให้คุณ น่าเสียดาย เมื่อคุณรวมข้อความและตัวเลขที่มีการจัดรูปแบบ เช่น วันที่ เวลา สกุลเงิน เป็นต้น แล้ว Excel ไม่ทราบว่าคุณต้องการแสดง จึงละการจัดรูปรูปแบบตัวเลข นี่คือจุดที่ฟังก์ชัน TEXT มีประโยชน์มาก เนื่องจากจะทำให้คุณบังคับให้ Excel จัดรูปแบบค่าด้วยวิธีที่คุณต้องการโดยใช้ โค้ดรูปแบบ เช่น "MM/DD/YY" สำหรับรูปแบบวันที่

ในตัวอย่างต่อไปนี้ คุณจะเห็นสิ่งที่เกิดขึ้นถ้าคุณลองรวมข้อความกับตัวเลขโดยไม่ใช้ฟังก์ชัน TEXT ในกรณีนี้ เราจะใช้ เครื่องหมาย (&) ในการเรียงสตริงข้อความ ช่องว่าง (“ “) และค่าให้ต่อกันด้วย =A2&” “&B2

ตัวอย่างของข้อความติดกัน โดยไม่มีฟังก์ชัน TEXT

ตามที่คุณเห็น Excel จะนำการจัดรูปแบบออกจากวันที่ในเซลล์ B2 ในตัวอย่างถัดไป คุณจะเห็นวิธีที่ฟังก์ชัน TEXT ช่วยให้คุณนำรูปแบบที่คุณต้องการไปใช้

ตัวอย่างของข้อความติดกัน โดยมีฟังก์ชัน TEXT

สูตรที่อัปเดตของเราคือ:

  • เซลล์ C2:=A2&" "&TEXT(B2,"mm/dd/yy") - รูปแบบข้อมูล

คำถามที่ถามบ่อย

น่าเสียดายที่คุณไม่สามารถทำสิ่งนั้นได้ด้วยฟังก์ชัน TEXT คุณต้องใช้โค้ดของ Visual Basic for Applications (VBA) ลิงก์ต่อไปนี้มีวิธีการ: วิธีการแปลงค่าตัวเลขเป็นคำภาษาอังกฤษใน Excel

ใช่ คุณสามารถใช้ฟังก์ชัน UPPER, LOWER และ PROPER ตัวอย่างเช่น =UPPER("hello") จะส่งกลับ "HELLO"

ได้ แต่จะต้องทำตามขั้นตอน ก่อนอื่น ให้เลือกเซลล์ที่คุณต้องการและใช้ Ctrl+1 เพื่อแสดงกล่องโต้ตอบ รูปแบบ > เซลล์ > แล้ว จัดแนว > ควบคุมข้อความ > ตรวจสอบตัวเลือก ตัดข้อความ จากนั้น ให้ปรับฟังก์ชัน TEXT ที่สมบูรณ์ของคุณเพื่อรวมฟังก์ชัน ASCII CHAR (10) ที่คุณต้องการใช้ตัวแบ่งบรรทัด คุณอาจต้องปรับความกว้างคอลัมน์ของคุณ โดยขึ้นอยู่กับวิธีการจัดแนวของผลลัพธ์สุดท้าย

ตัวอย่างของการใช้ TEXT ที่มี CHAR(10) เพื่อแทรกตัวแบ่งบรรทัด =”Today is: “&CHAR(10))&TEXT(TODAY(),”MM/DD/YY”)

ในกรณีนี้ เราใช้: =”Today is: “&CHAR(10)&TEXT(TODAY(),”mm/dd/yy”)

สิ่งนี้เรียกว่า เครื่องหมายทางวิทยาศาสตร์ และ Excel จะแปลงตัวเลขที่มีความยาวมากกว่า 12 หลักโดยอัตโนมัติ ถ้าเซลล์ถูกจัดรูปแบบเป็น ทั่วไป และมี 15 หลัก ถ้าเซลล์ถูกจัดรูปแบบเป็น จำนวน ถ้าคุณต้องการใส่สตริงตัวเลขที่ยาว แต่ไม่ต้องการแปลง ให้จัดรูปแบบเซลล์ในคำถามเป็น ข้อความ ก่อนที่คุณจะป้อนข้อมูลหรือวางค่าของคุณลงใน Excel

Excel MVP Mynda Treacy

Mynda แนะนำว่า...

ถ้าคุณแชร์ไฟล์และรายงาน Excel กับผู้ใช้จากประเทศต่างๆ แล้วคุณต้องการให้พวกเขาได้รับรายงานเป็นภาษาของพวกเขา Excel MVP, Mynda Treacy มีโซลูชันที่ยอดเยี่ยมในบทความ วันที่ Excel ที่แสดงเป็นภาษาต่างๆ นี้ ซึ่งยังมีเวิร์กบุ๊กตัวอย่างที่คุณสามารถดาวน์โหลดได้

ดูเพิ่มเติม

สร้างหรือลบรูปแบบตัวเลขแบบกำหนดเอง

แปลงข้อความเป็นตัวเลข

ฟังก์ชัน Excel ทั้งหมด (ตามประเภท)

ขยายทักษะของคุณ
สำรวจการฝึกอบรม
รับฟีเจอร์ใหม่ก่อนใคร
เข้าร่วม Office Insider

ข้อมูลนี้เป็นประโยชน์หรือไม่

ขอบคุณสำหรับคำติชมของคุณ!

ขอขอบคุณสำหรับคำติชมของคุณ! เราคิดว่าอาจเป็นประโยชน์ที่จะให้คุณได้ติดต่อกับหนึ่งในตัวแทนฝ่ายสนับสนุน Office ของเรา

×