Prijavite se pomoću Microsoft naloga
Prijavite se ili kreirajte nalog.
Zdravo,
Izaberite drugi nalog.
Imate više naloga
Odaberite nalog pomoću kojeg želite da se prijavite.
Razdeljivanje teksta u kolone pomoću funkcija

Tekstualne funkcije LEFT, MID, RIGHT, SEARCH i LEN možete da koristite da biste manipulisali niskama teksta u podacima. Na primer, možete da distribuirate ime, srednje ime i prezime iz jedne ćelije u tri odvojene kolone.

Ključ za distribuciju komponenti imena sa tekstualnim funkcijama jeste položaj svakog znaka u okviru tekstualne niske. Pozicije razmaka u tekstualnoj niski takođe su važne zato što ukazuju na početak ili kraj komponenti imena u niski.

Na primer, u ćeliji koja sadrži samo ime i prezime, prezime počinje posle prve instance razmaka. Neka imena na listi mogu da sadrže srednje ime, u tom slučaju, prezime počinje posle druge instance razmaka.

Ovaj članak vam pokazuje kako da izdvojite različite komponente iz različitih formata imena pomoću ovih korisnih funkcija. Takođe možete da razdelite tekst u različite kolone pomoću čarobnjaka za konvertovanje teksta u kolone

Primer imena

Opis

Ime

Srednje ime

Prezime

Sufiks

1

Džef Smit

Nema srednjeg imena

Janko

Savić

2

Erik S. Kurjan

Inicijali jedan po sredini

Erik

S.

Kurjan (Kurjan)

3

Janaina B. G. Bueno

Dva srednja inicijala

Janaina (Janaina)

B. G.

Bueno

4

Kahn, Wendy Bet

Prezime, sa zarezom

Vendi

Bet

Kan

5

Meri Kej D. Andersen

Ime iz dva dela

Meri Kej

D.

Daničić

6

Paula Barreto de Mattos

Prezime sa tri dela

Paula

Barreto de Mattos

7

James van Eaton

Prezime iz dva dela

Dћejms

van Eaton

8

Bacon Jr., Dan K.

Prezime i sufiks prvo, sa zarezom

Dan

K.

Slanina

Junior.

9

Gary Altman III

Sa sufiksom

Geri

Altman

III

10

Rajan Ihrig

Sa prefiksom

Rajan

Ihrig (Ihrig)

11

Džuli Taft-Rider

Rastavljanje reči na kraju reda u prezimenu

Jasmina

Taft-Rider

Napomena: U grafikama u sledećim primerima markiranje u punom imenu prikazuje znak koji traži formula pretrage koja se podudara.

Ovaj primer razdvaja dve komponente: ime i prezime. Jedan razmak razdvaja dva imena.

Kopirajte ćelije iz tabele i nalepite ih u Excel radni list u ćeliji A1. Formula koju vidite sa leve strane biće prikazana kao referenca, dok će Excel automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Džef Smit

Nema srednjeg imena

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Ime

    Ime počinje prvim znakom u niski (J) i završava se na petom znaku (razmaku). Ova formula daje pet znakova u ćeliji A2, počevši sleva.

    Formula za izdvajanje imena

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom razmaka u ćeliji A2, počevši s leva.

  2. Prezime

    Prezime počinje posle razmaka, na pet znakova zdesna i završava se na poslednjem znaku na desnoj strani (h). Ova formula izdvaja pet znakova u ćeliji A2, počevši zdesna.

    Formula za izdvajanje prezimena

    Koristite funkcije SEARCH i LEN da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom razmaka u ćeliji A2, počevši s leva. (5)

  3. Izračunajte ukupnu dužinu tekstualne niske, a potom oduzmite broj znakova sa leve strane od prvog razmaka, kao što je dato u 1. koraku.

Ovaj primer koristi ime, srednje ime i prezime. Razmak razdvaja svaku komponentu imena.

Kopirajte ćelije iz tabele i nalepite ih u Excel radni list u ćeliji A1. Formula koju vidite sa leve strane biće prikazana kao referenca, dok će Excel automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Erik S. Kurjan

Inicijali jedan po sredini

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (srednji inicijali)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Formula

