Postavljanje prilagođenih oznaka podataka u grafikonu

Sledeća VBA procedura (Visual Basic for Applications) omogućiće vam da koristite vrednosti ćelija kao oznake podataka u grafikonima u programu Excel za Mac. Da biste koristili proceduru, uradite sledeće:

1. U programu Excel izaberite stavku Alatke > Makroi > za snimanje novog makroa.

2. U padajućem okviru Uskladišti makro u: izaberite stavku Radna sveska ličnih makroa.

   Napomena: Skladišteći VBA proceduru u radnoj svesci ličnih makroa, možete da je koristite u bilo kojoj instanci programa Excel. To znači da nije samo ograničena na korišćenje u jednoj radnoj svesci.

3. Pritisnite dugme U redu.

4. Idite do stavke Alatke > makroe > zaustavi snimanje.

5. Idite na stavku Alatke > makroe> Visual Basic Editor.

6. Visual Basic Editor (VBE) će se otvoriti iznad programa Excel. U oknu za navigaciju sa leve strane razvijte VBA projekat (LIČNO. XLSB) fascikla za prikaz modula1.

7. Kliknite dvaput na Modul1 da biste prikazali okno Kôd koje će se otvoriti sa desne strane VBE prozora.

8. VBA kôd koji je kreiran kada ste snimili novi makro nije neophodan, pa ga izaberite sve, a zatim pritisnite taster Delete. 

9. Zatim izaberite VBA kôd u dolenavedenom okviru za tekst, pritisnite kombinaciju tastera CMD+C da biste ga kopirali, a zatim ga nalepite nazad u okno Kôd koristeći CMD+V. Sada možete da izađete iz programa Visual Basic Editor i vratite se u Excel.

10. Testirajte makro tako što ćete kreirati grafikon sa oznakama podataka. Zatim izaberite bilo koju oznaku podataka na grafikonu i pokrenite makro tako što ćete izabrati stavku Alatke > Makroi >Makroi. Izaberite Stavku SetCustomDataLabels, a zatim pritisnite dugme Pokreni. Automatski će vam biti zatraženo da izaberete opseg oznaka podataka, pa to uradite, a zatim kliknite na dugme U redu.  

    Napomena: VBA procedure nije moguće opozvati, pa obavezno isprobajte ovo na kopiji radne sveske. Ako pokrenete kôd i ne želite da zadržite rezultate, moraćete da zatvorite radnu svesku bez čuvanja.

11. Kada zatvorite Excel, uverite se da ste odabrali da sačuvate promene u ličnom dokumentu. XLSB kako bi makro bio dostupan u budućnosti.

12. Kad god želite da dodate ili uklonite oznake podataka sa grafikona, izaberite oznake podataka i pokrenite makro.

13. Excel možete da koristite > Željene postavke> traku & traci sa alatkama da biste dodali dugme za pokretanje makroa sa trake ili trake sa alatkama.

Option Explicit

Sub SetCustomDataLabels()
' make sure a series is selected
    If TypeOf Selection Is DataLabels Or TypeOf Selection Is Point Then
        Selection.Parent.Select
    ElseIf TypeOf Selection Is DataLabel Then
        Selection.Parent.Parent.Select
    End If

    If TypeOf Selection Is Series Then
        Else
        MsgBox "Select a chart series and try again."
        Exit Sub
    End If

    If Selection.HasDataLabels Then
        'If the data labels from cells are already showing, stop showing them and exit.
        'If labels include other info (e.g., values or categories) this will still appear
        If Selection.DataLabels.ShowRange Then
            Selection.DataLabels.ShowRange = False
            Exit Sub
        End If
    End If
 
'Use the InputBox dialog to set the range for the data labels
    On Error Resume Next
        Dim rng As Range
        Set rng = Application.InputBox(Prompt:="Select data label range.", Title:="Data Label Range", Type:=8)
    On Error GoTo 0

    If rng Is Nothing Then Exit Sub ' clicked cancel
        If Selection.HasDataLabels Then
            'This will include the new text from cells into existing data labels
        Else
        'Otherwise add data labels (empty labels)
            Selection.HasDataLabels = True
            Selection.DataLabels.ShowValue = False
        End If
    
    'Create a string that includes the sheet name and range reference.
    Dim rngAddress As String
        rngAddress = "='" & rng.Worksheet.Name & "'!" & rng.Address(RowAbsolute:=True, ColumnAbsolute:=True, External:=False)
        Selection.DataLabels.Format.TextFrame2.TextRange.InsertChartField msoChartFieldRange, rngAddress, 0
        Selection.DataLabels.ShowRange = True

End Sub