Vpišite se z Microsoftovim
Vpišite se ali ustvarite račun.
Pozdravljeni,
Izberite drug račun.
Imate več računov
Izberite račun, s katerim se želite vpisati.

S funkcijo TEXT lahko spreminjate način prikaza številke tako, da uporabite oblikovanje s kodami oblik. Ta način je uporaben v situacijah, ko želite prikazati številke v bolj berljivi obliki ali ko želite združiti številke z besedilom ali s simboli.

Opomba: Funkcija TEXT pretvori števila v besedilo, zaradi česar je oteženo sklicevanje v poznejših izračunih. Priporočamo, da ohranite izvirno vrednost v eni celici in nato uporabite funkcijo TEXT v drugi celici. Če morate ustvariti druge formule, nato vedno vstavite sklic na izvirno vrednost in ne na rezultat funkcije TEXT.

Sintaksa

TEXT(value, format_text)

V sintaksi funkcije TEXT so ti argumenti:

Ime argumenta

Opis

value

Številska vrednost, ki jo želite pretvoriti v besedilo.

format_text

Besedilni niz, ki določa oblikovanje, ki ga želite uporabiti v navedeni vrednosti.

Pregled

Pomen najpreprostejše oblike funkcije TEXT je:

  • =TEXT(vrednost, ki jo želite oblikovati; "koda oblike, ki jo želite uporabiti")

Tukaj je nekaj priljubljenih primerov, ki jih lahko neposredno kopirate v Excel za preskušanje. Upoštevajte kode oblik v narekovajih.

Formula

Opis

=TEXT(1234.567,"$#,##0.00")

Valuta z ločilom tisočic in 2 decimalnima mestoma, npr. 1.234,57 €. Upoštevajte, da Excel zaokroži vrednost na 2 decimalni mesti.

=TEXT(TODAY(),"MM/DD/YY")

Današnji datum v obliki zapisa MM/DD/LL, npr. 03/14/12.

=TEXT(TODAY(),"DDDD")

Današnji dan v tednu, kot je ponedeljek.

=TEXT(NOW(),"H:MM AM/PM")

Trenutni čas, kot je 13:29 h.

=TEXT(0.285,"0.0%")

Odstotek, npr. 28,5 %.

=TEXT(4.34 ,"# ?/?")

Ulomek, npr. 4 1/3.

=TRIM(TEXT(0.34,"# ?/?"))

Ulomek, npr. 1/3. Upoštevajte, da v tem primeru s funkcijo TRIM odstranite začetni presledek z decimalnim mestom.

=TEXT(12200000,"0.00E+00")

Znanstveni zapis, npr. 1.22E + 07

=TEXT(1234567898,"[<=9999999]###-####;(###) ###-####")

Posebni zapis (telefonska številka), npr. (123) 456-7898

=TEXT(1234,"0000000")

Dodajanje vodilnih ničel (0), npr. 0001234

=TEXT(123456,"##0° 00' 00''")

Po meri – zemljepisna širina/dolžina

Opomba: Čeprav lahko uporabite funkcijo TEXT za spreminjanje oblikovanja, to ni edini način. Obliko zapisa lahko spremenite brez formule tako, da pritisnete CTRL+1 (ali Slika ikone gumba MAC Command+1 v računalniku Mac), nato pa izberete želeno obliko v pogovornem oknu Oblikovanje celic > število.

Prenesite naše primere

Prenesete lahko vzorčni delovni zvezek z vsemi primeri funkcije TEXT, ki jih najdete v tem članku, ter z nekaterimi dodatnimi primeri. Upoštevate lahko funkcije iz vzorčnih primerov ali pa ustvarite svoje kode oblik funkcije TEXT.

Prenos primerov Excelove funkcije TEXT

Druge kode oblik, ki so na voljo

