Korišćenje funkcije IF sa funkcijama AND, OR i NOT

Funkcija IF vam omogućava da logički uporedite vrednost i ono što očekujete tako što testira stanje i vraća rezultat ako je taj uslov True ili False.

  • =IF(nešto ima vrednost True, uradite nešto, u suprotnom uradite nešto drugo)

Ali šta ako treba da testirate više uslova, gde recimo svi uslovi moraju biti True ili False (AND) ili samo jedan uslov mora da bude True ili False (OR) ili ako želite da proverite da li je uslov ne NOT ispunjava vaše kriterijume? Sve 3 funkcije se mogu koristiti samostalno, ali ćete ih mnogo češće videti uparene sa IF funkcijom.

Koristite funkciju IF, zajedno sa AND, OR i NOT da biste izvršili više procena ako su uslovi True ili False.

Sintaksa

  • IF(AND()) - IF(AND(logical1, [logical2], ...), value_if_true, [value_if_false]))

  • IF(OR()) - IF(OR(logical1, [logical2], ...), value_if_true, [value_if_false]))

  • IF(NOT()) - IF(NOT(logical1), value_if_true, [value_if_false]))

Ime argumenta

Opis

logički_test (neophodno)

Uslov koji želite da testirate.

vrednost_ako_je_tačno (neophodno)

Vrednost koja želite da se vrati ako logički_tekst ima rezultat TRUE.

vrednost_ako_je_netačno (neophodno)

Vrednost koja želite da se vrati ako logički_tekst ima rezultat FALSE.

Evo preglede kako da pojedinačno strukturirate funkcije AND, OR i NOT. Kada kombinujete svaku od njih sa izjavom IF, one izgledaju ovako:

  • AND – =IF(AND(Nešto je True, Nešto drugo True), Vrednost za True, Vrednost za False)

  • OR – =IF(OR(Nešto je True, Nešto drugo True), Vrednost za True, Vrednost za False)

  • NOT – =IF(NOT(Nešto je True), Vrednost za True, Vrednost za False)

Primeri

Slede primeri nekih uobičajenih ugnežđenih IF(AND()), IF(OR()) i IF(NOT()) izjava. Funkcije AND i OR mogu da podrže najviše 255 pojedinačnih uslova, ali nije dobro da koristite više od nekoliko jer složene, ugnežđene formule mogu biti veoma teške za pravljenje, testiranje i održavanje. Funkciji NOT potreban je samo jedan uslov.

Primeri korišćenja funkcije IF sa AND, OR i NOT za izračunavanje numeričkih vrednosti i teksta

Evo formula napisanih prema njihovoj logici:

Formula

Opis

=IF(AND(A2>0,B2<100),TRUE, FALSE)

Ako je A2 (25) veće od 0, AND B2 (75) manje od 100, vraća se vrednost TRUE, u suprotnom se vraća vrednost FALSE. U ovom slučaju su oba uslova tačna, tako da se vraća vrednost TRUE.

=IF(AND(A3="Crveno",B3="Zeleno"),TRUE,FALSE)

If A3 (“Plava”) = “Crvena”, AND B3 (“Zelena”) jednako “Zelena” vraća se TRUE, u suprotnom vraća se FALSE. U ovom slučaju samo je prvi uslov tačan, zato se dobija vrednost FALSE.

=IF(OR(A4>0,B4<50),TRUE, FALSE)

Ako je A4 (25) veće od 0, OR B4 (75) manje od 50, vraća se vrednost TRUE, u suprotnom se vraća vrednost FALSE. U ovom slučaju, samo prvi uslov ima vrednost TRUE, ali pošto OR zahteva da samo jedan argument bude tačan, formula vraća vrednost TRUE.

=IF(OR(A5="Crveno",B5="Zeleno"),TRUE,FALSE)

IF A5 (“Plava”) jednako “Crvena”, OR B5 (“Zelena”) jednako “Zelena” vraća se TRUE, u suprotnom vraća se FALSE. U ovom slučaju, drugi argument je True i zato formula vraća vrednost TRUE.

=IF(NOT(A6>50),TRUE,FALSE)

IF A6 (25) NOT veće od 50, vraća se vrednost TRUE, u suprotnom se vraća vrednost FALSE. U ovom slučaju 25 nije veće od 50, tako da formula vraća vrednost TRUE.

=IF(NOT(A7="Crveno"),TRUE,FALSE)

IF A7 („Plavo”) NOT jednako „Crveno”, vraća vrednost TRUE, u suprotnom vraća vrednost FALSE.

Imajte na umu da primeri imaju zatvorene zagrade nakon unosa odgovarajućih uslova. Preostali True/False argumenti zatim ostaju kao deo spoljašnje IF izjave. Takođe, možete da zamenite tekstualne ili numeričke vrednosti za vrednosti TRUE/FALSE koje se vraćaju u primerima.

