คุณสมบัติ PrtDevMode

นำไปใช้กับ

วัตถุ Form

วัตถุ Report

คุณสามารถใช้คุณสมบัติ PrtDevMode เพื่อตั้งค่าหรือส่งกลับข้อมูลโหมดอุปกรณ์พิมพ์ที่ระบุไว้สำหรับฟอร์มหรือรายงานในกล่องโต้ตอบ พิมพ์ อ่าน/เขียน ตัวแปร

นิพจน์ PrtDevMode

จำเป็นต้องมี นิพจน์ นิพจน์ที่ส่งกลับวัตถุใดวัตถุหนึ่งในรายการ นำไปใช้กับ

ข้อสังเกต

เราขอแนะนำให้คุณดูชุดพัฒนาซอฟต์แวร์ Win32 สำหรับเอกสารที่สมบูรณ์เกี่ยวกับคุณสมบัติ PrtDevMode, PrtDevNames และ PrtMip

การตั้งค่าคุณสมบัติ PrtDevMode คือโครงสร้าง 94 ไบต์ที่คล้ายกับโครงสร้าง DEVMODE มีคำอธิบายอยู่ในชุดพัฒนาซอฟต์แวร์ Win32 สำหรับข้อมูลที่สมบูรณ์เกี่ยวกับรายการคุณสมบัติ PrtDevMode ให้ดูชุดพัฒนาซอฟต์แวร์ Win32

คุณสมบัติ PrtDevMode จะใช้รายการต่อไปนี้

สมาชิก

คำอธิบาย

DeviceName

สตริง ที่มีขนาดสูงสุด 32 ไบต์ที่ระบุชื่ออุปกรณ์และโปรแกรมควบคุมที่สนับสนุน ตัวอย่างเช่น "HP LaserJet IIISi" เมื่อ Hewlett-Packard LaserJet IIISi คือเครื่องพิมพ์ที่ระบุ โปรแกรมควบคุมเครื่องพิมพ์แต่ละโปรแกรมที่สตริงที่ไม่ซ้ำกัน

SpecVersion

จำนวนเต็มที่ระบุหมายเลขเวอร์ชันของโครงสร้าง DEVMODE ในชุดการพัฒนาซอฟต์แวร์ Win32

DriverVersion

จำนวนเต็ม ที่ระบุหมายเลขเวอร์ชันของโปรแกรมควบคุมเครื่องพิมพ์ที่กำหนดโดยนักพัฒนาโปรแกรมควบคุมเครื่องพิมพ์

ขนาด

จำนวนเต็ม ที่ระบุขนาดเป็นไบต์ของโครงสร้าง DEVMODE (ค่านี้ไม่รวมรายการ dmDriverData เสริมสำหรับข้อมูลจำเพาะของอุปกรณ์ ซึ่งสามารถทำตามโครงสร้างนี้) ถ้าแอปพลิเคชันจัดการเฉพาะส่วนข้อมูลที่ไม่ใช้โปรแกรมควบคุม คุณสามารถใช้รายการนี้เพื่อค้นหาความยาวหรือโครงสร้างนี้ได้โดยไม่ต้องใช้เวอร์ชันอื่น

DriverExtra

จำนวนเต็มที่ระบุขนาด เป็นหน่วยไบต์ ของรายการ dmDriverData เสริมสำหรับข้อมูลจำเพาะของอุปกรณ์ ซึ่งสามารถทำตามโครงสร้างนี้ ถ้าแอปพลิเคชัยไม่ได้ใช้ข้อมูลจำเพาะของอุปกรณ์ คุณสามารถตั้งค่ารายการนี้เป็น 0

เขตข้อมูล

ค่าแบบยาวที่ระบุว่ารายการที่เหลือในโครงสร้าง DEVMODE ถูกเตรียมใช้งานหรือไม่

การวางแนว

จำนวนเต็ม ที่ระบุการวางแนวหน้ากระดาษ ซึ่งสามารถเป็น 1 (แนวตั้ง) หรือ 2 (แนวนอน)

PaperSize

จำนวนเต็ม ที่ระบุขนาดของกระดาษที่จะพิมพ์ ถ้าคุณตั้งค่ารายการนี้เป็น 0 หรือ 256 ความยาวและความกว้างของกระดาษจะถูกระบุโดยรายการ PaperLength และ PaperWidth ตามลำดับ มิฉะนั้น คุณสามารถตั้งค่ารายการ PaperSize ให้เป็นค่าที่กำหนดไว้ล่วงหน้าได้

PaperLength

จำนวนเต็ม ที่ระบุความยาวหน้ากระดาษเป็นหน่วย 1/10 มิลลิเมตร รายการนี้จะแทนที่ความยาวกระดาษที่ระบุโดยรายการ PaperSize สำหรับขนาดกระดาษแบบกำหนดเองหรืออุปกรณ์ เช่น เครื่องพิมพ์ดอตแมทริกซ์ที่สามารถพิมพ์กระดาษได้หลายขนาด

