Funkcija SUM

S funkcijo SUM, eno od funkcij matematike in trigonometrije, seštejete vrednosti. Seštejete lahko posamezne vrednosti, sklice celic, obsege ali mešanico vseh treh.

Primer:

  • =SUM(A2:A10)

  • =SUM(A2:A10, C2:C10)

Vaš brskalnik ne podpira tega videoposnetka. Namestite Microsoft Silverlight, Adobe Flash Player ali Internet Explorer 9.

Ta videoposnetek je del izobraževalnega tečaja z naslovom Seštevanje števil v programu Excel 2013.

SUM(število1,[število2],...)

Ime argumenta

Opis

število1    (obvezno)

Prvo število, ki ga želite dodati. Število je lahko na primer 4, sklic na celico npr. B6 ali obseg celice, kot je B2:B8.

number2-255    (izbirno)

Drugo število, ki ga želite dodati. Na ta način lahko navedete največ 255 števil.

Če želite hitro dobiti vsoto obsega celic, morate le izbrati obseg in pogledati v spodnji desni kot Excelovega okna.

Posnetek zaslona, na katerem sta prikazana izbiranje obsega celic in ogled vrstice stanja
Vrstica stanja


To je vrstica stanja. Prikazuje informacije o tem, kak ste izbrali (ena celica ali več celic). Če vrstico stanja kliknete z desno tipko miške, se bo prikazalo pogovorno okno o funkciji, v katerem bodo vse možnosti, ki jih lahko izberete. Poleg tega prikazuje tudi vrednosti za izbrani obseg, če imate potrjene te atribute. Več informacij o vrstici stanja.

Formulo SUM lahko na delovni list najhitreje dodate tako, da uporabite čarovnika za samodejno vsoto. Izberite prazno celico neposredno nad ali pod obsegom, ki ga želite sešteti, nato pa na zavihku Osnovno ali Formula v traku pritisnite Samodejna vsota > Sum. Čarovnik za samodejno vsoto bo samodejno zaznal obseg, ki ga želite sešteti, nato pa ustvaril formulo za vas. Deluje lahko tudi vodoravno, če izberete celico na levi ali na desni strani obsega, ki ga želite sešteti. Funkcija ne bo delovala pri prekinjenih nizih, vendar si bomo to podrobneje ogledali v naslednjem razdelku.

S čarovnikom za samodejno vsoto lahko samodejno ustvarite formulo SUM.  Izberite obseg nad/pod obsegom ali levo/desno od obsega, ki ga želite sešteti, in nato na zavihku »Formula« na traku izberite »Samodejna vsota« in »SUM«.
S čarovnikom za samodejno vsoto lahko hitro seštejete neprekinjene nize


V pogovornem oknu za samodejno vsoto lahko izberete tudi druge funkcije, na primer:

Navpična samodejna vsota

V celici B6 je prikazana formula samodejne vsote: =SUM(B2:B5)

Čarovnik za samodejno vsoto bo samodejno zaznal celice B2:B5 kot obseg, ki ga želite sešteti. Vi morate le pritisniti Enter, da to potrdite. Če morate dodati/izvzeti več celic, lahko pritisnete in pridržite tipko Shift > puščično tipko po želji, dokler ne pridete do želenega izbora, nato pa pritisnite Enter, ko končate.

Vodnik za funkcijo Intellisense: plavajoča oznaka SUM(number1,[number2], …) pod funkcijo je njen vodnik Intellisense. Če kliknete SUM ali ime funkcije, se bo spremenila v modro hiperpovezavo, s katero se boste premaknili do teme pomoči za to funkcijo. Če kliknete posamezne elemente funkcije, bodo označeni posamezni deli formule. V tem primeru bi bil označen le B2:B5, saj je v formuli le en sklic na število. Oznaka Intellisense se bo prikazala za vsako funkcijo.

Vodoravna samodejna vsota

V celici D2 je prikazana formulo samodejne vsote: =SUM(B2:C2)

