Funkcija TEXT

Saradnici: Josif „Brka“ Brkić Dimitrije Mihajlović

Funkcija TEXT omogućava da promenite kako broj izgleda tako što ćete primeniti oblikovanje na njega pomoću kodova za oblikovanje. To je korisno u situacijama kada želite da prikažete brojeve u čitljivijem obliku ili da kombinujete brojeve sa tekstom ili simbolima.

Napomena : Funkcija TEXT konvertuje brojeve u tekst, što može da oteža upućivanje na njih kasnije u izračunavanjima. Najbolje je da zadržite originalnu vrednost u jednoj ćeliji, a zatim da koristite funkciju TEXT u drugoj ćeliji. Onda, ako treba da sastavite druge formule, uvek upućujte na originalnu vrednost, a ne na rezultat funkcije TEXT.

Sintaksa

TEXT(vrednost, oblik_teksta)

Sintaksa funkcije TEXT ima sledeće argumente:

Ime argumenta

Opis

vrednost

Numerička vrednost koju želite da konvertujete u tekst.

oblik_teksta

Tekstualna niska koja definiše oblikovanje koje želite da primenite na pruženu vrednost.

Pregled

U svom najjednostavnijem obliku, funkcija TEXT glasi:

  • =TEXT(vrednost koju želite da oblikujete, "kôd za oblikovanje koji želite da primenite")

Evo nekih popularnih primera koje možete da kopirate direktno u Excel kako biste sami eksperimentisali. Obratite pažnju na kodove za oblikovanje pod znacima navoda.

Formula

Opis

=TEXT(1234,567,"$#,##0.00")

Valuta sa znakom za razdvajanje hiljada i 2 decimale, na primer 1.234,57 USD. Imajte na umu da Excel zaokružuje vrednost na 2 decimalna mesta.

=TEXT(TODAY(),"DD/MM/YY")

Današnji datum u obliku DD/MM/YY, na primer 14/03/12

=TEXT(TODAY(),"DDDD")

Današnji dan u sedmici, na primer ponedeljak.

=TEXT(NOW(),"H:MM")

Trenutno vreme, na primer 13:29

=TEXT(0,285,"0,0%")

Procenat, na primer 28,5%

=TEXT(4,34 ,"# ?/?")

Razlomak, na primer 4 1/3

=TRIM(TEXT(0,34,"# ?/?"))

Razlomak, na primer 1/3 Imajte na umu da se koristi funkcija TRIM kako bi se uklonio razmak na početku decimalne vrednosti.

=TEXT(12200000,"0,00E+00")

Naučni način zapisivanja, na primer 1,22E+07

=TEXT(1234567898,"[<=9999999]###-####;(###) ###-####")

Specijalno (broj telefona), na primer (123) 456-7898

=TEXT(1234,"0000000")

Dodaje početne nule (0), na primer 0001234

=TEXT(123456,"##0° 00' 00''")

Prilagođeno – geografska širina/geografska dužina

Napomena : Iako funkciju TEXT možete da koristite da biste promenili oblikovanje, to nije jedini način. Oblik možete da promenite bez formule tako što ćete pritisnuti kombinaciju tastera CTRL+1 (ili Slika ikonice MAC komandnog dugmeta +1 na Mac računaru), zatim izabrati željeni oblik u okviru stavke Oblikovanje ćelija > dijalog Broj.

Preuzmite naše primere

Možete da preuzmete primer radne sveske koja sadrži sve primere funkcije TEXT iz ovog članka uz još neke dodatne. Možete da ih pratite ili da napravite sopstvene kodove za oblikovanje funkcije TEXT.

Preuzimanje primera funkcije TEXT programa Excel

Drugi dostupni kodovi za oblikovanje

Dijalog Oblikovanje ćelija možete da koristite da biste pronašli druge dostupne kodove za oblikovanje:

  1. Pritisnite kombinaciju tastera Ctrl+1 ( Slika ikonice MAC komandnog dugmeta +1 na Mac računaru) da biste otvorili dijalog Oblikovanje ćelija.

  2. Izaberite željeni oblik sa kartice Broj.

  3. Izaberite opciju Prilagođeno,

  4. Željeni kôd za oblikovanje sada je prikazan u polju Tip. U ovom slučaju izaberite sve iz polja Tip osim tačke i zareza (;) i simbola @. U dolenavedenom primeru izabrali smo i kopirali samo dd/mm/yy.

  5. Pritisnite kombinaciju tastera Ctrl+C da biste kopirali kôd za oblikovanje, a zatim dugme Otkaži da biste odbacili dijalog Oblikovanje ćelija.

  6. Sve što sada treba da uradite jeste da pritisnete kombinaciju tastera Ctrl+V da biste nalepili kôd za oblikovanje u TEXT formulu, na primer: =TEXT(B2,"dd/mm/yy"). Obavezno nalepite kôd za oblikovanje unutar znakova navoda ("kôd za oblikovanje"), u suprotnom Excel daje poruku o grešci.

Primer korišćenja dijaloga „Oblikovanje > Ćelije > Broj > Prilagođeno“ da bi Excel kreirao niske za oblikovanje za vas.

Kodovi za oblikovanje po kategoriji

Slede neki primeri toga na koji način možete da primenite različite oblike brojeva na vrednosti pomoću dijaloga Oblikovanje ćelija, a zatim koristite opciju Prilagođeno da biste kopirali te kodove za oblikovanje u funkciju TEXT.

Zašto Excel briše moje početne nule?

Excel je obučen da traži brojeve koji su uneti u ćelije, a ne brojeve koji izgledaju kao tekst, kao što su brojevi delova ili SKU-ovi. Da biste zadržali početne nule, oblikujte ulazni opseg kao tekst pre nego što nalepite ili unesete vrednosti. Izaberite kolonu ili opseg u koji ćete unositi vrednosti, a zatim koristite kombinaciju tastera CTRL+1 da biste otvorili dijalog Oblikovanje > Ćelije i na karticiBroj izaberite stavku Tekst. Excel sada zadržava početne nule.

Ako ste već uneli podatke i Excel je uklonio početne nule, možete da koristite funkciju TEXT da biste ih dodali nazad. Možete da uputite na ćeliju na vrhu sa vrednostima i da koristite formulu =TEXT(vrednost,"00000"), gde broj nula predstavlja ukupan željeni broj znakova, a zatim je kopirajte i nalepite u ostatak opsega.

Primeri korišćenja funkcije TEXT za oblikovanje početnih nula.  =TEXT(A2,"00000")

Ako iz nekog razloga tekstualne vrednosti treba ponovo da konvertujete u brojeve, možete da ih pomnožite sa 1, na primer =D4*1 ili da koristite dvostruki unarni operator (--), na primer =--D4.

