Lastnost PrtDevMode

Pomembno : Besedilo članka je prevedeno strojno. Glejte zavrnitev odgovornosti. Angleško različico tega članka najdete tukaj .

Velja za

Predmet »Obrazec«

Predmet »Poročilo«

Z lastnostjo PrtDevMode lahko nastavite ali vrnete informacije o načinu tiskalne naprave, ki so za obrazec ali poročilo navedene v pogovornem oknu Natisni. Podatkovni tip Različica za branje/pisanje.

izraz.PrtDevMode

izraz Zahtevano. Izraz, ki vrne predmet s seznama »Velja za«.

Opombe

Priporočeno je, da si celotno dokumentacijo o lastnostih PrtDevMode, PrtDevNames in PrtMip ogledate v kompletu »Win32 SDK«.

Nastavitev lastnosti PrtDevMode je 94-bajtna struktura, ki odraža strukturo DEVMODE, kot je določena v kompletu »Win32 SDK«. Če želite popolne informacije o članih lastnosti PrtDevMode, si oglejte komplet »Win32 SDK«.

Lastnost PrtDevnačin uporablja te članov.

Član

Opis

ImeNaprave

niz z največ 32 bajti, ki navaja ime naprave, ki jo podpira gonilnik – na primer »HP LaserJet IIISi«, če je navedeni tiskalnik »Hewlett-Packard LaserJet IIISi«. Vsak gonilnik tiskalnika ima enoličen niz.

SpecRazličica

Za celo število, ki določa številko različice strukture DEVMODE v Win32 komplet za razvoj programske opreme.

RazličicaGonilnika

Celo število, ki navaja številko različice gonilnika tiskalnika, ki jo je dodelil razvijalec gonilnika tiskalnika.

Velikost

Celo število, ki v bajtih navaja velikost strukture DEVMODE. (Ta vrednost nima izbirnega člana dmPodatkiOGonilniku za podatke, ki so značilni za napravo in imajo lahko to strukturo.) Če program spremeni samo del podatkov, ki je neodvisen od gonilnika, lahko s tem članom ugotovite dolžino strukture, ne da bi bilo treba upoštevati druge različice.

DodatniGonilnik

Celo število, ki v bajtih navaja velikost izbirnega člana dmPodatkiOGonilniku za podatke, ki so značilni za napravo in lahko imajo to strukturo. Če program ne uporablja informacij, ki so značilne za napravo, tega člana nastavite na 0.

Polja

A dolgo vrednost, ki določa, katere preostali člani v strukturi DEVMODE so bili inicializirati.

Usmerjenost

Celo število, ki navaja usmerjenost papirja. Lahko je 1 (pokončno) ali 2 (ležeče).

VelikostPapirja

Celo število, ki navaja velikost papirja za tiskanje. Če tega člana nastavite na 0 ali 256, dolžino in širino papirja navajata člana »DolžinaPapirja« in »ŠirinaPapirja«. Člana »VelikostPapirja« lahko nastavite tudi na vnaprej določeno vrednost.

DolžinaPapirja

Celo število, ki navaja dolžino papirja v enotah 1/10 milimetra. Ta član prepiše dolžino papirja, ki jo član »VelikostPapirja« določi za velikosti papirja po meri ali za naprave, na primer matrične tiskalnike, ki lahko tiskajo na različne velikosti papirja.

ŠirinaPapirja

Celo število, ki navaja širino papirja v enotah 1/10 milimetra. Ta član prepiše širino papirja, ki jo navaja član »VelikostPapirja«.

Merilo

Celo število, ki navaja faktor za prilagajanje velikosti natisnjenega dokumenta. Resnično velikost strani prilagodite tako, da fizično velikost strani pomnožite s faktorjem merilo/100. Na listu papirja velikosti 8,5 x 11 palcev (pisemska velikost) z vrednostjo merila 50 bi bila na primer enaka količina podatkov kot na strani velikosti 17 x 22 palcev, ker bi bila velikost natisnjenega besedila in grafik dvakrat manjša od izvirne višine in širine.

Kopije

Celo število, ki navaja število natisnjenih kopij, če tiskalna naprava podpira kopije z več stranmi.

PrivzetiVir

Celo število, ki navaja privzeti pladenj, s katerega se podaja papir.

KakovostTiskanja

Celo število, ki navaja ločljivost tiskalnika. Vrednosti so –4 (visoka), –3 (srednja), –2 (nizka) in –1 (osnutek).

Barva

Celo število. Za barvni tiskalnik navaja, ali je dokument natisnjen barvno. Vrednosti sta 1 (barvno) in 2 (enobarvno).

Obojestransko

Celo število. Za tiskalnik z možnostjo obojestranskega tiskanja navaja, ali je dokument natisnjen na obeh straneh papirja. Vrednosti so 1 (enostransko), 2 (vodoravno) in 3 (navpično).

LočljivostY

Celo število ki navaja ločljivost y tiskalnika v pikah na palec (dpi). Če tiskalnik inicializira tega člana, član »KakovostTiskanja« navede ločljivost x tiskalnika v pikah na palec (dpi).

MožnostTT

Celo število, ki navaja, kako bodo natisnjene pisave TrueType.

Zbiranje kopij

Celo število, ki navaja, ali se ob tiskanju več kopij kopije zbirajo. Če se kopije ne zbirajo, se dokument natisne hitreje in učinkoviteje, ker se podatki tiskalniku pošljejo samo enkrat.

ImeObrazca

Niz z največ 16 znaki, ki navaja velikost uporabljanega papirja, na primer »Pismo« ali »Legal«.

Vrednost za zapolnitev

