SUM (funkcia)

Funkcia SUM, ktorá je jednou z matematických a trigonometrických funkcií, vykoná sčítanie hodnôt. Môžete spočítať jednotlivé hodnoty, odkazy na bunky alebo rozsahy, prípade kombináciu týchto troch položiek.

Príklad:

  • =SUM(A2:A10)

  • =SUM(A2:A10; C2:C10)

Nová úloha

Toto video je súčasťou školiaceho kurzu s názvom Sčítanie čísel v Exceli 2013.

SUM(číslo1;[číslo2];...)

Názov argumentu

Popis

číslo1    (povinné)

Prvé číslo, ktoré sa má sčítať. Číslo môže byť napríklad 4, odkaz na bunku B6 alebo bunka rozsah B2:B8.

číslo2-255    (voliteľné)

Toto je druhé číslo, ktoré sa má pripočítať. Takýmto spôsobom môžete zadať až 255 ďalších čísel.

Ak chcete rýchlo získať súčet rozsahu buniek, stačí len vybrať rozsah a pozrieť sa do pravej dolnej časti okna Excelu.

Snímka obrazovky znázorňujúca výber rozsahu buniek a potom Stavový riadok
Stavový riadok


Toto je stavový riadok, ktorý zobrazuje informácie týkajúce sa toho, čo ste vybrali, či už ide o jednu bunku alebo viacero buniek. Ak kliknete pravým tlačidlom myši na stavový riadok, zobrazí sa dialógové okno, v ktorom budú uvedené všetky možnosti, ktoré je možné vybrať. Všimnite si, že sa zobrazujú aj hodnoty pre vybratý rozsah, ak sú tieto atribúty začiarknuté. Ďalšie informácie o stavovom riadku.

Najjednoduchším spôsobom, ako do hárka pridať vzorec SUM, je použiť sprievodcu automatickým súčtom. Vyberte prázdnu bunku priamo nad alebo pod rozsahom, ktorý chcete sčítať, a na páse s nástrojmi na kartách Domov alebo Vzorce stlačte položky Automatický súčet > Suma. Sprievodca automatickým súčtom automaticky rozpozná rozsah, ktorý sa má sčítať, a vytvorí vzorec za vás. Dokáže tiež pracovať vo vodorovnom smere, ak vyberiete bunku naľavo alebo napravo od rozsahu, ktorý sa má sčítať. Sprievodca nebude fungovať pri nesúvislých rozsahoch. V ďalšej časti si však ukážeme postup aj pre takéto prípady.

Sprievodcu automatickým súčtom môžete použiť na automatické vytvorenie vzorca Sum.  Vyberte rozsah nad/pod alebo vpravo/vľavo od rozsahu, ktorý sa má spočítať, a prejdite na kartu Vzorec na páse s nástrojmi. Nakoniec vyberte položku Automatický súčet a SUM.
Použitie sprievodcu automatickým súčtom na rýchle sčítanie súvislých rozsahov


Dialógové okno Automatický súčet vám tiež umožňuje vybrať ďalšie bežné funkcie, ako napríklad:

Automatický súčet zvislo

Bunka B6 zobrazí vzorec Automatický súčet a Sum: =SUM(B2:B5)

Sprievodca automatickým súčtom automaticky zistil, že bunky B2:B5 tvoria rozsah, ktorý sa má sčítať. Stačí len stlačiť kláves Enter a potvrdiť to. Ak budete potrebovať pridať alebo vylúčiť viac buniek, môžete podržať stlačený kláves Shift > kláves so šípkou podľa vášho výberu, až kým výber nezodpovedá požadovanému stavu, a potom stlačte kláves Enter.

Sprievodca pre funkciu pomocou Intellisense: SUM(číslo1;[číslo2]; …) plávajúca značka pod funkciou predstavuje jej sprievodcu v Intellisense. Ak kliknete na SUM alebo na názov funkcie, zmení sa na modré hypertextové prepojenie, ktoré vás nasmeruje na tému pomocníka pre danú funkciu. Ak kliknete na jednotlivé prvky funkcie, ich reprezentatívne zložky vo vzorci sa zvýraznia. V tomto prípade budú zvýraznené iba bunky B2:B5, keďže v tomto vzorci existuje iba jeden číselný odkaz. Značka Intellisense sa zobrazí pre akúkoľvek funkciu.

Automatický súčet vodorovne

