TEXT (funkcia)

Prispievatelia: Karol „Kovi“ Kováč Dušan Sýkora

Funkcia TEXT vám umožňuje zmeniť spôsob, akým sa zobrazí číslo, použitím formátovania pomocou kódov formátu. Táto funkcia je užitočná v prípade, ak chcete zobraziť čísla v čitateľnejšom formáte, alebo ak chcete zlúčiť čísla s textom alebo symbolmi.

Poznámka : Funkcia TEXT skonvertuje čísla na text, čo môže sťažiť odkazovanie na čísla v ďalších výpočtoch. Oplatí sa ponechať pôvodnú hodnotu v jednej bunke a funkciu TEXT použiť v inej bunke. Ak budete vytvárať iné vzorce, vždy odkazujte na pôvodnú hodnotu, nie na výsledok funkcie TEXT.

Syntax

TEXT(hodnota; formát_text)

Syntax funkcie TEXT obsahuje tieto argumenty:

Názov argumentu

Popis

hodnota

Číselná hodnota, ktorú chcete skonvertovať na text.

formát_text

Textový reťazec, ktorý definuje formátovanie, ktoré chcete použiť na zadanú hodnotu.

Prehľad

V najjednoduchšej podobe funkcia TEXT znamená:

  • =TEXT(hodnota, ktorú chcete formátovať; kód formátu, ktorý chcete použiť)

Nasleduje niekoľko obľúbených príkladov, ktoré si môžete skopírovať priamo do Excelu a následne si ich vyskúšať. Všimnite si kódy formátov v úvodzovkách.

Vzorec

Popis

=TEXT(1234,567;"# ##0,00 €")

Mena s oddelením tisícok a dvoma desatinnými číslami, napríklad 1 234,57 €. Všimnite si, že Excel hodnotu zaokrúhľuje na dve desatinné čísla.

=TEXT(TODAY();"dd/mm/yy")

Dnešný dátum vo formáte mm/dd/rr, napríklad 03/14/12

=TEXT(TODAY();"dddd")

Dnešný názov dňa v týždni, napríklad pondelok

=TEXT(NOW();"H: MM AM/PM")

Aktuálny čas, napríklad 1:29 PM

=TEXT(0,285;"0,0%")

Percentuálna hodnota, napríklad 28,5%

=TEXT(4,34 ;"#?/?")

Zlomok v tvare 4 1/3

=TRIM (TEXT(0,34;"#?/?"))

Zlomok v tvare 1/3 Všimnite si použitú funkciu TRIM, ktorá odstraňuje úvodnú medzeru pred desatinným číslom.

=TEXT(12200000;"0,00E+00")

Vedecký zápis, napríklad 1,22E+07

=TEXT(1234567898;"[<=9999999]###-####;(###) ###-####")

Špeciálne (telefónne číslo), napríklad (123) 456-7898

=TEXT(1234;"0000000")

Pridanie úvodných núl (0), napríklad 0001234

=TEXT(123456;"##0° 00' 00''")

Vlastné – zemepisná šírka a dĺžka

Poznámka : Síce na zmenu formátovania môžete použiť funkciu TEXT, existujú aj iné spôsoby. Formátovanie môžete zmeniť bez vzorca stlačením kombinácie klávesov CTRL + 1 (alebo Obrázok ikony tlačidla Command na Macu + 1 na Macu) a potom v dialógovom okne Formát buniek > Čísla vyberte požadovaný formát.

Stiahnite si naše príklady

Môžete si stiahnuť vzorový zošit s príkladmi všetkých použití funkcie TEXT, ktoré nájdete v tomto článku, a aj pár naviac. Môžete pracovať podľa nich alebo vytvoriť vlastné kódy formátu funkcie TEXT.

Stiahnuť príklady funkcie TEXT v Exceli

Ďalšie dostupné kódy formátu

