Izračunavanje razlike između dva datuma

Izračunavanje razlike između dva datuma

Koristite funkciju DATEDIF kada želite da izračunate razliku između dva datuma. Prvo unesite datum početka u jednu ćeliju i datum završetka u drugu. Zatim unesite formulu sličnu nekoj od sledećih.

Razlika u danima

=DATEDIF(D9,E9,"d") sa rezultatom 856

U ovom primeru datum početka je u ćeliji D9, a datum završetka u E9. Formula je u ćeliji F9. Parametar „d“ vraća broj celih dana između dva datuma.

Razlika u sedmicama

=(DATEDIF(D13,E13,"d")/7) i rezultat: 122,29

U ovom primeru datum početka je u ćeliji D13, a datum završetka u E13. Parametar „d“ vraća broj dana. Ali zapazite da na kraju stoji /7. Ta opcija deli broj dana sa 7, pošto u sedmici ima 7 dana. Imajte na umu da ovaj rezultat takođe treba da bude oblikovan kao broj. Pritisnite kombinaciju tastera CTRL + 1. Zatim izaberite stavke Broj > Decimalnih mesta: 2.

Razlika u mesecima

=DATEDIF(D5,E5,"m") i rezultat: 28

U ovom primeru datum početka je u ćeliji D5, a datum završetka u E5. U formuli, parametar „m“ vraća broj celih meseci između dva dana.

Razlika u godinama

=DATEDIF(D2,E2,"y") i rezultat: 2

U ovom primeru datum početka je u ćeliji D2, a datum završetka u E2. Parametar „y“ vraća broj celih godina između dva dana.

Izračunavanje uzrasta prema dosadašnjim godinama, mesecima i danima

Možete i da izračunate nečiju starost ili dužinu nečijeg radnog staža. Rezultat može da bude nešto poput „2 godine, 4 meseca, 5 dana“.

1. Koristite DATEDIF da biste otkrili ukupan broj godina.

=DATEDIF(D17,E17,"y") i rezultat: 2

U ovom primeru datum početka je u ćeliji D17, a datum završetka u E17. U formuli, parametar „y“ vraća broj celih godina između dva dana.

2. Koristite DATEDIF ponovo sa parametrom „ym“ da biste izračunali mesece.

=DATEDIF(D17,E17,"ym") i rezultat: 4

U nekoj drugoj ćeliji, koristite formulu DATEDIF sa parametrom „ym“. Parametar „ym“ vraća broj preostalih meseci nakon poslednje cele godine.

3. Koristite neku drugu formulu da biste izračunali dane.

=DATEDIF(D17,E17,"md") i rezultat: 5

Sada treba da pronađemo broj preostalih dana. To ćemo uraditi tako što ćemo napisati drugu vrstu formule, prikazanu iznad. Ova formula oduzima prvi dan meseca koji se završava (1.5.2016) od originalnog datuma završetka u ćeliji E17 (6.5.2016). Evo kako to radi: Prvo funkcija DATE pravi datum, 1.5.2016. Pravi ga pomoću godine u ćeliji E17 i meseca u ćeliji E17. Zatim 1 predstavlja prvi dan tog meseca. Rezultat za funkciju DATE jeste 1.5.2016. Zatim to oduzimamo od originalnog datuma završetka u ćeliji E17, koji je 6.5.2016. Kada od 6.5.2016. oduzmemo 1.5.2016, dobijamo 5 dana.

Napomena : Preporučujemo da ne koristite argument „md“ funkcije DATEDIF jer on može da izračuna netačne rezultate.

4. Opcionalno: Kombinujte tri formule u jednu.

=DATEDIF(D17,E17,"y")&" years, "&DATEDIF(D17,E17,"ym")&" months, "&DATEDIF(D17,E17,"md")&" days" i rezultat: 2 godine, 4 meseca, 5 dana

Možete da smestite sva tri izračunavanja u jednu ćeliju, kao u ovom primeru. Koristite znake „ampersand“, znake navoda i tekst. Formula je duža za kucanje, ali bar je sve u jednoj ćeliji. Savet: Pritisnite kombinaciju tastera ALT+ENTER da biste uneli prelome reda u formulu. Tako će biti lakša za čitanje. Takođe, pritisnite kombinaciju tastera CTRL+SHIFT+U ako ne vidite čitavu formulu.

