Výpočet rozdielu medzi dvoma dátumami

Výpočet rozdielu medzi dvoma dátumami

Ak chcete vypočítať rozdiel medzi dvoma dátumami, použite funkciu DATEDIF. Najskôr do jednej bunky vložte počiatočný dátum a do inej dátum ukončenia. Potom napíšte vzorec podobný niektorému z nasledujúcich.

Rozdiel v dňoch

=DATEDIF(D9;E9;"d") s výsledkom 856

V tomto príklade je počiatočný dátum v bunke D9 a dátum ukončenia je v bunke E9. Vzorec je v bunke F9. Parameter “d” vráti počet celých dní medzi dvoma dátumami.

Rozdiel v týždňoch

=(DATEDIF(D13;E13;"d")/7) a výsledok: 122,29

V tomto príklade je počiatočný dátum v bunke D13 a dátum ukončenia je v bunke E13. Parameter “d” vráti počet dní. Ale všimnite si časť /7 na konci. Delí počet dní číslom 7, keďže týždeň má 7 dní. Upozorňujeme, že tento výsledok tiež musí byť formátovaný ako číslo. Stlačte kombináciu klávesov CTRL + 1. Potom kliknite na položku Číslo a v poli Desatinné miesta: 2 nastavte počet desatinných miest.

Rozdiel v mesiacoch

=DATEDIF(D5;E5;"m") a výsledok: 28

V tomto príklade je počiatočný dátum v bunke D5 a dátum ukončenia je v bunke E5. Parameter “m” vo vzorci vráti počet celých mesiacov medzi dvoma dátumami.

Rozdiel v rokoch

=DATEDIF(D2;E2;"y") a výsledok: 2

V tomto príklade je počiatočný dátum v bunke D2 a dátum ukončenia je v bunke E2. Parameter “y” vráti počet celých rokov medzi dvoma dátumami.

Vypočítanie veku z akumulovaných rokov, mesiacov a dní

Môžete vypočítať aj niečí vek alebo čas v službe. Výsledkom môže byť niečo ako „2 r., 4 mes., 5 d.“

1. Pomocou funkcie DATEDIF zistite celkový počet rokov.

=DATEDIF(D17;E17;"y") a výsledok: 2

V tomto príklade je počiatočný dátum v bunke D17 a dátum ukončenia je v bunke E17. Parameter “y” vo vzorci vráti počet celých rokov medzi dvoma dátumami.

2. Opäť použite funkciu DATEDIF s parametrom "ym" a zistíte počet mesiacov.

=DATEDIF(D17;E17;"ym") a výsledok: 4

Do inej bunky napíšte funkciu DATEDIF s parametrom "ym". Parameter "ym" vráti počet zostávajúcich mesiacov po poslednom celom roku.

3. Na vyhľadanie dní použite iný vzorec.

=DATEDIF(D17;E17;"md") a výsledok: 5

Teraz musíme nájsť počet zostávajúcich dní. Toto urobíme zápisom iného druhu vzorca, ako je ukázané vyššie. Tento vzorec odpočíta prvý deň v mesiaci ukončenia (1.5.2016) od pôvodného dátumu ukončenia v bunke E17 (6.5.2016). Tu je ukázané, ako sa to vykoná: Funkcia DATE vytvorí najprv dátum 1.5.2016. Vytvorí to pomocou roka v bunke E17 a mesiaca v bunke E17. 1 teda predstavuje prvý deň v tomto mesiaci. Výsledok funkcie DATE je 1.5.2016. Výsledok sa potom odráta od pôvodného dátumu ukončenia v bunke E17, čiže od 6.5.2016. 6.5.2016 mínus 1.5.2016 je 5 dní.

Poznámka : Neodporúčame použiť argument md vo funkcii DATEDIF, pretože s ním môžu vypočítať nepresné výsledky.

4. Voliteľné: Skombinujte tri vzorce do jedného.

=DATEDIF(D17;E17;"y")&" r., "&DATEDIF(D17;E17;"ym")&" mes., "&DATEDIF(D17;E17;"md")&" d." a výsledok: 2 r., 4 mes., 5 d.