V pogovornem oknu Oblikovanje celic lahko poiščete druge kode oblik, ki so na voljo:

  1. Pritisnite Ctrl + 1 (Slika ikone gumba MAC Command+ 1 v računalniku Mac), da odprete pogovorno okno Oblikovanje celic.

  2. Na zavihku Številka izberite želeno obliko zapisa.

  3. Izberite možnost Po meri.

  4. Želena koda oblike je nato prikazana v polju Vrsta. V tem primeru izberite vse elemente v polju Vrsta razen podpičja (;) in simbola @. V spodnjem primeru smo izbrali in kopirali le »mm/dd/ll«.

  5. Pritisnite Ctrl+C, da kopirate kodo oblike, nato pa pritisnite Prekliči , da zaprete pogovorno okno Oblikovanje celic.

  6. Nato morate pritisniti le Ctrl + V, da prilepite kodo oblike v svojo formulo TEXT, npr.: =TEXT(B2,"mm/dd/yy"). Kodo oblike prilepite v narekovaje (»koda oblike«), sicer vam bo Excel prikazal sporočilo o napaki.

Primer uporabe pogovornega okna »Oblika« > »Celice« > »Številka« > »Po meri«, ko želite, da Excel namesto vas ustvari nize oblik.

Kode oblik po kategoriji

V nadaljevanju je navedenih nekaj primerov, kako lahko uporabite različne oblike zapisa števil za vrednosti v pogovornem oknu Oblikovanje celic, nato pa uporabite možnost Po meri, da kopirate te kode oblik v svojo funkcijo TEXT.

Zakaj Excel izbriše moje vodilne ničle?

Excel je ustvarjen tako, da poišče številke, ki se vnašajo v celice, ne poišče pa številk, ki so videti kot besedilo, npr. številke delov ali inventarne številke. Če želite ohraniti vodilne ničle, vhodni obseg oblikujte kot besedilo, preden prilepite ali vnesete vrednosti. Izberite stolpec ali obseg, v katerega boste vnašali vrednosti, nato pa uporabite CTRL + 1 za prikaz pogovornega okna Oblika > Celice in na zavihku Številke izberite Besedilo. Nato Excel ohrani vaše vodilne ničle.

Če ste že vnesli podatke in je Excel odstranil vaše vodilne ničle, lahko uporabite funkcijo TEXT, da jih znova dodate. Za najvišjo celico lahko ustvarite sklic na vrednosti in uporabite =TEXT(value,"00000"), pri čemer število ničel v formuli predstavlja skupno število želenih znakov, nato pa kopirajte in prilepite v preostali del obsega.

Primeri uporabe funkcije TEXT za oblikovanje vodilnih ničel.  =TEXT(A2,"00000")

Če morate besedilne vrednosti znova pretvoriti v številke, jih lahko pomnožite z 1, npr. =D4*1, ali pa uporabite dvojni unarni operator (--), npr. =--D4.

