Funkcija SUM

Funkcija SUM, jedna od matematičkih i trigonometrijskih funkcija, sabira vrednosti. Možete dodati pojedinačne vrednosti, reference ili opsege ćelija ili kombinaciju sva tri.

Na primer:

  • =SUM(A2:A10)

  • =SUM(A2:A10, C2:C10)

Pregledač ne podržava video. Instalirajte Microsoft Silverlight, Adobe Flash Player ili Internet Explorer 9.

Ovaj video je deo kursa pod imenom Dodavanje brojeva u programu Excel 2013.

SUM(broj1,[broj2],...)

Ime argumenta

Opis

broj1    (obavezno)

Prvi broj koji želite da dodate. Broj može da bude kao 4, referenca ćelije kao B6 ili ćelija opseg kao B2:B8.

broj2–255    (opcionalno)

Ovo je drugi broj koji želite da dodate. Na ovaj način možete da navedete najviše 255 brojeva.

Ako želite brzo da dobijete zbir opsega ćelija, sve što treba da uradite jeste da izaberete opseg i pogledate u donju desnu stranu prozora programa Excel.

Snimak ekrana izbora opsega ćelija, zatim pogled na statusnu traku
Statusna traka


To je statusna traka i ona prikazuje informacije u vezi sa onim što ste izabrali, bilo da je u pitanju jedna ćelija ili više ćelija. Ako kliknete desnim tasterom miša na statusnu traku, iskočiće dijalog sa funkcijama koji prikazuje sve opcije koje možete da izaberete. Imajte na umu da on takođe prikazuje vrednosti za izabrani opseg ako su ti atributi potvrđeni. Saznajte više o statusnoj traci.

Najlakši način za dodavanje formule SUM u radni list jeste pomoću čarobnjaka za automatski zbir. Izaberite praznu ćeliju direktno iznad ili ispod opsega koji želite da saberete, a zatim na kartici „Početak“ ili „Formula“ na traci izaberite stavke Automatski zbir > Zbir. Čarobnjak za automatski zbir će automatski otkriti opseg za sabiranje i izgraditi formulu za vas. To može da funkcioniše i po horizontali ako izaberete ćeliju levo ili desno od opsega koji se sabira. Imajte na umu da to neće raditi kod opsega nesusednih ćelija, ali o tome ćemo više u sledećem odeljku.

Možete da koristite čarobnjak za automatski zbir za automatsko građenje formule za sabiranje.  Izaberite opseg iznad/ispod opsega za sabiranje ili sa njegove leve/desne strane i idite na karticu Formula na traci, zatim izaberite stavke Automatski zbir > Zbir.
Korišćenje čarobnjaka za automatski zbir za brzo sabiranje opsega susednih ćelija


Dijalog za automatski zbir vam omogućava da izaberete i druge uobičajene funkcije kao što su:

Automatski zbir vertikalno

Ćelija B6 prikazuje formulu automatskog zbira: =SUM(B2:B5)

Čarobnjak za automatski zbir automatski je otkrio ćelije B2: B5 kao opseg za sabiranje. Sve što treba da uradite jeste da pritisnite Enter da biste ga potvrdili. Ako treba da dodate/isključite više ćelija, možete da držite taster Shift i pritiskate strelicu po izboru dok ne izaberete sve što želite, a kada završite, pritisnite Enter.

Vodič za funkcije Intellisense: plutajuća oznaka SUM(broj1,[broj2], …) ispod funkcije je njen vodič Intellisense. Ako kliknete na stavku SUM ili ime funkcije, ono će se pretvoriti u plavu hipervezu koja će vas odvesti na temu pomoći za tu funkciju. Ako kliknete na pojedinačne elemente funkcije, odgovarajući delovi u formuli biće markirani. U ovom slučaju samo B2: B5 će biti markirano jer postoji samo jedna referenca broja u ovoj formuli. Oznaka Intellisense se pojavljuje za svaku funkciju.