Všetky tri výpočty môžete umiestniť do jednej bunky ako v tomto príklade. Použite znaky &, úvodzovky a text. Vzorec je síce rozsahovo dlhší, ale aspoň je všetko na jednom mieste. Tip: Stlačením kombinácie klávesov ALT + ENTER vložíte do vzorca zlom riadka. Bude čitateľnejší. Ak nevidíte celý vzorec, stlačte kombináciu klávesov CTRL + SHIFT + U.

Stiahnite si naše príklady

V tomto článku si môžete stiahnuť vzorový pracovný zošit so všetkými príkladmi. Môžete sa ich pridŕžať alebo si môžete vytvoriť vlastné vzorce.

Stiahnuť príklady výpočtov dátumu

Ďalšie výpočty dátumu a času

Ako ste videli vyššie, funkcia DATEDIF vypočíta rozdiel medzi počiatočným dátumom a dátumom ukončenia. Namiesto zadávania konkrétnych dátumov môžete v rámci vzorca použiť aj funkciu TODAY(). Pri používaní funkcie TODAY() preberie Excel aktuálny dátum vo vašom počítači. Nezabudnite, že po otvorení súboru v iný deň sa dátum zmení.

=DATEDIF(TODAY();D28;"y") a výsledok: 984

Upozorňujeme, že v čase písania tejto témy bol 6. október 2016.

Ak chcete vypočítať počet pracovných dní medzi dvoma dátumami, použite funkciu NETWORKDAYS.INTL. Môžete pomocou nej vynechať víkendy a sviatky.

Skôr než začnete: Rozhodnite sa, či chcete vylúčiť dátumy sviatkov. Ak áno, zadajte zoznam dátumov sviatkov do samostatnej oblasti alebo samostatného hárka. Umiestnite každý dátum sviatku do samostatnej bunky. Potom vyberte dané bunky a vyberte položky Vzorce > Definovať názov. Zadajte názov rozsahu MojeSviatky a kliknite na tlačidlo OK. Potom vytvorte vzorec pomocou nasledujúcich krokov.

1. Zadajte počiatočný dátum a dátum ukončenia.

Počiatočný dátum v bunke D53 je 1. 1. 2016, dátum ukončenia v bunke E53 je 31. 12. 2016

V tomto príklade je počiatočný dátum v bunke D53 a dátum ukončenia je v bunke E53.

2. Do inej bunky zadajte tento vzorec:

=NETWORKDAYS.INTL(D53;E53;1) a výsledok: 261

Zadajte vzorec ako v príklade vyššie. Číslo 1 vo vzorci definuje sobotu a nedeľu za víkendové dni a vylúči ich z celkového počtu.

Poznámka: Program Excel 2007 nemá funkciu NETWORKDAYS.INTL. Má však funkciu NETWORKDAYS. Príklad vyššie bude v programe Excel 2007 vyzerať takto: =NETWORKDAYS(D53;E53). Nešpecifikujete číslo 1, pretože funkcia NETWORKDAYS predpokladá, že víkend je v sobotu a nedeľu.

3. V prípade potreby zmeňte 1.

Zoznam IntelliSense zobrazujúci 2 – nedeľa, pondelok; 3 – pondelok, utorok, atď.

Ak sobota a nedeľa nie sú pre vás víkendovými dňami, zmeňte 1 na iné číslo zo zoznamu IntelliSense. Číslo 2 napríklad určuje za víkendové dni nedeľu a pondelok.

Ak používate program Excel 2007, tento krok preskočte. Funkcia NETWORKDAYS v programe Excel 2007 vždy predpokladá, že víkend je v sobotu a nedeľu.

4. Zadajte názov rozsahu sviatkov.

=NETWORKDAYS.INTL(D53;E53;1;Moje sviatky) a výsledok: 252

Ak ste vytvorili názov rozsahu sviatkov v časti Skôr než začnete, na konci ho zadajte rovnako. Ak sviatky nemáte, môžete bodkočiarku a MojeSviatky vynechať. Ak používate program Excel 2007, uvedený príklad bude vyzerať takto: =NETWORKDAYS(D53;E53;MojeSviatky).

Tip: Ak nechcete odkazovať na názov rozsahu sviatkov, môžete tiež zadať samotný rozsah, napríklad D35:E:39. Alebo môžete do vzorca zadať jednotlivé sviatky. Ak ste mali sviatky napríklad 1. a 2. januára 2016, môžete ich zadať takto: = NETWORKDAYS. INTL(D53;E53;1;{"1.1.2016";"2.1.2016"}). V programe Excel 2007 to bude vyzerať takto: =NETWORKDAYS(D53;E53;{"1.1.2016";"2.1.2016"})

Uplynutý čas môžete vypočítať odčítaním jedného času od druhého. Najskôr do jednej bunky vložte počiatočný čas a do inej čas ukončenia. Skontrolujte, či ste zadali celý čas, vrátane hodiny, minút. Postupujte nasledovne:

1. Zadajte počiatočný čas a čas ukončenia.

Počiatočný dátum/čas 7:15; dátum ukončenia/čas 16:30

V tomto príklade je počiatočný čas v bunke D80 a čas ukončenia je v bunke E80. Uistite sa, že ste zadali hodiny a minúty.

2. Nastavte formát na h:mm.

Dialógové okno Formát buniek, vlastný príkaz, typ h:mm AM/PM

Vyberte oba dátumy a stlačte kombináciu klávesov CTRL + 1 (alebo Obrázok ikony tlačidla Command na Macu + 1 v Macu). Ak ste ešte nenastavili formát, vyberte položky Vlastné > h:mm.

3. Odčítajte tieto dva časy.

=E80-D80 a výsledok: 9:15

V inej bunke odčítajte bunku s počiatočným časom od bunky s časom ukončenia.

4. Nastavte formát na h:mm.

Dialógové okno Formát buniek, vlastný príkaz, typ h:mm

Stlačte kombináciu klávesov CTRL + 1 (alebo Obrázok ikony tlačidla Command na Macu + 1 v Macu). Vyberte položky Vlastné > h: mm.

Ak chcete vypočítať čas medzi dvomi dátumami a časmi, môžete jednoducho odpočítať jeden od druhého. Musíte ale na každú bunku použiť formátovanie, aby program Excel vrátil požadovaný výsledok.

1. Zadajte dva úplné dátumy a časy.

Počiatočný dátum 1. 1. 2016 13:00;  dátum ukončenia 2. 1. 2016 14:00

Do jednej bunky zadajte úplný počiatočný dátum a čas. Do inej bunky zadajte úplný dátum a čas ukončenia. Každá bunka by mala obsahovať mesiac, deň, rok, hodinu a minútu.

2. Nastavte formát na 14.03.2012 13:30.

Dialógové okno Formát buniek, príkaz Dátum, typ 14. 3. 2012 13:30

Vyberte obe bunky a stlačte kombináciu klávesov CTRL + 1 (alebo Obrázok ikony tlačidla Command na Macu + 1 v Macu). Vyberte položky Dátum > 14.3.12 13:30. Nie je to dátum, ktorý máte zadať, je len ukážka toho, ako bude vyzerať požadovaný formát. Všimnite si, že vo verziách starších ako Excel 2016 môže tento formát vyzerať inak, napríklad 14.3.01 13:30.

3. Odčítajte ich od seba.

=E84-D84 a výsledok 1,041666667

V inej bunke odčítajte bunku s počiatočným dátumom/časom od bunky s dátumom/časom ukončenia. Výsledok bude pravdepodobne vyzerať ako desatinné číslo. Opravíte to v ďalšom kroku.

4. Nastavte formát na h:mm.

Dialógové okno Formát buniek, vlastný príkaz, typ [h]:mm

Stlačte kombináciu klávesov CTRL + 1 (alebo Obrázok ikony tlačidla Command na Macu + 1 v Macu). Vyberte položku Vlastné. Do poľa Typ zadajte formát h:mm.

Pozrite tiež

DATEDIF (funkcia)

NETWORKDAYS.INTL (funkcia)

NETWORKDAYS (funkcia)

Ďalšie funkcie dátumu a času

Výpočet rozdielu medzi dvoma časmi

Rozšírte svoje zručnosti
Preskúmať školenie
Buďte medzi prvými, ktorí získajú nové funkcie
Pridajte sa k insiderom pre Office

Boli tieto informácie užitočné?

Ďakujeme za vaše pripomienky!

Ďakujeme vám za pripomienky. Pravdepodobne vám pomôže, ak vás spojíme s pracovníkom podpory pre Office.

×