PaperWidth

จำนวนเต็ม ที่ระบุความกว้างหน้ากระดาษเป็นหน่วย 1/10 มิลลิเมตร รายการนี้จะแทนที่ความกว้างกระดาษที่ระบุโดยรายการ PaperSize

มาตราส่วน

จำนวนเต็ม ที่ระบุอัตราส่วนตามสิ่งที่พิมพ์ที่จะถูกปรับขนาด ขนาดหน้าที่ปรากฎถูกปรับขนาดจากขนาดหน้าจริงตามอัตราส่วน มาตราส่วน/100 ตัวอย่างเช่น กระดาษที่มีขนาด 8.5 และ 11 นิ้ว (ขนาดจดหมาย) ที่ค่ามาตราส่วน 50 อาจมีข้อมูลเท่ากับหน้าที่มีขนาด 17 และ 22 นิ้ว เนื่องจากข้อความและกราฟิกที่พิมพ์จะมีขนาดครึ่งหนึ่งของความสูงและความกว้างดั้งเดิม

สำเนา

จำนวนเต็มที่ระบุจำนวนสำเนาที่พิมพ์ ถ้าอุปกรณ์พิมพ์สนับสนุนสำเนาหลายหน้า

DefaultSource

จำนวนเต็ม ที่ระบุถาดป้อนกระดาษเริ่มต้นที่ใช้ป้อนกระดาษ

PrintQuality

จำนวนเต็ม ที่ระบุความละเอียดของเครื่องพิมพ์ ค่าคือ –4 (สูง), –3 (ปานกลาง), –2 (ต่ำ) และ –1 (แบบร่าง)

สี

จำนวนเต็ม สำหรับเครื่องพิมพ์สี ให้ระบุว่าจะพิมพ์เป็นแบบสีหรือไม่ ค่าคือ 1 (สี) และ 2 (ขาวดำ)

พิมพ์สองด้าน

จำนวนเต็ม สำหรับเครื่องพิมพ์ที่สนับสนุนการพิมพ์สองด้าน ให้ระบุว่าจะพิมพ์บนกระดาษทั้งสองด้านหรือไม่ ค่าคือ 1 (ทางเดียว), 2 (แนวนอน) และ 3 (แนวตั้ง)

YResolution

จำนวนเต็ม ที่ระบุความละเอียด y ของเครื่องพิมพ์เป็นหน่วย จุดต่อนิ้ว (dpi) ถ้าเครื่องพิมพ์เตรียมใช้งานรายการนี้ รายการ PrintQuality จะระบุความละเอียด x ของเครื่องพิมพ์เป็นหน่วย dpi

TTOption

จำนวนเต็ม ที่ระบุวิธีการพิมพ์ฟอนต์ TrueType

ทีละชุด

จำนวนเต็ม ที่ระบุว่าควรใช้การพิมพ์ทีละชุดเมื่อพิมพ์สำเนาหลายฉบับหรือไม่ การใช้สำเนาแบบไม่เรียงทีละชุดจะพิมพ์ได้เร็วและมีประสิทธิภาพมากขึ้น เนื่องจากข้อมูลถูกส่งไปยังเครื่องพิมพ์เพียงครั้งเดียว

FormName

สตริงที่มีความยาวสูงสุด 16 อักขระที่ระบุขนาดกระดาษที่จะใช้ ตัวอย่างเช่น “จดหมาย” หรือ “Legal”

Pad

ค่า แบบยาว ที่ใช้ขยายช่องว่าง อักชระ หรือค่าสำหรับเวอร์ชันในอนาคต

บิต

ค่า แบบยาว ที่ระบุเป็นหน่วย บิตต่อพิกเซล ของความละเอียดสีของอุปกรณ์แสดงผล

PW

ค่า แบบยาว ที่ระบุความกว้าง เป็นพิกเซล ของพื้นที่แสดงผลของอุปกรณ์ (หน้าจอหรือเครื่องพิมพ์)

PH

ค่า แบบยาว ที่ระบุความสูง เป็นพิกเซล ของพื้นที่แสดงผลของอุปกรณ์ (หน้าจอหรือเครื่องพิมพ์)

DFI

ค่า แบบยาว ที่ระบุโหมดแสดงผลของอุปกรณ์

DFR

ค่า แบบยาว ที่ระบุความถี่ เป็นหน่วยเฮิรตซ์ (รอบต่อวินาที) ของอุปกรณ์แสดงผลในบางโหมด


หมายเหตุ: คุณสามารถตั้งค่าคุณสมบัติ PrtDevMode โดยใช้โค้ด Visual Basic for Applications (VBA)

การตั้งค่าคุณสมบัตินี้เป็นแบบ อ่าน/เขียน ในมุมมองออกแบบหรือมุมมองเค้าโครง และเป็นแบบอ่านอย่างเดียวในมุมมองอื่นๆ