Automatski zbir horizontalno

Ćelija D2 prikazuje formulu automatskog zbira: =SUM(B2:C2)

Korišćenje funkcije SUM sa opsezima nesusednih ćelija.  Formula ćelije C8 je =SUM(C2:C3,C5:C6). Možete koristiti i opsege sa imenom, pa će formula biti =SUM(Sedmica1,Sedmica2).

Čarobnjak za automatski zbir će uglavnom raditi samo za opsege susednih ćelija, pa ako imate prazne redove ili kolone u opsegu sabiranja, Excel će stati kod prve prazne ćelije. U tom slučaju bi trebalo da koristite funkciju SUM uz izbor, kada dodajete pojedinačne opsege jedan po jedan. U ovom primeru, kada biste imali podatke u ćeliji B4, Excel bi generisao =SUM(C2:C6) jer prepoznaje opseg susednih ćelija.

Možete brzo da izaberete više opsega nesusednih ćelija koristeći Ctrl + klik levim tasterom miša. Prvo unesite „= SUM(“, a zatim izaberite različite opsege i Excel će umesto vas automatski dodati zarez za razdvajanje između opsega. Kada završite, pritisnite Enter.

SAVET: ALT + = možete da koristite da biste brzo dodali funkciju SUM u ćeliju. Sve što morate da uradite jeste da izaberete opsege.

Napomena: možda ćete primetiti da je Excel markirao različite funkcijske opsege po boji, a oni se podudaraju u samoj formuli, tako da je C2:C3 jedna boja, a C5:C6 je druga. Excel će to uraditi za sve funkcije, osim ako referentni opseg nije na drugom radnom listu ili u drugoj radnoj svesci. Za poboljšanu pristupačnost sa pomoćnom tehnologijom možete koristiti opsege sa imenom, kao što je „Sedmica1“, „Sedmica2“ itd., a zatim uputite na njih u formuli:

=SUM(Sedmica1,Sedmica2)

Pomoću programa Excel možete jednostavno da izvršavate samostalne matematičke operacije, kao i operacije u kombinacijama sa Excel funkcijama kao što je SUM. Sledeća tabela navodi operatore koje možete da koristite, kao i neke povezane funkcije. Možete da unosite operatore pomoću reda sa brojevima na tastaturi ili pomoću tastature sa 10 tastera, ako je imate. Na primer, kombinacijom tastera Shift + 8 unećete zvezdicu (*) za množenje.

Operator

Operacija

Primeri

+

Sabiranje

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

Oduzimanje

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

Množenje

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1,1) - funkcija PRODUCT

/

Deljenje

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1,1) - funkcija QUOTIENT

^

Stepenovanje

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1,1) - funkcija POWER

Više informacija potražite u članku Korišćenje programa Excel kao kalkulatora.

Drugi primeri

  1. Recimo da želite da primenite procenat popusta na opseg ćelija koje ste sabrali.

    Korišćenje operatora uz SUM.  Formula u ćeliji B16 je =SUM(A2:A14)*-25%.  Formula bi bila pravilno izgrađena kada bi -25% bila referenca ćelije umesto toga, na primer =SUM(A2:A14)*E2
    • =SUM(A2:A14)*-25%

    Bi vam dalo 25% od sabranog opsega, međutim, to upisuje vrednost 25% u formulu, a to će možda biti teško pronaći kasnije ako bude potrebno da se menja. Mnogo je bolje staviti 25% u ćeliju i uputiti na nju, jer je to napolju na otvorenom i lako se može promeniti, ovako:

    • =SUM(A2:A14)*E2

    Da biste izvršili deljenje umesto množenja, jednostavno zamenite „*“ sa „/“: =SUM(A2:A14)/E2

  2. Dodavanje ili oduzimanje od zbira

    i. Možete lako da dodate nešto u zbir ili oduzmete od njega koristeći + ili -, ovako:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

Ovaj odeljak razmatra neke od najboljih praksi za rad sa funkcijom SUM. Dosta toga može da se primeni i na rad sa drugim funkcijama.

Metod =1+2 ili =A+B – iako možete da unesete =1+2+3 ili =A1+B1+C2 i dobijete potpuno tačne rezultate, ovi metodi su skloni greškama iz nekoliko razloga:

  1. Greške u kucanju – zamislite da pokušavate da unesete više ovakvih vrednosti i/ili mnogo većih vrednosti:

    • =14598,93+65437,90+78496,23

    Zatim pokušajte da proverite da li su unosi ispravni. Mnogo je lakše da unesete ove vrednosti u pojedinačne ćelije i koristite formulu SUM. Osim toga, vrednosti možete da oblikujete kada su u ćelijama, što ih čini mnogo čitljivijim nego kada su u formuli.

    Koristite funkciju SUM, nemojte da upisujete vrednosti u formulama.  Formula u ćeliji D5 je =SUM(D2:D4)
  2. Greške #VALUE! od referentnog teksta umesto brojeva

    Ako koristite formulu kao što je:

    • =A1+B1+C1 ili =A1+A2+A3

    Primer loše gradnje formule.  Formula u ćeliji D2 je =A2+B2+C2

    Formula može da se ošteti ako u referentnim ćelijama postoji vrednost koja nije broj (već tekst), što će vratiti grešku #VALUE!. SUM će zanemariti tekstualne vrednosti i vratiti zbir samo numeričkih vrednosti.

    Pravilna izgradnja formule.  Umesto =A2+B2+C2, formula ćelije D2 je =SUM(A2:C2)
  3. Greška #REF! od brisanja redova ili kolona

    Greška #REF! izazvana brisanjem kolone.  Formula je promenjena u =A2+#REF!+B2

    Ako izbrišete red ili kolonu, formula se neće ažurirati da bi isključila izbrisani red i vratiće grešku #REF!, dok će se funkcija SUM automatski ažurirati.

    Funkcija SUM će se automatski prilagoditi za umetnute ili izbrisane redove i kolone
  4. Formule neće ažurirati reference pri umetanju redova ili kolona

    Formule =A+B+C neće se ažurirati ako dodate redove

    Ako umetnete red ili kolonu, formula se neće ažurirati radi uključivanja dodatog reda, dok će se funkcija SUM automatski ažurirati (sve dok niste van opsega na koji se upućuje u formuli). To je posebno važno ako očekujete da se formula ažurira, a ona se ne ažurira, jer vas to ostavlja sa nepotpunim rezultatima, što možda ne uvidite.

    Primer prikazuje formulu SUM koja se automatski širi od =SUM(A2:C2) do =SUM(A2:D2) pri umetanju kolone
  5. SUM sa pojedinačnim referencama ćelija u odnosu na opsege ćelija

    Korišćenje formule kao što je:

    • =SUM(A1,A2,A3,B1,B2,B3)

    Podjednako je sklono greškama prilikom umetanja ili brisanja redova unutar referentnog opsega iz istih razloga. Mnogo je bolje koristiti pojedinačne opsege, kao što je:

    • =SUM(A1:A3,B1:B3)

    Oni će se ažurirati prilikom dodavanja ili brisanja redova.

  1. Definitivno možete da koristite SUM sa drugim funkcijama. Evo primera koji kreira mesečno prosečno izračunavanje:

    Korišćenje funkcije SUM uz druge funkcije.  Formula u ćeliji M2 je =SUM(A2:L2)/COUNTA(A2:L2).  Napomena : kolone Maj–Novembar skrivene su zbog jasnoće.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. Excel preuzima zbir od A2:L2 podeljeno sa brojem ćelija koje nisu prazne u A2:L2 (ćelije od maja do decembra su prazne).

  1. Ponekad je potrebno da saberete određenu ćeliju na više radnih listova. Možda je primamljivo da kliknete na svaki list i ćeliju koju želite i jednostavno iskoristite „+“ da biste dodali vrednosti ćelija, ali to je zamorno i sklono greškama.

    • =List1!A1+List2!A1+List3!A1

    To možete mnogo lakše postići sa 3D ili 3-dimenzionalnom funkcijom SUM:

    3D zbir – formula u ćeliji D2 je =SUM(List1:List3!A2)
    • =SUM(List1:List3!A1)

    To će sabrati ćeliju A1 na svim listovima od lista 1 do lista 3.

    Ovo je naročito korisno u situacijama gde imate jedan list za svaki mesec (januar–decembar), a potrebno je da ih saberete na listu sa rezimeom.

    3D SUM za listove sa imenom.  Formula u D2 je =SUM(Januar:Decembar!A2)
    • =SUM(Januar:Decembar!A2)

    To će sabrati ćeliju A2 na svakom listu od januara do decembra.

    Napomene : Ako radni listovi sadrže razmake u imenima, kao što je „Prodaja u januaru“, onda morate da koristite apostrofe kada upućujete na imena listova u formuli. Obratite pažnju na apostrof PRE prvog imena radnog lista i ponovo POSLE poslednjeg.

    • =SUM(‘Prodaja u januaru:Prodaja u decembru’!A2)

    3D metod će raditi i sa drugim funkcijama, kao što su AVERAGE, MIN, MAX itd.:

    • =AVERAGE(List1:List3!A1)

    • =MIN(List1:List3!A1)

    • =MAX(List1:List3!A1)