Uporaba funkcije SUM z nezveznimi obsegi.  Formula v celici C8 je = SUM(C2:C3,C5:C6). Uporabili bi lahko tudi imenovane obsege, da bi bila formula =SUM(Teden1,Teden2).

Čarovnik za samodejno vsoto običajno deluje le za neprekinjene nize. Če imate torej prazne vrstice ali stolpce v obsegu, ki ga želite sešteti, se bo Excel ustavil pri prvi prekinitvi. V tem primeru bi morali s funkcijo SUM sešteti izbore, pri katerem dodate posamezne obsege. V tem primeru: če bi imeli podatke v celici B4, bi Excel ustvaril =SUM(C2:C6), saj bi prepoznal neprekinjen niz.

Več prekinjenih nizov lahko hitro izberete s kombinacijo Ctrl+levi klik. Najprej vnesite “=SUM(“, nato izberite različne obsege, Excel pa bo samodejno dodal ločilno vejico med obsege. Ko končate, pritisnite Enter.

NAMIG: s kombinacijo ALT+= lahko funkcijo SUM hitro dodate v celico. Nato morate le še izbrati obsege.

Opomba: morda boste opazili, da je Excel različne obsege označil z barvo, te pa se ujemajo znotraj same formule. C2:C3 je ene barve, C5:C6 pa druge. Excel bo to naredil za vse funkcije, razen če je sklicevani obseg na drugem delovnem listu ali v drugem delovnem zvezku. Za izboljšano dostopnost s pripomočki za osebe s posebnimi potrebami lahko uporabite imenovane obsege, na primer “Week1”, “Week2” itd., nato pa se nanje sklicujete v formuli:

=SUM(Week1,Week2)

Matematične operacije lahko preprosto samostojno izvajate z Excelom, lahko pa jih izvajate skupaj z Excelovimi formulami, kot je SUM. V tej tabeli je seznam operatorjev, ki jih lahko uporabite, poleg njih pa tudi nekatere povezane funkcije. Operatorje lahko vnesete bodisi s številskimi tipkami na tipkovnici bodisi z 10-številsko tipkovnico, če jo imate. Na primer s kombinacijo Shift+8 boste vnesli zvezdico (*) za množenje.

Operator

Operacija

Primeri

+

Seštevanje

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

Odštevanje

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

Množenje

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1,1) - funkcija PRODUCT

/

Deljenje

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1,1) - funkcija QUOTIENT

^

Potenciranje

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1,1) - funkcija POWER

Če želite več informacij, glejte Uprabite Excel kot kalkulator.

Drugi primeri

  1. Denimo, da želite odstotek popusta uporabiti za obseg celic, ki ste jih sešteli.

    Uporaba operatorjev s funkcijo SUM.  Formula v celici B16 je =SUM(A2:A14)*-25%.  Formula bi bila sestavljena pravilno, če bi bil odstotek -25 % sklic na celico, na primer =SUM(A2:A14)*E2
    • =SUM(A2:A14)*-25%

    Dobite 25 % seštetega obsega. Vendar pa s tem vrednost 25% vdelate v formulo. Zato jo boste morda pozneje težko našli, če jo boste morali spremeniti. Predlagamo, da vrednost 25% vstavite v celico in se namesto tega sklicujete nanjo. Tako je dobro vidna in jo je mogoče preprosto spremeniti. Na primer:

    • =SUM(A2:A14)*E2

    Če želite namesto množenja uporabiti deljenje, znak “*” zamenjate z znakom “/”: =SUM(A2:A14)/E2

  2. Seštevanje ali odštevanje od funkcije SUM

    i. Vrednost lahko preprosto dodate ali odštejete od seštete vrednosti z znakoma + ali -. To naredite tako:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

V tem razdelku je govora o najboljših praksah za delo s funkcijami SUM. Večino tega je mogoče uporabiti tudi za delo z drugimi funkcijami.