Ak chcete nájsť ďalšie dostupné kódy formátu, môžete použiť dialógové okno Formát buniek:

  1. Stlačte kombináciu klávesov CTRL + 1 ( Obrázok ikony tlačidla Command na Macu + 1 na Macu) a otvorí sa dialógové okno Formát buniek.

  2. Na karte Číslo vyberte požadovaný formát.

  3. Vyberte možnosť Vlastné.

  4. Požadovaný kód formátu sa teraz zobrazuje v okne Typ. V tomto prípade vyberte v okne Typ všetko okrem bodkočiarky (;) a symbolu @. V nižšie uvedenom príklade sme vybrali a skopírovali len dd/mm/yy.

  5. Stlačte kombináciu klávesov CTRL + C a skopírujete kód formátu, potom stlačte tlačidlo Zrušiť a dialógové okno Formát buniek sa zavrie.

  6. Teraz stačí stlačiť kombináciu klávesov CTRL + V a prilepiť kód formátu do vzorca TEXT, napríklad takto =TEXT(B2;"dd/mm/yy"). Nezabudnite kód formátu prilepiť v anglických úvodzovkách ("kód formátu"), inak Excel vypíše chybové hlásenie.

Príklad použitia dialógového okna Formát > Bunky > Číslo > Vlastné na formátovanie reťazcov v Exceli.

Kódy formátov podľa kategórií

Nasleduje niekoľko príkladov, ako môžete použiť rôzne kódy formátu na svoje číselné hodnoty. Pomocou dialógového okna Formát buniek a výberom možnosti Vlastné skopírujte kódy formátu do svojej funkcie TEXT.

Prečo Excel odstránil moje úvodné nuly?

Excel je vytvorený tak, aby v bunkách hľadal čísla, nie čísla, ktoré vyzerajú ako text, ako napríklad výrobné čísla alebo skladové jednotky. Ak chcete zachovať úvodné nuly, naformátujte pred prilepením alebo zadaním hodnôt vstupný rozsah na text. Vyberte stĺpec alebo rozsah, do ktorého budete zadávať hodnoty, potom stlačte kombináciu klávesov CTRL + 1 a otvorí sa dialógové okno Formát buniek a na karte Číslo vyberte možnosť Text. Teraz Excel vaše úvodné nuly neodstráni.

Ak ste už zadali údaje a Excel úvodné nuly odstránil, môžete ich pomocou funkcie TEXT pridať späť. Na prvú bunku s hodnotami môžete vytvoriť odkaz a použiť funkciu =TEXT(hodnota;"00000"), pričom počet núl predstavuje celkový počet požadovaných znakov. Potom skopírujte a prilepte zvyšnú časť rozsahu.

Príklady použitia funkcie TEXT na formátovanie úvodných núl. =TEXT(A2;"00000")

Ak z nejakého dôvodu potrebujete konvertovať textové hodnoty späť na čísla, môžete ich buď vynásobiť číslom 1, napríklad =D4*1, alebo použite dvojitý unárny operátor (--) v takomto tvare =--D4.