Vrednost Dolgo število, ki se uporablja za zapolnjevanje presledkov, znakov ali vrednosti za prihodnje različice.

Biti

Vrednost Dolgo število, ki v bitih na slikovno točko navaja barvno ločljivost naprave za prikaz.

PW

Vrednost Dolgo število, ki v slikovnih točkah navaja širino vidne površine naprave (zaslona ali tiskalnika).

PH

Vrednost Dolgo število, ki v slikovnih točkah navaja višino vidne površine naprave (zaslona ali tiskalnika).

DFI

Vrednost Dolgo število, ki navaja zaslonski način naprave.

DFR

Vrednost Dolgo število, ki v hertzih (nihajih na sekundo) navaja frekvenco naprave za prikaz v določenem načinu.


Opomba : Nastavite lahko v lastnost prtdevmode programom Visual Basic for Applications (VBA) kodo .

Ta nastavitev lastnosti je v pogledu načrta ali postavitve za branje/pisanje, v drugih pogledih pa samo za branje.

Gonilniki tiskalnika lahko dodajo podatke, značilne za tiskalnik, neposredno za 94 bajti strukture DEVMODE. Zaradi tega je pomembno, da zgoraj opisani podatki DEVMODE ne presegajo 94 bajtov.

Strukturo DEVMODE uporabljajo samo gonilniki tiskalnikov, ki izvažajo funkcijo NačinZunanjeNaprave.

Program lahko velikosti papirja in imena, ki jih podpira tiskalnik, pridobi z vrednostmi DC_PAPERS, DC_PAPERSIZE in DC_PAPERNAMES, s katerimi pokliče funkcijo ZmožnostiNaprave.

Pred nastavljanjem vrednosti člana MožnostTT morajo programi z vrednostjo DC_TRUETYPE, s katero pokličejo funkcijo ZmožnostiNaprave, ugotoviti, kako lahko gonilnik tiskalnika uporablja pisave TrueType.

Primer

V tem primeru se z lastnostjo PrtDevMode preveri uporabniško določena velikost strani za poročilo:

Private Type str_DEVMODE
RGB As String * 94
End Type
Private Type type_DEVMODE
strDeviceName As String * 32
intSpecVersion As Integer
intDriverVersion As Integer
intSize As Integer
intDriverExtra As Integer
lngFields As Long
intOrientation As Integer
intPaperSize As Integer
intPaperLength As Integer
intPaperWidth As Integer
intScale As Integer
intCopies As Integer
intDefaultSource As Integer
intPrintQuality As Integer
intColor As Integer
intDuplex As Integer
intResolution As Integer
intTTOption As Integer
intCollate As Integer
strFormName As String * 32
lngPad As Long
lngBits As Long
lngPW As Long
lngPH As Long
lngDFI As Long
lngDFr As Long
End Type
Public Sub CheckCustomPage(ByVal rptName As String)
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
Dim intResponse As Integer
' Opens report in Design view.
DoCmd.OpenReport rptName, acDesign
Set rpt = Reports(rptName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
' Gets current DEVMODE structure.
DevString.RGB = strDevModeExtra
LSet DM = DevString
If DM.intPaperSize = 256 Then
' Display user-defined size.
intResponse = MsgBox("The current custom page size is " & _
DM.intPaperWidth / 254 & " inches wide by " & _
DM.intPaperLength / 254 & " inches long. Do you want " & _
"to change the settings?", vbYesNo + vbQuestion)
Else
' Currently not user-defined.
intResponse = MsgBox("The report does not have a custom page size. " & _
"Do you want to define one?", vbYesNo + vbQuestion)
End If
If intResponse = vbYes Then
' User wants to change settings. Initialize fields.
DM.lngFields = DM.lngFields Or DM.intPaperSize Or _
DM.intPaperLength Or DM.intPaperWidth
' Set custom page.
DM.intPaperSize = 256
' Prompt for length and width.
DM.intPaperLength = InputBox("Please enter page length in inches.") * 254
DM.intPaperWidth = InputBox("Please enter page width in inches.") * 254
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
End If
Set rpt = Nothing
End Sub

Prikazan je način spreminjanja usmerjenosti poročila. V tem primeru se pokončna usmerjenost spremeni v ležečo ali obratno, odvisno od trenutne usmerjenosti poročila.

Public Sub SwitchOrient(ByVal strName As String)
Const DM_PORTRAIT = 1
Const DM_LANDSCAPE = 2
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
' Opens report in Design view.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
DevString.RGB = strDevModeExtra
LSet DM = DevString
DM.lngFields = DM.lngFields Or DM.intOrientation
' Initialize fields.
If DM.intOrientation = DM_PORTRAIT Then
DM.intOrientation = DM_LANDSCAPE
Else
DM.intOrientation = DM_PORTRAIT
End If
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
Set rpt = Nothing
End Sub

Opomba : Strojni prevod – zavrnitev odgovornosti: Ta članek je bil preveden z računalniškim programom brez človeškega posredovanja. Microsoft skuša s strojno prevedenimi članki vsebino o Microsoftovih izdelkih, storitvah in tehnologijah približati osebam, ki ne razumejo angleščine. Ker je bil članek strojno preveden, so lahko v njem jezikovne, slovnične in pravopisne napake.

Razširite svoja znanja
Oglejte si izobraževanje
Prvi dobite nove funkcije
Pridružite se programu Office Insider

Vam je bila informacija v pomoč?

Zahvaljujemo se vam za povratne informacije.

Zahvaljujemo se vam za povratne informacije. Videti je, da bi vam prišla prav pomoč enega od naših Officeovih agentov za podporo.

×