Način =1+2 ali =A+B – medtem ko lahko vnesete =1+2+3 ali =A1+B1+C2 in dobite popolnoma natančne rezultate, so ti načini pomanjkljivi zaradi teh razlogov:

  1. Tipkarske napake – predstavljajte si, da morate vnesti več in/ali veliko večje vrednosti, kot je na primer:

    • =14598.93+65437.90+78496.23

    Nato pa preverite, ali so vaši vnosi pravilni. Veliko lažje je te vrednosti vnesti v posamezne celice, nato pa uporabiti formulo SUM. Poleg tega lahko oblikujete vrednosti, ko so v celicah. Tako omogočite, da so bolj berljive kot v formuli.

    Namesto zakodiranja vrednosti v formule uporabite funkcijo SUM.  Formula v celici D5 je =SUM(D2:D4)
  2. #VALUE! napake v sklicevanem besedilu namesto številkah

    Če uporabite takšno formulo:

    • =A1+B1+C1 ali =A1+A2+A3

    Primer slabo sestavljene formule.  Formula v celici D2 je =A2+B2+C2

    Vaša formula se lahko prelomi, če so v sklicevanih celicah neštevilske vrednosti (besedilo), kar vrne napako #VALUE!. Funkcija SUM prezre besedilne vrednosti in vrne vsoto le številskih vrednosti.

    Pravilna zgradba formule.  Namesto formule =A2+B2+C2 je v celici D2 formula =SUM(A2:C2)
  3. Napaka #SKLIC! zaradi brisanja vrstic ali stolpcev

    Napaka #REF!, do katere pride zaradi brisanja stolpca.  Formula se je spremenila v =A2+#REF!+B2

    Če izbrišete vrstico ali stolpec, formula ne bo posodobljena tako, da bo izključila izbrisano vrstico, in bo vrnila napako #SKLIC!, funkcija SUM pa bo samodejno posodobljena.

    Funkcija SUM se samodejno prilagodi glede na vstavljene ali izbrisane vrstice in stolpce
  4. Formule ne bodo posodobile sklicev, ko vstavite vrstice ali stolpce

    Formule =A+B+C se ne posodobijo, če dodate vrstice

    Če vstavite vrstico ali stolpec, se formula ne bo posodobila tako, da bo vključevala dodano vrstico. Funkcija SUM se bo posodobila samodejno (dokler niste zunaj obsega, sklicevanega v formuli). To je zlasti pomembno, če pričakujete, da bo formula posodobljena, vendar se ta ne posodobi. V takem primeru dobite nepopolne rezultate, ki jih morda ne boste ujeli.

    Primer prikazuje formulo SUM, ki se samodejno razširi iz =SUM(A2:C2) v =SUM(A2:D2), ko je vstavljen stolpec
  5. Funkcija SUM s posameznimi sklici celic in obsegi

    Če uporabite formulo, podobno tej:

    • =SUM(A1,A2,A3,B1,B2,B3)

    Ta formula je enako dovzetna za napake, ko vstavljate ali brišete vrstice znotraj sklicevanega obsega zaradi istih razlogov. Veliko bolje je, da uporabite posamezne obsege:

    • =SUM(A1:A3,B1:B3)

    Ta oblika bo posodobljena, ko boste dodajali ali brisali vrstice.

  1. Funkcijo SUM lahko brez težav uporabljate z drugimi funkcijami. Tu je primer, ki ustvari izračun mesečnega povprečja:

    Uporaba funkcije SUM z drugimi funkcijami.  Formula v celici M2 je =SUM(A2:L2)/COUNTA(A2:L2) .  Opomba: celice od maja do novembra zaradi jasnosti niso prikazane.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. Ta uporabi funkcijo SUM obsega A2:L2, deljeno s številom nepraznih celic v obsegu A2:L2 (od maja do decembra so vrednosti prazne).

  1. Včasih boste morali sešteti določeno celico na več delovnih listih. Lahko bi kliknili vsak posamezen lic in celico, ki jo želite, nato pa uporabili “+” za seštevanje vrednosti celic, vendar je to dolgotrajen postopek, pri katerem lahko pride do napake.

    • =Sheet1!A1+Sheet2!A1+Sheet3!A1

    To lahko veliko lažje izvedete s funkcijo 3D ali 3-Dimensional SUM:

    3D-SUM – formula v celici D2 je =SUM(List1:List3!A2)
    • =SUM(Sheet1:Sheet3!A1)

    S to funkcijo seštejete celico A1 na vseh listih od Sheet 1 do Sheet 3.

    To je posebej priročno v primerih, kjer imate en list za vsak mesec (januar–december) in želite vsoto na listu s povzetkom.

    3D-SUM na več poimenovanih listih.  Formula v celici D2 je =SUM(januar:secember!A2)
    • =SUM(January:December!A2)

    Ta formula sešteje celico A2 na vsakem listu od januarja do decembra.

    Opombe : Če so v imenih delovnih listov presledki, na primer “January Sales”, potem morate uporabiti enojni narekovaj, ko se sklicujete na imena listov v formuli. Bodite pozorni na narekovaje PRED imenom prvega delovnega lista in ZA zadnjim.

    • =SUM(‘January Sales:December Sales’!A2)

    Način 3D bo deloval tudi z drugimi funkcijami, kot so AVERAGE, MIN, MAX itd.:

    • =AVERAGE(Sheet1:Sheet3!A1)

    • =MIN(Sheet1:Sheet3!A1)

    • =MAX(Sheet1:Sheet3!A1)