V Exceli sa tisíce oddelia medzerou vtedy, ak formát obsahuje medzeru, ktorá je uzavretá medzi symboly čísiel (#) alebo nuly. Ak má napríklad reťazec tvar # ###, v Exceli sa číslo 12200000 zobrazí ako 12 200 000.

Medzera, ktorá nasleduje po zástupnom čísle, upraví tvar čísla na tisícky. Ak je reťazec formátu "# ###,0", Excel zobrazí číslo 12200000 ako 12 200,0.

Príklady funkcie TEXT používajúce oddeľovač tisícov

Poznámky : 

  • Oddeľovač tisícov závisí od vašich miestnych nastavení. Na Slovensku je to medzera, ale v iných krajinách to môže byť čiarka (,).

  • Oddeľovač tisícov je dostupný pre formáty čísla, meny a účtovníctva.

Nasledujú príklady štandardných formátov čísla (iba s oddeľovačmi tisícov a desatinných čísel), meny a účtovníctva. Formát meny vám umožní vkladať ľubovoľný symbol meny a zarovnať ho vedľa hodnoty. Na druhej strane účtovnícky formát zarovná symbol meny na ľavú stranu bunky a hodnotu na pravú stranu. Všimnite si rozdiel medzi kódmi formátov meny a účtovníctva uvedené nižšie. V účtovníckych formátoch sa na vytvorenie medzery medzi symbolom a hodnotou používa hviezdička (*).

Príklady funkcie TEXT s formátmi Číslo, Mena a Účtovnícke

Ak chcete nájsť kód formátu pre symbol meny, stlačte najskôr kombináciu klávesov CTRL + 1 (alebo Obrázok ikony tlačidla Command na Macu + 1 na Macu), vyberte požadovaný formát a potom z rozbaľovacej ponuky Symbol vyberte požadovaný symbol.

Výber symbolu meny v dialógovom okne Formát buniek

Potom kliknite na možnosť Vlastné v sekcii Kategória naľavo a skopírujte kód formátu, vrátane symbolu meny.

Funkcia TEXT – vlastná mena so symbolom

Poznámka : Funkcia TEXT nepodporuje farebné formátovanie, takže ak z dialógového okna Formát buniek skopírujete kód formátu čísla, ktorý zahŕňa aj farbu, ako napríklad # ##0,00_€);[Červená](# ##0,00 €), funkcia TEXT kód formátu prijme, ale farbu nezobrazí.

Môžete zmeniť spôsob zobrazovania dátumov, stačí použiť kombináciu písmen, kde M znamená mesiac, D dni a Y roky.

Kódy formátov Mesiac, Deň a Rok

Funkcia TEXT v kódoch formátu nerozlišuje veľké a malé písmená, takže môžete použiť M alebo m, D alebo d, či Y alebo y.

MVP pre Excel Mynda Treacy

Mynda odporúča...

Ak zdieľate excelové súbory a zostavy s používateľmi z rôznych krajín, môžno im budete chcieť poskytnúť zostavy v ich jazyku. Mynda Treacy (MVP pre Excel) má skvelé riešenie v tomto článku Excelové dátumy v rôznych jazykoch. Nachádza sa tu aj vzorový zošit, ktorý sa dá stiahnuť.

Môžete zmeniť spôsob, ako sa zobrazuje čas, stačí použiť kombináciu písmen, kde H znamená hodiny, M minúty a S sekundy. Ak používate dvanásťhodinový formát, môžete použiť aj AM a PM.

Formát času pre hodiny, minúty a sekundy

Ak údaj AM/PM alebo A/P vynecháte, čas sa zobrazí v dvadsaťštyrihodinovom formáte.

Funkcia TEXT v kódoch formátu nerozlišuje veľké a malé písmená, takže môžete použiť H alebo h, M alebo m, S alebo s, či AM/PM alebo am/pm.

Pomocou formátov percent (%) môžete upraviť spôsob zobrazovania desatinných hodnôt.

Kódy formátov pre možnosť Percentá

Pomocou formátov zlomkov (?/?) môžete upraviť spôsob zobrazovania desatinných hodnôt.

Kódy formátov pre možnosť Zlomky

Vedecký zápis je spôsob zobrazenia čísel v desatinnom tvare od 1 do 10, ktorý je vynásobený mocninou čísla 10. Často sa používa na skrátenie zobrazení vysokých čísel.

Kódy formátov pre vedecký zápis

Excel poskytuje 4 špeciálne formáty:

  • PSČ – "000 00"

  • PSČ (bez medzery) – "00000"

  • Telefónne číslo – "[<=9999999]###-####;(###) ###-####"

  • Telefónne číslo (dlhé) – "000 00 00 00"

Špeciálne formáty pre funkciu TEXT

Špeciálne formáty sa líšia v závislosti od miestnych nastavení, ale ak pre vaše miestne nastavenia neexistujú špeciálne formáty, alebo ak existujúce formáty nespĺňajú vaše potreby, môžete si vytvoriť vlastné. V dialógovom okne Formát buniek vyberte možnosť Vlastné.

Bežný scenár

Funkcia TEXT sa málokedy používa samostatne. Väčšinou sa používa v spojení s niečim ďalším. Povedzme, že chcete spojiť text a číselnú hodnotu, ako je napríklad Zostava vytlačená dňa: 14.03.2012 alebo Týždenné príjmy: 66 348,72 €. Údaje by ste mohli zadať do Excelu aj manuálne, ale Excel máte na to, aby to urobil za vás. Keď kombinujete text a formátované čísla, ako napríklad dátumy, časy, meny a pod., Excel nevie, ako ich chcete zobraziť, takže vymaže formátovanie čísla. V takýchto prípadoch je použitie funkcie TEXT neoceniteľné, pretože umožňuje Excelu formátovať hodnoty do akejkoľvek požadovanej podoby. Stačí použiť kód formátu, napríklad "dd/mm/yy" ak chcete formát dátumu.

V nasledujúcom príklade uvidíte, čo sa stane, ak sa pokúsite spojiť text a číslo bez použitia funkcie TEXT. V tomto prípade sme použili operátor (&) na zreťazenie textového reťazca, medzery a hodnoty s argumentmi =A2&” “&B2.

Príklad spojenia textu bez funkcie TEXT

Ako vidíte, Excel odstránil formátovanie z dátumu v bunke B2. V nasledujúcom príklade uvidíte, ako funkcia TEXT umožňuje používať požadovaný formát.

Príklad spojenia textu s funkciou TEXT

Náš aktualizovaný vzorec vyzerá takto:

  • Bunka C2:=A2&" "&TEXT(B2,"dd/mm/yy") – Formát dátumu

Najčastejšie otázky

Na toto vám nestačí funkcia TEXT. Musíte použiť kód programu Visual Basic for Applications (VBA). V tomto prepojení nájdete postup: Konverzia číselnej hodnoty na slová v Exceli

Áno, môžete použiť funkcie UPPER, LOWER a PROPER. Napríklad funkcia =UPPER("ahoj") vráti AHOJ.

Áno, musíte však vykonať niekoľko krokov. Najprv vyberte bunku alebo bunky, v ktorých chcete túto akciu vykonať, potom stlačte kombináciu klávesov CTRL + 1 a otvorí sa dialógové okno Formát buniek, prejdite na položky Zarovnanie > Nastavenie textu a začiarknite možnosť Zalomiť text. Potom na mieste, kde chcete text zalomiť, upravte vyplnenú funkciu TEXT tak, aby sa v nej nachádzala funkcia CHAR(10) znakov ASCII. V závislosti od výsledku konečného zarovnania bude možno treba upraviť šírku stĺpcov.

Príklad použitia funkcie TEXT s CHAR(10) na vloženie zlomku riadka. = "Dnes je:" &CHAR(10))&TEXT(TODAY();"MM/DD/RR")

