Använda OM med funktionerna OCH, ELLER och ICKE

Med OM-funktionen kan du göra en logisk jämförelse mellan ett verkligt värde och det värde du förväntar dig genom att testa ett villkor och returnera ett resultat om villkoret är Sant eller Falskt.

  • =OM(Någonting är Sant, gör då så här, gör annars något annat)

Men hur gör du om du behöver testa flera villkor, där alla villkor måste vara Sant eller Falskt (OCH) eller där bara ett villkor måste vara Sant eller Falskt (ELLER), eller om du vill kontrollera om ett villkor inte (ICKE) uppfyller villkoren? Alla 3 funktionerna kan användas var för sig, men det är vanligare att se dem i kombination med OM-funktioner.

Använd funktionen OM tillsammans med OCH, ELLER och ICKE för att göra flera utvärderingar om villkor är Sant eller Falskt.

Syntax

  • OM(OCH()) - OM(OCH(logisk1, [logisk2], ...), värde_om_sant, [värde_om_falskt]))

  • OM(ELLER()) - OM(ELLER(logisk1, [logisk2], ...), värde_om_sant, [värde_om_falskt]))

  • OM(ICKE()) - OM(ICKE(logisk1), värde_om_sant, [värde_om_falskt]))

Argumentnamn

Beskrivning

logiskt_test (krävs)

Det villkor du vill testa.

värde_om_sant (krävs)

Det värde som ska returneras om resultatet av logiskt_test är SANT.

värde_om_falskt (valfritt)

Det värde som ska returneras om resultatet av logiskt_test är FALSKT.

Så här bygger du upp enskilda OCH-, ELLER- och ICKE-funktioner. När du kombinerar dem med en OM-sats, ser de ut så här:

  • OCH – =OM(OCH(Något är Sant, Något annat är Sant), Värde om Sant, Värde om Falskt)

  • ELLER – =OM(ELLER(Något är Sant, Något annat är Sant), Värde om Sant, Värde om Falskt)

  • ICKE – =OM(ICKE(Något är Sant), Värde om Sant, Värde om Falskt)

Exempel

Det här är exempel på några vanliga kapslade uttryck med OM(OCH()), OM(ELLER()) och OM(ICKE()). Funktionerna OCH och ELLER har stöd för upp till 255 enskilda villkor, men det är inte bra att använda fler än några stycken, eftersom komplexa, kapslade formler kan vara mycket svåra att skapa, testa och underhålla. ICKE-funktionen tar endast ett villkor.

Exempel på hur OM kan användas med OCH, ELLER och ICKE för att utvärdera numeriska värden och text

Här visas formler utskrivna i enlighet med deras logiska uppbyggnad:

Formel

Beskrivning

=OM(OCH(A2>0;B2<100);SANT; FALSKT)

OM A2 (25) är större än 0, OCH B2 (75) är mindre än 100, returneras SANT, annars returneras FALSKT. I det här fallet är båda villkoren sanna, så SANT returneras.

=OM(OCH(A3="Röd";B3="Grön");SANT;FALSKT)

Om A3 (”Blå”) = ”Röd”, OCH B3 (”Grön”) är lika med ”Grön” returneras SANT, annars returneras FALSKT. I detta fall är endast det första villkoret sant, så FALSKT returneras.

=OM(ELLER(A4>0;B4<50);SANT; FALSKT)

OM A4 (25) är större än 0, ELLER B4 (75) är mindre än 50, returneras SANT, annars returneras FALSKT. I det här fallet är endast det första villkoret SANT, men eftersom ELLER bara kräver att ett villkor är sant så returnerar formeln SANT.

=OM(ELLER(A5="Röd";B5="Grön");SANT;FALSKT)

Om A5 (”Blå”) är lika med ”Röd”, ELLER B5 (”Grön”) är lika med ”Grön” returneras SANT, annars returneras FALSKT. I det här fallet är det andra argumentet Sant, så formeln returnerar SANT.

=OM(ICKE(A6>50);SANT;FALSKT)

OM A6 (25) ICKE är större än 50, returneras SANT, annars returneras FALSKT. I det här fallet är 25 inte större än 50, så formeln returnerar SANT.

=OM(ICKE(A7=”Röd”);SANT;FALSKT)

OM A7 (”Blå”) ICKE är lika med ”Röd”, returneras SANT, annars returneras FALSKT.

Lägg märke till att alla exempel har en avslutande parentes efter att villkoren angivits. De kvarvarande argumenten för Sant/Falskt lämnas som en del av den yttre OM-satsen. Du kan även ange text eller numeriska värden att returnera istället för de SANT/FALSKT-uttryck som returneras i exemplen.