Bunka D2 zobrazí vzorec Automatický súčet a Sum: =SUM(B2:C2)

Použitie funkcie SUM s nesúvislými rozsahmi.  Vzorec bunky C8 je =SUM(C2:C3;C5:C6). Použiť môžete aj Pomenované rozsahy, takže vzorec bude =SUM(Týždeň1;Týždeň2).

Sprievodca automatickým súčtom vo všeobecnosti funguje len pre súvislé rozsahy, čiže ak máte vo svojom rozsahu prázdne riadky alebo stĺpce, Excel sa zastaví pri prvej medzere. V takomto prípade budete musieť použiť funkciu SUM pomocou výberu, kde jednotlivé rozsahy pridávate po jednom. V tomto príklade, ak by ste mali údaje v bunke B4, Excel by vytvoril =SUM(C2:C6) , keďže by to rozpoznal ako súvislý rozsah.

Pomocou klávesu Ctrl + kliknutia ľavým tlačidlom myši môžete rýchlo vybrať viaceré nesúvislé rozsahy. Najskôr zadajte výraz „=SUM (“, potom vyberte rôzne rozsahy a Excel za vás automaticky pridá medzi rozsahmi oddeľovač vo forme bodkočiarky. Po dokončení stlačte kláves Enter.

TIP: pomocou kombinácie klávesov ALT + = môžete rýchlo pridať funkciu SUM do bunky. Potom už stačí len vybrať požadovaný rozsah alebo rozsahy.

Poznámka: možno si všimnete, že Excel zvýraznil rôzne rozsahy funkcie pomocou farieb, ktoré zodpovedajú aj samotnému vzorcu, takže rozsah C2:C3 sa zobrazuje jednou farbou a C5:C6 druhou farbou. Excel to urobí pre všetky funkcie, pokiaľ odkazovaný rozsah nie je v inom hárku alebo v inom zošite. Ak chcete na lepšiu dostupnosť použiť pomocnú technológiu, môžete použiť Pomenované rozsahy, ako napríklad Týždeň1, Týždeň2 a podobne, a potom na ne odkazovať vo svojom vzorci:

=SUM(Týždeň1;Týždeň2)

Matematické operácie v Exceli môžete jednoducho použiť samostatne alebo v kombinácii s inými excelovými funkciami, ako napríklad SUM. V nasledujúcej tabuľke sú uvedené operátory, ktoré môžete použiť, spolu s niektorými súvisiacimi funkciami. Operátory môžete zadávať buď pomocou číselného riadka na klávesnici, alebo pomocou numerickej klávesnice. Kombináciou klávesov Shift + 8 napríklad zadáte hviezdičku (*) na násobenie.

Operátor

Operácia

Príklady

+

Sčítanie

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

Odčítanie

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

Násobenie

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1,1) – Funkcia PRODUCT

/

Delenie

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1,1) – Funkcia QUOTIENT

^

Umocňovanie

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1,1) – Funkcia POWER

Ďalšie informácie nájdete v téme Používanie programu Excel ako kalkulačky.

Ďalšie príklady

  1. Povedzme, že chcete použiť percentuálnu zľavu na rozsah buniek, ktoré ste sčítali.

    Používanie operátorov s funkciou SUM.  Vzorec v bunke = B16 je =SUM(A2:A14)*-25 %.  Vzorec by bol zostavený správne, ak by bola odkazom na bunku hodnota -25%, napríklad =SUM(A2:A14)*E2
    • =SUM(A2:A14)*-25%

    Tento vzorec by vrátil 25 % zo spočítaného rozsahu, no hodnotu 25 % by ste zadali napevno do vzorca, a v prípade, že ju neskôr budete potrebovať zmeniť, môže byť ťažké ju nájsť. Oveľa lepšie je namiesto toho vložiť hodnotu 25 % do bunky a urobiť na ňu odkaz. Takto ju budete môcť ľahko nájsť a zmeniť. Tu je príklad:

    • =SUM(A2:A14)*E2

    Ak chcete urobiť operáciu delenia namiesto násobenia, môžete jednoducho nahradiť znak "*" znakom "/": =SUM(A2:A14)/E2

  2. Pripočítanie alebo odpočítanie z funkcie SUM

    i. Z funkcie Sum môžete jednoducho vykonať operáciu pripočítania alebo odpočítania pomocou operátorov + alebo -. Tu je príklad:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

