Gäller för
|
Application-objekt |
Returnerar ett FileDialog-objekt som representerar en enda instans av en fildialogruta.
uttryck.FileDialog(dialogType)
Uttryck Obligatoriskt. Ett uttryck som returnerar ett av objekten i listan Gäller för.
dialogType krävs MsoFileDialogType . Typ av fildialogruta.
|
MsoFileDialogType kan vara en av dessa MsoFileDialogType-konstanter. |
|
msoFileDialogFilePicker |
|
msoFileDialogFolderPicker |
|
msoFileDialogOpen Stöds inte i Microsoft Access. |
|
msoFileDialogSaveAs Stöds inte i Microsoft Access. |
Kommentarer
Konstanterna msoFileDialogOpen och msoFileDialogSaveAs stöds inte i Microsoft Office Access 2007.
Exempel
Det här exemplet visar hur du använder objektet FileDialog för att visa en dialogruta som låter användaren välja en eller flera filer. De markerade filerna läggs sedan till en listrutan med namnet FileList.
Private Sub cmdFileDialog_Click()
' Requires reference to Microsoft Office 11.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
' Clear listbox contents.
Me.FileList.RowSource = ""
' Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
' Allow user to make multiple selections in dialog box
.AllowMultiSelect = True
' Set the title of the dialog box.
.Title = "Please select one or more files"
' Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.ACCDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"
' Show the dialog box. If the .Show method returns True, the
' user picked at least one file. If the .Show method returns
' False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub
