Razdeljivanje teksta u različite kolone sa funkcijama

Razdeljivanje teksta u različite kolone sa funkcijama

Važno : Ovaj članak je mašinski preveden, pogledajte odricanje odgovornosti. Pogledajte verziju ovog članka na engleskom jeziku ovde za referencu.

Možete da koristite tekstualne funkcije LEFT, MID, RIGHT, SEARCH i LEN da biste upravljali niskama teksta u podacima. Na primer, možete da raspodelite ime, srednje ime i prezime iz jedne ćelije u tri odvojene kolone.

Ključ ka raspoređivanju komponenti imena i tekstualnih funkcija je pozicija svakog znaka u okviru tekstualne niske. Pozicije razmaka u okviru tekstualne niske su takođe važne zato što ukazuju na početak ili kraj komponenti u nisci.

Na primer, u ćeliji koja sadrži samo ime i prezime, prezime počinje posle prve instance razmaka. Neka imena na listi mogu da sadrže srednje ime, u tom slučaju prezime počinje posle drugog razmaka.

Ovaj članak vam pokazuje kako da izdvojite različite komponente iz raznih formata imena pomoću ove korisne funkcije. Takođe možete da razdelite tekst u različite kolone sa Konvertovanje teksta u kolone

Primer imena

Opis

Ime

Srednje ime

Prezime

Sufiks

1

Jeff Smith

Bez srednjeg imena

Jevrem

Savić

2

Eric S. Kuzmić

Jedan inicijal u sredini

Zoran

S.

Kuzmić

3

Džanaina B. G. Bueno

Dva inicijala u sredini

Džanaina

B. G.

Bueno

4

Kan, Vendi Bet

Prezime na početku, sa zarezom

Vendi

Bet

Kan

5

Ana Meri ž D. Simić

Ime koje se sastoji iz dva dela

Ana Marija

Ž.

Simić

6

Paula Bareto de Matos

Prezime koje se sastoji iz tri dela

Paula

Bareto de Matos

7

James van Eaton

Prezime koje se sastoji iz dva dela

Džejms

van Iston

8

Bejkon ml, Dan K.

Prezime i sufiks na početku, sa zarezom

Dan

K.

Bejkon

ml.

9

Gari Altman III

Sa sufiksom

Gari

Altman

III

10

G. rade Ilić

Sa prefiksom

Rade

Ilić

11

Đurđa Tasić-Radenović

Prezime sa crticom

Đurđa

Tasić-Radenović

Napomena : U u sledećim primerima grafikama, markirano puno ime pokazuje znak koji traži odgovarajuća formula SEARCH.

U ovom primeru razdvaja dve komponente: ime i prezime. Jedan razmak razdvaja dva imena.

Kopirajte ćelije u tabeli i nalepite u Excel radni list u ćeliju A1. Formule koje vidite na levoj strani će biti prikazana za referencu, dok Excel će automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Jovan Savić

Bez srednjeg imena

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Ime  

    Ime počinje prvim znakom u niski (J) i završava se na petom znaku (razmaku). Ova formula daje pet znakova u ćeliji A2, počevši sleva.

    Formula za izdvajanje imena

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom razmaka u ćeliji A2, počevši s leva.

  2. Prezime  

    Prezime počinje kod razmaka, pet znakova zdesna i završava se kod poslednjeg znaka zdesna (ć). Formula izdvaja pet znakova u ćeliji A2, počevši zdesna.

    Formula za izdvajanje prezimena

    Koristite funkcije SEARCH i LEN da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom razmaka u ćeliji A2, počevši s leva. (5)

  3. Izračunajte ukupnu dužinu tekstualne niske, a potom oduzmite broj znakova sa leve strane od prvog razmaka, kao što je dato u 1. koraku.

Ovaj primer koristi ime, inicijal srednjeg imena i prezime. Razmak razdvaja sve komponente imena.

Kopirajte ćelije u tabeli i nalepite u Excel radni list u ćeliju A1. Formule koje vidite na levoj strani će biti prikazana za referencu, dok Excel će automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Zoran S. Kuzmić

Jedan inicijal u sredini

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (inicijal srednjeg imena)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Formula

Rezultat uživo (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Ime  

    Ime počinje prvim znakom sleva (Z) i završava se sa šestim znakom (prvi razmak). Formula izdvaja prvih šest znakova u ćeliji A2, počevši sleva.

    Formula za odvajanje imena i prezimena i inicijal srednjeg imena

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom razmaka u ćeliji A2, počevši s leva. (5)

  2. Srednje ime

    Srednje ime počinje na poziciji sedmog znaka (S) i završava se na poziciji devetog znaka (drugi razmak). Ova formula uključuje ugnežđivanje funkcije SEARCH za pronalaženje druge instance razmaka.

    Formula izdvaja tri znaka, počevši od sedme pozicije.

    Detalji formule za odvajanje imena, srednjih imena i prezimena

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta start_num:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (5).

  3. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (S). Ova numerička pozicija je početna pozicija srednjeg imena. (5 + 1 = 6)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (5)

  4. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (S). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (5 + 1 = 6)

  5. Izvršite pretragu za drugom instancom razmaka u ćeliji A2, počevši od šeste pozicije (S) date u 4. koraku. Ovaj broj znaka je krajnja pozicija srednjeg imena. (8)

  6. Izvršite pretragu za numeričkom pozicijom razmaka u ćeliji A2, počevši od prvog znaka s leva. (5)

  7. Uzmite broj znaka drugog razmaka datog u 5. koraku i oduzmite od njega broj znaka prvog razmaka datog u 6. koraku. Rezultat je broj znakova koje funkcija MID izdvaja iz tekstualne niske počevši od šeste pozicije date u 2. koraku . (8 – 5 = 3)

  8. Prezime  

    Prezime počinje šest znakova s desne strane (K) i završava se kod prvog znaka zdesna (ć). Ova formula uključuje ugnežđivanje funkcije SEARCH za pronalaženje druge i treće instance razmaka (koje su na šestoj i devetoj poziciji sleva).

    Formula izdvaja šest znakova u ćeliji A2, počevši zdesna.

    Druga Funkcija SEARCH u formuli za odvajanje imena, srednjeg, i prezimena
  9. Koristite ugnežđene funkcije SEARCH i LEN da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom razmaka u ćeliji A2, počevši od prvog znaka s leva. (5)

  10. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (S). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (5 + 1 = 6)

  11. Izvršite pretragu za drugom instancom razmaka u ćeliji A2, počevši od šeste pozicije (S) date u 2. koraku. Ovaj broj znaka je krajnja pozicija srednjeg imena. (8)

  12. Izračunajte ukupnu dužinu tekstualne niske u ćeliji A2, a zatim oduzmite broj znakova sa leve strane na drugu instancu razmaka pronađene u koraku 3. Rezultat je broj znakova koje bi trebalo izdvojiti s desna od punog imena. (14 – 8 = 6).

Evo primera kako da izdvojite dva inicijala srednjeg imena. Prva i treća instanca razmaka razdvajaju komponente imena.

Kopirajte ćelije u tabeli i nalepite u Excel radni list u ćeliju A1. Formule koje vidite na levoj strani će biti prikazana za referencu, dok Excel će automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Džanaina B. G. Bueno

Dva inicijala u sredini

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (srednji inicijali)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,1))

Formula

Rezultat uživo (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. Ime  

    Ime počinje prvim znakom sleva (D) i završava se sa devetim znakom (prvi razmak). Formula izdvaja prvih devet znakova u ćeliji A2, počevši sleva.

    Formula za odvajanje imena, prezimena i dva srednja inicijala

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (8)

  2. Srednje ime

    Srednje ime počinje na poziciji desetog znaka (B) i završava se na poziciji petnaestog znaka (drugi razmak). Ova formula uključuje ugnežđivanje funkcije SEARCH za pronalaženje druge instance razmaka.

    Formula izdvaja pet znakova, počevši od desete pozicije.

    Formula za odvajanje imena, prezimena i dva srednja inicijala

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta start_num:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (8)

  3. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (B). Ova numerička pozicija je početna pozicija srednjeg imena. (8 + 1 = 9)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (8)

  4. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (B). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (8 + 1 = 9)

  5. Potražite drugi razmak u ćeliji A2, počevši od desete pozicije (B) pronađene u koraku 4. (11).

  6. Dodajte 1 da biste dobili poziciju znaka nakon drugog razmaka (G). Ovaj broj znaka je početna pozicija na kojoj želite da otpočnete pretragu za trećim razmakom. (11 + 1 = 12)

  7. Izvršite pretragu za trećim razmakom u ćeliji A2, počevši od dvanaeste pozicije date u 6. koraku. (14)

  8. Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2. (8)

  9. Uzmite broj znaka trećeg razmaka datog u 7. koraku i oduzmite od njega broj znaka prvog razmaka datog u 6. koraku. Rezultat je broj znakova koje funkcija MID izdvaja iz tekstualne niske počevši od devete pozicije date u 2. koraku . (8 – 5 = 3)

  10. Prezime  

    Prezime počinje petim znakom zdesna (B) i završava se prvim znakom zdesna (o). Ova formula uključuje ugnežđivanje funkcije SEARCH za pronalaženje prve, druge i treće instance razmaka.

    Formula izdvaja šest znakova u ćeliji A2 počevši sa desne strane punog imena.

    Formula za odvajanje imena, prezimena i dva srednja inicijala

    Koristite ugnežđene funkcije SEARCH i LEN da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (8)

  11. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (B). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (8 + 1 = 9)

  12. Izvršite pretragu za drugom instancom razmaka u ćeliji A2, počevši od devete pozicije (B) date u 2. koraku. (11)

  13. Dodajte 1 da biste dobili poziciju znaka nakon drugog razmaka (G). Ovaj broj znaka je početna pozicija na kojoj želite da otpočnete pretragu za trećim razmakom. (11 + 1 = 12)

  14. Izvršite pretragu za trećim razmakom u ćeliji A2, počevši od dvanaeste pozicije (G) date u 6. koraku. (14)

  15. Izračunajte ukupnu dužinu tekstualne niske u ćeliji A2, a potom oduzmite broj znakova s leva zaključno sa trećom instancom razmaka datom u 5. koraku. Rezultat je broj znakova koji će biti izdvojen sa desne strane punog imena. (14 – 19 = 5)

U ovom primeru, prezime se pojavljuje pre imena, a srednje ime se pojavljuje na kraju. Zarez označava kraj prezimena, a razmak razdvaja svaku komponentu imena.

Kopirajte ćelije u tabeli i nalepite u Excel radni list u ćeliju A1. Formule koje vidite na levoj strani će biti prikazana za referencu, dok Excel će automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Kan, Vendi Bet

Prezime na početku, sa zarezom

Formula

Rezultat (ime)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-SEARCH(" ",A2,1))

Formula

Rezultat (srednje ime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Formula

Rezultat uživo (prezime)

'=LEFT(A2, SEARCH(" ",A2,1)-2)

=LEFT(A2, SEARCH(" ",A2,1)-2)

  1. Ime  

    Ime počinje šestim znakom sleva (V) i završava se sa jedanaestim znakom (drugim razmakom). Zato što se ime pojavljuje u sredini punog imena, morate da koristite funkciju MID da biste izdvojili ime.

    Formula izdvaja šest znakova, počevši od šeste pozicije.

    Formula za odvajanje prezimena za kojim slede ime i srednje ime

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta start_num:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (6)

  2. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (W). Ova numerička pozicija je početna pozicija imena. (6 + 1 = 7)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (6)

  3. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (W). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (6 + 1 = 7)

    Izvršite pretragu za drugom instancom razmaka u ćeliji A2, počevši od sedme pozicije (W) date u 4. koraku. (12)

  4. Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (6)

  5. Uzmite broj znaka drugog razmaka datog u 5. koraku i oduzmite od njega broj znaka prvog razmaka datog u 6. koraku. Rezultat je broj znakova koje funkcija MID izdvaja iz tekstualne niske počevši od sedme pozicije date u 2. koraku. (12 – 6 = 6)

  6. Srednje ime

    Srednje ime počinje trećim znakom zdesna (B) i završava se prvim znakom zdesna (t). Ova formula uključuje ugnežđivanje funkcije SEARCH za pronalaženje prve i druge instance razmaka na petoj i jedanaestoj poziciji sleva.

    Formula izdvaja tri znaka u ćeliji A2, počevši zdesna.

    Formula za odvajanje prezimena za kojim slede ime i srednje ime

    Koristite ugnežđene funkcije SEARCH i LEN da biste pronašli vrednost argumenta start_num:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (6)

  7. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (W). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (6 + 1 = 7)

  8. Izvršite pretragu za drugom instancom razmaka u ćeliji A2, počevši od sedme pozicije (W) date u 2. koraku. (12)

  9. Izračunajte ukupnu dužinu tekstualne niske u ćeliji A2, a potom oduzmite broj znakova s leva zaključno sa drugom instancom razmaka datom u 3. koraku. Rezultat je broj znakova koji će biti izdvojen sa desne strane punog imena. (12 – 16 = 4)

  10. Prezime  

    Prezime počinje prvim znakom sleva (K) i završava se sa trećim znakom (n). Formula izdvaja prva tri znaka u ćeliji A2, počevši sleva.

    Formula za odvajanje prezimena za kojim slede ime i srednje ime

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (6)

  11. Oduzmite 2 da biste dobili numeričku poziciju znaka krajnji prezime (n). Rezultat je broj znakova koje želite da izdvoji LEFT. (6 - 2 = 4)

Ovaj primer koristi dvodelno ime, Mary Kay. Drugi i treći razmak razdvajaju komponente imena.

Kopirajte ćelije u tabeli i nalepite u Excel radni list u ćeliju A1. Formule koje vidite na levoj strani će biti prikazana za referencu, dok Excel će automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Mary Kay D. Andersen

Ime koje se sastoji iz dva dela

Formula

Rezultat (ime)

LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=LEFT(A2, SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Formula

Rezultat (inicijal srednjeg imena)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Formula

Rezultat uživo (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

  1. Ime  

    Ime počinje prvim znakom sleva i završava se jedanaestim znakom (drugim razmakom). Ova formula uključuje ugnežđivanje funkcije SEARCH za pronalaženje druge instance razmaka sleva.

    Formula izdvaja prvih jedanaest znakova u ćeliji A2, počevši sleva.

    Formula za odvajanje imena, srednjeg imena, srednjeg inicijala i prezimena

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (5)

  2. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (K). Rezultat je broj znaka na kom želite da otpočnete pretragu za drugom instancom razmaka. (5 + 1 = 6)

  3. Izvršite pretragu za drugom instancom razmaka u ćeliji A2, počevši od šeste pozicije (K) date u 2. koraku. Rezultat je broj znakova koje funkcija LEFT izdvaja iz tekstualne niske. (9)

  4. Srednje ime

    Srednje ime počinje na poziciji dvanaestog znaka (Ž) i završava se na poziciji četrnaestog znaka (treći razmak). Ova formula uključuje ugnežđivanje funkcije SEARCH za pronalaženje prve, druge i treće instance razmaka.

    Formula izdvaja dva znaka iz sredine, počevši od dvanaeste pozicije.

    Formula za odvajanje imena, srednjeg imena, srednjeg inicijala i prezimena

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost argumenta start_num:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši od prvog znaka s leva. (5)

  5. Dodajte 1 da biste dobili znak nakon prvog razmaka (K). Rezultat je broj znaka na kom želite da otpočnete pretragu za drugom instancom razmaka. (5 + 1 = 6)

  6. Izvršite pretragu za pozicijom druge instance razmaka u ćeliji A2, počevši od šeste pozicije (K) date u 2. koraku. Rezultat je broj znakova koje funkcija LEFT izdvaja s leva. (9)

  7. Dodajte 1 da biste dobili znak nakon drugog razmaka (D). Rezultat je početna pozicija srednjeg imena. (9 + 1 = 10)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom znaka nakon drugog razmaka (D). Rezultat je broj znaka od kog želite da otpočnete pretragu za trećom instancom razmaka. (10)

  8. Izvršite pretragu za numeričkom pozicijom trećeg razmaka u ćeliji A2, počevši s leva. Rezultat je krajnja pozicija srednjeg imena. (12)

  9. Izvršite pretragu za numeričkom pozicijom znaka nakon drugog razmaka (D). Rezultat je početna pozicija srednjeg imena. (10)

  10. Uzmite broj znaka trećeg razmaka datog u 6. koraku i oduzmite od njega broj znaka „D" datog u 7. koraku. Rezultat je broj znakova koje funkcija MID izdvaja iz tekstualne niske počevši od desete pozicije date u 4. koraku. (12 – 10 = 2)

  11. Prezime  

    Prezime počinje petim znakom zdesna. Ova formula uključuje ugnežđivanje funkcije SEARCH za pronalaženje prve, druge i treće instance razmaka na četvrtoj, jedanaestoj i četrnaestoj poziciji.

    Formula izdvaja pet znakova u ćeliji A2, sa desne strane.

    Formula za odvajanje imena, srednjeg imena, srednjeg inicijala i prezimena

    Koristite ugnežđene funkcije SEARCH i LEN da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (5)

  12. Dodajte 1 da biste dobili znak nakon prvog razmaka (K). Rezultat je broj znaka od kog želite da otpočnete pretragu za razmakom. (5 + 1 = 6)

  13. Izvršite pretragu za drugom instancom razmaka u ćeliji A2, počevši od šeste pozicije (K) date u 2. koraku. (9)

  14. Dodajte 1 da biste dobili poziciju znaka nakon drugog razmaka (D). Rezultat je početna pozicija srednjeg imena. (9 + 1 = 10)

  15. Izvršite pretragu za numeričkom pozicijom trećeg razmaka u ćeliji A2, počevši s leva. Rezultat je krajnja pozicija srednjeg imena. (12)

  16. Izračunajte ukupnu dužinu tekstualne niske u ćeliji A2, a potom oduzmite broj znakova s leva zaključno sa trećom instancom razmaka datom u 5. koraku. Rezultat je broj znakova koji će biti izdvojen sa desne strane punog imena. (12 – 20 = 8)

Ovaj primer koristi trodelno prezime: Barreto de Mattos. Prvi razmak označava kraj imena i početak prezimena.

Kopirajte ćelije u tabeli i nalepite u Excel radni list u ćeliju A1. Formule koje vidite na levoj strani će biti prikazana za referencu, dok Excel će automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Paula Bareto de Matos

Prezime koje se sastoji iz tri dela

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (prezime)

RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Ime  

    Ime počinje prvim znakom sleva (P) i završava se sa šestim znakom (prvi razmak). Formula izdvaja prvih šest znakova u ćeliji A2, počevši sleva.

    Formula za odvajanje imena i tri dela prezime

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (6)

  2. Prezime  

    Prezime počinje petnaestim znakom zdesna (B) i završava se sa prvim znakom zdesna (s). Formula izdvaja petnaest znakova u ćeliji A2, počevši zdesna.

    Formula za odvajanje imena i tri dela prezime

    Koristite funkcije LEN i SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (6)

  3. Izračunajte ukupnu dužinu tekstualne niske u ćeliji A2, a potom oduzmite broj znakova s leva zaključno sa prvom instancom razmaka datom u 1. koraku. Rezultat je broj znakova koji će biti izdvojen sa desne strane punog imena. (23 – 6 = 17)

Ovaj primer koristi dvodelno prezime: van Eaton. Prvi razmak označava kraj imena i početak prezimena.

Kopirajte ćelije u tabeli i nalepite u Excel radni list u ćeliju A1. Formule koje vidite na levoj strani će biti prikazana za referencu, dok Excel će automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Džejms van Iston

Prezime koje se sastoji iz dva dela

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Ime  

    Ime počinje prvim znakom sleva (D) i završava se sa sedmim znakom (prvi razmak). Formula izdvaja prvih sedam znakova u ćeliji A2, počevši sleva.

    Formula za odvajanje imena i prezimena koje se sastoji od dva dela

    Koristite funkciju SEARCH da biste pronašli vrednost za broj_znakova:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (6)

  2. Prezime  

    Prezime počinje devetim znakom zdesna (v) i završava se sa prvim znakom zdesna (n). Formula izdvaja devet znakova sa desne strane punog imena.

    Formula za odvajanje imena i prezimena koje se sastoji od dva dela

    Koristite funkcije LEN i SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (6)

  3. Izračunajte ukupnu dužinu tekstualne niske u ćeliji A2, a potom oduzmite broj znakova s leva zaključno sa prvom instancom razmaka datom u 1. koraku. Rezultat je broj znakova koji će biti izdvojen sa desne strane punog imena. (15 – 6 = 9)

U ovom primeru prezime dolazi pre imena, praćeno sufiksom. Zarez razdvaja prezime i sufiks od imena i inicijala u sredini.

Kopirajte ćelije u tabeli i nalepite u Excel radni list u ćeliju A1. Formule koje vidite na levoj strani će biti prikazana za referencu, dok Excel će automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Bejkon ml., Dan K.

Prezime i sufiks na početku, sa zarezom

Formula

Rezultat (ime)

'=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1,SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

Formula

Rezultat (inicijal srednjeg imena)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)+1))

Formula

Rezultat (prezime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (dodatak)

'=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

=MID(A2,SEARCH(" ", A2,1)+1,(SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-2)-SEARCH(" ",A2,1))

  1. Ime  

    Ime počinje trinaestim znakom sleva (D) i završava se šesnaestim znakom (treći razmak). Formula izdvaja tri znaka počevši od trinaeste pozicije.

    Formula za odvajanje poslednju imenovanje i sufiks na početku, sa zarezom

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost argumenta start_num:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (6)

  2. Dodajte 1 da biste dobili znak nakon prvog razmaka (J). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (6 + 1 = 7)

  3. Izvršite pretragu za drugom instancom razmaka u ćeliji A2, počevši od sedme pozicije (J) date u 2. koraku. (11)

  4. Dodajte 1 da biste dobili znak nakon drugog razmaka (D). Rezultat je početna pozicija imena. (11 + 1 = 12)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom znaka nakon drugog razmaka (D). Rezultat je broj znaka od kog želite da otpočnete pretragu za trećom instancom razmaka. (12)

  5. Izvršite pretragu za numeričkom pozicijom trećeg razmaka u ćeliji A2, počevši s leva. Rezultat je krajnja pozicija imena. (15)

  6. Izvršite pretragu za numeričkom pozicijom znaka nakon drugog razmaka (D). Rezultat je početna pozicija imena. (12)

  7. Uzmite broj znaka trećeg razmaka datog u 6. koraku i oduzmite od njega broj znaka „D" datog u 7. koraku. Rezultat je broj znakova koje funkcija MID izdvaja iz tekstualne niske počevši na dvanaestoj poziciji datoj u 4. koraku. (15 – 12 = 3)

  8. Srednje ime

    Srednje ime počinje drugim znakom zdesna (K). Formula izdvaja dva znaka sa desne strane.

    Formula za odvajanje poslednju imenovanje i sufiks na početku, sa zarezom

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (6)

  9. Dodajte 1 da biste dobili znak nakon prvog razmaka (J). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (6 + 1 = 7)

  10. Izvršite pretragu za drugom instancom razmaka u ćeliji A2, počevši od sedme pozicije (J) date u 2. koraku. (11)

  11. Dodajte 1 da biste dobili znak nakon drugog razmaka (D). Rezultat je početna pozicija imena. (11 + 1 = 12)

  12. Potražite numeričku poziciju trećeg razmaka u ćeliji A2, počevši s leve strane. Rezultat je završna pozicija srednjeg imena. (15)

  13. Izračunajte ukupnu dužinu tekstualne niske u ćeliji A2, a potom oduzmite broj znakova s leva zaključno sa trećom instancom razmaka datom u 5. koraku. Rezultat je broj znakova koji će biti izdvojen sa desne strane punog imena. (17 – 15 = 2)

  14. Prezime  

    Prezime počinje prvim znakom sleva (B) i završava se sedmim znakom (prvi razmak). Formula izdvaja sedam znakova sleva.

    Formula za odvajanje poslednju imenovanje i sufiks na početku, sa zarezom

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (6)

  15. Sufiks

    Sufiks počinje osmim znakom sleva (m) i završava se devetim znakom sleva. Formula izdvaja tri znaka počevši od osmog znaka.

    Formula za odvajanje poslednju imenovanje i sufiks na početku, sa zarezom

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta start_num:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (6)

  16. Dodajte 1 da biste dobili znak nakon prvog razmaka (J). Rezultat je početna pozicija imena. (6 + 1 = 7)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (6)

  17. Dodajte 1 da biste dobili numeričku poziciju znaka nakon prvog razmaka (J). Rezultat je broj znaka na kom želite da otpočnete pretragu za drugom instancom razmaka. (7)

  18. Izvršite pretragu za numeričkom pozicijom druge instance razmaka u ćeliji A2, počevši od sedmog znaka datog u 4. koraku. (11)

  19. Oduzmite 1 od broja znaka drugog razmaka datog u 4. koraku da biste dobili broj znaka „,". Rezultat je krajnja pozicija titule. 11 - 1 = 10)

  20. Izvršite pretragu za numeričkom pozicijom prvog razmaka. (6)

  21. Nakon pronalaženja prvog razmaka, dodajte 1 da biste pronašli sledeći znak (J), takođe dat u 3. i 4. koraku. (7)

  22. Uzmite broj znaka „," datog u 6. koraku i oduzmite od njega broj znaka „J" datog u 3. i 4. koraku. Rezultat je broj znakova koje funkcija MID izdvaja iz tekstualne niske počevši od dvanaeste pozicije date u 4. koraku. (10 – 7 = 3)

U ovom primeru, ime je na početku niske, a titula je na kraju, stoga možete da koristite formule slične onima u 2. primeru: koristite funkciju LEFT da biste izdvojili ime, funkciju MID da biste izdvojili prezime i funkciju RIGHT da biste izdvojili titulu.

Kopirajte ćelije u tabeli i nalepite u Excel radni list u ćeliju A1. Formule koje vidite na levoj strani će biti prikazana za referencu, dok Excel će automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Gari Altman III

Ime i prezime sa dodatkom

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (prezime)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Formula

Rezultat (dodatak)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Ime  

    Ime počinje prvim znakom sleva (G) i završava se petim znakom (prvi razmak). Formula izdvaja pet znakova sleva.

    Formula za odvajanje i poslednje ime iza kojeg sledi sufiks

    Potražite numeričku poziciju prvog razmaka u ćeliji A2, počevši s leve strane. (5)

  2. Prezime  

    Prezime počinje šestim znakom sleva (A) i završava se dvanaestim znakom (drugim razmakom). Ova formula uključuje ugnežđivanje funkcije SEARCH za pronalaženje razmaka.

    Formula izdvaja šest znakova od sredine, počevši od šestog znaka.

    Formula za odvajanje i poslednje ime iza kojeg sledi sufiks

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta start_num:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (5)

  3. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (A). Rezultat je početna pozicija prezimena. (5 + 1 = 6)

    Koristite ugnežđene funkcije SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (5)

  4. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (A). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (5 + 1 = 6)

  5. Izvršite pretragu za numeričkom pozicijom druge instance razmaka u ćeliji A2, počevši od šestog znaka datog u 4. koraku. Ovaj broj znaka je krajnja pozicija prezimena. (12)

  6. Izvršite pretragu za numeričkom pozicijom prvog razmaka. (5)

  7. Dodajte 1 da biste pronašli numeričku poziciju znaka nakon prvog razmaka (A), takođe datog u 3. i 4. koraku. (6)

  8. Uzmite broj znaka drugog razmaka datog u 5. koraku i oduzmite od njega broj znaka „A" datog u 6. i 7. koraku. Rezultat je broj znakova koje funkcija MID izdvaja iz tekstualne niske počevši na šestoj poziciji datoj u 2. koraku . (12 – 6 = 6)

  9. Sufiks

    Sufiks počinje tri znaka zdesna. Ova formula uključuje ugnežđivanje funkcije SEARCH za pronalaženje razmaka.

    Formula za odvajanje i poslednje ime iza kojeg sledi sufiks

    Koristite ugnežđene funkcije SEARCH i LEN da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (5)

  10. Dodajte 1 da biste dobili znak nakon prvog razmaka (A). Rezultat je broj znaka na kom želite da otpočnete pretragu za drugom instancom razmaka. (5 + 1 = 6)

  11. Izvršite pretragu za drugom instancom razmaka u ćeliji A2, počevši od šeste pozicije (A) date u 2. koraku. (12)

  12. Izračunajte ukupnu dužinu tekstualne niske u ćeliji A2, a potom oduzmite broj znakova s leva zaključno sa drugom instancom razmaka datom u 3. koraku. Rezultat je broj znakova koji će biti izdvojen sa desne strane punog imena. (15 – 12= 3)

U ovom primeru, imenu prethodi titula, a možete da koristite formule slične onima u 2. primeru: funkciju MID da biste izdvojili ime, funkciju RIGHT da biste izdvojili prezime.

Kopirajte ćelije u tabeli i nalepite u Excel radni list u ćeliju A1. Formule koje vidite na levoj strani će biti prikazana za referencu, dok Excel će automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

G. Rade Ilić

Sa prefiksom

Formula

Rezultat (ime)

'=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

=MID(A2,SEARCH(" ",A2,1)+1,SEARCH(" ",A2,SEARCH(" ",A2,1)+1)-(SEARCH(" ",A2,1)+1))

Formula

Rezultat (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,SEARCH(" ",A2,1)+1))

  1. Ime  

    Ime počinje petim znakom sleva (R) i završava se na devetom znaku (drugom razmaku). Ova formula ugnežđuje funkciju SEARCH da bi pronašla pozicije razmaka. Ona izdvaja četiri znaka, počevši od pete pozicije.

    Formula za odvajanje imena prefiks prethodi

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta start_num:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (4)

  2. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (R). Rezultat je početna pozicija imena. (4 + 1 = 5)

    Koristite ugnežđenu funkciju SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (4)

  3. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (R). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (4 + 1 = 5)

  4. Izvršite pretragu za numeričkom pozicijom druge instance razmaka u ćeliji A2, počevši od petog znaka datog u 3. i 4. koraku. Ovaj broj znaka je krajnja pozicija imena. (9)

  5. Izvršite pretragu za prvim razmakom. (4)

  6. Dodajte 1 da biste pronašli numeričku poziciju znaka nakon prvog razmaka (R), takođe datog u 3. i 4. koraku. (5)

  7. Uzmite broj znaka drugog razmaka datog u 5. koraku i oduzmite od njega broj znaka „R" datog u 6. i 7. koraku. Rezultat je broj znakova koje funkcija MID izdvaja iz tekstualne niske počevši od pete pozicije date u 2. koraku . (9 – 5 = 4)

  8. Prezime  

    Prezime počinje četiri znaka zdesna. Ova formula uključuje ugnežđivanje funkcije SEARCH za pronalaženje razmaka.

    Formula za odvajanje imena prefiks prethodi

    Koristite ugnežđene funkcije SEARCH i LEN da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (4)

  9. Dodajte 1 da biste dobili poziciju znaka nakon prvog razmaka (R). Rezultat je broj znaka od kog želite da otpočnete pretragu za drugom instancom razmaka. (4 + 1 = 5)

  10. Izvršite pretragu za drugom instancom razmaka u ćeliji A2, počevši od pete pozicije (R) date u 2. koraku. (9)

  11. Izračunajte ukupnu dužinu tekstualne niske u ćeliji A2, a potom oduzmite broj znakova s leva zaključno sa drugom instancom razmaka datom u 3. koraku. Rezultat je broj znakova koji će biti izdvojen sa desne strane punog imena. (14 – 9 = 5)

Ovaj primer koristi dva prezimena povezana crticom. Razmak razdvaja sve komponente imena.

Kopirajte ćelije u tabeli i nalepite u Excel radni list u ćeliju A1. Formule koje vidite na levoj strani će biti prikazana za referencu, dok Excel će automatski konvertovati formulu sa desne strane u odgovarajući rezultat.

Savet    Pre nego što nalepite podatke u radni list, podesite širine kolona A i B na 250.

Primer imena

Opis

Đurđa Tasić-Radenović

Prezime sa crticom

Formula

Rezultat (ime)

'=LEFT(A2, SEARCH(" ",A2,1))

=LEFT(A2, SEARCH(" ",A2,1))

Formula

Rezultat (prezime)

'=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))

  1. Ime  

    Ime počinje prvim znakom sleva i završava se sa šestom pozicijom (prvi razmak). Formula izdvaja prvih šest znakova u ćeliji A2, počevši sleva.

    Formula za odvajanje prvi put i prezime sa crticom

    Koristite funkciju SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom prvog razmaka u ćeliji A2, počevši s leva. (6)

  2. Prezime  

    Čitavo prezime počinje sedmim znakom zdesna (T) i završava se prvim znakom zdesna (ć).

    Formula za odvajanje prvi put i prezime sa crticom

    Koristite funkcije LEN i SEARCH da biste pronašli vrednost argumenta num_chars:

    Izvršite pretragu za numeričkom pozicijom razmaka u ćeliji A2, počevši od prvog znaka s leva. (6)

  3. Izračunajte ukupnu dužinu tekstualne niske koja se izdvaja, a potom oduzmite broj znakova s leva zaključno sa prvom instancom razmaka datom u 1. koraku. (16 - 6= 10)

Napomena : Odricanje odgovornosti za mašinski prevod: Ovaj članak je preveo računarski sistem bez ljudske intervencije. Microsoft nudi ove mašinske prevode da bi pomogao korisnicima koji ne govore engleski da uživaju u sadržaju o Microsoft proizvodima, uslugama i tehnologijama. Budući da je članak mašinski preveden, može da sadrži greške u rečniku, sintaksi ili gramatici.

Takođe pogledajte

Razdeljivanje teksta u različite kolone sa Konvertovanje teksta u kolone

Unapredite veštine
Istražite obuku
Prvi nabavite nove funkcije
Pridružite se Office Insider korisnicima

Da li su vam ove informacije koristile?

Hvala vam na povratnim informacijama!

Hvala za povratne informacije! Zvuči da će biti od pomoći ako vas povežemo sa našim agentima Office podrške.

×