Problem

U čemu je problem

Moja funkcija SUM prikazuje #####, ne rezultat.

Proverite širine kolona. ### obično znači da je kolona suviše uska da bi prikazala rezultat formule.

Moja funkcija SUM prikazuje samu formulu kao tekst, ne rezultat.

Proverite da ćelija nije oblikovana kao tekst. Izaberite ćeliju ili opseg u pitanju i pritisnite Ctrl + 1 da biste pokrenuli dijalog Oblikovanje ćelija, a zatim kliknite na karticu Broj i izaberite željeni oblik. Ako je ćelija oblikovana kao tekst i ne promeni se nakon promene oblika, možda ćete morati da pritisnite F2 > Enter da biste nametnuli promenu oblikovanja.

Moja funkcija SUM se ne ažurira.

Uverite se da je opcija Izračunavanje postavljena na vrednost Automatsko. Na kartici Formula idite na stavku Opcije za izračunavanje. Možete da koristite i F9 da biste nametnuli izračunavanje radnog lista.

Uverite se da je izračunavanje postavljeno na vrednost Automatsko.  Na kartici Formula idite na stavku Opcije za izračunavanje.

Neke vrednosti nisu dodate.

Samo numeričke vrednosti iz reference ili opsega funkcije mogu se sabirati. Prazne ćelije, logičke vrednosti kao što je TRUE ili tekst se zanemaruju.

Umesto očekivanog rezultata se pojavljuje pogrešna vrednost „#NAME?“.

To obično znači da formula nije dobro napisana, na primer =sume(A1:A10) umesto =SUM(A1:A10).

Moja funkcija SUM prikazuje ceo broj, ali bi trebalo da prikazuje decimale