Excel tisočice ločuje z vejicami, če oblika zapisa vsebuje vejico (,), ki jo obdajajo številčni znaki (#) ali ničle. Na primer, če je niz oblike zapisa "#,###", Excel prikaže številko 12200000 kot 12,200,000.

Vejica, ki je postavljena za označbo mesta števke, spremeni merilo za številko za 1.000. Na primer, če je niz oblike "#,###.0,", Excel prikaže številko 12200000 kot 12,200.0.

Primeri funkcije TEXT, ki uporablja ločilo tisočic

Opombe: 

  • Ločilo tisočic je odvisno od območnih nastavitev. V ZDA je uporabljena vejica, medtem ko je lahko pri drugih območnih nastavitvah uporabljena pika (.).

  • Ločilo tisočic je na voljo za številko, valuto in računovodske oblike zapisa.

To so primeri standardnih oblik zapisa številk (le ločilo tisočic in decimalna mesta), valute in računovodskih oblik zapisa. Oblika zapisa valute vam omogoča vstavljanje želenega simbola valute zraven vrednosti, medtem ko bo računovodska oblika zapisa postavila simbol valute levo od celice in vrednost desno od celice. Spodaj si oglejte razliko med kodo oblike zapisa valute in kodo računovodske oblike zapisa, pri čemer računovodska oblika uporablja zvezdico (*) za ustvarjanje ločila med simbolom in vrednostjo.

Primeri funkcije TEXT z oblikami zapisa »Število«, »Valuta« in »Računovodstvo«

Če želite poiskati kodo oblike zapisa simbola valute, najprej pritisnite Ctrl + 1 (ali Slika ikone gumba MAC Command+ 1 v računalniku Mac), izberite želeno obliko zapisa, nato pa izberite simbol v spustnem meniju Simbol:

Izbor »Simbol valute« v pogovornem oknu »Oblikovanje celic«

Nato kliknite Po meri levo od razdelka Kategorija in kopirajte kodo oblike, vključno s simbolom valute.

Funkcija TEXT – valuta po meri s simbolom

Opomba: Funkcija TEXT ne podpira barvnega oblikovanja. Če kopirate kodo oblike številke iz pogovornega okna »Oblikovanje celic«, ki vključuje barvo, npr.: $#,##0.00_);[Red]($#,##0.00), bo funkcija TEXT sprejela kodo oblike, ne bo pa prikazala barve.

Način prikaza datuma lahko spremenite z uporabo kombinacije črk »M« za mesec, »D« za dan in »Y« za leto.

Kode oblike »Mesec«, »Dan« in »Leto«

V kodah oblik v funkciji TEXT ni razlikovanja med velikimi in malimi črkami, tako da lahko uporabite ali »M« ali »m«, »D« ali »d« ter »Y« ali »y«.

Mynda Treacy, MVP za Excel

Mynda priporoča ...

Če delite Excelove datoteke in poročila z uporabniki iz različnih držav, vam priporočamo, da jim posredujete poročilo v njihovem jeziku. Mynda Treacy, MVP za Excel ima odlično rešitev, ki je predstavljena v članku Prikaz podatkov v Excelu v različnih jezikih. Vključuje tudi vzorčni delovni zvezek, ki ga lahko prenesete.

Prikaze časa lahko spremenite z uporabo kombinacije črk »H« za ure, »M« za minute ali »S« za sekunde ter možnosti »AM/PM« za 12-urni prikaz.

Oblike zapisa časa za ure, minute in sekunde

Če ne uporabite možnosti »AM/PM« ali »A/P«, bo čas prikazan v 24-urni obliki.

V kodah oblik v funkciji TEXT ni razlikovanja med malimi in velikimi črkami, tako da lahko uporabite »H« ali »h«, »M« ali »m«, »S« ali »s« ter »AM/PM« ali »am/pm«.

Način prikaza decimalnih vrednosti lahko spremenite z oblikami zapisa odstotkov (%).

Kode oblik za odstotke

Način prikaza decimalnih vrednosti lahko spremenite z zapisom ulomkov (?/?). Oblike.

Kode oblik za ulomke

Znanstveni zapis je način prikaza številk z decimalnimi mesti med 1 in 10, pomnožen z 10. Zapis je pogosto uporabljen za skrajšanje prikaza velikih številk.

Kode oblik za znanstveni zapis

Excel zagotavlja 4 posebne oblike zapisa:

  • Poštna številka – "00000"

  • Poštna številka + 4 - "00000-0000"

  • Telefonska številka - "[<=9999999]###-####;(###) ###-####"

  • EMŠO – "000-00-0000"

Posebne oblike za funkcijo TEXT

Posebne oblike zapisa se bodo razlikovale glede na območne nastavitve, vendar, če za vaše območne nastavitve ni na voljo posebnih oblik zapisa ali če oblike ne ustrezajo vašim potrebam, lahko ustvarite svoje oblike v pogovornem oknu Oblikovanje celic > Po meri.

Pogost primer

Funkcija TEXT je redko uporabljena sama, pogosto je uporabljena skupaj z drugimi elementi. Denimo, da želite združiti besedilne in številske vrednosti, na primer »Poročilo natisnjeno dne: 14. 3. 2012" ali »Tedenski prihodek: 66.348,72 €". To bi lahko vnesli ročno v Excel, vendar potem Excelovo samodejno delovanje ne bi imelo pomena. Če združite besedilo in oblikovane številke, npr. datume, čase, valute itd., Excel žal ne zazna, kako jih želite prikazati, zato opusti oblikovanje številk. Tukaj je funkcija TEXT neprecenljiva, ker vam omogoča, da Excel prisilite v oblikovanje vrednosti na želeni način tako, da uporabite kodo oblike, kot je "DD/MM/YY", za obliko zapisa datuma.

V tem primeru boste videli, kaj se zgodi, če poskušate združiti besedilo in številko, ne da bi uporabili funkcijo TEXT. V tem primeru uporabljamo znak »in« (&), da združimo besedilni niz, presledek (" ") in vrednost s kodo =A2&" "&B2.

Primer združevanja besedila brez funkcije TEXT

Kot lahko vidite, je Excel odstranil oblikovanje datuma v celici B2. V naslednjem primeru boste videli, kako vam funkcija TEXT omogoča, da uporabite želeno obliko zapisa.

Primer združevanja besedila s funkcijo TEXT

Naša posodobljena formula je takšna:

  • Celica C2:=A2&" "&TEXT(B2,"mm/dd/yy") – oblika zapisa datuma

Pogosto zastavljena vprašanja

Žal tega ne morete narediti s funkcijo TEXT; morate uporabiti kodo VBA (VBA). Spodnja povezava ima metodo: Kako pretvoriti številsko vrednost v angleške besede v Excelu.

Da, uporabite lahko funkcije UPPER, LOWER in PROPER. Na primer =UPPER("Živijo") vrne »ŽIVIJO«.

Da, vendar je treba izvesti nekaj korakov. Najprej izberite celico ali celice, kjer želite, da se to zgodi, > uporabite Ctrl + 1, da odprete pogovorno okno Oblikovanje > celice, nato pa > Poravnava > Kontrolnik besedila > potrdite možnost Prelomi besedilo. Nato prilagodite dokončano funkcijo TEXT, da vključite funkcijo ASCII CHAR(10) na mesto, kjer želite vstaviti prelom vrstice. Morda boste morali prilagoditi širino stolpca, kar je odvisno od tega, kako je poravnan končni rezultat.

Primer uporabe funkcije TEXT s »CHAR(10)« za vstavljanje preloma vrstice. ="Today is: "&CHAR(10))&TEXT(TODAY(),"MM/DD/YY")

