Pregled formul v Excelu

Pregled formul v Excelu

Če programa Excel še niste uporabljali, boste kmalu ugotovili, da je to več kot le mreža, v kateri v stolpce ali vrstice vnašate številke. Da, s programom Excel lahko določite skupno vsoto vrednosti v stolpcu ali v vrsticah številk, vendar pa lahko izračunate tudi plačilo hipoteke, rešite matematične ali inženirske težave ali pa poiščete najboljši možen scenarij na podlagi spremenljivk, ki jih vnesete.

Excel to izvede s formulami v celicah. Formula podatke na delovnem listu izračuna ali z njimi izvede druga dejanja. Formula se vedno začne z znakom za »je enako« (=), temu pa lahko sledijo številke, matematični operatorji (na primer znak + ali - za seštevanje ali odštevanje) in vgrajene Excelove funkcije, ki lahko znatno razširijo zmogljivost formule.

Ta formula na primer pomnoži 2 in 3, nato pa rezultatu prišteje 5, tako da znaša končni rezultat 11.

=2*3+5

Tu so dodatni primer formul, ki jih lahko vnesete na delovni list.

  • =A1+A2+A3    Sešteje vrednosti v celicah A1, A2 in A3.

  • =SUM(A1:A10)    Uporablja funkcijo SUM, da vrne seštevek vrednosti v celicah od A1 do A10.

  • =TODAY()    Vrne trenutni datum.

  • =UPPER("živijo")    Besedilo »živijo« pretvori v »ŽIVIJO« s funkcijo UPPER .

  • =IF(A1>0)    Uporablja funkcijo IF za preizkus celice A1, s katerim določi, ali je v njej vrednost, večja od 0.

Formula lahko vsebuje tudi enega ali vse od teh elementov: funkcije, sklici, operatorji in konstante.

Deli formule   

Deli formule

1. Funkcije: S funkcijo PI() dobite vrednost za pi: 3,142 ...

2. Sklici: Z A2 dobite vrednost v celici A2.

3. Konstante: številke ali besedilne vrednosti, ki so vnesene neposredno v formulo, na primer 2.

4. Operatorji: Z operatorjem ^ (strešico) povečate število na določeno potenco, medtem ko z operatorjem * (zvezdico) pomnožite števila.

Konstanta je vrednost, ki ni izračunana; vrednost je vedno enaka. Konstante so na primer datum 10. 9. 2008, število 210 in besedilo »Četrtletni zaslužek«. izraz ali vrednost, izračunana z izrazom, ni konstanta. Če v formuli namesto sklicev na celice uporabljate konstante (na primer =30+70+110), se rezultat spremeni le, če spremenite formulo. Na splošno velja, da je konstante najbolje postaviti v posamezne celice, v katerih jih lahko po potrebi preprosto spremenite, nato pa se na te celice sklicujete v formulah.

Operatorji določajo vrsto izračuna, ki ga želite izvesti z elementi formule. Excel sledi splošnim matematičnim pravilom za kalkulacije, ki so oklepaji, potence, množenje in deljenje ter seštevanje in odštevanje. Z oklepaji lahko spremenite vrstni red izračunavanja.

