Funktionen SUMMA

Du lägger till värden med funktionen SUMMA, som ingår i matematiska och trigonometriska funktioner. Du kan lägga till enskilda värden, cellreferenser eller områden eller en blandning av alla tre.

Till exempel:

  • =SUMMA(A2:A10)

  • =SUMMA(A2:A10, C2:C10)

Din webbläsare har inte stöd för video. Installera Microsoft Silverlight, Adobe Flash Player eller Internet Explorer 9.

Det här videoklippet ingår i kursen Addera tal i Excel 2013.

SUMMA(tal1,[tal2],...)

Argumentnamn

Beskrivning

tal1   . (obligatoriskt)

Det första talet som ska läggas till. Det kan vara en siffra som 4, en cellreferens som B6 eller ett cell- område som B2:B8.

tal2-255    (valfritt)

Det här är det andra talet du vill lägga till. Du kan ange upp till 255 tal på det här sättet.

Om du snabbt vill få fram summan av ett cellområde behöver du bara markera området och titta längst ned till höger i Excel-fönstret.

Skärmbild av markering av ett cellområde, och titta sedan i statusfältet.
Statusfält


Det här är statusfältet som visar information om vad du har markerat, om det är en enstaka cell eller flera celler. Om du högerklickar i statusfältet visas en funktionsdialogruta som visar alla alternativ som du kan välja. Observera att det även visar värden för det markerade området om de attributen är markerade. Läs mer om statusfältet.

Det enklaste sättet att lägga till en SUMMA-formel i kalkylbladet är att använda guiden Autosumma. Markera en tom cell direkt ovanför eller nedanför det område du vill summera. På fliken Start eller Formel i menyfliksområdet trycker du på Autosumma > Summa. Guiden Autosumma kan automatiskt känna av området för att sammanfatta och skapa formeln åt dig. Det fungerar även vågrätt om du markerar en cell åt vänster eller höger i området som ska summeras. Observera att det inte går att arbeta med osammanhängande intervall, men vi ska gå igenom det i nästa avsnitt.

Du kan använda guiden Autosumma för att automatiskt skapa en Summa-formel.  Välj ett område ovanför/nedanför eller till vänster/höger om området som ska summeras och gå till fliken Formel i menyfliksområdet och markera Autosumma och SUMMA.
Använda guiden Autosumma för att snabbt summera angränsande områden


I dialogrutan Autosumma kan du välja andra vanliga funktioner som:

Autosumma lodrätt

Cell D6 visar summaformeln för Autosumma: =SUMMA(B2:B5)

Guiden Autosumma har automatiskt upptäckt att cellerna B2:B5 är området som ska summeras. Allt du behöver göra är att bekräfta det är att trycka på RETUR. Om du behöver lägga till/utelämna fler celler kan du hålla ned Skift > valfri piltangent tills ditt val matchar det du önskar och trycka på RETUR när du är klar.

IntelliSense-funktionsguide: SUMMANS (tal1, [tal2], ...) flytande tagg under den här funktionen är dess Intellisense-guide. Om du klickar på SUMMA eller namnet på funktionen ändras den till en blå hyperlänk som tar dig till hjälpavsnittet för funktionen. Om du klickar på de enskilda funktionselement markeras deras representativa delar i formeln. I det här fallet skulle endast B2:B5 markeras eftersom det finns bara en talreferens i den här formeln. Intellisense-taggen visas för vilken funktion som helst.

Autosumma vågrätt

Cell D2 visar summaformeln för Autosumma: =SUMMA(B2:C2)

Användning av SUMMA med osammanhängande områden.  Formeln i cell C8 är =SUMMA(C2:C3,C5:C6). Du kan också använda namngivna områden, så att formeln skulle bli =SUMMA(Vecka1,Vecka2)

Guiden Autosumma fungerar oftast bara för angränsande områden, så om du har tomma rader eller kolumner i summaområdet stoppar Excel vid det första mellanrummet. Då skulle du behöva SUMMA baserat på val, där du lägger till enskilda områden ett i taget. Om du skulle ha data i cell B4 i det här exemplet skulle Excel generera =SUMMA(C2:C6) eftersom det skulle känna igen ett angränsande område.