V tomto prípade sme použili vzorec: =Dnes je: &CHAR(10)&TEXT(TODAY();"dd/mm/yy")

Táto podoba sa nazýva Vedecký zápis a Excel do nej automaticky konvertuje čísla dlhšie ako 12 znakov, ak je bunka vo formáte Všeobecné a dlhšie ako 15 znakov, ak je bunka vo formáte Číslo. Ak potrebujete zadať dlhý číselný reťazec, ale nechcete ho konvertovať, tak dané bunky formátujte ako Text ešte pred vložením alebo prilepením vašich hodnôt do Excelu.

MVP pre Excel Mynda Treacy

Mynda odporúča...

Ak zdieľate excelové súbory a zostavy s používateľmi z rôznych krajín, môžno im budete chcieť poskytnúť zostavy v ich jazyku. Mynda Treacy (MVP pre Excel) má skvelé riešenie v tomto článku Excelové dátumy v rôznych jazykoch. Nachádza sa tu aj vzorový zošit, ktorý sa dá stiahnuť.

Pozrite tiež

Vytvorenie alebo odstránenie vlastného číselného formátu

Konvertovanie textu na čísla

Všetky funkcie Excelu (podľa kategórie)

Rozšírte svoje zručnosti
Preskúmať školenie
Buďte medzi prvými, ktorí získajú nové funkcie
Pridajte sa k insiderom pre Office

Boli tieto informácie užitočné?

Ďakujeme za vaše pripomienky!

Ďakujeme vám za pripomienky. Pravdepodobne vám pomôže, ak vás spojíme s pracovníkom podpory pre Office.

×