ANTAL.OM (Funktionen ANTAL.OM)

ANTAL.OM (Funktionen ANTAL.OM)

Använd ANTAL.OM, en av statistikfunktionerna, om du vill räkna det antal celler som uppfyller ett villkor, till exempel antalet gånger en viss stad finns med i en kundlista.

I sin enklaste form säger ANTAL.OM:

  • =ANTAL.OM(Var vill du leta?, Vad vill du leta efter?)

Till exempel:

  • =ANTAL.OM(A2:A5,"London")

  • =ANTAL.OM(A2:A5;A4)

Din webbläsare har inte stöd för video. Installera Microsoft Silverlight, Adobe Flash Player eller Internet Explorer 9.

ANTAL.OM(område, villkor)

Argumentnamn

Beskrivning

intervall    (obligatoriskt)

Den grupp celler som du vill räkna. Intervallet kan innehålla tal, matriser, ett namngivet område eller referenser som innehåller tal. Tomma värden och textvärden ignoreras.

Lär dig hur du markerar områden i ett kalkylblad.

villkor    (obligatoriskt)

Ett tal, ett uttryck, en cellreferens eller en textsträng som anger vilka celler som ska räknas.

Du kan till exempel använda ett tal som 32, en jämförelse som ">32 ", en cell som B4 eller ett ord som "äpplen".

För ANTAL.OM används bara ett enda villkor. Använd ANTAL.OMF om du vill använda flera villkor.

Exempel

För att använda de här exemplen i Excel ska du kopiera data i tabellen nedan och klistra in dem i cell A1 på ett nytt kalkylblad.

Data

Data

äpplen

32

apelsiner

54

persikor

75

äpplen

86

Formel

Beskrivning

=ANTAL.OM(A2:A5;"äpplen")

Räknar antalet celler med äpplen i cell A2 till och med A5. Resultatet är 2.

=ANTAL.OM(A2:A5;A4)

Räknar antalet celler med persikor (värdet i A4) i cell A2 till A5. Resultatet är 1.

=ANTAL.OM(A2:A5,A2)+ANTAL.OM(A2:A5,A3)

Räknar antalet äpplen (värdet i A2) och apelsiner (värdet i A3) i cell A2 till A5. Resultatet är 3. Den här formeln använder ANTAL.OM två gånger för att ange flera villkor, ett villkor per uttryck. Du kan också använda funktionen ANTAL.OMF.

=ANTAL.OM(B2:B5;">55")

Räknar antalet celler med ett större värde än 55 i cell B2 till och med B5. Resultatet är 2.

=ANTAL.OM(B2:B5;"<>"&B4)

Räknar antalet celler med ett värde som inte är lika med 75 i cell B2 till och med B5. Et-tecknet (&) slår ihop jämförelseoperatorn för inte lika med (<>) och värdet i B4 till =ANTAL.OM(B2:B5;"<>75"). Resultatet är 3.

=ANTAL.OM(B2:B5;">=32")-ANTAL.OM(B2:B5;">85")

Räknar antalet celler med ett värde större än (>) eller lika med (=) 32 och mindre än (<) eller lika med (=) 85 i cell B2 till och med B5. Resultatet är 3.

=ANTAL.OM(A2:A5;"*")

Räknar antalet celler som innehåller text i cell A2 till och med A5. Asterisken (*) används som jokertecken för att matcha ett valfritt tecken. Resultatet är 4.

=ANTAL.OM(A2:A5,"?????es")

Räknar antalet celler som har exakt 7 tecken och slutar med bokstäverna "es" i cell A2 till och med A5. Frågetecknet (?) används som jokertecken för att matcha enskilda tecken. Resultatet är 2.

Vanliga problem

Problem

Vad gick fel

Fel värde returneras för långa strängar.

Funktionen ANTAL.OM returnerar ogiltiga resultat om du använder den för att matcha strängar som är längre än 255 tecken.