Evo nekoliko primera korišćenja funkcije AND, OR i NOT za proveru datuma.

Primeri korišćenja funkcije IF sa AND, OR i NOT za proveru datuma

Evo formula napisanih prema njihovoj logici:

Formula

Opis

=IF(A2>B2,TRUE,FALSE)

IF A2 je veće od B2, vraća se vrednost TRUE, u suprotnom se vraća vrednost FALSE. U ovom slučaju 12.03.2014. nije veće od 01.01.2014. pa formula vraća vrednost TRUE.

=IF(AND(A3>B2,A3<C2),TRUE,FALSE)

IF A3 je veće od B2 AND A3 je manje od C2, vraća se vrednost TRUE, u suprotnom se vraća vrednost FALSE. U ovom slučaju, oba argument su tačna i zato formula vraća vrednost TRUE.

=IF(OR(A4>B2,A4<B2+60),TRUE,FALSE)

IF A4 je veće od B2 OR A4 je manje od B2+60, vraća se vrednost TRUE, u suprotnom se vraća vrednost FALSE. U ovom slučaju prvi argument tačan, ali drugi je netačan. Pošto OR zahteva da samo jedan od argumenata bude tačan, formula vraća vrednost TRUE. Ako koristite čarobnjak za proveru formulu na kartici „Formule“, vidćete kako Excel proverava formulu.

=IF(NOT(A5>B2),TRUE,FALSE)

IF A5 nije veće od B2, vraća se vrednost TRUE, u suprotnom se vraća vrednost FALSE. U ovom slučaju, A5 je veće od B2, tako da formula vraća vrednost FALSE.

Primer čarobnjaka za proveru formule

Korišćenje AND, OR i NOT uz uslovno oblikovanje

Možete da koristite AND, OR i NOT za postavljanje kriterijuma uslovnog oblikovanja pomoću opcija „formula“. Kada to uradite možete da izostavite funkciju IF i koristite samo AND i OR.

Na kartici Početak kliknite na dugme Uslovno oblikovanje > Novo pravilo. Zatim izaberite opciju „Koristi formulu za određivanje ćelija koje treba oblikovati“, unesite formulu i primenite oblikovanje po vašem izboru.

Uslovno oblikovanje > dijalog „Uređivanje pravila“ koji prikazuje metod „Formula“

Koristeći prethodne primere sa datumima, evo kako bi formule izgledale.

Primer korišćenja AND, OR i NOT kao testova uslovnog oblikovanja


Formula

Opis

=A2>B2

Ako je A2 veće od B2, oblikujte ćelije. U suprotnom, nemojte ništa da radite.

=AND(A3>B2,A3<C2)

Ako je A3 veće od B2 AND A3 je manje od C2, oblikujte ćelije. U suprotnom, nemojte ništa da radite.

=OR(A4>B2,A4<B2+60)

Ako je A4 veće od B2 OR A4 je manje od B2 plus 60 (dana) , oblikujte ćelije. U suprotnom, nemojte ništa da radite.

=NOT(A5>B2)

Ako je A5 NOT veće od B2, oblikujte ćelije. U suprotnom, nemojte ništa da radite. U ovom slučaju, A5 je veće od B2, tako da formula vraća vrednost FALSE. Ako promenite formulu tako da = NOT(B2>A5), vraćaće vrednost TRUE i ćelija će biti oblikovana.

Napomena : Uobičajena greška je unos formula u uslovno oblikovanje bez znaka jednakosti (=). Ako to uradite, videćete da će dijalog „Uslovno oblikovanje“ dodati znak jednakosti i ponude za formule – = "ili (A4 > B2, A4 < B2 + 60)”, tako da ćete morati da uklonite navodnike pre pravilnog odgovora formule.

Vrh stranice

Potrebna vam je dodatna pomoć?

Možete uvek da postavite pitanje stručnjaku u zajednici Excel Tech Community, dobijete podršku u zajednici Answers community ili predložite novu funkciju ili poboljšanje na sajtu Excel User Voice.

Takođe pogledajte

Pogledajte video o korišćenju funkcije IF

Saznajte kako se koriste ugnežđene funkcije u formuli

Funkcija IF

Funkcija AND

Funkcija OR

Funkcija NOT

Pregled formula u programu Excel

Izbegavanje neispravnih formula

Korišćenje provere grešaka za otkrivanje grešaka u formulama

Tasterske prečice u programu Excel 2016 za Windows

Tasterske prečice u programu Excel 2016 za Mac

Logičke funkcije (referenca)

Excel funkcije (abecednim redom)

Excel funkcije (po kategorijama)

Unapredite veštine
Istražite obuku
Prvi nabavite nove funkcije
Pridružite se Office Insider korisnicima

Da li su vam ove informacije koristile?

Hvala vam na povratnim informacijama!

Hvala za povratne informacije! Zvuči da će biti od pomoći ako vas povežemo sa našim agentima Office podrške.

×