Excel razdvaja hiljade tačkama ako oblik sadrži tačku (.) koja se nalazi između znakova brojeva (#) ili nula. Na primer, ako je niska za oblikovanje "#.###", Excel prikazuje broj 12200000 kao 12.200.000.

Tačka koja prati čuvar mesta za cifru razdeljuje broj na 1.000. Na primer, ako je niska za oblikovanje "#.###,0,", Excel prikazuje broj 12200000 kao 12.200,0.

Primeri funkcije TEXT pomoću znaka za razdvajanje hiljada

Napomene : 

  • Znak za razdvajanje hiljada zavisi od regionalnih postavki. U SAD to je zarez, ali u drugim lokalnim standardima može da bude tačka (.).

  • Znak za razdvajanje hiljada dostupan je za oblike broja, valute i računovodstvene oblike.

U nastavku su primeri standardnih oblika broja (samo znak za razdvajanje hiljada i decimale), valute i računovodstvenih oblika. Oblik valute omogućava da umetnete simbol valute po izboru i poravnava ga pored valute, dok računovodstveni oblik poravnava simbol valute na levoj strani ćelije, a vrednost na desnoj. Obratite pažnju na razliku između kodova za oblikovanje oblika valute i računovodstvenog oblika u nastavku, pri čemu računovodstveni oblik koristi zvezdicu (*) da bi napravio razmak između simbola i vrednosti.

Primeri funkcije TEXT sa formatima „Broj“, „Valuta“ i „Računovodstvo“

Da biste pronašli kôd za oblikovanje za simbol valute, prvo pritisnite kombinaciju tastera Ctrl+1 (ili Slika ikonice MAC komandnog dugmeta +1 na Mac računaru), izaberite željeni oblik, a zatim odaberite simbol u padajućem meniju Simbol:

Izbor simbola valute u dijalogu „Oblikovanje ćelija“

Zatim izaberite stavku Prilagođeno sa leve strane odeljka Kategorija i kopirajte kôd za oblikovanje, uključujući simbol valute.

Funkcija TEXT – prilagođena valuta sa simbolom

Napomena : Funkcija TEXT ne podržava oblikovanje boje, tako da ako kopirate kôd za oblikovanje broja iz dijaloga „Oblikovanje ćelija“ koji obuhvata boju, na primer: $#.##0,00_);[Crvena]($#.##0,00), funkcija TEXT prihvata kôd za oblikovanje, ali ne prikazuje boju.

Način na koji se prikazuje datum možete da izmenite pomoću kombinacije „M“ za mesece, „D“ za dane i „Y“ za godine.

Kodovi formata meseca, dana i godine

Kodovi za oblikovanje u funkciji TEXT ne razlikuju velika i mala slova, tako da možete da koristite „M“ ili „m“, „D“ ili „d“, „Y“ ili „y“.

Excel MVP Minda Trejsi

Minda preporučuje...

Ako Excel datoteke i izveštaje delite sa korisnicima iz različitih zemalja, onda bi možda trebalo da im date izveštaj na njihovom jeziku. Excel MVP, Minda Trejsi ima sjajno rešenje u ovom članku Excel datumi prikazani na raznim jezicima. On obuhvata i uzorak radne sveske koji možete da preuzmete.

Način na koji se prikazuje vreme možete da izmenite pomoću kombinacije „H“ za časove, „M“ za minute ili „S“ za sekunde i „AM/PM“ za 12-časovni sat.

Formati vremena za časove, minute i sekunde

Ako izostavite „AM/PM“ ili „A/P“, vreme se prikazuje na osnovu 24-časovnog sata.

Kodovi za oblikovanje u funkciji TEXT ne razlikuju velika i mala slova, tako da možete da koristite „H“ ili „h“, „M“ ili „m“, „S“ ili „s“, „AM/PM“ ili „am/pm“.

Način na koji se prikazuju decimalne vrednosti možete da izmenite pomoću oblika procenta (%).

Kodovi formata za procenat

Način na koji se prikazuju decimalne vrednosti možete da izmenite pomoću oblika razlomka (?/?).

Kodovi formata za razlomke

Naučni način zapisivanja jeste način za prikazivanje brojeva kao decimala između 1 i 10, pomnoženih sa stepenom od 10. On se često koristi za skraćivanje prikaza velikih brojeva.

Kodovi formata za naučni način zapisivanja

Excel pruža 4 specijalna oblika:

  • Poštanski broj – "00000"

  • Poštanski broj + 4 – "00000-0000"

  • Broj telefona – "[<=9999999]###-####;(###) ###-####"

  • Matični broj socijalnog osiguranja – "000-00-0000"

Specijalni formati za funkciju TEXT

Specijalni oblici se razlikuju u zavisnosti od lokalnog standarda, ali ako za vaš lokalni standard ne postoje specijalni oblici ili ako oni ne odgovaraju vašim potrebama, onda možete da napravite sopstvene tako što ćete izabrati stavku Oblikovanje ćelija > dijalog Prilagođeno.

Uobičajena situacija

Funkcija TEXT retko se koristi sama, najčešće se koristi u kombinaciji sa nekom drugom. Recimo da želite da kombinujete tekstualnu i numeričku vrednost, na primer, „Izveštaj je odštampan: 14.03.12.“ ili „Sedmični prihod: 66.348,72“. Možete to da otkucate ručno u programu Excel, ali i Excel to može da uradi umesto vas. Nažalost, kada kombinujete tekst i oblikovane brojeve, na primer datume, vremena, valutu itd. Excel ne zna na koji način želite da ih prikažete i zato odustaje od oblikovanja brojeva. Funkcija TEXT je u tom slučaju od neprocenjivog značaja jer omogućava da nametnete programu Excel da oblikuje vrednosti onako kako želite pomoću koda za oblikovanje, na primer "DD.MM.YY." za oblik datuma.

U sledećem primeru vidite šta se dešava ako pokušate da spojite tekst i broj bez korišćenja funkcije TEXT. U ovom slučaju koristimo ampersand (&) da bismo spojili tekstualnu nisku, razmak („ “) i vrednost pomoću formule =A2&" "&B2.

Primer spajanja teksta bez funkcije TEXT

Kao što vidite, Excel je uklonio oblikovanje datuma u ćeliji B2. U sledećem primeru videćete na koji način funkcija TEXT omogućava da primenite željeni oblik.

Primer spajanja teksta pomoću funkcije TEXT

Ažurirana formula je:

  • Ćelija C2:=A2&" "&TEXT(B2,"dd/mm/yy") – oblik datuma

Najčešća pitanja

Nažalost, to ne možete da uradite pomoću funkcije TEXT. Trebalo bi da koristite kôd programa Visual Basic for Applications (VBA). Sledeća veza sadrži metod: Kako se numerička vrednost konvertuje u reči na srpskom jeziku u programu Excel

Možete. Možete da koristite funkcije UPPER, LOWER i PROPER. Na primer, =UPPER("zdravo") daje „ZDRAVO“.

Možete, ali je neophodno nekoliko koraka. Prvo izaberite ćelije u kojima želite to da uradite i koristite kombinaciju tastera Ctrl+1 da biste otvorili dijalog Oblik > Ćelije, a zatim izaberite stavke Poravnavanje > Kontrola teksta > potvrdite izbor u polju za potvrdu za opciju Prelomi tekst. Zatim prilagodite funkciju TEXT tako da obuhvati ASCII funkciju CHAR(10) tamo gde želite prelom reda. Možda ćete morati da prilagodite širinu kolone u zavisnosti od toga kako je poravnat krajnji rezultat.

Primer korišćenja funkcije TEXT uz CHAR(10) za umetanje preloma reda. = "Danas je: "&CHAR(10))&TEXT(TODAY(),"MM/DD/YY")