V tejto časti sa pozrieme na niektoré najvhodnejšie postupy pri práci s funkciou. Veľkú časť týchto informácií je možné použiť aj na prácu s inými funkciami.

Metóda =1+2 alebo =A+B – Hoci môžete zadať vzorec vo forme =1+2+3 alebo =A1+B1+C2 a dostanete úplne presné výsledky, tieto metódy sú z niekoľkých dôvodov náchylné na chyby:

  1. Preklepy – Predstavte si, že zadávate viac hodnôt alebo väčšie hodnoty. Napríklad:

    • =14598,93+65437,90+78496,23

    Potom sa pokúste overiť, či sú vaše položky správne. Oveľa jednoduchšie je umiestniť tieto hodnoty do jednotlivých buniek a použiť vzorec s funkciou SUM. Okrem toho, keď sú hodnoty v bunkách, môžete ich formátovať, vďaka čomu sú lepšie čitateľné, ako keď sú vo vzorci.

    Vo vzorci použite namiesto pevného kódovania funkciu SUM.  Vzorec v bunke D5 je =SUM(D2:D4)
  2. Chyby typu #HODNOTA! pri odkazovaní na text namiesto na čísla

    Ak používate napríklad takýto vzorec:

    • =A1+B1+C1 alebo =A1+A2+A3

    Príklad slabej štruktúry vzorca.  Vzorec v bunke D2 je =A2+B2+C2

    Vzorec môže zlyhať, ak sa v odkazovaných bunkách nachádzajú ľubovoľné nečíselné (textové) hodnoty, ktoré vrátia chybu typu #HODNOTA! Funkcia SUM bude ignorovať textové hodnoty a vráti iba súčet číselných hodnôt.

    Správna štruktúra vzorca.  Namiesto =A2+B2+C2 bude vzorec bunky D2 =SUM(A2:C2)
  3. Chyba typu #ODKAZ!, ktorá vznikne odstránením riadkov alebo stĺpcov

    Chyba #REF! spôsobená odstránením stĺpca.  Vzorec sa zmenil na =A2+#REF!+B2

    Ak odstránite riadok alebo stĺpec, vzorec sa nebude aktualizovať, aby vynechal odstránený riadok a vráti chybu #ODKAZ! V tomto bode sa funkcia SUM automaticky aktualizuje.

    Funkcia SUM sa automaticky prispôsobí vloženým alebo odstráneným riadkom a stĺpcom
  4. Pri vložení riadkov alebo stĺpcov sa vo vzorcoch neaktualizujú odkazy

    Vzorce =A+B+C sa po pridaní riadkov neaktualizujú

    Ak vložíte riadok alebo stĺpec, vzorec sa nebude aktualizovať, aby zahŕňal pridaný riadok. V tomto bode sa funkcia SUM automaticky aktualizuje (pokiaľ nie ste mimo rozsahu, ktoré sa odkazuje vo vzorci). Toto je obzvlášť dôležité, ak očakávate, že sa vzorec aktualizuje, ale v skutočnosti sa neaktualizuje, pretože získate neúplné výsledky, ktoré sa vám nemusí podariť zachytiť.

    Príklad zobrazuje vzorec SUM, ktorý sa po vložení stĺpca automaticky rozbalí z pozície =SUM(A2:C2) do pozície =SUM(A2:D2)
  5. Funkcia SUM s odkazmi na jednotlivé bunky vs. rozsahy

    Použitie takéhoto vzorca:

    • =SUM(A1;A2;A3;B1;B2;B3)

    je z tých istých dôvodov rovnako náchylné na chyby pri vkladaní alebo odstraňovaní riadkov vrámci odkazovaného rozsahu. Oveľa lepšie je používať jednotlivé rozsahy, ako napríklad:

    • =SUM(A1:A3;B1:B3)

    Takýto vzorec sa pri pridaní alebo odstránení riadkov aktualizuje.

  1. Funkciu SUM môžete jednoznačne použiť s inými funkciami. Tu je príklad, ktorý vytvorí výpočet mesačného priemeru:

    Použitie funkcie SUM s inými funkciami.  Vzorec v bunke M2 je =SUM(A2:L2)/COUNTA(A2:L2) .  Poznámka: stĺpce Máj-November sú pre zrozumiteľnosť skryté.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. Tento vzorec prevezme súčet z rozsahu A2:L2 a vydelí ho počtom neprázdnych buniek v rozsahu A2:L2 (máj až december sú prázdne).

  1. Niekedy potrebujete sčítať konkrétnu bunku vo viacerých hárkoch. Asi vás bude zvádzať, aby ste klikli na každý hárok a požadovanú bunku a jednoducho použili znak + na pridanie hodnoty bunky, no to je zdĺhavé a môže pri tom dochádzať k chybám.

    • =Hárok1!A1+Hárok2!A1+Hárok3!A1

    Môžete to urobiť oveľa jednoduchšie pomocou 3D alebo trojrozmernej funkcie SUM:

    3D Sum – Vzorec v bunke D2 je =SUM(Hárok1:Hárok3!A2)
    • =SUM(Hárok1:Hárok3!A1)

    Tento vzorec sčíta bunky A1 vo všetkých hárkoch od Hárka 1 po Hárok 3.

    Toto je užitočné najmä v prípadoch, keď máte jeden hárok na každý mesiac (január až december) a potrebujete urobiť súčet v súhrnnom hárku.

    3d SUM v Pomenovaných hárkoch.  Vzorec v bunke D2 je =SUM(Január:December!A2)
    • =SUM(január:december!A2)

    Tento vzorec sčíta bunky A2 vo všetkých hárkoch za mesiace január až december.

    Poznámky : Ak sú v názvoch hárkov medzery, napríklad Predaj za január, potom pri odkazovaní na názvy hárkov vo vzorci musíte použiť apostrof. Všimnite si apostrof PRED názvom prvého hárka a ZA názvom posledného.

    • =SUM(‘Predaj za január:Predaj za december’!A2)

    Metóda 3D funguje aj s ďalšími funkciami, napríklad AVERAGE, MIN, MAX atď.:

    • =AVERAGE(Hárok1:Hárok3!A1)

    • =MIN(Hárok1:Hárok3!A1)

    • =MAX(Hárok1:Hárok3!A1)

