Funkcija „Nz“

Funkciju Nz možete koristiti da biste dobili nulu, niska dužine nula (" ") ili drugu navedenu vrednost kad tip podataka Variant ima vrednost Null. Na primer, ovu funkciju možete upotrebiti da pretvorite vrednost Null u drugu vrednost i sprečite njeno prenošenje kroz izraz.

Sintaksa

Nz ( variant [, valueifnull ] )

Sintaksa funkcije Nz ima sledeće argumente:

Argument

Opis

variant

Obavezno. Promenljiva tip podatkaVariant.

valueifnull

Opcionalno (osim ako se koristi u upitu). Tip Variant koji obezbeđuje vrednost koja treba da bude vraćena ako argument variant ima vrednost Null. Ovaj argument vam omogućava da dobijete vrednost koja nije nula ili niska nulte dužine.

Napomena : Rezultat korišćenja funkcije Nz u izrazu upita, bez korišćenja argumenta vrednostakojenull, jeste niska nulte dužine u poljima sa praznim vrednostima.


Ako je vrednost argumenta variantNull, funkcija Nz vraća broj nula ili nisku nulte dužine (uvek vraća nisku nulte dužine kad se koristi u izrazu upita), u zavisnosti od toga ukazuje li kontekst na to da vrednost treba da bude broj ili niska. Ako je uključen opcionalni argument valueifnull, funkcija Nz vraća vrednost koju navodi taj argument, ako argument variant ima vrednost Null. Kad se koristi u izrazu upita, funkcija Nz uvek treba da obuhvata argument valueifnull.

Ako vrednost argumenta variant nije Null, funkcija Nz vraća vrednost argumenta variant.

Napomene

Funkcija Nz je korisna za izraze koji možda obuhvataju Null vrednosti. Da biste nametnuli da izraz kao rezultat daje vrednost koja nije Null čak i kad sadrži vrednost Null, upotrebite funkciju Nz kako biste dobili nulu, nisku nulte dužine ili prilagođenu povratnu vrednost.

Na primer, izraz 2 + varX uvek vraća vrednost Null kad Variant varX ima vrednost Null. Međutim, 2 + Nz(varX) vraća 2.

Funkciju Nz često možete koristiti kao alternativu funkciji IIf. Na primer, u sledećem kodu dva izraza koja uključuju funkciju IIf neophodna su da bi se dobio željeni rezultat. Prvi izraz koji uključuje funkciju IIf se koristi za proveru vrednosti promenljive i njeno pretvaranje u nulu ako ona ima vrednost Null.

varTemp = IIf(IsNull(varFreight), 0, varFreight)
varResult = IIf(varTemp > 50, "High", "Low")

U sledećem primeru, funkcija Nz pruža istu funkcionalnost kao i prvi izraz, a željeni rezultat se postiže u jednom koraku umesto u dva.

varResult = IIf(Nz(varFreight) > 50, "High", "Low")

Ako navedete vrednost za opcionalni argument valueifnull, ta vrednost se vraća kad argument variant ima vrednost Null. Uključivanjem ovog opcionalnog argumenta možda možete izbeći upotrebu izraza koji sadrži funkciju IIf. Na primer, sledeći izraz koristi funkciju IIf kako bi se dobila niska ako varFreight ima vrednost Null.

varResult = IIf(IsNull(varFreight), _
"No Freight Charge", varFreight)

U sledećem primeru opcionalni argument naveden za funkciju Nz omogućava da se dobije niska ako varFreight ima vrednost Null.

varResult = Nz(varFreight, "No Freight Charge")

Primer

Napomena : Primeri koji slede pokazuju upotrebu ove funkcije u Visual Basic for Applications (VBA) modulu. Ako vam je potrebno više informacija o radu sa VBA modulom, izaberite stavku Referenca razvojnog programera sa padajuće liste pored stavke Pretraga i unesite jedan ili više termina u polje za pretragu.

Sledeći primer procenjuje kontrolu u obrascu i na osnovu njene vrednosti vraća jednu od dve niske. Ako je vrednost kontrole Null, procedura koristi funkciju Nz za pretvaranje vrednosti Null u nisku nulte dužine.

Public Sub CheckValue()
Dim frm As Form
Dim ctl As Control
Dim varResult As Variant
' Return Form object variable
' pointing to Orders form.
Set frm = Forms!Orders
' Return Control object variable
' pointing to ShipRegion.
Set ctl = frm!ShipRegion
' Choose result based on value of control.
varResult = IIf(Nz(ctl.Value) = vbNullString, _
"No value.", "Value is " & ctl.Value & ".")
' Display result.
MsgBox varResult, vbExclamation
End Sub
Unapredite veštine
Istražite obuku
Prvi nabavite nove funkcije
Pridružite se Office Insider korisnicima

Da li su vam ove informacije koristile?

Hvala vam na povratnim informacijama!

Hvala za povratne informacije! Zvuči da će biti od pomoći ako vas povežemo sa našim agentima Office podrške.

×