S formulami in funkcijami na seznamih ali v knjižnicah lahko izračunate podatke na različne načine. Če dodate izračunan stolpec na seznam ali v knjižnico, lahko ustvarite formulo, ki vključuje podatke iz drugih stolpcev in izvaja funkcije za izračun datumov in časov, izvajanje matematičnih enačb ali spreminjanje besedila. Na seznamu opravil lahko na primer uporabite stolpec za izračun števila dni za dokončanje posameznega opravila na podlagi stolpcev Začetni datum in Datum dokončanja.
Opomba: V tem članku so opisani osnovni koncepti, povezani s formulami in funkcijami. Če želite določene informacije o določeni funkciji, si oglejte članek o tej funkciji.
V tem članku
Pregled formul
Formule so enačbe, ki izračunajo vrednosti na seznamu ali v knjižnici. Formula se začne z enačajem (=). Ta formula na primer pomnoži 2 in 3, nato pa rezultatu prišteje 5.
=5+2*3
V izračunanem stolpcu lahko uporabite formulo in izračunate privzete vrednosti za stolpec. Formula lahko vsebuje funkcije, sklice na stolpce, operatorje in konstante, kot je v tem primeru.
=PI()*[Result]^2
|
Element |
Opis |
|---|---|
|
Funkcija |
Funkcija PI() vrne vrednost za pi: 3,141592654. |
|
Sklic (ali ime stolpca) |
[Rezultat] predstavlja vrednost v stolpcu Rezultat za trenutno vrstico. |
|
Konstanta |
Številke ali besedilne vrednosti, vnesene neposredno v formulo, na primer 2. |
|
Operator |
Z operatorjem * (zvezdico) pomnožite, operator ^ (pika) pa število poveča na poteno. |
Formula lahko uporabi enega ali več elementov iz prejšnje tabele. Tukaj je nekaj primerov formul (po vrstnem redu zapletenosti).
Preproste formule (na primer =128+345)
Te formule vsebujejo konstante in operatorje.
|
Primer |
Opis |
|---|---|
|
=128+345 |
Prišteje 128 in 345 |
|
=5^2 |
Kvadrati 5 |
Formule, ki vsebujejo sklice na stolpce (na primer =[Prihodek] >[Stroški])
Te formule se sklicujejo na druge stolpce na istem seznamu ali v isti knjižnici.
|
Primer |
Opis |
|---|---|
|
=[Prihodek] |
Uporabi vrednost v stolpcu Prihodek. |
|
=[Prihodek]*10/100 |
10 % vrednosti v stolpcu Prihodek. |
|
=[Prihodek] > [Stroški] |
Vrne Da, če je vrednost v stolpcu Prihodek večja od vrednosti v stolpcu Stroški. |
Formule, ki priklicajo funkcije (na primer =AVERAGE(1; 2; 3; 4; 5))
Te formule priklicajo vgrajene funkcije.
|
Primer |
Opis |
|---|---|
|
=AVERAGE(1; 2; 3; 4; 5) |
Vrne povprečje nabora vrednosti. |
|
=MAX([Q1], [Q2], [Q3], [Q4]) |
Vrne največjo vrednost v množici vrednosti. |
|
=IF([Stroški]>[Prihodki], "Ni v redu", "V redu") |
Vrne Ni v redu, če je strošek večji od prihodka. Potem vrne V redu. |
|
=DAY("15-Apr-2008") |
Vrne del dneva v datumu. Ta formula vrne število 15. |
Formule z ugnezdenimi funkcijami (kot so =SUM(IF([A]>[B], [A]-[B], 10), [C]))
Te formule določajo eno ali več funkcij kot argumente funkcije.
|
Primer |
Opis |
|---|---|
|
=SUM(IF([A]>[B], [A]-[B], 10), [C]) |
Funkcija IF vrne razliko med vrednostmi v stolpcih A in B ali 10. Funkcija SUM doda vrnjeno vrednost funkcije IF in vrednost v stolpcu C. |
|
=DEGREES(PI()) |
Funkcija PI vrne število 3,141592654. Funkcija DEGREES pretvori vrednost, določeno v radianih, v stopinje. Ta formula vrne vrednost 180. |
|
=ISNUMBER(FIND("BD",[Stolpec1])) |
Funkcija FIND poišče niz BD v Stolpcu1 in vrne začetni položaj niza. Vrne vrednost napake, če niza ni mogoče najti. Funkcija ISNUMBER vrne Da, če je funkcija FIND vrnila številsko vrednost. Else, it returns No. |
Pregled funkcij
Funkcije so vnaprej določene formule za izvajanje izračunov z določenimi vrednostmi, imenovanimi argumenti, v posebnem vrstnem redu ali strukturi. Funkcije lahko uporabite za izvajanje preprostih ali zapletenih izračunov. Ta primerek funkcije ROUND na primer zaokroži število v stolpcu »Stroški« na dve decimalni mesti.
=ROUND([Cost], 2)
Ta besednjak je koristen, ko se učite funkcij in formul:
Struktura Struktura funkcije se začne z enačaj (=), ki mu sledi ime funkcije, oklepaj, argumenti za funkcijo, ki so ločeni z vejicami, in zaklepaji.
Ime funkcije To je ime funkcije, ki jo podpirajo seznami ali knjižnice. Vsaka funkcija vzame določeno število argumentov, jih obdela in vrne vrednost.
Argumenti Argumenti so lahko števila, besedilo, logične vrednosti, kot sta »True« ali »False« ali sklici na stolpce. Argument, ki ga določite, mora zagotoviti veljavno vrednost za ta argument. Argumenti so lahko tudi konstante, formule ali druge funkcije.
V določenih primerih boste morda morali uporabiti funkcijo kot enega od argumentov druge funkcije. Ta formula na primer uporablja ugnezdeno funkcijo AVERAGE in primerja rezultat z vsoto dveh vrednosti v stolpcu.
=AVERAGE([Cost1], SUM([Cost2]+[Discount]))
Veljavni vračili Ko funkcijo uporabite kot argument, mora vrniti isto vrsto vrednosti, ki jo uporablja argument. Če argument na primer uporablja »Da« ali »Ne« mora ugnezdena funkcija vrniti »Da« ali »Ne«. Če ni, seznam ali knjižnica prikaže #VALUE! .
Omejitve ravni gnezdenja Formula lahko vsebuje do osem ugnezdenih ravni funkcij. Če je funkcija B uporabljena kot argument v funkciji A, je funkcija B druga raven. V primeru zgoraj je na primer funkcija SUM druga raven, ker je argument funkcije AVERAGE. Funkcija, ugnezdena v funkciji SUM, bi bila funkcija tretje ravni in tako naprej.
Opombe:
-
Seznami in knjižnice ne podpirajo funkcij RAND in NOW.
-
Funkciji TODAY in ME v izračunanih stolpcih nita podprti, vendar sta podprti v privzeti nastavitvi vrednosti stolpca.
Uporaba sklicev na stolpce v formuli
Sklic določa celico v trenutni vrstici in pokaže na seznam ali knjižnico, kjer iskati vrednosti ali podatke, ki jih želite uporabiti v formuli. Na primer[ Strošek] se sklicuje na vrednost v stolpcu »Stroški« v trenutni vrstici. Če je v stolpcu »Stroški« vrednost 100 za trenutno vrstico, potem =[Stroški]*3 vrne 300.
S sklici lahko podatke iz različnih stolpcev seznama ali knjižnice uporabite v eni ali več formulah. V formuli se lahko sklicujete na stolpce teh podatkovnih tipov: ena vrstica besedila, število, valuta, datum in ura, izbira, da/ne in izračunano.
Prikazano ime stolpca uporabite, če se želite sklicevati na stolpec v formuli. Če ime vključuje presledek ali poseben znak, morate ime vdati med oglate oklepaje ([ ]). Sklici ne pišejo z velikimi in malimi črkami. Stolpec »Cena enote« v formuli lahko na primer sklicujete na [Cena enote] ali [cena enote].
Opombe:
-
Na vrednost v vrstici, ki ni trenutna vrstica, se ni mogoče sklicevati nanjo.
-
Na vrednost na drugem seznamu ali v drugi knjižnici se ne morete sklicevati.
-
Ne morete se sklicevati na ID vrstice za novo vstavljeno vrstico. ID še ne obstaja, ko se izvede izračun.
-
V formuli, ki ustvari privzeto vrednost za stolpec, se ne morete sklicevati na drug stolpec.
Uporaba konstant v formuli
Konstanta je vrednost, ki ni izračunana. Datum 10/9/2008, število 210 in besedilo »Quarterly Earnings« so konstante. Konstante so lahko teh podatkovnih tipov:
-
Niz (primer: =[Priimek] = "Smith")
Konstante niza so v narekovajih in lahko vsebujejo do 255 znakov.
-
Število (primer: =[Stroški] >= 29,99)
Številske konstante lahko vključujejo decimalna mesta in so lahko pozitivne ali negativne.
-
Datum (primer: =[Datum] > DATE(2007,7,1))
Datumske konstante zahtevajo uporabo funkcije DATE(leto, mesec, dan).
-
Logična vrednost (primer: =IF([Stroški]>[Prihodek], "Izguba", "Brez izgube")
Da in Ne sta logični konstanti. Uporabite jih lahko v pogojnih izrazih. Če je v zgoraj omenjenem primeru vrednost v »Stroški« večja od vrednosti v »Prihodek«, funkcija IF vrne »Da«, formula pa vrne niz »Izguba«. Če je vrednost v stroških enaka ali manjša od vrednosti v prihodku, funkcija vrne Ne, formula pa vrne niz »Brez izgube«.
Uporaba računskih operatorjev v formuli
Operatorji določajo vrsto izračuna, ki ga želite izvesti v elementih formule. Seznami in knjižnice podpirajo tri različne vrste računskih operatorjev: aritmetični operatorji, primerjave in besedilo.
Aritmetični operatorji
Za izvajanje osnovnih matematičnih operacij, kot so seštevanje, odštevanje ali množenje, uporabite te aritmetične operatorje. združevanje števil; ali za izdelavo številskih rezultatov.
|
Aritmetični operator |
Pomen (primer) |
|---|---|
|
+ (znak plus) |
Seštevec (3+3) |
|
- (znak minus) |
Odštevanje (3–1) |
|
* (zvezdica) |
Množenje (3*3) |
|
/ (poševnica naprej) |
Deljenje (3/3) |
|
% (znak za odstotke) |
Odstotek (20 %) |
|
^ (strešica) |
Eksponent (3^2) |
Operatorji primerjave
S temi operatorji lahko primerjate dve vrednosti. Ko ti dve vrednosti primerjate s temi operatorji, je rezultat logična vrednost »Da« ali »Ne«.
|
Operator primerjave |
Pomen (primer) |
|---|---|
|
= (enačaj) |
Enako kot (A=B) |
|
> (znak večji od) |
Večje kot (A>B) |
|
< (znak manjši od) |
Manjše kot (A<B) |
|
>= (znak večji ali enak) |
Večje od ali enako (A>=B) |
|
<= (znak manjši od ali enak) |
Manjše ali enako kot (A<=B) |
|
<> (znak ni enako) |
Ni enako kot (A<>B) |
Besedilni operator
Uporabite »in» (&) za združevanje ali združevanje enega ali več besedilnih nizov, da se ustvari en sam del besedila.
|
Besedilni operator |
Pomen (primer) |
|---|---|
|
& (znak »in«) |
Poveže ali spoji dve vrednosti, da ustvari eno neprekinjeno besedilno vrednost ("Sever"&"veter") |
Vrstni red, v katerem seznam ali knjižnica izvaja operacije v formuli
Formule vrednosti računajo po določenem vrstnem redu. Formula se lahko začne z enačaj (=). Za enačajem so elementi, ki bodo izračunani (operandi), ki so ločeni z računski operatorji. Seznami in knjižnice izračunajo formulo od leve proti desni glede na določen vrstni red posameznega operatorja v formuli.
Vrstni red, v katerem si sledijo operatorji
Če v eno formulo združite več operatorjev, seznami in knjižnice izvajajo operacije po vrstnem redu, ki je prikazan v spodnji tabeli. Če so v formuli operatorji z enakim vrstnim redom – če je na primer v formuli tako operator množenja kot tudi operator deljenje – seznami in knjižnice ovrednotijo operatorje od leve proti desni.
|
Operator |
Opis |
|---|---|
|
– |
Negacija (kot pri -1) |
|
% |
Odstotek |
|
^ |
Potenciranje |
|
* in / |
Množenje in deljenje |
|
+ in – |
Seštevanje in odštevanje |
|
& |
Spojitev (poveže dva niza besedila) |
|
= < > <= >= <> |
Primerjava |
Uporaba oklepajev
Če želite spremeniti vrstni red preračunavanja, del formule, ki naj se najprej izračuna, obda z oklepaji. Naslednja formula na primer izračuna vrednost 11, ker seznam ali knjižnica izračuna množenje pred seštevom. Formula zmnoži 2 in 3 in nato rezultatu doda 5.
=5+2*3
Če pa z oklepaji spremenite sintakso, seznam ali knjižnica sešteje 5 in 2 ter nato rezultat pomnoži s 3, tako da je rezultat 21.
=(5+2)*3
V tem primeru je v oklepajih okoli prvega dela formule vsiljeno, da seznam ali knjižnica najprej izračuna [Strošek]+25 in nato rezultat deli z vsoto vrednosti v stolpcih EC1 in EC2.
=([Cost]+25)/SUM([EC1]+[EC2])