Du kan snabbt markera flera icke angränsande intervall med Ctrl + vänsterklick. Ange först ”=SUMMA(”, välj sedan dina olika intervall så lägger Excel automatiskt till kommaavgränsare mellan intervallen åt dig. Tryck på Retur när du är klar.

TIPS! Med ALT+ = kan du snabbt lägga till funktionen SUMMA till en cell. Allt du behöver göra sedan är att välja område(n).

Obs! Du kanske märker att Excel har markerat olika funktionsområden med färg, och de överensstämmer inom själva formeln så C2:C3 har en färg och C5:C6 en annan. Excel gör det här för alla funktioner, såvida inte området som refereras är på ett annat kalkylblad eller i en annan arbetsbok. Du kan använda namngivna områden som "Vecka1" och "Vecka2", och referera till dem i en formel för bättre åtkomst med tekniska hjälpmedel:

=SUMMA(Vecka1,Vecka2)

Du kan enkelt utföra matematiska operationer med Excel på egen hand och genom att använda Excel-funktioner som SUMMA. I följande tabell visas operatorer som du kan använda samt vissa relaterade funktioner. Du kan ange operatorerna med hjälp av siffertangenterna på ditt tangentbord eller det numeriska tangentbordet (10 tangenter) om du har ett. Med Skift+8 kan du till exempel ange asterisken (*) för multiplikation.

Operator

Åtgärd

Exempel

+

Addition

=1+1

=A1+B1

=SUMMA(A1:A10)+10

=SUMMA(A1:A10)+B1

-

Subtraktion

=1-1

=A1-B1

=SUMMA(A1:A10)-10

=SUMMA(A1:A10)-B1

*

Multiplikation

=1*1

=A1*B1

=SUMMA(A1:A10)*10

=SUMMA(A1:A10)*B1

=PRODUKT(1,1) - Funktionen PRODUKT

/

Division

=1/1

=A1/B1

=SUMMA(A1:A10)/10

=SUMMA(A1:A10)/B1

=KVOT(1,1) - Funktionen KVOT

^

Exponentiering

=1^1

=A1^B1

=SUMMA(A1:A10)^10

=SUMMA(A1:A10)^B1

=UPPHÖJT.TILL(1,1) - Funktionen UPPHÖJT.TILL

Mer information finns i Använda Excel som miniräknare.

Andra exempel

  1. Anta att du vill använda en procentuell rabatt till ett område med celler som du har summerat.

    Använd operatorer med SUMMA.  Formeln i cell B16 är =SUMMA(A2:A14)*-25%.  Formeln skulle skapas korrekt om -25% var en cellreferens i stället, t.ex. = SUMMA(A2:A14)*E2
    • =SUMMA(A2:A14)*-25%

    skulle ge dig 25 % av det summerade området, men det hårdkodar 25 % i formeln och det kan vara svårt att hitta den senare om du behöver ändra den. Det är mycket bättre att placera dessa 25 % i en cell och referera till den istället där den är öppen och enkel att ändra, så här:

    • =SUMMA(A2:A14)*E2

    För att dividera istället för att multiplicera ersätter du bara ”*” med ”/”: =SUMMA(A2:A14)/E2

  2. Addera eller subtrahera från en SUMMA

    i. Du kan enkelt addera eller subtrahera från en summa med hjälp av + eller - så här:

    • =SUMMA(A1:A10)+E2

    • =SUMMA(A1:A10)-E2

I det här avsnittet beskrivs några beprövade metoder för att arbeta med SUMMA-funktionen. Mycket av det här kan användas för att arbeta med andra funktioner också.

Metoden =1+2 eller =A+B – Du kan skriva =1+2+3 eller =A1+B1+C2 och få helt korrekta resultat, men de här metoderna blir lätt fel av flera orsaker:

  1. Skrivfel – föreställ dig att du försöker ange fler och/eller mycket större värden som dessa:

    • =14598.93+65437.90+78496.23

    Försök att verifiera att posterna är korrekta. Det är mycket enklare att placera dessa värden i enskilda celler och använda en SUMMA-formel. Du kan också formatera värdena när de är i celler, vilket gör dem mycket mer lättlästa sedan när de ingår i en formel.

    Använda funktionen SUMMA i stället för hårdkodningsvärden i formler.  Formeln i cell D5 är =SUMMA(D2:D4)
  2. #VÄRDE!-fel vid referens till text istället för siffror

    Om du använder en formel som:

    • =A1+B1+C1 or =A1+A2+A3

    Exempel på en dålig formelkonstruktion.  Formeln i cell D2 är =A2+B2+C2

    Formeln kan bli fel om det finns icke-numeriska värden (text) i de refererade cellerna, som returnerar ett #VÄRDE!-fel. SUMMA ignorerar textvärden och ger dig bara summan av numeriska värden.

    Rätt formelkonstruktion.  Istället för =A2+B2+C2 är formeln för cell D2 =SUMMA(A2:C2)
  3. #REFERENS!-fel vid borttagning av rader eller kolumner

    #REFERENS!-fel som orsakas genom att en kolumn har tagits bort.  Formeln har ändrats till =A2+#REFERENS!+B2

    Om du tar bort en rad eller en kolumn uppdateras inte formeln så att den exkluderar den borttagna raden, och ett #REFERENS!-fel uppstår där en SUMMA-funktion uppdateras automatiskt.

    SUMMA-funktionen justeras automatiskt för infogade eller borttagna rader och kolumner
  4. Formler uppdaterar inte referenser när du infogar rader eller kolumner

    =A+B+C-formler uppdateras inte om du lägger till rader

    Om du infogar en rad eller kolumn uppdateras inte formeln så att den inkluderar den tillagda raden där en SUMMA-funktion uppdateras automatiskt (förutsatt att du inte är utanför området som formeln refererar till). Det här är extra viktigt om du förväntar dig att formeln ska uppdatera och inte gör det, eftersom det ger dig ofullständiga resultat som du kanske inte upptäcker.

    Exemplet återger en SUMMA-formel som automatiskt expanderade från =SUMMA(A2:C2) till =SUMMA(A2:D2) när en kolumn infogades
  5. SUMMA med enskilda cellreferenser jämfört med Områden

    Med hjälp av en formel som:

    • =SUMMA(A1,A2,A3,B1,B2,B3)

    blir det lika lätt fel när du infogar eller tar bort rader i det refererade området av samma orsaker. Det är mycket bättre att använda enskilda områden som:

    • =SUMMA(A1:A3,B1:B3)

    som uppdateras när du lägger till eller tar bort rader.

  1. Du kan absolut använda SUMMA med andra funktioner. Här är ett exempel som skapar en månatlig medelvärdesberäkning:

    Använda SUMMA med andra funktioner.  Formeln i cell M2 är=SUMMA(A2:L2)/ANTALV(A2:L2)  Obs! Kolumnerna maj-november döljs för tydlighetens skull.
    • =SUMMM(A2:L2)/ANTALV(A2:L2)

  2. vilket tar SUMMAN i A2:L2 dividerat med antalet ej tomma celler i A2:L2 (maj till december är tomt).

  1. Ibland behöver du summera en viss cell i flera kalkylblad. Det kan vara frestande att klicka på varje blad och cell du vill ha och bara använda ”+” för att lägga till cellvärdena, men det är omständligt och kan skapa fel.

    • =Blad1!A1+Blad2!A1+Blad3!A1

    Du kan göra det mycket enklare med en 3D- eller 3-dimensionell SUMMA:

    3D-SUMMA – Formeln i cell D2 är =SUMMA(Blad1:Blad3!A2)
    • =SUMMA(Blad1:Blad3!A1)

    Detta summerar cellen i A1 i alla blad från Blad 1 till 3.

    Detta är särskilt praktiskt i situationer där du har ett enda blad för varje månad (januari-december) och du behöver summera dem på ett sammanfattningsblad.

    3D-SUMMAN för det namngivna bladet.  Formeln i D2 är=SUMMA(januari:december!A2)
    • =SUMMA(januari:december!A2)

    Detta summerar cell A2 i varje blad från januari till december.

    Meddelanden: Om kalkylbladets namn innehåller blanksteg, som "försäljning i januari", måste du använda en apostrof när du refererar till kalkylbladets namn i en formel: Lägg märke till apostrofen föredet första kalkylbladsnamnet, och igen efter det sista.

    • =SUMMA(’försäljning i januari:försäljning i december’!A2)

    3D-metoden fungerar även med andra funktioner som medel, MIN, MAX, osv:

    • = MEDEL(Ark1:Ark3! A1)

    • = MIN(Ark1:Ark3! A1)

    • = MAX(Ark1:Ark3! A1)

Problem

Vad gick fel

Min SUMMA-funktion visar #####, inte resultatet.

Kontrollera kolumnbredden. ##### innebär vanligtvis att kolumnen är för smal för att visa resultatet av formeln.

SUMMA-funktionen visar själva formeln som text, inte resultatet.

Kontrollera att cellen inte är formaterad som text. Markera cellen eller området i fråga och använd Ctrl+1 så att dialogrutan Formatera celler visas, och klicka på fliken Tal och välj det format du vill ha. Om cellen är formaterad som text och inte ändras när du ändrar formatet kan du behöva använda F2 > RETUR för att tvinga format att ändras.

Funktionen SUMMA uppdateras inte.

Kontrollera att Beräkning är inställd på Automatisk. På fliken Formelgå du till Beräkningsalternativ. Du kan också använda F9 för tvinga kalkylbladet att beräkna.

Kontrollera att Beräkning är inställd på Automatisk.  På fliken Formel går du till Beräkningsalternativ.

Vissa värden adderas inte.

Endast numeriska värden kan adderas i funktionerna referens eller intervall. Tomma celler, logiska värden som SANT eller text ignoreras.

Felvärdet #NAMN? visas i stället för det förväntade resultatet.

Det här betyder vanligtvis att formeln är felstavad, som =summe(A1:A10) i stället för = SUMMA(a1:A10).

Funktionen SUMMA visar ett heltal, men den borde visa decimaler

Kontrollera cellformateringen så att du säkert vet att du valt att visa decimaler. Markera cellen eller området i fråga och använd Ctrl+1 så att dialogrutan Formatera celler visas, klicka på fliken Tal och välj format. Var noga med att ange det antal decimaler du vill ha.

  1. Jag vill bara addera/subtrahera/multiplicera/dividera tal Se den här videoserien om grundläggande matematiska beräkningar i Excel, eller Använda Excel som miniräknare.

  2. Hur visar jag fler/färre decimaler? Du kan ändra talformatet. Markera cellen eller området i fråga och använd Ctrl+1så att dialogrutan Formatera celler visas, klicka på fliken Tal och välj format. Var noga med att ange det antal decimaler du vill ha.

  3. Hur gör jag för att addera eller subtrahera gånger? Du kan addera och subtrahera gånger på ett par olika sätt. För att till exempel få fram skillnaden mellan 8:00 AM – 12:00 PM för löneändamål kan du använda: =("12:00 PM"-"8:00 AM")*24, det vill säga ta sluttiden minus starttiden. Observera att Excel beräknar gånger som en del av en dag, vilket innebär att du måste multiplicera med 24 för att få det totala antalet timmar. I det första exemplet använder vi =((B2-A2)+(D2-C2))*24 för att få summan av timmar från början till slut, minus en lunchpaus (8,50 timmar totalt).

    Om du bara adderar timmar och minuter och vill visa det på det sättet kan du summera, och behöver följaktligen inte multiplicera med 24. I det andra exemplet använder vi alltså =SUMMA(A6:C6) eftersom vi bara behöver det totala antalet timmar och minuter för tilldelade uppgifter (5:36, eller 5 timmar, 36 minuter).

    Beräkna gånger

    Mer information finns i: Addera eller subtrahera tid.

  4. Hur får jag skillnaden mellan datum? Du kan addera och subtrahera datum som med gånger. Här är ett mycket vanligt exempel på hur man räknar antalet dagar mellan två datum. Det är så enkelt som = B2-A2. Nyckeln till att arbeta med både datum och tider är att du börjar med slutdatum/sluttid och subtraherar startdatum/starttid.

    Beräkna skillnaden mellan datum

    Fler sätt att arbeta med datum finns i: Beräkna antalet dagar mellan två datum.

  5. Hur gör jag för att summera enbart synliga celler? Ibland när du döljer rader manuellt eller använder AutoFilter för att bara visa vissa data vill du kanske även endast summera de synliga cellerna. Du kan använda funktionen DELSUMMA. Om du använder en summarad i en Excel-tabell anges alla funktioner som du väljer från den nedrullningsbara listrutan Summa automatiskt som delsummor. Läs mer om hur du kan summera data i en Excel-tabell.

Behöver du mer hjälp?

Du kan alltid fråga en expert i Excel Tech Community, få support i Answers-communityn eller föreslå en ny funktion eller förbättringar på Excel User Voice.

Se även

Titta på en video om hur du använder funktionen SUMMA

Med funktionen SUMMA.OM lägger du endast till värden som uppfyller ett enda villkor

Med funktionen SUMMA.OMF lägger du endast till värden som uppfyller flera villkor

Med funktionen ANTAL.OM räknar du endast de värden som uppfyller ett villkor

Med funktionen ANTAL.OMF räknar du endast de värden som uppfyller flera villkor

Översikt över formler i Excel

Hur du undviker felaktiga formler

Hitta och korrigera fel i formler

Tangentbordsgenvägar i Excel för Windows

Kortkommandon i Excel för Mac

Funktioner inom matematik och trigonometri

Excel-funktioner (alfabetisk ordning)

Excel-funktioner (efter kategori)

Utöka dina kunskaper
Utforska utbildning
Få nya funktioner först
Anslut till Office Insiders

Hade du nytta av den här informationen?

Tack för din feedback!

Tack för din feedback! Det låter som att det kan vara bra att koppla dig till en av våra Office-supportrepresentanter.

×