Vlastnosť PrtDevMode

Dôležité : Tento článok je strojovo preložený, prečítajte si vyhlásenie. Anglickú verziu tohto článku nájdete tu a môžete ju použiť ako referenciu.

Vzťahuje sa na

Objekt Form

Objekt Report

Pomocou vlastnosti PrtDevMode môžete nastaviť alebo vrátiť informácie o režime tlačového zariadenia zadaného zadaného pre formulár alebo zostavu v dialógovom okne Tlač. Hodnota typu Variant na čítanie aj na zápis.

výraz.PrtDevMode

výraz Povinné. Výraz, ktorý vráti jeden z objektov v zozname Vzťahuje sa na.

Poznámky

Dôrazne sa odporúča, aby ste používali súpravu Win32 Software Development Kit, ktorá obsahuje úplnú dokumentáciu o vlastnostiach PrtDevMode, PrtDevNames a PrtMip.

Nastavenie vlastnosti PrtDevMode predstavuje 94-bajtovú štruktúru, do ktorej sa premieta štruktúra DEVMODE definovaná v súprave Win32 Software Development Kit. Ak chcete získať úplné informácie o členoch vlastnosti PrtDevMode, použite súpravu Win32 Software Development Kit.

Vlastnosť PrtDevrežim používa nasledujúci členovia.

Člen

Popis

DeviceName