โปรแกรมควบคุมเครื่องพิมพ์สามารถเพิ่มข้อมูลจำเพาะของอุปกรณ์ต่อจาก 94 ไบต์ของโครงสร้าง DEVMODE ด้วยสาเหตุนี้ จึงเป็นสิ่งสำคัญที่ข้อมูล DEVMODE ที่ระบุไว้ข้างต้นต้องมีขนาดไม่เกิน 94 ไบต์

โปรแกรมควบคุมเครื่องพิมพ์ที่ส่งออกฟังก์ชัน ExtDeviceMode เท่านั้นที่ใช้โครงสร้าง DEVMODE

แอปพลิเคชันสามารถรับขนาดและชื่อกระดาษที่เครื่องพิมพ์สนับสนุนโดยใช้ค่า DC_PAPERS, DC_PAPERSIZE และ DC_PAPERNAMES เพื่อเรียกใช้ฟังก์ชัน DeviceCapabilities

ก่อนที่จะตั้งค่ารายการ TTOption แอปพลิเคชันควรค้นหาวิธีการใช้ฟอนต์ TrueType ของเครื่องพิมพ์โดยใช้ค่า DC_TRUETYPE เพื่อเรียกใช้ฟังก์ชัน DeviceCapabilities

ตัวอย่าง

ตัวอย่างต่อไปนี้จะใช้คุณสมบัติ PrtDevMode เพื่อตรวจสอบขนาดหน้าที่กำหนดโดยผู้ใช้สำหรับรายงาน

Private Type str_DEVMODE
RGB As String * 94
End Type
Private Type type_DEVMODE
strDeviceName As String * 32
intSpecVersion As Integer
intDriverVersion As Integer
intSize As Integer
intDriverExtra As Integer
lngFields As Long
intOrientation As Integer
intPaperSize As Integer
intPaperLength As Integer
intPaperWidth As Integer
intScale As Integer
intCopies As Integer
intDefaultSource As Integer
intPrintQuality As Integer
intColor As Integer
intDuplex As Integer
intResolution As Integer
intTTOption As Integer
intCollate As Integer
strFormName As String * 32
lngPad As Long
lngBits As Long
lngPW As Long
lngPH As Long
lngDFI As Long
lngDFr As Long
End Type
Public Sub CheckCustomPage(ByVal rptName As String)
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
Dim intResponse As Integer
' Opens report in Design view.
DoCmd.OpenReport rptName, acDesign
Set rpt = Reports(rptName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
' Gets current DEVMODE structure.
DevString.RGB = strDevModeExtra
LSet DM = DevString
If DM.intPaperSize = 256 Then
' Display user-defined size.
intResponse = MsgBox("The current custom page size is " & _
DM.intPaperWidth / 254 & " inches wide by " & _
DM.intPaperLength / 254 & " inches long. Do you want " & _
"to change the settings?", vbYesNo + vbQuestion)
Else
' Currently not user-defined.
intResponse = MsgBox("The report does not have a custom page size. " & _
"Do you want to define one?", vbYesNo + vbQuestion)
End If
If intResponse = vbYes Then
' User wants to change settings. Initialize fields.
DM.lngFields = DM.lngFields Or DM.intPaperSize Or _
DM.intPaperLength Or DM.intPaperWidth
' Set custom page.
DM.intPaperSize = 256
' Prompt for length and width.
DM.intPaperLength = InputBox("Please enter page length in inches.") * 254
DM.intPaperWidth = InputBox("Please enter page width in inches.") * 254
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
End If
Set rpt = Nothing
End Sub

ตัวอย่างต่อไปนี้แสดงวิธีการเปลี่ยนการวางแนวของรายงาน ตัวอย่างนี้จะสลับการวางแนวจากแนวตั้งเป็นแนวนอนหรือจากแนวนอนเป็นแนวตั้ง โดยขึ้นอยู่กับการวางแนวปัจจุบันของรายงาน

Public Sub SwitchOrient(ByVal strName As String)
Const DM_PORTRAIT = 1
Const DM_LANDSCAPE = 2
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
' Opens report in Design view.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
DevString.RGB = strDevModeExtra
LSet DM = DevString
DM.lngFields = DM.lngFields Or DM.intOrientation
' Initialize fields.
If DM.intOrientation = DM_PORTRAIT Then
DM.intOrientation = DM_LANDSCAPE
Else
DM.intOrientation = DM_PORTRAIT
End If
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
Set rpt = Nothing
End Sub
ขยายทักษะของคุณ
สำรวจการฝึกอบรม
รับฟีเจอร์ใหม่ก่อนใคร
เข้าร่วม Office Insider

ข้อมูลนี้เป็นประโยชน์หรือไม่

ขอบคุณสำหรับคำติชมของคุณ!

ขอขอบคุณสำหรับคำติชมของคุณ! เราคิดว่าอาจเป็นประโยชน์ที่จะให้คุณได้ติดต่อกับหนึ่งในตัวแทนฝ่ายสนับสนุน Office ของเรา

×