Preuzmite naše primere

Možete da preuzmete probnu radnu svesku sa svim primerima iz ovog članka. Možete da koristite njih ili da napravite sopstvene formule.

Preuzmite primere izračunavanja datuma

Druga izračunavanja datuma i vremena

Kao što ste videli iznad, funkcija DATEDIF izračunava razliku između datuma početka i datuma završetka. Međutim, umesto da unosite konkretne datume, možete i da koristite funkciju TODAY() unutar formule. Kada koristite funkciju TODAY(), Excel kao datum koristi trenutni datum računara. Imajte na umu da će se to promeniti kada se datoteka ponovo otvori nekog drugog dana u budućnosti.

=DATEDIF(TODAY(),D28,"y") i rezultat: 984

Imajte na umu da je u vreme dok je ovo pisano, dan bio 6. oktobar 2016.

Koristite funkciju NETWORKDAYS.INTL kada želite da izračunate broj radnih dana između dva datuma. Možete i da je podesite tako da izuzima vikende i praznike.

Pre nego što počnete: Odlučite da li želite da izuzmete datume praznika. Ako želite, unesite listu datuma praznika u zasebnoj oblasti ili na zasebnom listu. Stavite svaki datum praznika u posebnu ćeliju. Zatim izaberite te ćelije i izaberite stavke Formule > Definiši ime. Imenujte opseg MojiPraznici i kliknite na dugme U redu. Zatim napravite formulu pomoću koraka ispod.

1. Unesite datum početka i datum završetka.

Datum početka u ćeliji D53 je 1.1.2016, a datum završetka u ćeliji E53 je 31.12.2016.

U ovom primeru datum početka je u ćeliji D53, a datum završetka u E53.

2. U neku drugu ćeliju unesite formulu poput ove:

=NETWORKDAYS.INTL(D53,E53,1) i rezultat: 261

Unesite formulu kao u primeru iznad. Broj 1 u formuli određuje subotu i nedelju kao dane vikenda i izuzima ih iz ukupnog zbira.

Napomena: Excel 2007 nema funkciju NETWORKDAYS.INTL. Međutim, ima NETWORKDAYS. Gornji primer bi ovako glasio u programu Excel 2007: =NETWORKDAYS(D53,E53). Ne navodite 1 jer NETWORKDAYS podrazumeva da su subota i nedelja vikend.

3. Ako treba, promenite 1.

Intellisense lista koja prikazuje 2 – nedelja, ponedeljak; 3 – ponedeljak, utorak i tako dalje

Ako vam subota i nedelja nisu dani vikenda, umesto 1 unesite neki drugi broj sa liste IntelliSense. Na primer, 2 navodi da su dani vikenda nedelja i ponedeljak.

Ako koristite Excel 2007, preskočite ovaj korak. Funkcija NETWORKDAYS u programu Excel 2007 uvek podrazumeva da su subota i nedelja vikend.

4. Unesite ime opsega praznika.

=NETWORKDAYS.INTL(D53,E53,1,MojiPraznici) i rezultat: 252

Ako ste ime opsega praznika napravili u odeljku „Pre nego što počnete“, unesite ga na kraju kao ovde. Ako nemate praznike, možete da izostavite zarez i segment „MojiPraznici“. Ako koristite Excel 2007, gornji primer bi glasio ovako: =NETWORKDAYS(D53,E53,MojiPraznici).

Savet: Ako ne želite da navedete referencu za ime opsega praznika, možete i da unesete opseg, na primer D35:E:39. Mogli biste i da unesete svaki praznik unutar formule. Na primer, ako su vam praznici 1. i 2. januara 2016, uneli biste ih ovako: =NETWORKDAYS.INTL(D53,E53,1,{"1.1.2016","2.1.2016"}). U programu Excel 2007, to bi izgledalo ovako: =NETWORKDAYS(D53,E53,{"1.1.2016","2.1.2016"})