Problém

Kde sa stala chyba

Funkcia SUM zobrazuje namiesto výsledku #####.

Skontrolujte šírku stĺpcov. ##### vo všeobecnosti znamená, že stĺpec je príliš úzky na zobrazenie výsledku vzorca.

Funkcia SUM zobrazuje samotný vzorec ako text, nie výsledok.

Skontrolujte, či bunka nie je formátovaná ako text. Vyberte požadovanú bunku alebo rozsah a stlačením kombinácie klávesov Ctrl + 1 otvorte dialógové okno Formát buniek. Potom kliknite na kartu Číslo a vyberte požadovaný formát. Ak bola bunka formátovaná ako text a po zmene formátu sa nezmení, možno bude potrebné na vynútenie zmeny formátu použiť klávesy F2 > Enter.

Funkcia SUM nevykonáva aktualizáciu.

Skontrolujte, či je ponuka Výpočet nastavená na možnosť Automaticky. Na karte Vzorce prejdite na položku Možnosti výpočtov. Na vynútenie výpočtu v hárku tiež môžete použiť kláves F9.

Skontrolujte, či je výpočet nastavený na Automaticky.  Na karte Vzorce prejdite na položku Možnosti výpočtov.

Niektoré hodnoty sa nesčítajú.

Započítavajú sa len číselné hodnoty v odkaze funkcie na bunku alebo v rozsahu buniek. Prázdne bunky, logické hodnoty ako TRUE alebo text sa ignorujú.

Namiesto očakávaného výsledku sa zobrazí chyba #NÁZOV?

Toto zvyčajne znamená, že vzorec je nesprávne napísaný, napríklad =suma(A1:A10) namiesto =SUM(A1:A10).

Moja funkcia SUM zobrazuje celé číslo, ale mala by zobrazovať desatinné číslo.

