Opomba: V tej temi opisana funkcija, metoda, predmet ali lastnost, je onemogočena, če se izvaja storitev Microsoft Jet Expression Service v načinu peskovnika, ki preprečuje vrednotenje morebitno nevarnih izrazov. Za več informacij o načinu peskovnika poiščite »način peskovnika« v pomoči.
Vrne sklic na predmet, ki ga posreduje komponenta ActiveX.
Sintaksa
GetObject([ime poti ] [, razred ] )
Sintaksa funkcije GetObject ima te argumente:
|
Argument |
Opis |
|
ime poti |
Izbirno. Variant (niz). Celotna pot in ime datoteke, ki vsebuje predmet, ki ga želite pridobiti. Če ime poti izpustite, je razred obvezen. |
|
razred |
Izbirno. Variant (niz). Niz, ki predstavlja razred predmeta. |
Razred argument uporablja sintakso ime programa.vrsta predmeta in je sestavljen iz teh delov:
|
Del |
Opis |
|
ime programa |
Obvezno. Variant (niz). Ime programa, ki posreduje predmet. |
|
vrsta predmeta |
Obvezno. Variant (niz). Vrsta ali razred predmeta, ki ga želite ustvariti. |
Opombe
Opomba: V spodnjih primerih je prikazana uporaba te funkcije v modulu Visual Basic for Applications (VBA). Če želite več informacij o delu z modulom VBA, izberite Vsebina za razvijalce na spustnem seznamu ob možnosti Iskanje in v iskalno polje vnesite enega ali več izrazov.
Uporabite funkcijo GetObject za dostop do predmeta ActiveX iz datoteke in dodelite predmet spremenljivka predmeta. Z izjavo Set lahko dodelite predmet, ki ga vrne GetObject , spremenljivki predmeta. Primer:
Dim CADObject As Object
Set CADObject = GetObject("C:\CAD\SCHEMA.CAD")
Ko se izvaja ta koda, se zažene program, povezan z določenim imenom poti in aktivira se predmet v določeni datoteki.
Če je ime poti niz z ničelno dolžino (»«), funkcija GetObject vrne nov primerek določene vrste predmeta. Če argument ime poti izpustite, funkcija GetObject vrne trenutno aktivni predmet določene vrste. Če predmet določene vrste ne obstaja, pride do napake.
Nekateri programi omogočajo, da aktivirate del datoteke. Dodajte klicaj (!) na koncu imena datoteke, nato dodajte niz, ki določa del datoteke, ki jo želite aktivirati. Za več informacij o tem, kako ustvarite ta niz, glejte dokumentacijo za program, ki je ustvaril predmet.
Na primer, v programu za risanje imate morda več plasti za risbo, shranjeno v datoteki. Za aktiviranje plasti v risbi, imenovani SCHEMA.CAD, lahko uporabite to kodo:
Set LayerObject = GetObject("C:\CAD\SCHEMA.CAD!Layer3")
Če ne določite razreda predmeta, avtomatizacija določi program za zagon in predmet za aktiviranje glede na podano ime datoteke. Vendar pa nekatere datoteke lahko podpirajo več razredov predmeta. Na primer, risba lahko podpira tri različne vrste predmetov: program, risanje in orodno vrstico, vsi so del iste datoteke. Če želite določiti, kateri predmet v datoteki želite aktivirati, uporabite izbirni argument razreda. Na primer:
Dim MyObject As Object
Set MyObject = GetObject("C:\DRAWINGS\SAMPLE.DRW", _
"FIGMENT.DRAWING")
V primeru je FIGMENT ime programa za risanje, DRAWING pa ena od vrst predmetov, ki jih podpira.
Ko je predmet aktiviran, se sklicujete nanj v kodi z uporabo spremenljivke predmeta, ki ste jo določili. V prejšnjem primeru do lastnosti in metod novega predmeta dostopate s spremenljivko predmeta MyObject. Na primer:
MyObject.Line 9, 90
MyObject.InsertText 9, 100, "Hello, world."
MyObject.SaveAs "C:\DRAWINGS\SAMPLE.DRW"
Opomba: Uporabite funkcijo GetObject, ko je na voljo trenutni primerek predmeta ali če želite ustvariti predmet z datoteko, ki je že naložena. Če trenutni primerek ni na voljo in predmeta ne želite zagnati z naloženo datoteko, uporabite funkcijo CreateObject.
Če se je predmet registriral kot enkratni primerek predmeta, se ustvari samo en primerek predmeta, ne glede na to, kolikokrat se izvede funkcija CreateObject. Z enkratnim primerkom predmeta funkcija GetObject vedno vrne isti primerek, ko je priklicana s sintakso niza ničelne dolžine (»«), kar povzroči napako, če je argument ime poti izpuščen. Funkcije GetObject ne morete uporabiti za pridobitev sklica na razred, ustvarjenega v programu Visual Basic.
Primer
V tem primeru je uporabljena funkcija GetObject za pridobitev sklica na določen delovni list programa Microsoft Office Excel 2007 (MyXL). Uporablja lastnost Application delovnega lista za prikaz Excela, njegovo zapiranje in tako naprej. Z uporabo dveh priklicev API podpostopek DetectExcel poišče Excel, in če se ta izvaja, ga vnese v tabelo predmetov, ki se izvajajo. Prvi priklic funkcije GetObject povzroči napako, če se Microsoft Excel še ne izvaja. V primeru napako povzroča zastavica ExcelWasNotRunning, ki jo je treba nastaviti na True. Drugi priklic funkcije GetObject določa datoteko za odpiranje. Če se Excel še ne izvaja, ga zažene drugi priklic in vrne sklic na delovni list, ki ga predstavlja določena datoteka, mytest.xls. Datoteka mora biti na voljo na določenem mestu; v nasprotnem primeru se ustvari napaka avtomatizacije programa Visual Basic. Nadalje koda v primeru povzroči, da sta Excel in okno, ki vsebuje navedeni delovni list, vidna. Na koncu, če se ne izvaja prejšnja različica Excela, koda uporabi metodo Quit predmeta Application, da zapre Excel. Če se program že izvaja, ni poskusov, da bi se zaprl. Izda se sam sklic, tako da se nastavi na Nothing.
' Declare necessary API routines:
Declare Function FindWindow Lib "user32" Alias _
"FindWindowA" (ByVal lpClassName as String, _
ByVal lpWindowName As Long) As Long
Declare Function SendMessage Lib "user32" Alias _
"SendMessageA" (ByVal hWnd as Long,ByVal wMsg as Long, _
ByVal wParam as Long, _
ByVal lParam As Long) As Long
Sub GetExcel()
Dim MyXL As Object ' Variable to hold reference
' to Microsoft Excel.
Dim ExcelWasNotRunning As Boolean ' Flag for final release.
' Test to see if there is a copy of Microsoft Excel already running.
On Error Resume Next ' Defer error trapping.
' GetObject function called without the first argument returns a
' reference to an instance of the application. If the application isn't
' running, an error occurs.
Set MyXL = GetObject(, "Excel.Application")
If Err.Number <> 0 Then ExcelWasNotRunning = True
Err.Clear ' Clear Err object in case error occurred.
' Check for Microsoft Excel. If Microsoft Excel is running,
' enter it into the Running Object table.
DetectExcel
' Set the object variable to reference the file you want to see.
Set MyXL = GetObject("c:\vb4\MYTEST.XLS")
' Show Microsoft Excel through its Application property. Then
' show the actual window containing the file using the Windows
' collection of the MyXL object reference.
MyXL.Application.Visible = True
MyXL.Parent.Windows(1).Visible = True
Do manipulations of your file here.
' ...
' If this copy of Microsoft Excel was not running when you
' started, close it using the Application property's Quit method.
' Note that when you try to quit Microsoft Excel, the
' title bar blinks and a message is displayed asking if you
' want to save any loaded files.
If ExcelWasNotRunning = True Then
MyXL.Application.Quit
End IF
Set MyXL = Nothing ' Release reference to the
' application and spreadsheet.
End Sub
Sub DetectExcel()
' Procedure dectects a running Excel and registers it.
Const WM_USER = 1024
Dim hWnd As Long
' If Excel is running this API call returns its handle.
hWnd = FindWindow("XLMAIN", 0)
If hWnd = 0 Then ' 0 means Excel not running.
Exit Sub
Else
' Excel is running so use the SendMessage API
' function to enter it in the Running Object Table.
SendMessage hWnd, WM_USER + 18, 0, 0
End If
End Sub