Težava

Vzrok težave

Funkcija SUM ne pokaže rezultata, temveč znake #####.

Preverite širino stolpca. Znaki ##### običajno pomenijo, da je stolpec preozek in ni mogoče prikazati rezultata formule.

Funkcija SUM ne prikaže rezultata, temveč samo formulo v obliki besedila.

Preverite, ali je celica morda oblikovana kot besedilo. Izberite zadevno celico ali obseg, nato pa s kombinacijo Ctrl+1 prikličite pogovorno okno za oblikovanje celic, kliknite zavihek Število, nato pa izberite želeno obliko zapisa. Če je bila celica oblikovana kot besedilo in se ne spremeni po tem, ko spremenite obliko, boste morali spremembo oblike morda vsiliti s kombinacijo F2 > Enter.

Moja funkcija SUM se ne posodobi.

Poskrbite, da bo možnost Izračun nastavljena na Samodejno. Na zavihku Formula se premaknite v razdelek z možnostmi izračunavanja. S tipko F9 lahko delovni list tudi prisilite k zagonu izračuna.

Poskrbite, da bo možnost izračuna nastavljena na »Samodejno«.  Na zavihku »Formula« se premaknite v razdelek z možnostmi izračunavanja.

Nekatere vrednosti niso dodane.

Sešteti je mogoče le številske vrednosti v sklicu funkcije ali obsegu. Prazne celice, logične vrednosti, kot je TRUE, ali besedilo so prezrti.

Namesto pričakovanega rezultata se prikaže napaka »#NAME?«.

To običajno pomeni, da je formula napačno črkovana, na primer =sume(A1:A10) namesto =SUM(A1:A10).

Funkcija SUM pokaže celo število, prikazati pa bi morala decimalke