Om du vill matcha strängar som är längre än 255 tecken använder du funktionen SAMMANFOGA eller sammanfogningsoperatorn &amp;. Exempel: =ANTAL.OM(A2:A5,"lång sträng"&amp;"ännu en lång sträng").

Inget värde returneras när du förväntar dig ett värde.

Se till att argumentet villkor står inom citattecken.

En ANTAL.OM-formel genererar ett #VÄRDE!-fel när du refererar till ett annat kalkylblad.

Det här felet inträffar när den formel som innehåller funktionen refererar till celler eller ett cellområde i en stängd arbetsbok och cellerna beräknas. För att den här funktionen ska fungera måste den andra arbetsboken vara öppen.

Metodtips

Gör du så här

Varför

Observera att ANTAL.OM ignorerar versaler och gemener i textsträngar.

Villkor är inte skiftlägeskänsliga. Strängen "äpplen" och strängen "ÄPPLEN" matchar alltså samma celler.

Använda jokertecken

Du kan använda jokertecken – frågetecken (?) och asterisker (*) – i villkor. Ett frågetecken representerar ett obestämt enskilt tecken och en asterisk representerar en obestämd teckenföljd. Om du vill söka efter ett frågetecken eller en asterisk skriver du tilde (~) före tecknet.

Exempel: =ANTAL.OM(A2:A5,"äpple?") räknar alla förekomster av "äpple" med en sista bokstav som kan variera.

Kontrollera att dina data inte innehåller felaktiga tecken.

Kontrollera att informationen inte innehåller några inledande blanksteg, avslutande blanksteg, inkonsekvent användning av raka eller typografiska citattecken eller icke utskrivbara tecken när du räknar textvärden. I så fall kan ANTAL.OM returnera ett oväntat värde.

Prova att använda funktionen STÄDA eller RENSA.

Använd namngivna områden för enkelhetens skull

ANTAL.OM stöder namngivna områden i en formel (exempel: =ANTAL.OM(frukt;">=32")-ANTAL.OM(frukt;">85"). Det namngivna området kan finnas i det aktuella kalkylbladet, ett annat kalkylblad i samma arbetsbok eller i en annan arbetsbok. Om du vill referera till en annan arbetsbok måste den också vara öppen.

Obs!: Funktionen ANTAL.OM räknar inte celler baserat på cellbakgrund eller teckenfärg. Excel stöder dock användardefinierade funktioner med Microsoft VBA-åtgärder (Visual Basic for Applications) på celler baserat på bakgrund eller teckenfärg. Här är ett exempel på hur du kan Räkna antalet celler med specifik cellfärg genom att använda VBA.

Behöver du mer hjälp?

Du kan alltid fråga en expert i Excel Tech Community, få support i Answers-communityn eller föreslå en ny funktion eller förbättringar på Excel User Voice.

Mer information finns i

Om du vill räkna celler som inte är tomma använder du funktionen ANTALV

Om du vill räkna celler med flera villkor använder du funktionen ANTAL.OM

Visa en video om hur man använder funktionen ANTAL.OM

Funktionen SUMMA.OM lägger endast till de värden som uppfyller ett enda villkor

Funktionen i SUMMA.OMF lägger endast till de värden som uppfyller flera villkor

IFS-funktionen (Office 365, Excel 2016 och senare)

Använd funktionen RENSA för att ta bort inledande och avslutande blanksteg från celler

Använd funktionen STÄDA för att ta bort icke utskrivbara tecken

Översikt över formler i Excel

Så här undviker du felaktiga formler

Hitta fel i formler

Statistikfunktioner

Excel-funktioner (alfabetisk ordning)

Excel-funktioner (efter kategori)

Använd SUMMA.OM, ANTAL.OM och relaterade funktioner för snabb dataanalys (gratis smakprov)

Utöka dina kunskaper
Utforska utbildning
Få nya funktioner först
Anslut till Office Insiders

Hade du nytta av den här informationen?

Tack för din feedback!

Tack för din feedback! Det låter som att det kan vara bra att koppla dig till en av våra Office-supportrepresentanter.

×