Vrste operaterjev. Obstajajo štiri različne vrste računskih operatorjev: aritmetični operatorji, operatorji primerjave, besedilni operatorji spajanja in operatorji sklicev.

  • Aritmetični operatorji

    Za izvajanje osnovnih matematičnih operacij, kot je na primer seštevanje, odštevanje, množenje ali deljenje, sestavljanje številskih vrednosti in ustvarjanje številskih rezultatov, uporabljajte te aritmetične operatorje.

    Aritmetični operator

    Pomen

    Primer

    + (znak plus)

    Seštevanje

    =3+3

    - (znak minus)

    Odštevanje
    Negacija

    =3–3
    =-3

    * (zvezdica)

    Množenje

    =3*3

    / (poševnica naprej)

    Deljenje

    =3/3

    % (znak za odstotke)

    Odstotek

    30 %

    ^ (strešica)

    Potence

    =3^3

  • Operatorji primerjave

    S temi operatorji lahko primerjate dve vrednosti. Ko ti dve vrednosti primerjate s temi operatorji, je rezultat logična vrednost – TRUE ali FALSE.

    Operator primerjave

    Pomen

    Primer

    = (enačaj)

    Enak kot

    =A1=B1

    > (znak večji od)

    Večji kot

    =A1>B1

    < (znak manjši od)

    Manjši kot

    =A1<B1

    >= (znak večji ali enak)

    Večje od ali enako

    =A1>=B1

    <= (znak manjši od ali enak)

    Manjše od ali enako

    =A1<=B1

    <> (znak ni enako)

    Ni enako

    =A1<>B1

  • Besedilni operator spajanja

    Uporabljajte znak »and« (&) za spajanje (združevanje) enega ali več besedilnih nizov, da ustvarite enotno besedilo.

    Besedilni operator

    Pomen

    Primer

    & (znak »in«)

    Poveže ali spoji dve vrednosti in ustvari eno povezano besedilno vrednost

    ="North"&"wind" vrne "Northwind".
    V celici A1 je "Priimek", v celici B1 pa je "Ime", =A1&", "&B1 vrne "Priimek, Ime".

  • Operatorji sklicev

    Sestavljajo obsege celic za izračune z naslednjimi operatorji.

    Operator sklicev

    Pomen

    Primer

    : (dvopičje)

    Operator obsega, ki ustvari en sklic za vse celice med dvema sklicema, vključno med tema dvema sklicema.

    B5:B15

    , (vejica)

    Operator unije, ki združi več sklicev v en sklic

    =SUM(B5:B15,D5:D15)

    (presledek)

    Operator preseka, ki ustvari en sklic na celice, ki so skupne tema dvema sklicema

    B7:D7 C6:C8

Na vrh strani

V nekaterih primerih lahko vrstni red, po katerem se izvaja izračun, vpliva na vrnjeno vrednost formule, zato morate razumeti, kako je vrstni red določen in kako lahko spremenite ta vrstni red, da dobite želene rezultate.

  • Vrstni red izračunavanja

    Formule vrednosti računajo po določenem vrstnem redu. V programu Microsoft Excel se formula vedno prične z enačajem (=). Excel znake, ki sledijo enačaju, obravnava kot formulo. Za enačajem so elementi, ki bodo izračunani (operandi), na primer konstante in sklici na celice. Ločeni so z računskimi operatorji. Excel računa formule od leve proti desni glede na določen vrstni red posameznega operatorja v formuli.

  • Prednostni vrstni red operatorjev v Excelovih formulah

    Če v eno formulo vključite več operatorjev, Excel izvaja operacije po vrstnem redu, ki je prikazan v spodnji tabeli. Če so v formuli enakovredni operatorji – če je na primer v formuli tako operator množenja kot tudi operator deljenja – Excel preračunava operatorje od leve proti desni.

    Operator

    Opis

    : (dvopičje)

    (presledek)

    ; (podpičje)

    Operatorji sklicev

    -

    Negacija (kot pri -1)

    %

    Odstotek

    ^

    Potenciranje

    * in /

    Množenje in deljenje

    + in –

    Seštevanje in odštevanje

    &

    Združi dva niza besedila (povezava)

    =
    < >
    <=
    >=
    <>

    Primerjalni operatorji

  • Uporaba oklepajev v Excelovih formulah

    Če želite spremeniti vrstni red preračunavanja, postavite del formule, ki naj se najprej izračuna, v oklepaje. Naslednja formula na primer izračuna vrednost 11, ker Excel izvede množenje pred seštevanjem. Formula zmnoži 2 in 3 in nato rezultatu doda 5.

    =5+2*3

    Če z oklepaji spremenite sintakso formule, Excel najprej sešteje 5 in 2 ter nato rezultat pomnoži s 3, tako da je rezultat 21.

    =(5+2)*3

    V tem primeru je Excel zaradi oklepajev, ki obdajajo prvi del formule, prisiljen, da najprej izračuna B4+25 in nato rezultat deli z vsoto vrednosti v celicah D5, E5 in F5.

    =(B4+25)/SUM(D5:F5)

    Na vrh strani

Funkcije so vnaprej določene formule za izvajanje izračunov z določenimi vrednostmi, imenovanimi argumenti, v posebnem vrstnem redu ali strukturi. Funkcije lahko uporabite za izvajanje preprostih ali zapletenih izračunov. Vse Excelove funkcije najdete na traku na zavihku »Formule«:

