COUNTIF (funkcija COUNTIF)

COUNTIF (funkcija COUNTIF)

Funkcija COUNTIF je ena od statističnih funkcij, s katero je mogoče prešteti, koliko celic izpolnjuje pogoje; če želite na primer prešteti, kolikokrat se določeno mesto pojavi na seznamu stranke.

Najpreprostejša oblika formule COUNTIF je:

  • =COUNTIF(Kje želite iskati?, Kaj želite poiskati?)

Primer:

  • =COUNTIF(A2:A5,"London")

  • =COUNTIF(A2:A5; A4)

Vaš brskalnik ne podpira tega videoposnetka. Namestite Microsoft Silverlight, Adobe Flash Player ali Internet Explorer 9.

COUNTIF(obseg, pogoji)

Ime argumenta

Opis

obseg    (zahtevano)

Skupina celic, ki jih želite prešteti. Obseg lahko zajema števila, polja, imenovan obseg ali sklice s števili. Prazne in besedilne vrednosti so prezrte.

Oglejte si navodila za izbiranje obsegov na delovnem listu.

pogoji    (zahtevano)

Število, izraz, sklic na celico ali besedilni niz, ki določa, katere celice bodo preštete.

Uporabite lahko na primer število 32, primerjavo, npr. »> 32«, celico, npr. B4, ali besedo, npr. »jabolka«.

COUNTIF uporablja le en pogoj. Če želite uporabiti več pogojev, uporabite funkcijo COUNTIFS.

Primeri

Če želite uporabiti te primere v Excelu, kopirajte podatke v spodnjo tabelo in jih prilepite v celico A1 na novem delovnem listu.

Podatki

Podatki

jabolka

32

pomaranče

54

breskve

75

jabolka

86

Formula

Opis

=COUNTIF(A2:A5; "jabolka")

Prešteje število celic z jabolki v celicah od A2 do A5. Rezultat je 2.

=COUNTIF(A2:A5; A4)

Prešteje število celic z breskvami (z vrednostjo v celici A4) v celicah od A2 do A5. Rezultat je 1.

=COUNTIF(A2:A5,A2)+COUNTIF(A2:A5,A3)

Prešteje število jabolk (vrednost v celici A2) in pomaranč (vrednost v celici A3) v celicah od A2 do A5. Rezultat je 3. Ta formula dvakrat uporabi formulo COUNTIF, da določi več pogojev – en pogoj na en izraz. Uporabite lahko tudi funkcijo COUNTIFS.

=COUNTIF(B2:B5; ">55")

Prešteje število celic z vrednostjo, ki je večja od 55, in sicer v celicah od B2 do B5. Rezultat je 2.

=COUNTIF(B2:B5; "<>"&B4)

Prešteje število celic z vrednostjo, ki ni enaka 75, in sicer v celicah od B2 do B5. Znak »&« spoji operator primerjanja »<> « (ni enako kot) in vrednost v celici B4 za branje =COUNTIF (B2:B5,"<> 75"). Rezultat je 3.

=COUNTIF(B2:B5; ">=32")-COUNTIF(B2:B5; ">85")

Prešteje število celic z vrednostjo, ki je večja (>) od 32 ali enaka (=) 32 in manjša (<) od 85 ali enaka (=) 85, in sicer v celicah od B2 do B5. Rezultat je 3.

=COUNTIF(A2:A5,"*")

Prešteje število celic, v katerih je poljubno besedilo, in sicer v celicah od A2 do A5. Nadomestni znak (*) se uporablja za kateri koli znak. Rezultat je 4.

=COUNTIF(A2:A5,"?????es")

Prešteje število celic, v katerih je točno 7 znakov, ki se končajo s črkama »es« v celicah od A2 do A5. Vprašaj (?) je uporabljen kot nadomestni znak za posamezne znake. Rezultat je 2.

Pogoste težave

Težava

Vzrok težave

Vrne napačno vrednost za dolge nize.

Funkcija COUNTIF vrne nepravilne rezultate, kadar jo uporabite za ujemanje nizov, ki so daljši od 255 znakov.

Za ujemanje nizov, ki so daljši od 255 znakov, uporabite funkcijo CONCATENATE ali operator za združitev »&«. Na primer, =COUNTIF(A2:A5, »dolg niz« & »drug dolg niz«).

