Napomena: Funkcija, metod, objekat ili svojstvo opisano u ovoj temi onemogućena je ako je usluga Microsoft Jet Expression pokrenuta u režimu sandbox, što sprečava procenu potencijalno nebezbednih izraza. Više informacija o režimu "sandbox" potražite u odeljku "režim sandbox" u pomoći.
Daje referencu na objekat koji je obezbedila ActiveX komponenta.
Sintaksa
GetObject([ime putanje ] [, klasa ] )
Sintaksa funkcije GetObject ima sledeće argumente:
|
Argument |
Opis |
|
ime putanje |
Opcionalno. Varijanta (niska). Puna putanja i ime datoteke koja sadrži objekat koji treba preuzeti. Ako je argument pathname izostavljen, klasa je obavezna. |
|
klasa |
Opcionalno. Varijanta (niska). Niska koja predstavlja klasa objekta. |
Klasa argument koristi sintaksno ime aplikacije.objecttype i ima sledeće delove:
|
Deo |
Opis |
|
ime aplikacije |
Obavezno. Varijanta (niska). Ime aplikacije koja obezbeđuje objekat. |
|
tip objekta |
Obavezno. Varijanta (niska). Tip ili klasa objekta koji treba kreirati. |
Napomene
Napomena: Primeri koji slede pokazuju upotrebu ove funkcije u Visual Basic for Applications (VBA) modulu. Za više informacija o radu sa VBA modulom izaberite stavku Referenca razvojnog programera sa padajuće liste pored stavke Pretraga i unesite termine u polje za pretragu.
Koristite funkciju GetObject da biste pristupili ActiveX objektu iz datoteke i dodelili objekat objektu promenljiva objekta. Koristite izraz Set da biste dodelili objekat koji je vratio GetObject promenljivoj objekta. Na primer:
Dim CADObject As Object
Set CADObject = GetObject("C:\CAD\SCHEMA.CAD")
Kada se ovaj kôd izvrši, pokreće se aplikacija povezana sa navedenim imenom putanje, a objekat u navedenoj datoteci je aktiviran.
Ako je "pathname " niska nulte dužine (""), funkcija GetObject vraća novu instancu objekta navedenog tipa. Ako je argument "pathname " izostavljen, funkcija GetObject vraća trenutno aktivni objekat navedenog tipa. Ako ne postoji nijedan objekat navedenog tipa, dolazi do greške.
Neke aplikacije vam omogućavaju da aktivirate deo datoteke. Dodajte znak uzvika (!) na kraj imena datoteke i pratite ga pomoću niske koja identifikuje deo datoteke koji želite da aktivirate. Informacije o tome kako da kreirate ovu nisku potražite u dokumentaciji za aplikaciju koja je kreirala objekat.
Na primer, u aplikaciji za crtanje možda imate više slojeva na crtežu uskladištenom u datoteci. Možete da koristite sledeći kôd da biste aktivirali sloj u okviru crteža pod imenom SCHEMA.CAD:
Set LayerObject = GetObject("C:\CAD\SCHEMA.CAD!Layer3")
Ako ne navedete klasu objekta, automatizacija određuje da se aplikacija pokrene i objekat koji treba aktivirati na osnovu imena datoteke koje navedete. Međutim, neke datoteke mogu da podržavaju više klasa objekata. Na primer, crtež može da podržava tri različita tipa objekata: objekat aplikacije, crtež i objekat trake sa alatkama, od kojih su svi deo iste datoteke. Da biste naveli koji objekat u datoteci želite da aktivirate, koristite opcionalni argument klase . Na primer:
Dim MyObject As Object
Set MyObject = GetObject("C:\DRAWINGS\SAMPLE.DRW", _
"FIGMENT.DRAWING")
U primeru, FIGMENT je ime aplikacije za crtanje i DRAWING je jedan od tipova objekata koje podržava.
Kada se objekat aktivira, upućujete na njega u kodu pomoću promenljive objekta koju ste definisali. U prethodnom primeru možete da pristupite svojstvima i metodama novog objekta pomoću promenljive MyObject. Na primer:
MyObject.Line 9, 90
MyObject.InsertText 9, 100, "Hello, world."
MyObject.SaveAs "C:\DRAWINGS\SAMPLE.DRW"
Napomena: Funkciju GetObject koristite kada postoji trenutna instanca objekta ili ako želite da kreirate objekat sa već učitanim datotekom. Ako ne postoji trenutna instanca, a ne želite da objekat počne sa učitanim datotekama, koristite funkciju CreateObject .
Ako se objekat registrovao kao objekat sa jednom instancom, kreira se samo jedna instanca objekta, bez obzira na to koliko se puta createObject izvršava. Uz jedan objekat, GetObject uvek vraća istu instancu kada se poziva sa sintaksom niske nulte dužine ("") i dovodi do greške ako se argument pathname izostavi. Funkciju GetObject ne možete da koristite da biste dobili referencu na klasu kreiranu pomoću programa Visual Basic.
Primer
Ovaj primer koristi funkciju GetObject za dobijanje reference na određeni radni Microsoft Office Excel 2007 (MyXL). On koristi svojstvo Aplikacija radnog lista kako bi Excel bio vidljiv, da bi ga zatvorio i tako dalje. Pomoću dva API poziva, procedura DetectExcel Sub traži Excel i, ako je pokrenut, unosi ga u tabelu pokrenutog objekta. Prvi poziv funkcije GetObject dovodi do greške ako Microsoft Excel već nije pokrenut. U primeru, greška dovodi do toga da excelWasNotRunning zastavica bude postavljena na Tačno. Drugi poziv funkcije GetObject navodi datoteku za otvaranje. Ako Excel nije već pokrenut, drugi poziv ga započinje i vraća referencu na radni list koji predstavlja navedena datoteka, a zatim mytest.xls. Datoteka mora da postoji na navedenoj lokaciji; u suprotnom, generiše se visual Basic greška automatizacije grešaka. Zatim, primer koda čini Excel i prozor koji sadrži navedeni radni list vidljivim. Na kraju, ako prethodna verzija programa Excel nije pokrenuta, kôd koristi metod Quit objekta aplikacije za zatvaranje programa Excel. Ako je aplikacija već pokrenuta, nije izvršen nijedan pokušaj da se zatvori. Sama referenca se objavljuje tako što se postavlja na " Ništa".
' Declare necessary API routines:
Declare Function FindWindow Lib "user32" Alias _
"FindWindowA" (ByVal lpClassName as String, _
ByVal lpWindowName As Long) As Long
Declare Function SendMessage Lib "user32" Alias _
"SendMessageA" (ByVal hWnd as Long,ByVal wMsg as Long, _
ByVal wParam as Long, _
ByVal lParam As Long) As Long
Sub GetExcel()
Dim MyXL As Object ' Variable to hold reference
' to Microsoft Excel.
Dim ExcelWasNotRunning As Boolean ' Flag for final release.
' Test to see if there is a copy of Microsoft Excel already running.
On Error Resume Next ' Defer error trapping.
' GetObject function called without the first argument returns a
' reference to an instance of the application. If the application isn't
' running, an error occurs.
Set MyXL = GetObject(, "Excel.Application")
If Err.Number <> 0 Then ExcelWasNotRunning = True
Err.Clear ' Clear Err object in case error occurred.
' Check for Microsoft Excel. If Microsoft Excel is running,
' enter it into the Running Object table.
DetectExcel
' Set the object variable to reference the file you want to see.
Set MyXL = GetObject("c:\vb4\MYTEST.XLS")
' Show Microsoft Excel through its Application property. Then
' show the actual window containing the file using the Windows
' collection of the MyXL object reference.
MyXL.Application.Visible = True
MyXL.Parent.Windows(1).Visible = True
Do manipulations of your file here.
' ...
' If this copy of Microsoft Excel was not running when you
' started, close it using the Application property's Quit method.
' Note that when you try to quit Microsoft Excel, the
' title bar blinks and a message is displayed asking if you
' want to save any loaded files.
If ExcelWasNotRunning = True Then
MyXL.Application.Quit
End IF
Set MyXL = Nothing ' Release reference to the
' application and spreadsheet.
End Sub
Sub DetectExcel()
' Procedure dectects a running Excel and registers it.
Const WM_USER = 1024
Dim hWnd As Long
' If Excel is running this API call returns its handle.
hWnd = FindWindow("XLMAIN", 0)
If hWnd = 0 Then ' 0 means Excel not running.
Exit Sub
Else
' Excel is running so use the SendMessage API
' function to enter it in the Running Object Table.
SendMessage hWnd, WM_USER + 18, 0, 0
End If
End Sub