Zavihek »Formule« na traku  v Excelu
  • Sintakda Excelovih funkcij

    Spodnji primer uporabe funkcije ROUND, ki zaokroži število v celici A10, prikazuje sintakso funkcije.

    Struktura funkcije

    1. Struktura. Struktura funkcije se začne z enačajem (=), ki mu sledi ime funkcije, oklepaj, argumenti funkcije, ki so med seboj ločeni s podpičji, in zaklepaj.

    2. Ime funkcije. Če želite prikazati seznam funkcij, ki so na voljo, kliknite celico in pritisnite tipki SHIFT+F3. S tem boste odprli pogovorno okno Vstavljanje funkcij.

    Excelove formule – pogovorno okno za vstavljanje funkcij

    3. Argumenti. Argumenti so lahko števila, besedilo, logične vrednosti, kot sta TRUE ali FALSE, polja, vrednosti napak, kot je #N/V, ali sklici na celice. Argument, ki ga določite, mora zagotoviti veljavno vrednost za ta argument. Argumenti so lahko tudi konstante, formule ali druge funkcije.

    4. Opis argumentov. Opis s sintakso in argumenti se prikaže, ko vnašate formulo. Vnesite na primer =ROUND( in prikazal se bo opis. Opisi so prikazani le za vgrajene funkcije.

    Opomba : Funkcij vam ni treba vnašati s samimi velikimi črkami, na primer =ROUND. Ko pritisnete Enter, Excel samodejno spremeni črke funkcije v velike črke. Če pri vnosu imena funkcije naredite napako, na primer =SUME(A1:A10) namesto =SUM(A1:A10), vrne Excel napako #NAME?.

  • Vnos Excelovih funkcij

    Ko ustvarite formulo s funkcijo, uporabite pogovorno okno Vstavljanje funkcije za pomoč pri vnosu funkcij delovnega zvezka. Ko izberete funkcijo v pogovornem oknu Vstavljanje funkcije, Excel zažene čarovnika za funkcije, ki prikaže ime funkcije, posamezne argumente, opis funkcije in vsakega argumenta, trenutni rezultat funkcije in trenutni rezultat celotne formule.

    Excelov čarovnik za funkcije

    Za lažje ustvarjanje in urejanje formul ter za zmanjšanje možnosti črkovalnih napak in napak v sintaksi uporabite funkcijo Samodokončanje formule. Ko vnesete = (enačaj) in začetne črke funkcije, Excel prikaže dinamični spustni seznam z veljavnimi funkcijami, argumenti in imeni, ki ustrezajo vnesenim črkam. V spustnem seznamu lahko nato izberete želeno funkcijo, Excel pa jo bo vnesel namesto vas.

    Uporaba funkcije za samodokončanje formul

  • Gnezdenje Excelovih funkcij

    V določenih primerih boste morda morali uporabiti funkcijo kot enega od argumentov druge funkcije. Ta formula na primer uporablja ugnezdeno funkcijo AVERAGE in primerja rezultate z vrednostjo 50.

    Ugnezdene funkcije

    1. Funkciji AVERAGE in SUM sta ugnezdeni v funkciji IF.

    Veljavni rezultati    Če se ugnezdena funkcija uporablja kot argument, mora vrniti isto vrsto vrednosti, kot jo uporablja argument. Če argument na primer vrne vrednost TRUE ali FALSE, mora tudi ugnezdena funkcija vrniti vrednost TRUE ali FALSE. Če se to ne zgodi, Excel prikaže vrednost napake #VREDN!.

    Omejitve ravni gnezdenja    Formula lahko vsebuje do sedem ugnezdenih ravni funkcij. Ko je ena funkcija (imenovali jo bomo funkcija B) uporabljena kot argument v drugi funkciji (imenovali jo bomo funkcija A), funkcija B deluje kot funkcija druge ravni. Funkciji AVERAGE in SUM sta na primer obe funkciji druge ravni, če sta uporabljeni kot argumenta funkcije IF. Funkcija, ki je ugnezdena v ugnezdeni funkciji AVERAGE je nato funkcija tretje ravni in tako naprej.

    Na vrh strani

Sklic določa celico ali obseg celic na delovnem listu in pove Excelu, kje iskati vrednosti ali podatke, ki jih želite uporabiti v formuli. S sklici lahko podatke, ki so v različnih delih delovnega lista, uporabite v eni formuli ali pa uporabite vrednost ene celice v več formulah. Prav tako se lahko sklicujete na celice na drugih listih istega delovnega zvezka in na druge delovne zvezke. Sklici na celice v drugih delovnih zvezkih se imenujejo povezave ali zunanji sklici.

  • Slog sklicevanja A1

     Excel privzeto uporablja slog sklicevanja A1, ki se na stolpce sklicuje s črkami (A do XFD, skupaj 16.384 stolpcev) in na vrstice z številkami (od 1 do 1.048.576). Te črke in številke so imenovane naslovi vrstic in stolpcev. Če se želite sklicevati na celico, vnesite črko stolpca, ki ji sledi številka vrstice. B2 se sklicuje na primer na celico v presečišču stolpca B in vrstice 2.

    Za sklicevanje na

    Uporabi

    Celico v stolpcu A in vrstici 10

    A10

    Obseg celic v stolpcu A in vrsticah od 10 do 20

    A10:A20

    Obseg celic v vrstici 15 in stolpcih od B do E

    B15:E15

    Vse celice v vrstici 5

    5:5

    Vse celice v vrsticah od 5 do 10

    5:10

    Vse celice v stolpcu H

    H:H

    Vse celice v stolpcih od H do J

    H:J

    Obseg celic v stolpcih od A do E in vrsticah od 10 do 20

    A10:E20

  • Sklic na celico ali obseg celic na drugem delovnem listu v istem delovnem zvezku

     V naslednjem primeru funkcija AVERAGE izračuna povprečno vrednost za obseg B1:B10 na delovnem listu imenovanem »Trženje« v istem delovnem zvezku.

    Primer sklicevanja na list

    1. Sklicuje se na delovni list »Trženje«

    2. Se sklicuje na obseg celic od B1 do B10

    3. Klicaj (!) loči sklic na delovni list od sklica na obseg celice

    Opomba : Če so na sklicevanem delovnem listu presledki ali številke, potem morate pred imenom delovnega lista in za njim dodati opuščaje ('), na primer ='123'!A1 ali ='January Revenue'!A1.

  • Razlika med absolutnimi, relativnimi in mešanimi sklici

    1. Relativni sklici    Relativni sklic v formuli, kot je A1, temelji na relativnem položaju celice, ki vsebuje formulo in celico, na katero se sklic nanaša. Če se mesto celice, ki vsebuje formulo, spremeni, se spremeni tudi sklic. Če formulo kopirate ali zapolnite prek vrstic ali stolpcev, bo sklic samodejno prilagojen. Nove formule privzeto uporabljajo relativni sklic. Če na primer kopirate ali zapolnite relativni sklic celice B2 v B3, bo samodejno prilagojen iz =A1 v =A2.

      Kopirana formula z relativnim sklicem   

      Kopirana formula z relativnim sklicem

    2. Absolutni sklici    Absolutni sklic na celico v formuli, kot je $A$1, se vedno sklicuje na celico na določenem mestu. Če se mesto celice, ki vsebuje formulo, spremeni, absolutni sklic ostane nespremenjen. Če formulo kopirate ali zapolnite prek vrstic ali stolpcev, absolutni sklic ne bo prilagojen. Nove formule privzeto uporabljajo relativni sklic, zato jih boste morda morali zamenjati z absolutnim sklicem. Če na primer kopirate ali zapolnite absolutni sklic celice B2 v B3, ostane v obeh celicah nespremenjen =$A$1.

      Kopirana formula z absolutnim sklicem   

      Kopirana formula z absolutnim sklicem
    3. Mešani sklici    Mešani sklic vsebuje absolutni stolpec in relativno vrstico ali absolutno vrstico in relativen stolpec. Sklic na absolutni stolpec uporablja oblike $A1, $B1 itd. Sklic na absolutno vrstico uporablja oblike A$1, B$1 itd. Če se mesto celice, ki vsebuje formulo, spremeni, se relativni sklic spremeni, medtem ko se absolutni sklic ne. Če formulo kopirate ali zapolnite prek vrstic in stolpcev, bo relativni sklic samodejno prilagojen, absolutni pa ne. Če na primer kopirate ali zapolnite mešani sklic iz celice A2 v B3, bo prilagojen iz =A$1 v =B$1.

      Kopirana formula z mešanim sklicem   

      Kopirana formula z mešanim sklicem

  • 3-D slog sklicevanja

    Preprosto sklicevanje na več delovnih listov    Če želite analizirati podatke v isti celici ali obsegu celic na več delovnih listih v delovnem zvezku, uporabite 3-D sklic. 3-D sklic vključuje sklic celice ali obsega, pred katerim je zapisan obseg imen delovnih listov. Excel uporablja katere koli delovne liste, shranjene med začetnim in končnim imenom sklica. =SUM(List2:List13!B5) na primer sešteje vse vrednosti v celici B5 na vseh delovnih listih med in na List2 in List13.

    • 3-D sklice lahko uporabljate za sklicevanje na celice na drugih delovnih listih, določanje imen in ustvarjanje formul s temi funkcijami: SUM, AVERAGE, AVERAGEA, COUNT, COUNTA, MAX, MAXA, MIN, MINA, PRODUCT, STDEV.P, STDEV.S, STDEVA, STDEVPA, VAR.P, VAR.S, VARA, and VARPA.

    • 3-D sklicev ni mogoče uporabiti v matričnih formulah.

    • 3-D sklicev ne morete uporabljati z operatorjem preseka (presledek) ali v formulah z implicitnim presekom.

    Kaj se zgodi, ko premikate, kopirate, vstavljate ali brišete delovne liste    Naslednji primeri pojasnjujejo, kaj se zgodi, ko premikate, kopirate, vstavljate ali brišete delovne liste, ki so vključeni v 3-D sklic. V primerih je uporabljena formula za seštevanje celic od A2 do A5 na delovnih listih od List2 do List6 [=SUM(List2:List6!A2:A5)].

    • Vstavljanje ali kopiranje    Če vstavite liste ali jih kopirate med List2 in List6 (končni meji izbora v tem primeru), Excel vključi vse vrednosti v celicah od A2 do A5 na dodane liste v izračun.

    • Brisanje     Če izbrišete liste med List2 in List6, Excel odstrani njihove vrednosti iz izračuna.

    • Premikanje    Če premaknete liste, ki so v obsegu listov od List2 do List6, na mesto, ki ni v obsegu sklica, Excel odstrani njihove vrednosti iz izračuna.

    • Premikanje končne točke    Če premaknete List2 ali List6 na drugo mesto v delovnem zvezku, Excel prilagodi izračun tako, da bo upošteval nov obseg listov med njima.

    • Brisanje končne točke    Če izbrišete List2 ali List6, Excel prilagodi izračun novemu obsegu listov.

  • Slog sklicevanja R1C1

    Prav tako lahko uporabljate slog sklicevanja, kjer so na delovnem listu oštevilčene tako vrstice kot stolpci. Slog sklicevanja R1C1 je uporaben za računanje postavitve vrstice in stolpca v makrih. V slogu R1C1 Excel pokaže mesto celice s črko »R«, ki ji sledi številka vrstice, in s črko »C«, ki ji sledi vrstica stolpca.

    Sklic

    Pomen

    R[-2]C

    relativni sklic na celico, ki je dve vrstici višje v istem stolpcu kot celica s formulo

    R[2]C[2]

    Relativni sklic na celico, ki je dve vrstici navzdol in dva stolpca v desno kot celica s formulo

    R2C2

    Absolutni sklic na celico v drugi vrstici in v drugem stolpcu

    R[-1]

    Relativni sklic na celotno vrstico nad aktivno celico

    R

    Absolutni sklic na vrstico, v kateri je celica s formulo

    Kadar snemate makro, Excel posname nekatere ukaze s slogom sklicevanja R1C1. Če na primer snemate ukaz, kot je klik gumba Samodejna vsota, s katerim vstavite formulo, ki sešteje obseg celic, Excel posname formulo s sklici sloga R1C1 in ne sloga A1.

    Slog sklicevanja R1C1 vklopite ali izklopite tako, da v pogovornem oknu Možnosti v kategoriji Formule v razdelku Delo s formulami potrdite ali počistite potrditveno polje Slog sklicevanja R1C1. Če želite prikazati to pogovorno okno, kliknite zavihek Datoteka.

    Na vrh strani

Ustvarite lahko definirana imena, ki predstavljajo celice, obseg celic, formule, konstante ali tabele Excela. Ime je pomenska okrajšava, ki omogoči lažje razumevanje namena sklica na celico, konstante, formule ali tabele, kar je na prvi pogled težko ugotoviti. Te informacije prikazujejo pogoste primere imen in kako njihova uporaba v formulah lahko izboljša jasnost ter naredi formule bolj razumljive.

1. primer

Vrsta primera

Primer, v katerem so namesto imen uporabljeni obsegi

Primer, v katerem so uporabljena imena

Sklic

=SUM(A16:A20)

=SUM(Prodaja)

Konstanta

=PRODUCT(A12,9.5%)

=PRODUCT(Price,TaxRate)

Formula

=TEXT(VLOOKUP(MAX(A16; A20); A16:B20; 2; FALSE); "m/dd/yyyy")

=TEXT(VLOOKUP(MAX(Prodaja),Informacije o prodaji,2,FALSE),"m/dd/yyyy")

Tabela

A22:B25

=PRODUCT(Cena,Tabela1[@Stopnja davkov])

2. primer

Kopirajte vzorčne podatke iz te tabele in jih prilepite v celico A1 v novem Excelovem delovnem listu. Če želite, da formule prikažejo rezultate, jih izberite, pritisnite F2 in nato tipko ENTER. Po potrebi lahko prilagodite širine stolpcev in si ogledate vse podatke.

Opomba :  V formulah v stolpcih C in D se določeno ime »Prodaja« zamenja s sklicem na (obseg) A9:A13 in ime »Informacije o prodaji« z obsegom A9:B13. Če v testnem delovnem zvezku ne ustvarite teh imen, bodo formule v celicah D2:D3 vrnile napako #NAME?.

Vrsta primera

Primer, brez uporabe imena

Primer, z uporabo imena

Formula in rezultat, z uporabo imena

Sklic

'=SUM(A9:A13)

'=SUM(Prodaja)

=SUM(Prodaja)

Formula

'=TEXT(VLOOKUP(MAX(A9:13); A9:B13; 2; FALSE); "m/dd/yyyy")

'=TEXT(VLOOKUP(MAX(Prodaja); Informacije o prodaji; 2; FALSE),"m/dd/yyyy")

=TEXT(VLOOKUP(MAX(Prodaja); Informacije o prodaji; 2; FALSE); "m/dd/yyyy")

Cena

995 €

Prodaja

Datum prodaje

249 €

17. 3. 2011

399 €

2. 4. 2011

643 €

23. 4. 2011

275 €

30. 4. 2011

447 €

4. 5. 2011

  • Vrste imen

    Obstaja več vrst imen, ki jih lahko ustvarite in uporabite

    • Definirano ime    Ime, ki predstavlja celico, obseg celic, formulo ali konstantno vrednost. Ustvarite lahko lastno definirano ime. Prav tako Excel včasih sam ustvari definirano ime namesto vas, na primer, ko določite območje tiskanja.

    • Ime tabele    Ime Excelove tabele, ki je zbirka podatkov o določenem predmetu, ki so shranjeni v zapisih (vrsticah) in poljih (stolpcih). Excel ustvari privzeto ime Excelove tabele »Tabela1«, »Tabela2«, in tako naprej, vsakič ko vstavite Excelovo tabelo, vendar lahko ta imena spremenite tako, da bodo bolj smiselna. Če želite več informacij o Excelovih tabelah, si oglejte Uporaba sestavljenih sklicev v Excelovih tabelah.

      Če želite več informacij o Excelovih tabelah, glejte Uporaba sestavljenih sklicev v Excelovih tabelah.

  • Ustvarjanje in vnašanje imen

    Ime ustvarite tako, da uporabite:

    • Polje z imenom v vnosni vrstici     Ta način je najprimernejši za ustvarjanje imena na ravni delovnega zvezka za izbrani obseg.

    • Ustvarjanje imena iz izbora     Imena lahko preprosto ustvarite iz obstoječih oznak vrstic in stolpcev, tako da uporabite izbrane celice na delovnem listu.

    • Pogovorno okno Novo ime    Ta način je najprimernejši, ko potrebujete več prilagodljivosti pri ustvarjanju imen, na primer ko določate obseg na ravni lokalnega delovnega lista ali ustvarjate opombo imena.

    Opomba : Imena privzeto uporabljajo absolutne sklice na celice.

    Ime vnesete tako, da:

    • Ga vtipkate    Vnesite ime, na primer kot argument formule.

    • Uporaba funkcije »Samodokončanje formul«    Uporabite spustni seznam »Samodokončanje formul«, kjer so veljavna imena samodejno navedena.

    • Ga izberete iz ukaza »Uporabi v formulah«    Izberite določeno ime na seznamu, ki je na voljo v ukazu Uporabi v formulah v skupini Določena imena na zavihku Formula.

Če želite več informacij, si oglejte članek Določanje in uporaba imen v formulah.

Na vrh strani

Formula polja lahko izvede več izračunov hkrati in nato vrne en sam rezultat ali več rezultatov. Formule polja se izvajajo v enem ali več naborih vrednosti, ki se imenujejo konstante polja. Vse konstante polja morajo imeti enako število vrstic in stolpcev. Formule polja ustvarite enako kot druge, le da za vnos formule pritisnete tipke CTRL+SHIFT+ENTER. Nekatere vgrajene funkcije so formule polja in jih je treba vnesti kot polja, da dobite pravilne rezultate.

Konstante polja lahko uporabite namesto sklica, ko ne želite vnašati vsake konstante v svojo celico na delovnem listu.

Uporaba formule polja za izračun enega in več rezultatov

Opomba : Ko vnesete matrična formula, Excel samodejno postavi formulo med { } (zavita oklepaja). Če poskušate zavite oklepaje vnesti sami, Excel prikaže formulo kot besedilo.

  • Formula s polji, ki vrne en rezultat    Ta vrsta formule polja lahko poenostavi model delovnega lista, ko namesto več različnih formul uporabite eno formulo polja.

    Ta primer izračuna skupno vrednost matrike cen delnic in obveznic brez uporabe vrstice celic za izračun in prikaz posameznih vrednosti delnic.

    Formula polja, ki vrne en rezultat

    Ko vnesete formulo ={SUM(B2:D2*B3:D3)} kot formulo polja, ta zmnoži polji »Delež« in »Cena« za vsako delnico in nato sešteje rezultate teh izračunov.

  • Formula s polji, ki vnre več rezultatov    Nekatere funkcije delovnih listov vrnejo matriko vrednosti ali pa potrebujejo matriko vrednosti kot argument. Za izračun več rezultatov s formulo polja morate vnesti matriko v obseg celic, ki ima enako število vrstic in stolpcev kot argumenti matrike.

    Če imate na primer tri obsege prodaje (v stolpcu B) za obdobje treh mesecev (v stolpcu A), s funkcijo TREND določite linearne vrednosti za te tri obsege prodaje. Če želite prikazati vse rezultate, ki jih dobite s formulo, jo vnesite v vse tri celice v stolpcu C (C1:C3).

    Formula polja, ki vrne več rezultatov

    Ko vnesete formulo =TREND(B1:B3;A1:A3) kot formulo polja, ta vrne tri ločene rezultate (22.196, 17.079 in 11.962), ki temeljijo na treh obsegih prodaje in treh mesecih.

Uporaba konstant polja

V navadno formulo lahko vnesete sklic na celico, ki vsebuje vrednost, ali pa vnesete vrednost, ki se imenuje konstanta. Podobno lahko v formulo polja vnesete sklic na matriko ali pa vnesete matriko vrednosti, ki so v celicah, ki se imenujejo konstante polja. Formule polja sprejmejo konstante enako kot formule, ki niso formule polja, vendar morate vnesti konstante polja v določeni obliki zapisa.

V konstantah polja so lahko števila, besedilo, logične vrednosti (TRUE ali FALSE) ali vrednosti napak, na primer #N/V. Različne vrste vrednosti so lahko v isti konstanti polja – na primer {1,3,4;TRUE,FALSE,TRUE}. Števila v konstantah polja so lahko v celoštevilski, decimalni ali znanstveni obliki. Besedilo mora biti navedeno v dvojnih narekovajih, na primer "torek".

Konstante polja ne smejo vsebovati sklicev na celice, stolpcev ali vrstic neenakih dolžin, formul, posebnih znakov $ (znak za dolar), oklepajev ali % (znak za odstotek).

Ko oblikujete konstante polja, se prepričajte, da:

  • jih vnesete med zavite oklepaje ({ }).

  • vrednosti v različnih stolpcih ločite s podpičjem (;). Tako na primer za predstavitev vrednosti 10, 20, 30 in 40 vnesite {10; 20; 30; 40}. Taka konstanta polja je matrika velikosti 1 krat 4 in je enakovredna sklicu na obseg razsežnosti 1 vrstica krat 4 stolpci.

  • boste vrednosti v različnih vrsticah ločili s podpičji (;). Tako na primer za predstavitev vrednosti 10, 20, 30 in 40 v eni vrstici ter 50, 60, 70 in 80 v vrstici, ki je takoj pod njo, vnesite konstanto polja 2 krat 4: {10; 20; 30; 40; 50; 60; 70; 80}.

Na vrh strani

Ko formulo izbrišete, so izbrisane tudi izračunane vrednosti formule. Lahko pa odstranite samo formulo in izračunane vrednosti formule pustite v celici.

  • Če želite izbrisati formule skupaj z izračunanimi vrednostmi, naredite to:

    1. Izberite celico ali obseg celic, v katerem je formula.

    2. Pritisnite tipko DELETE.

  • Če želite izbrisati formule, pri tem pa ne želite izbrisati izračunanih vrednosti, naredite to:

    1. Izberite celico ali obseg celic, v katerem je formula.

      Če je formula formula polja, izberite obseg celic, v katerem je formula polja.

      Izbiranje obsega celic, v katerem je formula polja

      1. Kliknite celico v formuli polja.

      2. Na zavihku Osnovno v skupini Urejanje kliknite Najdi in izberi in nato Pojdi v.

      3. Kliknite Posebno.

      4. Kliknite gumb Trenutno matriko.

    2. Na zavihku Osnovno v skupini Odložišče kliknite Kopiraj Slika gumba .
      Slika Excelovega traku

      Bližnjica na tipkovnici    Pritisnete lahko tudi kombinacijo CTRL+C.

    3. Na zavihku Osnovno v skupini Odložišče kliknite puščico v razdelku Prilepi Slika gumba in nato še Prilepi vrednosti.

Na vrh strani

V tej tabeli so povzete nekatere najpogostejše napake, ki jih lahko naredite, ko vnašate formulo, in navodila, kako se lahko napakam v formulah izognete:

Prepričajte se, da ...

Več informacij

Ujemanje vseh oklepajev in zaklepajev v formuli   

Vsi oklepaji so sestavljeni iz oklepaja in zaklepaja. Ko ustvarjate formulo, Excel prikazuje oklepaje v barvi, medtem ko jih vnašate.

Uporaba dvopičja za označevanje obsega, vnesenega v formulo   

Dvopičje (:) je uporabljeno za ločevanje referenc na prvo in zadnjo celico v obsegu. Na primer A1:A5.

Vnos vseh zahtevanih argumentov    

Funkcije imajo lahko zahtevane in opcijske argumente (v sintaksi označeno z oglatimi oklepaji). Vnesti je treba vse zahtevane argumente. Prepričajte se tudi, da niste vnesli preveč argumentov.

V formulo ne ugnezdite več kot 64 funkcij   

V formulo lahko ugnezdite funkcije v največ 64 ravneh.

Postavitev imen delovnega zvezka ali delovnega lista v enojne narekovaje    

Če se sklicujete na vrednosti ali celice na drugih delovnih listih ali delovnih zvezkih, ki imajo v imenih znake, ki niso ne črke ne številke, morate imena obdati z enojnimi narekovaji ( ' ).

Vključitev poti do zunanjih delovnih zvezkov    

V zunanjih sklicih mora biti ime delovnega zvezka in pot do tega zvezka.

Vnos števil brez oblikovanja.    

Številke, ki jih vnesete v formulo, ne bi smele biti oblikovane z decimalnimi ločili ali znaki za dolar ($), ker so vejice že uporabljene kot ločila argumentov v formulah, znaki za dolar pa so uporabljeni za označevanje absolutnih sklicev. Namesto da v formulo vnesete $1,000, vnesite 1000.

Na vrh strani

Pomembno : Med izračunanimi rezultati formul in nekaterimi Excelovimi funkcijami delovnih listov lahko pride do manjših razlik, in sicer glede na to, ali uporabljate računalnik s sistemom Windows z arhitekturo x86 ali x86-64 oz računalnik s sistemom Windows RT z arhitekturo ARM. Več informacij o razlikah.

Ali imate vprašanje o določeni funkciji?

Objavite vprašanje v forumu skupnosti za Excel

Pomagajte nam izboljšati Excel

Ali imate predloge za izboljšanje naslednje različice Excela? Če jih imate, si oglejte teme na spletnem mestu Excel UserVoice.

Glejte tudi

Pregled formul v Excelu

Kako se izogniti nedelujočim formulam

Iskanje in popravljanje napak v formulah

Bližnjice na tipkovnici in funkcijske tipke v Excelu

Funkcije v Excelu (po abecedi)

Excelove funkcije (po kategoriji)

Razširite svoja znanja
Oglejte si izobraževanje
Prvi dobite nove funkcije
Pridružite se programu Office Insider

Vam je bila informacija v pomoč?

Zahvaljujemo se vam za povratne informacije.

Zahvaljujemo se vam za povratne informacije. Videti je, da bi vam prišla prav pomoč enega od naših Officeovih agentov za podporo.

×