Skontrolujte formátovanie buniek, či zobrazujú desatinné miesta. Vyberte požadovanú bunku alebo rozsah a stlačením kombinácie klávesov Ctrl + 1 otvorte dialógové okno Formát buniek. Potom kliknite na kartu Číslo a vyberte požadovaný formát. Nezabudnite nastaviť potrebný počet desatinných miest.

  1. Potrebujem len sčítať/odčítať/násobiť/deliť čísla Pozrite si sériu videí v téme Základné matematické operácie v Exceli alebo Používanie programu Excel ako kalkulačky.

  2. Ako môžem zobraziť viac alebo menej desatinných miest? Zmenou formátu čísla. Vyberte požadovanú bunku alebo rozsah a stlačením kombinácie klávesov Ctrl + 1 otvorte dialógové okno Formát buniek. Potom kliknite na kartu Číslo a vyberte požadovaný formát. Nezabudnite nastaviť potrebný počet desatinných miest.

  3. Ako sčítam alebo odčítam časové údaje? Časové údaje môžete sčítať alebo odčítať viacerými spôsobmi. Ak napríklad potrebujete získať rozdiel medzi časmi 8:00 a 12:00 na účely výpočtu mzdy, použijete vzorec: =("12:00"-"8:00")*24, ktorým sa od času ukončenia odpočíta čas začatia. Excel počíta časy ako zlomky dňa, celkový počet hodín preto získate po vynásobení hodnotou 24. V prvom príklade používame vzorec =((B2-A2)+(D2-C2))*24 na výpočet celkového počtu hodín od začiatku do konca, pričom neberieme do úvahy prestávku na obed (spolu 8,50 hodiny).

    Ak jednoducho sčítavate hodiny a minúty a chcete ich týmto spôsobom aj zobraziť, môžete ich spočítať bez toho, aby ste ich následne vynásobili číslom 24. V druhom príklade teda používame vzorec =SUM(A6:C6), keďže nám stačí poznať celkový počet hodín a minút pre priradené úlohy (5:36, teda 5 hodín a 36 minút).

    Výpočet časov

    Ďalšie informácie nájdete v téme: Pripočítanie alebo odpočítanie času

  4. Ako vypočítam rozdiel medzi dátumami? Dátumy môžete sčítať a odčítať rovnako ako časy. Tu je príklad, ako sa zvyčajne ráta počet dní medzi dvomi dátumami. Je to veľmi jednoduché: stačí zadať vzorec =B2-A2. Pri práci s dátumami a časmi platí, že od dátumu/času ukončenia treba odčítať dátum/čas začatia.

    Výpočet rozdielu medzi dátumami

    Ďalšie spôsoby práce s dátumami nájdete v téme: Výpočet počtu dní medzi dvoma dátumami.

  5. Ako sčítam len viditeľné bunky? Niekedy, keď manuálne skryjete riadky alebo použijete funkciu Automatický filter, aby sa zobrazovali len konkrétne údaje, môžete potrebovať sčítať len viditeľné bunky. Môžete použiť funkciu SUBTOTAL. Ak v excelovej tabuľke používate riadok súčtu, všetky funkcie, ktoré vyberiete z rozbaľovacieho zoznamu súčtu, sa automaticky vložia ako medzisúčet. Ďalšie informácie nájdete v téme Súčet údajov v tabuľke programu Excel.

Potrebujete ďalšiu pomoc?

Vždy sa môžete opýtať odborníka v komunite technikov pre Excel, získať podporu v rámci komunity lokality Answers alebo navrhnúť novú funkciu či vylepšenie na lokalite Excel User Voice.

Pozrite tiež

Pozrite si video po používaní funkcie SUM

Funkcia SUMIF sčíta iba hodnoty, ktoré spĺňajú jedno kritérium

Funkcia SUMIFS sčíta iba hodnoty, ktoré spĺňajú viaceré kritériá

Funkcia COUNTIF sčíta iba hodnoty, ktoré spĺňajú jedno kritérium

Funkcia COUNTIFS sčíta iba hodnoty, ktoré spĺňajú viaceré kritériá

Prehľad vzorcov v Exceli

Zabránenie vzniku nefunkčných vzorcov

vyhľadanie a oprava chýb vo vzorcoch

Klávesové skratky v Exceli pre Windows

Exceli pre Mac

Matematické a trigonometrické funkcie

Zoznam funkcií Excelu (podľa abecedy)

Zoznam funkcií Excelu (podľa kategórie)

Pridávanie vzorcov a funkcií (bezplatná ukážka)

Rozšírte svoje zručnosti
Preskúmať školenie
Buďte medzi prvými, ktorí získajú nové funkcie
Pridajte sa k insiderom pre Office

Boli tieto informácie užitočné?

Ďakujeme za vaše pripomienky!

Ďakujeme vám za pripomienky. Pravdepodobne vám pomôže, ak vás spojíme s pracovníkom podpory pre Office.

×