Ko ste pričakovali vrednost, ni bila vrnjena nobena vrednost.

Ne pozabite, da morate argument pogoja postaviti v narekovaje.

Formula COUNTIF prejme napako #VALUE! pri sklicu na drug delovni list.

Do te napake pride, ko se formula, v kateri je funkcija, sklicuje na celice ali obseg v zaprtem delovnem zvezku, celice pa so izračunane. Ta funkcija lahko deluje le, če je drug delovni zvezek odprt.

Najboljše prakse

Naredite to

Razlog

Ne pozabite, da funkcija COUNTIF prezre velike in male črke v besedilnih nizih.

Pogoji ne razlikujejo med velikimi in malimi črkami. Z drugimi besedami, niza »jabolka« in »JABOLKA« se ujemata z isto celico.

Uporabljajte nadomestne znake.

V pogojih lahko uporabljate nadomestne znake – vprašaj (?) in zvezdico (*). Vprašaj označuje kateri koli znak, zvezdica pa poljubno zaporedje znakov. Če želite poiskati dejanski vprašaj ali zvezdico, pred znak vnesite tildo (~).

Formula =COUNTIF(A2:A5,"jabolko?") bo preštela vse primerke »jabolka«, pri čemer se lahko zadnja črka spreminja.

Zagotovite, da v vaših podatkih ni napačnih znakov.

Pri štetju besedilnih vrednosti se prepričajte, da v podatkih ni začetnih presledkov, končnih presledkov, nedosledno uporabljenih ravnih in zavitih narekovajev oz. znakov, ki jih ni mogoče natisniti. V teh primerih lahko funkcija COUNTIF vrne nepričakovano vrednost.

Poskusite uporabiti funkcijo CLEAN ali funkcijo TRIM.

Zaradi priročnosti uporabite imenovane obsege

COUNTIF podpira imenovane obsege v formuli (na primer =COUNTIF(sadje,">=32")-COUNTIF(sadje,">85"). Imenovani obseg je lahko na trenutnem delovnem listu, na drugem delovnem listu v istem delovnem zvezku ali v drugem delovnem zvezku. Pri sklicu iz drugega delovnega zvezka mora biti tudi ta delovni zvezek odprt.

Opomba : Funkcija COUNTIF ne bo preštela celic na podlagi barve celice ali barve pisave. Vendar pa Excel podpira uporabniško določenih funkcij (UDF) z operacijami Microsoft Visual Basic for Applications (VBA) v celicah na podlagi barve ozadja ali barve pisave. Tu je primer, kako lahko preštejete število celic z določeno barvo tako, da uporabite VBA.

Potrebujete dodatno pomoč?

Kadar koli lahko zastavite vprašanje strokovnjaku v skupnosti tehničnih strokovnjakov za Excel, pridobite podporo skupnosti Answers ali predlagate novo funkcijo oziroma izboljšavo na spletnem mestu Excel User Voice.

Glejte tudi

Za štetje celic, ki niso prazne, uporabite funkcijo COUNTA

Za štetje celic z več pogoji uporabite funkcijo COUNTIFS

Oglejte si videoposnetek o uporabi funkcije COUNTIFS

Funkcija SUMIF sešteje le vrednosti, ki izpolnjujejo en pogoj

Funkcija SUMIFS sešteje le vrednosti, ki izpolnjujejo več pogojev

Funkcija IFS (Office 365, Excel 2016 in novejše različice)

S funkcijo TRIM odstranite vodilne in končne presledke iz celic

S funkcijo CLEAN odstranite nenatisljive znake iz celic

Pregled formul v Excelu

Kako se izogniti nedelujočim formulam

Zaznavanje napak v formulah

Statistične funkcije

Excelove funkcije (po abecedi)

Excelove funkcije (po kategoriji)

Uporaba funkcij SUMIF in COUNTIF ter povezanih funkcij za hitro analizo podatkov (brezplačni predogled)

Razširite svoja znanja
Oglejte si izobraževanje
Prvi dobite nove funkcije
Pridružite se programu Office Insider

Vam je bila informacija v pomoč?

Zahvaljujemo se vam za povratne informacije.

Zahvaljujemo se vam za povratne informacije. Videti je, da bi vam prišla prav pomoč enega od naših Officeovih agentov za podporo.

×