reťazec s maximálnou veľkosťou 32 bajtov, ktorý určuje názov zariadenia podporovaného ovládačom (napríklad "HP LaserJet IIISi", ak je zadaná tlačiareň Hewlett-Packard LaserJet IIISi. Každý ovládač tlačiarne má jedinečný reťazec.

SpecVersion

Celé číslo, ktoré určuje číslo verzie DEVMODE štruktúra v vývoj softvéru Win32.

DriverVersion

Hodnota typu Integer, ktorá určuje číslo verzie ovládača tlačiarne priradené vývojárom ovládača tlačiarne.

Size

Hodnota typu Integer, ktorá určuje veľkosť štruktúry DEVMODE v bajtoch. (Táto hodnota nezahŕňa voliteľný člen dmDriverData pre údaje špecifické pre dané zariadenie, ktoré môžu používať túto štruktúru.) Ak nejaká aplikácia manipuluje iba s časťou údajov, ktorá nie je závislá od ovládača, tento člen môžete použiť na zistenie dĺžky tejto štruktúry bez toho, aby ste museli brať do úvahy jednotlivé verzie.

DriverExtra

Hodnota typu Integer, ktorá určuje veľkosť voliteľného člena dmDriverData v bajtoch pre údaje špecifické pre dané zariadenie, ktoré môžu používať túto štruktúru. Ak určitá aplikácia nepoužíva informácie špecifické pre dané zariadenie, nastavte tento člen na hodnotu 0.

Fields

A inicializovať dlhý hodnotu, ktorá určuje, ktoré ostatní členovia DEVMODE štruktúra, máte.

Orientation

Hodnota typu Integer, ktorá určuje orientáciu papiera. Môže mať hodnotu 1 (na výšku) alebo 2 (na šírku).

PaperSize

Hodnota typu Integer, ktorá určuje veľkosť papiera pre tlač. Ak nastavíte tento člen na hodnotu 0 alebo 256, dĺžku a šírku papiera určujú členy PaperLength a PaperWidth. Ak je to inak, môžete nastaviť člen paperSize na preddefinovanú hodnotu.

PaperLength

Hodnota typu Integer, ktorá určuje dĺžku papiera v jednotkách 1/10 milimetra. Tento člen prepisuje dĺžku papiera určenú členom PaperSize pre vlastné veľkosti papiera alebo pre zariadenia, ako sú napríklad ihličkové tlačiarne, ktoré môžu tlačiť na papier rôznej veľkosti.

PaperWidth

Hodnota typu Integer, ktorá určuje šírku papiera v jednotkách 1/10 milimetra. Tento člen prepisuje šírku papiera určenú členom PaperSize.

Scale

Hodnota typu Integer, ktorá určuje faktor škálovania tlačeného výstupu. Aktuálna veľkosť strany je škálovaná ako fyzická veľkosti strany po použití faktora mierka/100. Napríklad hárok papiera s rozmermi 21,6 cm x 27,9 cm s hodnotou Scale 50 bude obsahovať toľko údajov, ako strana s rozmermi 43,2 cm x 55,9 cm, pretože výstupný text a grafické objekty budú mať polovičnú veľkosť pôvodnej výšky a šírky.

Copies

Hodnota typu Integer, ktorá určuje počet vytlačených kópií, ak tlačové zariadenie pre tlač podporuje viacstranové kópie.

DefaultSource

Hodnota typu Integer, ktorá určuje predvolený zásobník, z ktorého je papier podávaný.

PrintQuality

Hodnota typu Integer, ktorá určuje rozlíšenie tlačiarne. Hodnoty sú –4 (vysoké), –3 (stredné), –2 (nízke) a –1 (konceptové).

Color

Hodnota typu Integer. Pre farebnú tlačiareň určuje, či sa výstup vytlačí ako farebný. Hodnoty sú 1 (farebne) a 2 (čiernobielo).

Duplex

Hodnota typu Integer. Určuje pre tlačiareň, ktorá dokáže tlačiť na obe strany, či sa výstup bude tlačiť na obe strany papiera. Hodnoty sú 1 (jednoduché), 2 (vodorovné) a 3 (zvislé).

YResolution

Hodnota typu Integer, ktorá určuje zvislé rozlíšenie tlačiarne v bodoch na palec (dpi). Ak tlačiareň inicializuje tento člen, člen PrintQuality určuje vodorovné rozlíšenie tlačiarne v bodoch na palec.

TTOption

Hodnota typu Integer, ktorá určuje, ako sa vytlačia písma TrueType.

Collate

Hodnota typu Integer, ktorá určuje, či sa má použiť zoradenie pri tlači viacerých kópií. Použitie nezoradených kópií poskytuje rýchlejší, účinnejší výstup, pretože údaje sa odosielajú do tlačiarne len raz.

FormName

Reťazec s maximálnym počtom 16 znakov, ktorý určuje veľkosť papiera na použitie, napríklad Letter alebo Legal.

Pad

Hodnota typu Long, ktorá sa používa na vyplnenie voľného miesta, znakov alebo hodnôt pre budúce verzie.

Bits

Hodnota typu Long, ktorá určuje farebné rozlíšenie zobrazovacieho zariadenia v bitoch na pixel.

PW

Hodnota typuLong, ktorá určuje šírku viditeľného povrchu zariadenia (obrazovky alebo tlačiarne) v pixeloch.

PH

Hodnota typu Long, ktorá určuje výšku viditeľného povrchu zariadenia (obrazovky alebo tlačiarne) v pixeloch.

DFI

Hodnota typu Long, ktorá určuje režim zobrazovania zariadenia.

DFR

Hodnota typu Long, ktorá určuje frekvenciu zobrazovacieho zariadenia v konkrétnom režime v hertzoch (počte cyklov za sekundu) .


Poznámka : Môžete nastaviť vlastnosť PrtDevMode pomocou Visual Basic for Applications (VBA) kód.

Táto vlastnosť je v návrhovom zobrazení alebo zobrazení rozloženia nastavená na čítanie aj na zápis a v ostatných zobrazeniach je len na čítanie.

Ovládače tlačiarne môžu pridať údaje špecifické pre dané zariadenie bezprostredne po 94 bajtoch štruktúry DEVMODE. Je preto dôležité, aby údaje štruktúry DEVMODE uvedené vyššie neprekročili 94 bajtov.

Iba ovládače tlačiarne, ktoré exportujú funkciu ExtDeviceMode, používajú štruktúru DEVMODE.

Aplikácia môže načítať veľkosti papiera a názvy podporované tlačiarňou použitím hodnôt DC_PAPERS, DC_PAPERSIZE a DC_PAPERNAMES na volanie funkcie DeviceCapabilities.

Pred nastavením hodnoty člena TTOption by mali aplikácie získať informácie o tom, ako môže ovládač tlačiarne používať písma TrueType, použitím hodnoty DC_TRUETYPE na volanie funkcie DeviceCapabilities.

Príklad

V nasledujúcom príklade sa vlastnosť PrtDevMode používa na overenie používateľom definovanej veľkosti strany pre zostavu:

Private Type str_DEVMODE
RGB As String * 94
End Type
Private Type type_DEVMODE
strDeviceName As String * 32
intSpecVersion As Integer
intDriverVersion As Integer
intSize As Integer
intDriverExtra As Integer
lngFields As Long
intOrientation As Integer
intPaperSize As Integer
intPaperLength As Integer
intPaperWidth As Integer
intScale As Integer
intCopies As Integer
intDefaultSource As Integer
intPrintQuality As Integer
intColor As Integer
intDuplex As Integer
intResolution As Integer
intTTOption As Integer
intCollate As Integer
strFormName As String * 32
lngPad As Long
lngBits As Long
lngPW As Long
lngPH As Long
lngDFI As Long
lngDFr As Long
End Type
Public Sub CheckCustomPage(ByVal rptName As String)
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
Dim intResponse As Integer
' Opens report in Design view.
DoCmd.OpenReport rptName, acDesign
Set rpt = Reports(rptName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
' Gets current DEVMODE structure.
DevString.RGB = strDevModeExtra
LSet DM = DevString
If DM.intPaperSize = 256 Then
' Display user-defined size.
intResponse = MsgBox("The current custom page size is " & _
DM.intPaperWidth / 254 & " inches wide by " & _
DM.intPaperLength / 254 & " inches long. Do you want " & _
"to change the settings?", vbYesNo + vbQuestion)
Else
' Currently not user-defined.
intResponse = MsgBox("The report does not have a custom page size. " & _
"Do you want to define one?", vbYesNo + vbQuestion)
End If
If intResponse = vbYes Then
' User wants to change settings. Initialize fields.
DM.lngFields = DM.lngFields Or DM.intPaperSize Or _
DM.intPaperLength Or DM.intPaperWidth
' Set custom page.
DM.intPaperSize = 256
' Prompt for length and width.
DM.intPaperLength = InputBox("Please enter page length in inches.") * 254
DM.intPaperWidth = InputBox("Please enter page width in inches.") * 254
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
End If
Set rpt = Nothing
End Sub

V nasledujúcom príklade je ukázane, ako je možné zmeniť orientáciu zostavy. V tomto príklade sa orientácia prepne z orientácie na výšku na orientáciu na šírku alebo z orientácie na šírku na orientáciu na výšku podľa aktuálnej orientácie zostavy.

Public Sub SwitchOrient(ByVal strName As String)
Const DM_PORTRAIT = 1
Const DM_LANDSCAPE = 2
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
' Opens report in Design view.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
DevString.RGB = strDevModeExtra
LSet DM = DevString
DM.lngFields = DM.lngFields Or DM.intOrientation
' Initialize fields.
If DM.intOrientation = DM_PORTRAIT Then
DM.intOrientation = DM_LANDSCAPE
Else
DM.intOrientation = DM_PORTRAIT
End If
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
Set rpt = Nothing
End Sub

Poznámka : Vyhlásenie týkajúce sa strojového prekladu: Tento článok bol preložený počítačovým systémom bez zásahu človeka. Poskytovaním týchto strojových prekladov umožňuje spoločnosť Microsoft aj používateľom, ktorí nehovoria po anglicky, využívať obsah o produktoch, službách a technológiách spoločnosti Microsoft. Článok bol preložený strojovo, môže preto obsahovať chyby týkajúce sa slovnej zásoby, syntaxe alebo gramatiky.

Rozšírte svoje zručnosti
Preskúmať školenie
Buďte medzi prvými, ktorí získajú nové funkcie
Pridajte sa k insiderom pre Office

Boli tieto informácie užitočné?

Ďakujeme za vaše pripomienky!

Ďakujeme vám za pripomienky. Pravdepodobne vám pomôže, ak vás spojíme s pracovníkom podpory pre Office.

×