Možete da izračunate proteklo vreme tako što ćete jedno vreme oduzeti od drugog. Prvo unesite vreme početka u jednu ćeliju, a zatim vreme završetka u drugu. Obavezno unesite kompletno vreme, uključujući čas, minut i razmak pre AM ili PM. Evo kako:

1. Unesite vreme početka i vreme završetka.

Datum/vreme početka 7:15 AM, datum/vreme završetka 4:30 PM

U ovom primeru vreme početka je u ćeliji D80, a vreme završetka u E80. Obavezno unesite čas, minut i razmak pre AM ili PM.

2. Podesite format h:mm AM/PM.

Dijalog „Oblikovanje ćelija“ komanda „Prilagođeno“, tip h:mm AM/PM

Izaberite oba datuma i pritisnite kombinaciju tastera CTRL + 1 (ili Slika ikonice MAC komandnog dugmeta + 1 na Mac računaru). Obavezno izaberite stavke Prilagođeno > h:mm AM/PM, ako to već nije podešeno.

3. Oduzmite dva vremena.

=E80-D80 i rezultat: 9:15 AM

U nekoj drugoj ćeliji oduzmite ćeliju sa vremenom početka od ćelije sa vremenom završetka.

4. Podesite format h:mm.

Dijalog „Oblikovanje ćelija“, komanda „Prilagođeno“, tip h:mm

Pritisnite kombinaciju tastera CTRL + 1 (ili Slika ikonice MAC komandnog dugmeta + 1 na Mac računaru). Izaberite stavke Prilagođeno > h:mm da biste izuzeli AM i PM iz rezultata.

Da biste izračunali vreme između dva datuma i vremena, možete jednostavno da oduzmete jedno od drugog. Međutim, morate da primenite oblikovanje na svaku ćeliju da biste bili sigurni da će Excel vratiti rezultat koji želite.

1. Unesite dva puna datuma i vremena.

Datum početka 1.1.16. 1:00 PM; datum završetka 2.1.16. 2:00 PM

U jednu ćeliju unesite kompletan datum/vreme početka. U neku drugu ćeliju unesite kompletan datum/vreme završetka. Svaka ćelija treba da ima mesec, dan, godinu, čas, minut i razmak ispred AM ili PM.

2. Podesite format 14.3.12. 1:30 PM.

Dijalog „Oblikovanje ćelija“, komanda „Prilagođeno“, tip 14.3.12. 1:30 PM

Izaberite obe ćelije i pritisnite kombinaciju tastera CTRL + 1 (ili Slika ikonice MAC komandnog dugmeta + 1 na Mac računaru). Zatim izaberite stavke Datum > 14.3.12. 1:30 PM. Ovo nije datum koji ćete podesiti, već samo primer toga kako će format izgledati. Imajte na umu da u verzijama pre verzije Excel 2016, ovaj format može da ima drugačiji uzorak datuma, na primer 14.3.01. 1:30 PM.

3. Oduzmite ove dve stavke.

=E84-D84 i rezultat 1,041666667

U nekoj drugoj ćeliji oduzmite datum/vreme početka od datuma/vremena završetka. Rezultat će verovatno izgledati kao broj sa decimalnim ostatkom. To ćete ispraviti u sledećem koraku.

4. Podesite format [h]:mm.

Dijalog „Oblikovanje ćelija“ komanda „Prilagođeno“, tip [h]:mm

Pritisnite kombinaciju tastera CTRL + 1 (ili Slika ikonice MAC komandnog dugmeta + 1 na Mac računaru). Izaberite stavku Prilagođeno. U polje Tip unesite [h]:mm.

Takođe pogledajte

Funkcija DATEDIF

Funkcija NETWORKDAYS.INTL

NETWORKDAYS

Još funkcija za datum i vreme

Izračunavanje razlike između dva vremena

Unapredite veštine
Istražite obuku
Prvi nabavite nove funkcije
Pridružite se Office Insider korisnicima

Da li su vam ove informacije koristile?

Hvala vam na povratnim informacijama!

Hvala za povratne informacije! Zvuči da će biti od pomoći ako vas povežemo sa našim agentima Office podrške.

×