U ovom slučaju koristili smo: ="Danas je: "&CHAR(10)&TEXT(TODAY(),"dd/mm/yy")

To se zove Naučni način zapisivanja i Excel automatski konvertuje brojeve duže od 12 cifara ako je ćelija oblikovana kao Opšte, a 15 cifara ako je ćelija oblikovana kao Broj. Ako treba da unesete duge numeričke niske, ali ne želite da se konvertuju, oblikujete date ćelije kao Tekst pre nego sto unesete ili nalepite vrednosti u Excel.

Excel MVP Minda Trejsi

Minda preporučuje...

Ako Excel datoteke i izveštaje delite sa korisnicima iz različitih zemalja, onda bi možda trebalo da im date izveštaj na njihovom jeziku. Excel MVP, Minda Trejsi ima sjajno rešenje u ovom članku Excel datumi prikazani na raznim jezicima. On obuhvata i uzorak radne sveske koji možete da preuzmete.

Takođe pogledajte

Kreiranje ili brisanje prilagođenog formata broja

Konvertovanje teksta u brojeve

Sve Excel funkcije (po kategoriji)

Unapredite veštine
Istražite obuku
Prvi nabavite nove funkcije
Pridružite se Office Insider korisnicima

Da li su vam ove informacije koristile?

Hvala vam na povratnim informacijama!

Hvala za povratne informacije! Zvuči da će biti od pomoći ako vas povežemo sa našim agentima Office podrške.

×