Några exempel på hur OCH, ELLER och ICKE kan användas för att utvärdera datum.

Exempel på hur OM kan användas med OCH, ELLER och ICKE för att utvärdera datum

Här visas formler utskrivna i enlighet med deras logiska uppbyggnad:

Formel

Beskrivning

=OM(A2>B2;SANT;FALSKT)

OM A2 är större än B2, returneras SANT, annars returneras FALSKT. I det här fallet är 14-03-12 större än 14-01-01, så formeln returnerar SANT.

=OM(OCH(A3>B2;A3<C2);SANT;FALSKT)

OM A3 är större än B2 OCH B3 är mindre än C2, returneras SANT, annars returneras FALSKT. I det här fallet är båda argumenten sanna, så formeln returnerar SANT.

=OM(ELLER(A4>B2;A4<B2+60);SANT;FALSKT)

OM A4 är större än B2 ELLER B4 är mindre än B2 + 60, returneras SANT, annars returneras FALSKT. I det här fallet är det första argumentet sant, men det andra är falskt. Eftersom ELLER bara kräver att ett av argumenten är sant, returneras SANT. Om du använder guiden Utvärdera formel från fliken Formler kan du se hur Excel utvärderar formeln.

=OM(ICKE(A5>B2);SANT;FALSKT)

OM A5 inte är större än B2, returneras SANT, annars returneras FALSKT. I detta fall är A5 större än B2, så formeln returnerar FALSKT.

Exempel på guiden Utvärdera formel

Använda OCH, ELLER och ICKE med villkorsstyrd formatering

OCH, ELLER och ICKE kan även användas med kriterier för villkorsstyrd formatering i en formel. När du gör detta behöver du inte ange OM-funktionen, utan kan använda OCH, ELLER och ICKE fristående.

Från fliken Start klickar du på Villkorsstyrd formatering > Ny regel. Välj sedan alternativet ”Bestäm vilka celler som ska formateras genom att använda en formel”, ange din formel och ställ in formatet du vill använda.

Villkorsstyrd formatering > dialogrutan Redigera regel med Formel-metoden

Med det tidigare exemplet för datum, skulle formlerna se ut så här.

Exempel på hur OCH, ELLER och ICKE kan användas som test för villkorsstyrd formatering


Formel

Beskrivning

=A2>B2

Om A2 är större än B2, formatera cellen, gör inget annars.

=OCH(A3>B2;A3<C2)

Om A3 är större än B2 OCH A3 är mindre än C2, formatera cellen, gör inget annars.

=ELLER(A4>B2;A4<B2+60)

Om A4 är större än B2 ELLER A4 är mindre än B2 plus 60 (dagar), formatera cellen, gör inget annars.

=ICKE(A5>B2)

Om A5 ICKE är större än B2, formatera cellen, gör inget annars. I detta fall är A5 större än B2, så FALSKT returneras. Om du ändrar formeln till =ICKE(B2>A5), returneras SANT, och cellen skulle formateras.

Obs!: Ett vanligt misstag är att skriva in formeln i Villkorsstyrd formatering utan likhetstecknet (=). Om du gör det kommer du att se att dialogrutan Villkorsstyrd formatering lägger till likhetstecknet och citattecknen till formeln - ="ELLER(A4>B2;A4<B2+60)", så du måste ta bort citattecknen innan formeln fungerar korrekt.

Överst på sidan

Behöver du mer hjälp?

Du kan alltid fråga en expert i Excel Tech Community, få support i Answers-communityn eller föreslå en ny funktion eller förbättringar på Excel User Voice.

Mer information finns i

Titta på en video om hur du använder funktionen OM

Läs mer om att använda kapslade funktioner i en formel

Funktionen OM

Funktionen OCH

Funktionen ELLER

Funktionen INTE

Översikt över formler i Excel

Hur du undviker felaktiga formler

Använd felkontroll om du vill hitta fel i formler

Kortkommandon i Excel för Windows

Kortkommandon i Excel för Mac

Logiska funktioner (referens)

Excel-funktioner (alfabetisk ordning)

Excel-funktioner (efter kategori)

Utöka dina kunskaper
Utforska utbildning
Få nya funktioner först
Anslut till Office Insiders

Hade du nytta av den här informationen?

Tack för din feedback!

Tack för din feedback! Det låter som att det kan vara bra att koppla dig till en av våra Office-supportrepresentanter.

×