Oglejte si oblikovanje celice in preverite, ali so prikazane decimalke. Izberite celico ali obseg in s kombinacijo Ctrl+1 prikličite pogovorno okno Oblikovanje celice, kliknite zavihek Število in izberite želeno oblikovanje, pri tem pa ne pozabite navesti števila decimalnih mest.

  1. Želim je seštevati/odštevati/množiti/deliti števila – oglejte si ta niz videoposnetkov na temo osnovnih matematičnih funkcij v Excelu ali Uporabite Excel kot kalkulator.

  2. Kako pokažem več/manj decimalnih mest? – spremenite lahko obliko zapisa števila. Izberite zadevno celico ali obseg, nato pa s kombinacijo Ctrl+1 prikličite pogovorno okno za oblikovanje celic, kliknite zavihek Število, nato pa izberite želeno obliko zapisa in želeno število decimalnih mest.

  3. Kako seštevati ali odštevati ure? Ure lahko seštevate in odštevate na različne načine. Če želite dobiti razliko med urama 8:00 h in 12:00 h za namen obračuna plač, uporabite formulo: =("12:00 PM"-"8:00 AM")*24, v kateri od končne ure odštejete začetni čas. Excel izračuna uro kot ulomek vrednosti dneva, zato morate vrednost pomnožiti s 24, da dobite skupno število ur. V prvem primeru uporabimo formulo =((B2-A2)+(D2-C2))*24, da dobimo seštevek ur od začetka do konca z odštetim odmorom za kosilo (skupaj 8,50 h).

    Če le seštevate ure in minute in jih želite prikazati na tak način, lahko vrednosti seštevate in vam vrednosti ni treba pomnožiti s 24. V naslednjem primeru uporabljamo funkcijo =SUM(A6:C6), saj moramo le sešteti skupno število ur in minut za dodeljena opravila (5:36 ali 5 ur, 36 minut).

    Izračun časa

    Za več informacij si oglejte: Seštevanje ali odštevanje časa.

  4. Kako dobim razliko med datumi? Podobno kot ure lahko seštevate in odštevate tudi datume. Tu je zelo pogost primer štetja števila dni med dvema datumoma. Formula je zelo preprosta: =B2-A2. Pomembno pri delu z datumi in urami je, da začnete z vrednostjo končnega datuma/ure in od tega odštejete začetni datum/uro.

    Izračun razlike med datumi

    Če želite več načinov za delo z datumi, glejte: Računanje števila dni med dvema datumoma.

  5. Kako seštejem le vrednosti v vidnih celicah? Včasih ročno skrijete celice ali pa uporabite samodejno filtriranje, da prikažete le določene podatke. V teh primerih boste morda želeli sešteti le vrednosti v vidnih celicah. Uporabite lahko funkcijo SUBTOTAL. Če v Excelovi tabeli uporabljate vrstico »Skupaj«, bo vsaka funkcija, ki jo izberete s spustnega seznama »Skupaj« samodejno vnesena kot delna vsota. Več informacij o tem, kako seštejete skupno vrednost podatkov v Excelovi tabeli.

Potrebujete dodatno pomoč?

Kadar koli lahko zastavite vprašanje strokovnjaku v skupnosti tehničnih strokovnjakov za Excel, pridobite podporo skupnosti Answers ali predlagate novo funkcijo oziroma izboljšavo na spletnem mestu Excel User Voice.

Glejte tudi

Oglejte si videoposnetek o uporabi funkcije SUM

Funkcija SUMIF sešteje le vrednosti, ki izpolnjujejo en pogoj

Funkcija SUMIFS sešteje le vrednosti, ki izpolnjujejo več pogojev

Funkcija COUNTIF prešteje le vrednosti, ki izpolnjujejo en pogoj

Funkcija COUNTIFS prešteje le vrednosti, ki izpolnjujejo več pogojev

Pregled formul v Excelu

Kako se izogniti nedelujočim formulam

Iskanje in popravljanje napak v formulah

Bližnjice na tipkovnici v Excelu za Windows

Bližnjice na tipkovnici v Excelu za Mac

Matematične in trigonometrične funkcije

Funkcije v Excelu (po abecedi)

Excelove funkcije (po kategoriji)

Razširite svoja znanja
Oglejte si izobraževanje
Prvi dobite nove funkcije
Pridružite se programu Office Insider

Vam je bila informacija v pomoč?

Zahvaljujemo se vam za povratne informacije.

Zahvaljujemo se vam za povratne informacije. Videti je, da bi vam prišla prav pomoč enega od naših Officeovih agentov za podporo.

×