Proverite oblikovanje ćelija da biste se uverili da prikazujete decimale. Izaberite ćeliju ili opseg u pitanju i koristite kombinaciju tastera Ctrl + 1 da biste pokrenuli dijalog Oblikovanje ćelija, a zatim kliknite na karticu Broj i izaberite željeni format uz obavezno ukazivanje na željeni broj decimalnih mesta.

  1. Želim samo da saberem/oduzmem/pomnožim/podelim brojeve Pogledajte ovu seriju video zapisa na sajtovima Osnovna matematika u programu Excel ili Korišćenje programa Excel kao kalkulatora.

  2. Kako da prikažem više/manje decimalnih mesta? Možete da promenite format brojeva. Izaberite ćeliju ili opseg u pitanju i koristite kombinaciju tastera Ctrl + 1 da biste pokrenuli dijalog Oblikovanje ćelija, zatim kliknite na karticu Broj i izaberite željeni format uz obavezno ukazivanje na željeni broj decimalnih mesta.

  3. Kako da dodam ili oduzmem vremena? Možete da dodajete i oduzimate vremena na nekoliko različitih načina. Na primer, da biste dobili razliku između 8:00 ujutro i 12:00 uveče u svrhu platnog spiska, koristićete: =("12:00 PM"-"8:00 AM")*24, gde ćete od vremena završetka oduzeti vreme početka. Imajte na umu da Excel izračunava vremena kao delove dana, pa je potrebno da pomnožite brojem 24 da biste dobili ukupan broj časova. U prvom primeru koristimo =((B2-A2)+(D2-C2))*24 da bismo dobili zbir časova od početka od završetka, izuzimajući pauzu za ručak (8,50 časova ukupno).

    Ako jednostavno sabirate časove i minute i želite to i da prikažete, možete da saberete, bez potrebe za množenjem brojem 24, pa u drugom primeru koristimo =SUM(A6:C6) jer nam treba samo ukupan broj časova i minuta za dodeljene zadatke (5:36, odnosno 5 časova, 36 minuta).

    Izračunavanje vremena

    Više informacija potražite u sledećem članku: Sabiranje ili oduzimanje vremena.

  4. Kako da dobijem razliku između datuma? Kao i kod vremena, možete da sabirate i oduzimate datume. Ovo je vrlo čest primer brojanja dana između dva datuma. To je jednostavno kao =B2-A2. Ključ za rad sa datumima i vremenom jeste da počnete sa datumom/vremenom završetka i oduzmete datum/vreme početka.

    Izračunavanje razlika između datuma

    Više načina za rad sa datumima potražite u članku Izračunavanje broja dana između dva datuma.

  5. Kako da saberem samo vidljive ćelije? Ponekad, kad ručno sakrijete redove ili koristite automatski filter za prikaz određenih podataka, takođe želite da sabirate samo vidljive ćelije. Možete da koristite funkciju SUBTOTAL. Ako koristite red sa ukupnom vrednošću u Excel tabeli, funkcija koju izaberete iz padajuće liste „Ukupna vrednost“ biće automatski uneta kao međuvrednost. Više informacija potražite u članku Ukupne vrednosti podataka u Excel tabeli.

Potrebna vam je dodatna pomoć?

Možete uvek da postavite pitanje stručnjaku u zajednici Excel Tech Community, dobijete podršku u zajednici Answers community ili predložite novu funkciju ili poboljšanje na sajtu Excel User Voice.

Takođe pogledajte

Pogledajte video o korišćenju funkcije SUM

Funkcija SUMIF dodaje samo vrednosti koje ispunjavaju jedan kriterijum

Funkcija SUMIFS dodaje samo vrednosti koje zadovoljavaju više kriterijuma

Funkcija COUNTIF broji samo vrednosti koje zadovoljavaju jedan kriterijum

Funkcija COUNTIFS broji samo vrednosti koje zadovoljavaju više kriterijuma

Pregled formula u programu Excel

Kako da izbegnete oštećene formule

Pronalaženje i ispravljanje grešaka u formulama

Tasterske prečice u programu Excel za Windows

Tasterske prečice u programu Excel za Mac

Matematičke i trigonometrijske funkcije

Excel funkcije (abecedno)

Excel funkcije (po kategoriji)

Dodavanje formula i funkcija (besplatan pregled)

Unapredite veštine
Istražite obuku
Prvi nabavite nove funkcije
Pridružite se Office Insider korisnicima

Da li su vam ove informacije koristile?

Hvala vam na povratnim informacijama!

Hvala za povratne informacije! Zvuči da će biti od pomoći ako vas povežemo sa našim agentima Office podrške.

×