V tem primeru smo uporabili: ="Today is: "&CHAR(10)&TEXT(TODAY(),"mm/dd/yy")

To se imenuje znanstveni zapis in Excel samodejno pretvori številke z več kot 12 števkami, če je celica (celice) oblikovana kot Splošno, in s 15 števkami, če je celica (celice) oblikovana kot število. Če morate vnesti dolge številske nize, vendar jih ne želite pretvoriti, oblikujte te celice kot besedilo, preden vnesete ali prilepite vrednosti v Excel.

Mynda Treacy, MVP za Excel

Mynda priporoča ...

Če delite Excelove datoteke in poročila z uporabniki iz različnih držav, vam priporočamo, da jim posredujete poročilo v njihovem jeziku. Mynda Treacy, MVP za Excel ima odlično rešitev, ki je predstavljena v članku Prikaz podatkov v Excelu v različnih jezikih. Vključuje tudi vzorčni delovni zvezek, ki ga lahko prenesete.

Glejte tudi

Ustvarjanje ali brisanje oblike zapisa števil po meri

Pretvarjanje števil v obliki besedila v število

Vse Excelove funkcije (po kategoriji)

Ali potrebujete dodatno pomoč?

Ali želite več možnosti?

Raziščite ugodnosti naročnine, prebrskajte izobraževalne tečaje, preberite, kako zaščitite svojo napravo in še več.

Skupnosti vam pomagajo postaviti vprašanja in odgovoriti nanje, posredovati povratne informacije in prisluhniti strokovnjakom z bogatim znanjem.

Vam je bila informacija v pomoč?

Kako ste zadovoljni s kakovostjo jezika?
Kaj je vplivalo na vašo izkušnjo?
Če pritisnete »Pošlji«, bomo vaše povratne informacije uporabili za izboljšanje Microsoftovih izdelkov in storitev. Vaš skrbnik za IT bo lahko zbiral te podatke. Izjavi o zasebnosti.

Zahvaljujemo se vam za povratne informacije.

×