Live Result (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Ime

    Ime počinje prvim znakom sleva (E) i završava se na petom znaku (prvom razmaku). Formula izdvaja prvih pet znakova u ćeliji A2, počevši sleva.

    Formula za odvajanje imena i prezimena, plus srednji inicijali

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom razmaka u ćeliji A2, počevši s leva. (5)

  2. Srednje ime

    Srednje ime počinje od šeste pozicije znaka (S) i završava se na osmoj poziciji (drugom razmaku). Ova formula uključuje ugnežđivanje funkcija SEARCH radi pronalaženja druge instance razmaka.

    Formula izdvaja tri znaka, počevši od šeste pozicije.

    Detalji formule za odvajanje imena, srednjih imena i prezimena

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (5).

  3. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (S). Ova numerička pozicija je početna pozicija srednjeg imena. (5 + 1 = 6)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (5)

  4. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (S). Rezultat je broj znaka od kog želite da počnete da tražite drugu instancu razmaka. (5 + 1 = 6)

  5. Potražite drugu instancu razmaka u ćeliji A2, počevši od šeste pozicije (S) pronađene u 4. koraku. Ovaj broj znaka je krajnja pozicija srednjeg imena. (8)

  6. Potražite numeričku poziciju razmaka u ćeliji A2, počevši od prvog znaka sleva. (5)

  7. Uzmite broj znaka drugog razmaka u 5. koraku i oduzmite broj znaka prvog razmaka koji je pronađen u 6. koraku. Rezultat je broj znakova koje MID izdvaja iz tekstualne niske počevši od šeste pozicije pronađene u 2. koraku. (8 – 5 = 3)

  8. Prezime

    Prezime počinje na šest znakova zdesna (K) i završava se na prvom znaku zdesna (n). Ova formula uključuje ugnežđivanje funkcija SEARCH radi pronalaženja druge i treće instance razmaka (koje se nalaze na petoj i osmoj poziciji sleva).

    Formula izdvaja šest znakova iz ćelije A2, počevši zdesna.

    Druga funkcija SEARCH u formuli za odvajanje imena, srednjih imena i prezimena
  9. Koristite funkcije LEN i ugnežđene funkcije SEARCH da biste pronašli vrednost za num_chars:

    Potražite numeričku poziciju razmaka u ćeliji A2, počevši od prvog znaka sleva. (5)

  10. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (S). Rezultat je broj znaka od kog želite da počnete da tražite drugu instancu razmaka. (5 + 1 = 6)

  11. Potražite drugu instancu razmaka u ćeliji A2, počevši od šeste pozicije (S) pronađene u 2. koraku. Ovaj broj znaka je krajnja pozicija srednjeg imena. (8)

  12. Prebrojte ukupnu dužinu tekstualne niske u ćeliji A2, a zatim oduzmite broj znakova sa leve strane do druge instance razmaka koja je pronađena u 3. koraku. Rezultat je broj znakova koji će biti izdvojeni sa desne strane punog imena. (14 – 8 = 6).

Evo primera kako da izdvojite dva srednja inicijala. Prva i treća instanca razmaka razdvajaju komponente imena.

Kopirajte ćelije iz tabele i nalepite ih u Excel radni list u ćeliji A1. Formula koju vidite sa leve strane biće prikazana kao referenca, dok će Excel automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Janaina B. G. Bueno

Dva srednja inicijala

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (srednji inicijali)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

Formula

Live Result (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. Ime

    Ime počinje prvim znakom sleva (J) i završava se na osmom znaku (prvom razmaku). Formula izdvaja prvih osam znakova iz ćelije A2, počevši sleva.

    Formula za odvajanje imena, prezimena i dva srednja inicijala

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (8)

  2. Srednje ime

    Srednje ime počinje od devete pozicije (B) i završava se na četnaestoj poziciji (treći razmak). Ova formula uključuje ugnežđivanje funkcije SEARCH da bi se pronašli prva, druga i treća instanca razmaka u osmoj, jedanaestoj i četrnijoj poziciji.

    Formula izdvaja pet znakova, počevši od devete pozicije.

    Formula za odvajanje imena, prezimena i dva srednja inicijala

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (8)

  3. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (B). Ova numerička pozicija je početna pozicija srednjeg imena. (8 + 1 = 9)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (8)

  4. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (B). Rezultat je broj znaka od kog želite da počnete da tražite drugu instancu razmaka. (8 + 1 = 9)

  5. Potražite drugi razmak u ćeliji A2, počevši od devete pozicije (B) pronađenog u 4. koraku. (11).

  6. Dodajte 1 da biste dobili poziciju znaka posle drugog razmaka (G). Ovaj broj znaka je početna pozicija na kojoj želite da počnete da tražite treći razmak. (11 + 1 = 12)

  7. Potražite treći razmak u ćeliji A2, počevši od dvadesete pozicije pronađene u 6. koraku. (14)

  8. Potražite numeričku poziciju prvog razmaka u ćeliji A2. (8)

  9. Uzmite broj znaka trećeg razmaka u 7. koraku i oduzmite broj znaka prvog razmaka koji je pronađen u 6. koraku. Rezultat je broj znakova koje MID izdvaja iz tekstualne niske počevši od devete pozicije pronađene u 2. koraku.

  10. Prezime

    Prezime počinje sa pet znakova zdesna (B) i završava se na prvom znaku zdesna (o). Ova formula uključuje ugnežđivanje funkcije SEARCH da bi se pronašli prva, druga i treća instanca razmaka.

    Formula izdvaja pet znakova u ćeliji A2, počevši od desne strane punog imena.

    Formula za odvajanje imena, prezimena i dva srednja inicijala

    Koristite ugnežđene funkcije SEARCH i LEN da biste pronašli vrednost za num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (8)

  11. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (B). Rezultat je broj znaka od kog želite da počnete da tražite drugu instancu razmaka. (8 + 1 = 9)

  12. Potražite drugi razmak u ćeliji A2, počevši od devete pozicije (B) pronađenog u 2. koraku. (11)

  13. Dodajte 1 da biste dobili poziciju znaka posle drugog razmaka (G). Ovaj broj znaka je početna pozicija na kojoj želite da počnete da tražite treću instancu razmaka. (11 + 1 = 12)

  14. Potražite treći razmak u ćeliji A2, počevši od dvadesetog položaja (G) pronađenog u 6. koraku. (14)

  15. Prebrojte ukupnu dužinu tekstualne niske u ćeliji A2, a zatim oduzmite broj znakova sa leve strane do trećeg razmaka koji je pronađen u 5. koraku. Rezultat je broj znakova koji će biti izdvojeni sa desne strane punog imena. (19 - 14 = 5)

U ovom primeru, prezime stoji pre imena, a srednje ime je na kraju. Zarez označava kraj prezimena, a razmak razdvaja svaku komponentu imena.

Kopirajte ćelije iz tabele i nalepite ih u Excel radni list u ćeliji A1. Formula koju vidite sa leve strane biće prikazana kao referenca, dok će Excel automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Kahn, Wendy Bet

Prezime, sa zarezom

Formula

Rezultat (ime)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Formula

Rezultat (srednje ime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Formula

Live Result (prezime)

'=LEFT(A2, SEARCH(" ",A2,1)-2)

=LEFT(A2, SEARCH(" ",A2,1)-2)

  1. Ime

    Ime počinje sedmim znakom sleva (W) i završava se na dvanaestom znaku (drugom razmaku). Budući da se ime pojavljuje na sredini punog imena, potrebno je da koristite funkciju MID da biste izdvojili ime.

    Formula izdvaja šest znakova, počevši od sedme pozicije.

    Formula za odvajanje prezimena za kojim slede ime i srednje ime

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (6)

  2. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (W). Ova numerička pozicija je početna pozicija imena. (6 + 1 = 7)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (6)

  3. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (W). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (6 + 1 = 7)

    Potražite drugi razmak u ćeliji A2, počevši od sedme pozicije (W) pronađenog u 4. koraku. (12)

  4. Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (6)

  5. Uzmite broj znaka drugog razmaka u 5. koraku i oduzmite broj znaka prvog razmaka koji je pronađen u 6. koraku. Rezultat je broj znakova koje mid izdvaja iz tekstualne niske počevši od sedme pozicije pronađene u 2. koraku. (12 - 6 = 6)

  6. Srednje ime

    Srednje ime počinje na četiri znaka s desna (B) i završava se na prvom znaku s desna (h). Ova formula uključuje ugnežđivanje funkcija SEARCH da bi se pronašle prva i druga instanca razmaka na šestoj i dvanaestoj poziciji s leva.

    Formula izdvaja četiri znaka, počevši s desna.

    Formula za odvajanje prezimena za kojim slede ime i srednje ime

    Koristite funkciju LEN i ugnežđenu funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (6)

  7. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (W). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (6 + 1 = 7)

  8. Potražite drugu instancu razmaka u ćeliji A2 počevši od sedme pozicije (W) pronađene u 2. koraku. (12)

  9. Prebrojte ukupnu dužinu tekstualne niske u ćeliji A2, a zatim oduzmite broj znakova sa leve strane do drugog razmaka koji je pronađen u 3. koraku. Rezultat je broj znakova koji će biti izdvojeni sa desne strane punog imena. (16 - 12 = 4)

  10. Prezime

    Prezime počinje prvim znakom sleva (K) i završava se na četvrtom znaku (n). Ova formula izdvaja četiri znaka, počevši sleva.

    Formula za odvajanje prezimena za kojim slede ime i srednje ime

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (6)

  11. Oduzmite 2 da biste dobili numeričku poziciju krajnjeg znaka prezimena (n). Rezultat je broj znakova koje želite da funkcija LEFT izdvoji. (6 - 2 =4)

Ovaj primer koristi ime od dva dela, Meri Kej. Drugi i treći razmaci razdvajaju svaku komponentu imena.

Kopirajte ćelije iz tabele i nalepite ih u Excel radni list u ćeliji A1. Formula koju vidite sa leve strane biće prikazana kao referenca, dok će Excel automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Meri Kej D. Andersen

Ime iz dva dela

Formula

Rezultat (ime)

LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Formula

Rezultat (srednji inicijali)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Formula

Live Result (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. Ime

    Ime počinje prvim znakom sleva i završava se na devetom znaku (drugom razmaku). Ova formula uključuje ugnežđivanje funkcije SEARCH da bi se pronašli druga instanca razmaka sa leve strane.

    Formula izdvaja devet znakova, počevši sleva.

    Formula za odvajanje imena, srednjeg imena, srednjeg inicijala i prezimena

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (5)

  2. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (K). Rezultat je broj znaka od kog želite da počnete da tražite drugu instancu razmaka. (5 + 1 = 6)

  3. Potražite drugu instancu razmaka u ćeliji A2, počevši od šeste pozicije (K) pronađene u 2. koraku. Rezultat je broj znakova koje funkcija LEFT izdvaja iz tekstualne niske. (9)

  4. Srednje ime

    Srednje ime počinje od desete pozicije (D) i završava se na srednjoj poziciji (trećem razmaku). Ova formula uključuje ugnežđivanje funkcije SEARCH da bi se pronašli prva, druga i treća instanca razmaka.

    Formula izdvaja dva znaka iz sredine, počevši od desete pozicije.

    Formula za odvajanje imena, srednjeg imena, srednjeg inicijala i prezimena

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost za start_num:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (5)

  5. Dodajte 1 da biste dobili znak posle prvog razmaka (K). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (5 + 1 = 6)

  6. Potražite poziciju druge instance razmaka u ćeliji A2, počevši od šeste pozicije (K) pronađene u 2. koraku. Rezultat je broj znakova koje funkcija LEFT izdvaja sa leve strane. (9)

  7. Dodajte 1 da biste dobili znak posle drugog razmaka (D). Rezultat je početna pozicija srednjeg imena. (9 + 1 = 10)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost za broj_znakova:

    Potražite numeričku poziciju znaka posle drugog razmaka (D). Rezultat je broj znaka od kog želite da počnete da tražite treći razmak. (10)

  8. Potražite numeričku poziciju trećeg razmaka u ćeliji A2, počevši s leva. Rezultat je krajnja pozicija srednjeg imena. (12)

  9. Potražite numeričku poziciju znaka posle drugog razmaka (D). Rezultat je početna pozicija srednjeg imena. (10)

  10. Uzmite broj znaka trećeg razmaka, koji se nalazi u 6. koraku i oduzmite broj znaka "D" koji je pronađen u 7. koraku. Rezultat je broj znakova koje MID izdvaja iz tekstualne niske počevši od desete pozicije pronađene u 4. koraku. (12 - 10 = 2)

  11. Prezime

    Prezime počinje sa osam znakova zdesna. Ova formula uključuje ugnežđivanje funkcije SEARCH da bi se pronašli prva, druga i treća instanca razmaka u petoj, devetoj i petoj poziciji.

    Formula izdvaja osam znakova sa desne strane.

    Formula za odvajanje imena, srednjeg imena, srednjeg inicijala i prezimena

    Koristite ugnežđene funkcije SEARCH i LEN da biste pronašli vrednost za num_chars:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (5)

  12. Dodajte 1 da biste dobili znak posle prvog razmaka (K). Rezultat je broj znaka od kog želite da počnete da tražite razmak. (5 + 1 = 6)

  13. Potražite drugi razmak u ćeliji A2, počevši od šeste pozicije (K) pronađenog u 2. koraku. (9)

  14. Dodajte 1 da biste dobili poziciju znaka posle drugog razmaka (D). Rezultat je početna pozicija srednjeg imena. (9 + 1 = 10)

  15. Potražite numeričku poziciju trećeg razmaka u ćeliji A2, počevši s leva. Rezultat je krajnja pozicija srednjeg imena. (12)

  16. Prebrojte ukupnu dužinu tekstualne niske u ćeliji A2, a zatim oduzmite broj znakova sa leve strane do trećeg razmaka koji je pronađen u 5. koraku. Rezultat je broj znakova koji će biti izdvojeni sa desne strane punog imena. (20 - 12 = 8)

Ovaj primer koristi prezime od tri dela: Barreto de Mattos. Prvi razmak označava kraj imena i početka prezimena.

Kopirajte ćelije iz tabele i nalepite ih u Excel radni list u ćeliji A1. Formula koju vidite sa leve strane biće prikazana kao referenca, dok će Excel automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Paula Barreto de Mattos

Prezime sa tri dela

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (prezime)

RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Ime

    Ime počinje prvim znakom sleva (P) i završava se na šestom znaku (prvom razmaku). Formula izdvaja šest znakova sleva.

    Formula za odvajanje imena i prezimena od tri dela

    Koristite funkciju "Pretraga" da biste pronašli vrednost num_chars:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (6)

  2. Prezime

    Prezime počinje sa sedamnaest znakova zdesna (B) i završava se prvim znakom zdesna (s). Formula izdvaja sedamnaest znakova sa desne strane.

    Formula za odvajanje imena i prezimena od tri dela

    Koristite funkcije LEN i SEARCH da biste pronašli vrednost za num_chars:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (6)

  3. Prebrojte ukupnu dužinu tekstualne niske u ćeliji A2, a zatim oduzmite broj znakova sa leve strane do prvog razmaka koji je pronađen u 1. koraku. Rezultat je broj znakova koji će biti izdvojeni sa desne strane punog imena. (23 - 6 = 17)

Ovaj primer koristi prezime od dva dela: van Eaton. Prvi razmak označava kraj imena i početka prezimena.

Kopirajte ćelije iz tabele i nalepite ih u Excel radni list u ćeliji A1. Formula koju vidite sa leve strane biće prikazana kao referenca, dok će Excel automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

James van Eaton

Prezime iz dva dela

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Ime

    Ime počinje prvim znakom sleva (J) i završava se na osmom znaku (prvom razmaku). Formula izdvaja šest znakova sleva.

    Formula za odvajanje imena i prezimena koje se sastoji od dva dela

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (6)

  2. Prezime

    Prezime počinje devetim znakom zdesna (v) i završava se na prvom znaku zdesna (n). Formula izdvaja devet znakova sa desne strane punog imena.

    Formula za odvajanje imena i prezimena koje se sastoji od dva dela

    Koristite funkcije LEN i SEARCH da biste pronašli vrednost za num_chars:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (6)

  3. Prebrojte ukupnu dužinu tekstualne niske u ćeliji A2, a zatim oduzmite broj znakova sa leve strane do prvog razmaka koji je pronađen u 1. koraku. Rezultat je broj znakova koji će biti izdvojeni sa desne strane punog imena. (15 - 6 = 9)

U ovom primeru prvo dolazi prezime, a zatim sledi sufiks. Zarez razdvaja prezime i sufiks od imena i srednjeg inicijala.

Kopirajte ćelije iz tabele i nalepite ih u Excel radni list u ćeliji A1. Formula koju vidite sa leve strane biće prikazana kao referenca, dok će Excel automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Bacon Jr., Dan K.

Prezime i sufiks prvo, sa zarezom

Formula

Rezultat (ime)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Formula

Rezultat (srednji inicijali)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Formula

Rezultat (prezime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (sufiks)

'=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

  1. Ime

    Ime počinje od petnaestog znaka (D) i završava se petnaestim znakom (treći razmak). Formula izdvaja tri znaka, počevši od pozicije od12.

    Formula za odvajanje prezimena i sufiksa prvo, sa zarezom

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost za start_num:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (6)

  2. Dodajte 1 da biste dobili znak posle prvog razmaka (J). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (6 + 1 = 7)

  3. Potražite drugi razmak u ćeliji A2, počevši od sedme pozicije (J), pronađene u 2. koraku. (11)

  4. Dodajte 1 da biste dobili znak posle drugog razmaka (D). Rezultat je početna pozicija imena. (11 + 1 = 12)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost za broj_znakova:

    Potražite numeričku poziciju znaka posle drugog razmaka (D). Rezultat je broj znaka od kog želite da počnete da tražite treći razmak. (12)

  5. Potražite numeričku poziciju trećeg razmaka u ćeliji A2, počevši s leva. Rezultat je krajnja pozicija imena. (15)

  6. Potražite numeričku poziciju znaka posle drugog razmaka (D). Rezultat je početna pozicija imena. (12)

  7. Uzmite broj znaka trećeg razmaka, koji se nalazi u 6. koraku i oduzmite broj znaka "D" koji je pronađen u 7. koraku. Rezultat je broj znakova koje MID izdvaja iz tekstualne niske počevši od tupe pozicije, pronađene u 4. koraku. (15 - 12 = 3)

  8. Srednje ime

    Srednje ime počinje drugim znakom zdesna (K). Formula izdvaja dva znaka sa desne strane.

    Formula za odvajanje prezimena i sufiksa prvo, sa zarezom

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (6)

  9. Dodajte 1 da biste dobili znak posle prvog razmaka (J). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (6 + 1 = 7)

  10. Potražite drugi razmak u ćeliji A2, počevši od sedme pozicije (J), pronađene u 2. koraku. (11)

  11. Dodajte 1 da biste dobili znak posle drugog razmaka (D). Rezultat je početna pozicija imena. (11 + 1 = 12)

  12. Potražite numeričku poziciju trećeg razmaka u ćeliji A2, počevši s leva. Rezultat je krajnja pozicija srednjeg imena. (15)

  13. Prebrojte ukupnu dužinu tekstualne niske u ćeliji A2, a zatim oduzmite broj znakova sa leve strane do trećeg razmaka, pronađene u 5. koraku. Rezultat je broj znakova koji će biti izdvojeni sa desne strane punog imena. (17 - 15 = 2)

  14. Prezime

    Prezime počinje od prvog znaka sleva (B) i završava se na šestom znaku (prvom razmaku). Prema tome, formula izdvaja šest znakova sa leve strane.

    Formula za odvajanje prezimena i sufiksa prvo, sa zarezom

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (6)

  15. Sufiks

    Sufiks počinje od sedmog znaka sleva (J) i završava se na devetom znaku sleva (.). Formula izdvaja tri znaka, počevši od sedmog znaka.

    Formula za odvajanje prezimena i sufiksa prvo, sa zarezom

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (6)

  16. Dodajte 1 da biste dobili znak posle prvog razmaka (J). Rezultat je početna pozicija sufiksa. (6 + 1 = 7)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost za broj_znakova:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (6)

  17. Dodajte 1 da biste dobili numeričku poziciju znaka posle prvog razmaka (J). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (7)

  18. Potražite numeričku poziciju drugog razmaka u ćeliji A2, počevši od sedmog znaka pronađenog u 4. koraku. (11)

  19. Oduzmite 1 od broja znaka drugog razmaka u 4. koraku da biste dobili broj znaka ",". Rezultat je krajnja pozicija sufiksa. (11 - 1 = 10)

  20. Potražite numeričku poziciju prvog razmaka. (6)

  21. Kada pronađete prvi razmak, dodajte 1 da biste pronašli sledeći znak (J), takođe u koracima 3 i 4. (7)

  22. Uzmite broj znaka "", pronađen u 6. koraku i oduzmite broj znaka "J" koji se nalazi u koracima 3 i 4. Rezultat je broj znakova koje funkcija MID izdvaja iz tekstualne niske počevši od sedme pozicije, koja se nalazi u 2. koraku. (10 - 7 = 3)

U ovom primeru, ime je na početku niske, a sufiks je na kraju, tako da možete da koristite formule slične 2. primeru: Koristite funkciju LEFT da biste izdvojiti ime, funkciju MID za izdvajanje prezimena, a funkciju RIGHT za izdvajanje sufiksa.

Kopirajte ćelije iz tabele i nalepite ih u Excel radni list u ćeliji A1. Formula koju vidite sa leve strane biće prikazana kao referenca, dok će Excel automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Gary Altman III

Ime i prezime sa sufiksom

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (prezime)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Formula

Rezultat (sufiks)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Ime

    Ime počinje od prvog znaka sleva (G) i završava se na petom znaku (prvom razmaku). Stoga formula izdvaja pet znakova sa leve strane punog imena.

    Formula za odvajanje imena i prezimena praćeno sufiksom

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (5)

  2. Prezime

    Prezime počinje od šestog znaka sleva (A) i završava se na jedanaestom znaku (drugom razmaku). Ova formula uključuje ugnežđivanje funkcije SEARCH da bi se pronašli položaji razmaka.

    Formula izdvaja šest znakova iz sredine, počevši od šestog znaka.

    Formula za odvajanje imena i prezimena praćeno sufiksom

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (5)

  3. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (A). Rezultat je početna pozicija prezimena. (5 + 1 = 6)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost za broj_znakova:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (5)

  4. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (A). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (5 + 1 = 6)

  5. Potražite numeričku poziciju drugog razmaka u ćeliji A2, počevši od šestog znaka pronađenog u 4. koraku. Ovaj broj znaka je krajnja pozicija prezimena. (12)

  6. Potražite numeričku poziciju prvog razmaka. (5)

  7. Dodajte 1 da biste pronašli numeričku poziciju znaka posle prvog razmaka (A), takođe u koracima 3 i 4. (6)

  8. Uzmite broj znaka drugog razmaka, koji se nalazi u 5. koraku, a zatim oduzmite broj znaka "A" koji se nalazi u koracima 6 i 7. Rezultat je broj znakova koje mid izdvaja iz tekstualne niske, počevši od šeste pozicije, pronađene u 2. koraku. (12 - 6 = 6)

  9. Sufiks

    Sufiks počinje sa tri znaka zdesna. Ova formula uključuje ugnežđivanje funkcije SEARCH da bi se pronašli položaji razmaka.

    Formula za odvajanje imena i prezimena praćeno sufiksom

    Koristite ugnežđene funkcije SEARCH i LEN da biste pronašli vrednost za num_chars:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (5)

  10. Dodajte 1 da biste dobili znak posle prvog razmaka (A). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (5 + 1 = 6)

  11. Potražite drugi razmak u ćeliji A2, počevši od šeste pozicije (A), pronađene u 2. koraku. (12)

  12. Prebrojte ukupnu dužinu tekstualne niske u ćeliji A2, a zatim oduzmite broj znakova sa leve strane na drugi razmak, pronađen u 3. koraku. Rezultat je broj znakova koji će biti izdvojeni sa desne strane punog imena. (15 - 12 = 3)

U ovom primeru pre punog imena prefiksa prefiksa koristite formule slične kao 2. primer: funkcija MID za izdvajanje imena, funkcija RIGHT za izdvajanje prezimena.

Kopirajte ćelije iz tabele i nalepite ih u Excel radni list u ćeliji A1. Formula koju vidite sa leve strane biće prikazana kao referenca, dok će Excel automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Rajan Ihrig

Sa prefiksom

Formula

Rezultat (ime)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Formula

Rezultat (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Ime

    Ime počinje od petog znaka sleva (R) i završava se na devetom znaku (drugom razmaku). Formula ugnežđuje funkciju SEARCH da bi se pronašli položaji razmaka. Izdvaja četiri znaka, počevši od pete pozicije.

    Formula za odvajanje imena ispred prefiksa

    Koristite funkciju SEARCH da biste pronašli vrednost za start_num:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (4)

  2. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (R). Rezultat je početna pozicija imena. (4 + 1 = 5)

    Koristite ugnežđenu funkciju SEARCH da biste pronašli vrednost za num_chars:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (4)

  3. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (R). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (4 + 1 = 5)

  4. Potražite numeričku poziciju drugog razmaka u ćeliji A2, počevši od petog znaka, pronađenih u koracima 3 i 4. Ovaj broj znaka je krajnja pozicija imena. (9)

  5. Potražite prvi razmak. (4)

  6. Dodajte 1 da biste pronašli numeričku poziciju znaka posle prvog razmaka (R), takođe u koracima 3 i 4. (5)

  7. Uzmite broj znaka drugog razmaka, koji se nalazi u 5. koraku, a zatim oduzmite broj znaka "R" koji se nalazi u koracima 6 i 7. Rezultat je broj znakova koje MID izdvaja iz tekstualne niske, počevši od pete pozicije pronađene u 2. koraku. (9 - 5 = 4)

  8. Prezime

    Prezime počinje sa pet znakova zdesna. Ova formula uključuje ugnežđivanje funkcije SEARCH da bi se pronašli položaji razmaka.

    Formula za odvajanje imena ispred prefiksa

    Koristite ugnežđene funkcije SEARCH i LEN da biste pronašli vrednost za num_chars:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (4)

  9. Dodajte 1 da biste dobili poziciju znaka posle prvog razmaka (R). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (4 + 1 = 5)

  10. Potražite drugi razmak u ćeliji A2, počevši od pete pozicije (R), pronađene u 2. koraku. (9)

  11. Prebrojte ukupnu dužinu tekstualne niske u ćeliji A2, a zatim oduzmite broj znakova sa leve strane na drugi razmak, pronađen u 3. koraku. Rezultat je broj znakova koji će biti izdvojeni sa desne strane punog imena. (14 - 9 = 5)

Ovaj primer koristi prezime sa crticama. Razmak razdvaja svaku komponentu imena.

Kopirajte ćelije iz tabele i nalepite ih u Excel radni list u ćeliji A1. Formula koju vidite sa leve strane biće prikazana kao referenca, dok će Excel automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Džuli Taft-Rider

Rastavljanje reči na kraju reda u prezimenu

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Ime

    Ime počinje od prvog znaka sleva i završava se na šestoj poziciji (prvom razmaku). Formula izdvaja šest znakova sleva.

    Formula za odvajanje imena i prezimena sa crticom

    Koristite funkciju SEARCH da biste pronašli vrednost num_chars:

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši sleva. (6)

  2. Prezime

    Celo prezime počinje na deset znakova s desna (T) i završava se na prvom znaku s desna (r).

    Formula za odvajanje imena i prezimena sa crticom

    Koristite funkcije LEN i SEARCH da biste pronašli vrednost za num_chars:

    Potražite numeričku poziciju razmaka u ćeliji A2, počevši od prvog znaka sleva. (6)

  3. Prebrojte ukupnu dužinu tekstualne niske koju želite da izdvojite, a zatim oduzmite broj znakova sa leve strane do prvog razmaka, pronađenog u 1. koraku. (16 - 6 = 10)

Razdeljivanje teksta u kolone pomoću čarobnjaka za pretvaranje teksta u kolone

Da li vam je potrebna dodatna pomoć?

Želite još opcija?

Istražite pogodnosti pretplate, pregledajte kurseve za obuku, saznajte kako da obezbedite uređaj i još mnogo toga.

Zajednice vam pomažu da postavljate pitanja i odgovarate na pitanja, dajete povratne informacije i čujete mišljenje od stručnjaka sa bogatim znanjem.

Da li su vam ove informacije koristile?

Koliko ste zadovoljni kvalitetom jezika?
Šta je uticalo na vaše iskustvo?
Kada kliknete na dugme Prosledi“, vaše povratne informacije će se koristiti za poboljšanje Microsoft proizvoda i usluga. Vaš IT administrator će moći da prikupi ove podatke. Izjava o privatnosti.

Hvala vam na povratnim informacijama!

×